# Difference between revisions of "LlSameGroup"

 LSL Portal

## Contents

Function: integer llSameGroup( key uuid );
 219 Function ID 0 Forced Delay 10 Energy

Returns a boolean (an integer) that is TRUE if uuid and the prim the script is in are of the same group, otherwise FALSE.

 • key uuid – group, avatar or prim UUID that is in the same region

This function compares the group-uuid of the prim containing the script to that of the group-uuid of what uuid describes. It answers these two questions:

• "Is the script's prim in the same group as uuid?"
• "Is the group-uuid of the script's prim equal to uuid?"

## Specification

The group of the prim the script is in is...

• The group the prim is set-to
• The group the prim is deeded-to
• The group the prim is otherwise owned by
• If no group information is set, the group-uuid used for this is NULL_KEY.

The group of the uuid is...

• If uuid is a prim (known to the region)...
• and it is an attachment, the active group of the owner*
• The group the prim is set-to
• The group the prim is deeded-to
• The group the prim is otherwise owned by
• If no group information is set, the group-uuid used for this is NULL_KEY.
• If uuid is an avatar (known to the region)...
• The active group of the avatar.
• If no group information is set, the group-uuid used for this is NULL_KEY.
• Otherwise, treat uuid AS the group-uuid.
• This means that instead of doing "Is the script's prim in the same group as uuid?", it becomes "Is the group-uuid of the script's prim equal to uuid?"

Note: No group, prim, or avatar share the same uuid.

In pseudocode:

```integer llSameGroup(key uuid){
key group = getGroupKey(llGetKey());
if(uuid == group)
return TRUE;
if(getGroupKey(uuid) == group)
return TRUE;
return FALSE;
}```

## Caveats

• Not so obvious is that it returns TRUE if the object is not set to a group (i.e. "(none)") and either the AV with the given key has no group active or the function is called with a NULL_KEY.

#### Important Issues

 VWR-5044 Attachments only change/inherit the active group when they're "rezzed"

## Examples

```// Gives inventory object only to agents with the same active group

default
{
touch_start(integer total_number)
{
key id = llDetectedKey(0);

integer sameGroup = llSameGroup(id);
//      same as llDetectedGroup(i) (with llDetectedGroup, detected does not need to be in the sim)

if (sameGroup)
{
integer numberOfObjectsInPrim = llGetInventoryNumber(INVENTORY_OBJECT);

if (numberOfObjectsInPrim)
llGiveInventory(id, llGetInventoryName(INVENTORY_OBJECT, 0));
}
else
{
llRegionSayTo(id, 0, "Wrong active group!");
}
}
}```

## Useful Snippets

To determine if an avatar is an object's owner when deeded to group, you should use a function similar to that provided for llGetOwner().

The following uses llSameGroup() to determine if a parcel is rezzable based on the object's active group and parcel details. Useful for preventing unnecessary rez failure notices from various types of attached objects (e.g. guns, water/skywalk HUDs, etc).

```/*
By Aryn Gellner
pos - position (in region coordinates) to check against.
*/
/*
*/

integer is_rezzable(vector pos)
{
list details = llGetParcelDetails(pos, [PARCEL_DETAILS_GROUP, PARCEL_DETAILS_OWNER]);
key group_id = llList2Key(details, 0);
key owner_id = llList2Key(details, 1);

integer parcel_flags = llGetParcelFlags(pos);
if(owner_id != llGetOwner())
{
if(parcel_flags & PARCEL_FLAG_ALLOW_CREATE_OBJECTS)
{
return TRUE;
}
else if((parcel_flags & PARCEL_FLAG_ALLOW_CREATE_GROUP_OBJECTS) && llSameGroup(group_id))
{
return TRUE;
}
else
{
return FALSE;
}
}
else{return TRUE;}
}```

## Notes

#### Child Prims

It is possible for the group of a child prim to differ from that of the root prim. To build such an object it must first be unlinked, the groups set, and then relinked. Rezzing an objects resets the group of the object to that of the group that the user currently has activated. Changing the group of an object changes the group for the entire object. This may only be an artifact or manifestation of VWR-5044.

### Functions

 • llDetectedGroup – Used in conjunction with detection events • llGetAttachedList – Together with llGetObjectDetails and OBJECT_GROUP, it can be used to determine the active group of an avatar that is wearing at least one non-HUD attachment.

## Deep Notes

#### All Issues

 VWR-5044 Attachments only change/inherit the active group when they're "rezzed"

### Tests

 • llSameGroup Test

#### Signature

```function integer llSameGroup( key uuid );
```

#### Haiku

Do you belong or
Are you alien, unknown
To us, unwanted?