LlSetContentType

From Second Life Wiki
Revision as of 20:39, 2 August 2013 by Strife Onizuka (Talk | contribs)

Jump to: navigation, search

Summary

Function: llSetContentType( key request_id, integer content_type );

Set the Internet media type of an LSL HTTP server response.[1]

• key request_id a valid http_request() key
• integer content_type Media type to use with any following llHTTPResponse(request_id, ...)
content_type Content-Type
CONTENT_TYPE_TEXT 0 text/plain
CONTENT_TYPE_HTML 1 text/html
CONTENT_TYPE_XML 2 application/xml
CONTENT_TYPE_XHTML 3 application/xhtml+xml
CONTENT_TYPE_ATOM 4 application/atom+xml
CONTENT_TYPE_JSON 5 application/json
CONTENT_TYPE_LLSD 6 application/llsd+xml
CONTENT_TYPE_FORM 7 application/x-www-form-urlencoded
CONTENT_TYPE_RSS 8 application/rss+xml

Caveats

  • When using CONTENT_TYPE_HTML, this setting will be ignored unless all of these conditions are met:
    1. the web browser is the Second Life client
    2. the user (logged into the SL client viewing the page) is the owner of the object.
    3. the user (logged into the SL client viewing the page) is connected to the region the object is located in
    Obviously this is not compatible with group owned objects.
All Issues ~ Search JIRA for related Bugs

Examples

<lsl> key url_request;

string HTML_BODY = "<!DOCTYPE html> <html> <body>

My First Heading

My first paragraph.

</body> </html>";

default {

   state_entry()
   {
       url_request = llRequestURL();
   }
   http_request(key id, string method, string body)
   {
       key owner = llGetOwner();
       vector ownerSize = llGetAgentSize(owner);
       if (url_request == id)
       {
       //  if you're usually not resetting the query ID
       //  now is a good time to start!
           url_request = "";
           if (method == URL_REQUEST_GRANTED)
           {
               llOwnerSay("URL: " + body);
           //  if owner in sim
               if (ownerSize)//  != ZERO_VECTOR
                   llLoadURL(owner, "I got a new URL!", body);
           }
           else if (method == URL_REQUEST_DENIED)
               llOwnerSay("Something went wrong, no url:\n" + body);
       }
       else
       {
           llOwnerSay("request body:\n" + body);
       //  if owner in sim
           if (ownerSize)//  != ZERO_VECTOR
           {
               llSetContentType(id, CONTENT_TYPE_HTML);
               llHTTPResponse(id, 200, HTML_BODY);
           }
           else
           {
               llSetContentType(id, CONTENT_TYPE_TEXT);
               llHTTPResponse(id, 200, "OK");
           }
       }
   }

}

</lsl>

Notes

  • A workaround for displaying html to non-owners inworld can be found here.

See Also

Events

•  http_request

Functions

•  llHTTPResponse

Articles

•  LSL HTTP server

Deep Notes

History

  • Released August 16, 2011.
  • SCR-394 - Documentation revised but no change in functionality.
Search JIRA for related Issues

Footnotes

  1. ^ This function sets the "Content-Type" header in any subsequent llHTTPResponse responses.

Signature

function void llSetContentType( key request_id, integer content_type );
integer CONTENT_TYPE_TEXT = 0;//text/plain
integer CONTENT_TYPE_HTML = 1;//text/html
integer CONTENT_TYPE_XML = 2;//application/xml
integer CONTENT_TYPE_XHTML = 3;//application/xhtml+xml
integer CONTENT_TYPE_ATOM = 4;//application/atom+xml
integer CONTENT_TYPE_JSON = 5;//application/json
integer CONTENT_TYPE_LLSD = 6;//application/llsd+xml
integer CONTENT_TYPE_FORM = 7;//application/x-www-form-urlencoded
integer CONTENT_TYPE_RSS = 8;//application/rss+xml

Comments

The client and owner limitations are most likely to remove the possibility of running a website from a prim.