LlLinksetDataDelete/ja

/ja

/LSL

LinksetDataDelete

llLinksetDataDelete

Summary

Summary: llLinksetDataDelete, llLinksetDataDeleteProtected

関数llLinksetDataDeleteおよびllLinksetDataDeleteProtectedは、リンクセットのデータストアからname:valueペアを削除します。

この関数がname:valueペアを正常に削除すると、リンクセット内で実行されているすべてのスクリプトにlinkset_dataイベントが発生し、アクションがLINKSETDATA_DELETEで、nameパラメータが削除されたnameに設定されます。イベントのvalueパラメータは空の文字列に設定されます。

llLinksetDataDelete

llLinksetDataDelete

Function: integer llLinksetDataDelete( string name );

?	Function ID
0	Forced Delay
10.0	Energy

リンクセットのデータストアから保護されていないname:valueペアを削除します。もしペアが作成された場合は
Returns an integer 成功または失敗のコード。

• string

name

–

削除するリンクセットのname:valueペアのキー。

All Issues ~ Search JIRA for related Bugs

llLinksetDataDeleteProtected

Function: integer llLinksetDataDeleteProtected( string name, string pass );

?	Function ID
0.0	Forced Delay
10.0	Energy

関数llLinksetDataDeleteProtectedは、リンクセットのデータストアから保護されたname:valueペアを削除します。
Returns an integer 成功または失敗のコード。

• string	name	–	削除するリンクセットのname:valueペアのキー。
• string	pass	–	以前にname:valueペアを保護するために使用されたパスフレーズ。

All Issues ~ Search JIRA for related Bugs

定数	名前	説明
LINKSETDATA_OK	0	name:value ペアがデータストアに書き込まれました。
LINKSETDATA_EMEMORY	1	name:value ペアがリンクセットのデータストアに書き込むのに大きすぎました。
LINKSETDATA_ENOKEY	2	llLinksetDataWrite に提供された名前が空でした。
LINKSETDATA_EPROTECTED	3	name:value ペアはリンクセットのデータストアで上書きから保護されています。
LINKSETDATA_NOTFOUND	4	指定されたキーがリンクセットのデータストアで見つかりませんでした。削除を試行する際にキーが見つからない場合に返ります。
LINKSETDATA_NOUPDATE	5	書き込まれた値がリンクセットに格納された値と一致するため、書き込み操作によって格納された name:value が変更されませんでした。

Caveats

• もしnameが存在しないか、passが一致しない場合、イベントはトリガーされません。

All Issues ~ Search JIRA for related Bugs

Examples

// Simple blacklist management.

integer gDialogChannel;
integer gDialogHandle;
integer gManagingBlocks;

startDialog(key person)
{
    gManagingBlocks = 0;
    gDialogHandle = llListen(gDialogChannel, "", person, "");
    llDialog(person, "\nSelect action", ["List blocks", "Add block", "Remove block"], gDialogChannel);
    llSetTimerEvent(60);
}

stopDialog()
{
    llSetTimerEvent(0);
    llListenRemove(gDialogHandle);
}

default
{

    on_rez(integer sp)
    {
        llResetScript();
    }

    state_entry()
    {
        gDialogChannel = (integer)(llFrand(-10000000)-10000000);
        llListen(PUBLIC_CHANNEL, "", NULL_KEY, "");;
    }

    timer()
    {
        stopDialog();
    }

    touch_start(integer nd)
    {
        key toucherKey = llDetectedKey(0);
        if (toucherKey == llGetOwner())
        {
            startDialog(toucherKey);
        }
    }

    listen(integer channel, string name, key id, string message)
    {

        if (llGetAgentSize(id) == ZERO_VECTOR)
        {
            return;
        }

        if (channel == gDialogChannel)
        {
            stopDialog();
            if (gManagingBlocks)
            {
                message = llStringTrim(message, STRING_TRIM);
                if ((key)message)
                {
                    if (gManagingBlocks == 1)
                    {
                        llOwnerSay("Addition request has been sent to the blacklist storage");
                        llLinksetDataWrite("blocklist:" + message, "1");
                    }
                    else
                    {
                        llOwnerSay("Removal request has been sent to the blacklist storage.");
                        llLinksetDataDelete("blocklist:" + message);
                    }
                }
                else
                {
                    llOwnerSay("The UUID '" + message + "' appears to be invalid.");
                }
                startDialog(id);
            }
            else if (message == "List blocks")
            {
                list blocks = llLinksetDataFindKeys("^blocklist:", 0, 0);
                integer listLength = llGetListLength(blocks);
                llOwnerSay("Blacklist items: " + (string)listLength);
                integer i;
                while (i < listLength)
                {
                    string record = llGetSubString(llList2String(blocks, i), 10, -1);
                    llOwnerSay("- secondlife:///app/agent/" + record + "/about" + " - " + record);
                    ++i;
                }
                blocks = [];
                startDialog(id);
            }
            else if (message == "Add block" || message == "Remove block")
            {
                string label = "add to";
                gManagingBlocks = 1;
                if (message == "Remove block")
                {
                    gManagingBlocks = 2;
                    label = "remove from";
                }
                gDialogHandle = llListen(gDialogChannel, "", id, "");
                llTextBox(id, "\nPlease specify one single avatar UUID you'd like to " + label + " the blacklist storage.", gDialogChannel);
                llSetTimerEvent(60);
            }
            return;
        }

        if (llGetListLength(llLinksetDataFindKeys("blocklist:" + (string)id, 0, 1)) > 0)
        {
            llRegionSayTo(id, 0, "You're blacklisted.");
            return;
        }

        llRegionSayTo(id, 0, "Hello there, secondlife:///app/agent/" + (string)id + "/about - your message: " + message);

    }

    linkset_data(integer action, string name, string value)
    {
        if (action == LINKSETDATA_RESET || action == LINKSETDATA_DELETE || action == LINKSETDATA_UPDATE)
        {
            llOwnerSay("Blacklist storage modified.");
        }
    }

}

See Also

Events

•

linkset_data

Functions

•	llLinksetDataAvailable
•	llLinksetDataCountKeys
•	llLinksetDataFindKeys
•	llLinksetDataListKeys
•	llLinksetDataRead
•	llLinksetDataReadProtected
•	llLinksetDataReset
•	llLinksetDataWrite
•	llLinksetDataWriteProtected

Deep Notes

Search JIRA for related Issues

Signature
function integer llLinksetDataDelete( string name ); function integer llLinksetDataDeleteProtected( string name, string pass );