LlListen

Template:Needs Translation/LSL/es Template:Needs Translation/LSL/el Template:Needs Translation/LSL/he Template:Needs Translation/LSL/it Template:Needs Translation/LSL/ko Template:Needs Translation/LSL/nl Template:Needs Translation/LSL/hu Template:Needs Translation/LSL/no Template:Needs Translation/LSL/da Template:Needs Translation/LSL/sv Template:Needs Translation/LSL/tr Template:Needs Translation/LSL/pl Template:Needs Translation/LSL/pt Template:Needs Translation/LSL/ru Template:Needs Translation/LSL/th Template:Needs Translation/LSL/uk Template:Needs Translation/LSL/zh-Hans Template:Needs Translation/LSL/zh-Hant

/LSL

Listen

llListen

Summary

Function: integer llListen( integer channel, string name, key id, string msg );

25	Function ID
0.0	Forced Delay
10.0	Energy

Sets a callback for msg on channel from name and id.
Returns an integer that can be used to deactivate or remove the listen.

• integer	channel	–	any valid integer, positive or negative.
• string	name
• key	id
• string	msg

If msg, name or id are blank they are not used to filter incoming messages. If id is an invalid key or a null key, it is considered blank.

Specification

For the listen event to be triggered it must first match the criteria set forth by the filters; only when all the criteria have been met is a listen event generated. First the message must have been transmitted on channel channel. If name is set then the speaker's name must match name exactly. If id is a valid, non-null key then the speaker's key must be equivalent. If msg is set then the spoken message must match msg exactly.

Channel Constant		Description
DEBUG_CHANNEL	0x7FFFFFFF	Chat channel reserved for script debugging and error messages, broadcasts to all nearby users.
PUBLIC_CHANNEL	0x0	Chat channel that broadcasts to all nearby users. This channel is sometimes referred to as: open chat, local chat and public chat.

Caveats

• On state change or script reset all listens are removed automatically.
  • A state change can be used as a shortcut to releasing listens.
• Only 64 listens can simultaneously be open in any single script.
  • If this number is exceeded an error is shouted.
• Avoid channel 0 and set name or id where possible to avoid lag. (Lag)
  • llListen(0,"","","") is extremely laggy as it listens to all chat from everyone in chat range and should be avoided at all cost.
• Negative channel numbers can only be used for inter-object communication (and are preferable in that case).
  • This may just be an artificial limitation placed on the client and not the underlying protocol.

All Issues ~ Search JIRA for related Bugs

Examples

Trivial example to listen to any chat from the object owner and respond once. To reduce lag and avoid spamming surrounding users, it is vastly preferable to listen on channels other than 0 and to trigger the listen event by chatting on an alternative channel such as '/5 hello'.

// says beep to owner the first time owner says something in main chat;
integer listen_handle;

default
{
    state_entry()
    {   //Registers the listen to the owner of the object at the moment of the call.
        // This does not automatically update when the owner changes.
        // Change 0 to another positive number to listen for '/5 hello' style of chat.
        listen_handle = llListen(0, "", llGetOwner(), "");
    }
    listen( integer channel, string name, key id, string message )
    {
        llOwnerSay("beep");
        // Stop listening until script is reset
        llListenRemove(listen_handle);
    }
    on_rez(integer param)
    {   //Triggered when the object is rezed, like after the object had been sold from a vendor
        llResetScript();//By resetting the script on rez it forces the listen to re-register.
    }
    changed(integer mask)
    {   //Triggered when the object containing this script changes owner.
        if(mask & CHANGED_OWNER)
        {
            llResetScript();
        }
    }
}

See Also

Events

•

listen

Functions

•	llListenRemove	–	Removes a listen
•	llListenControl	–	Enables/Disables a listen
•	llWhisper	–	Sends chat limited to 10 meters
•	llSay	–	Sends chat limited to 20 meters
•	llShout	–	Sends chat limited to 100 meters
•	llRegionSay	–	Sends chat limited current sim

Deep Notes

Search JIRA for related Issues

Signature
function integer llListen( integer channel, string name, key id, string msg );