llSetText
| LSL Portal | Functions | Events | Types | Operators | Constants | Flow Control | Script Library | Categorized Library | Tutorials |
Summary
Function: llSetText( string text, vector color, float alpha );| 152 | Function ID |
| 0.0 | Forced Delay |
| 10.0 | Energy |
Displays text that hovers over the prim with specific color and translucency (specified with alpha).
| • string | text | – | floating text to display | |
| • vector | color | – | color in RGB <R, G, B> (<0.0, 0.0, 0.0> = black, <1.0, 1.0, 1.0> = white) | |
| • float | alpha | – | from 0.0 (clear) to 1.0 (solid) (0.0 <= alpha <= 1.0) |
Caveats
- Do not rely on Floating Text as a storage medium; it is neither secure nor finalized.
- Floating text has been altered in past server updates, breaking existing content; future changes may occur.
- Even "invisible"[1] floating text is transmitted to the client.
- It can be viewed by anyone with a client that is capable of rendering text that is supposed to be invisible.
- The network packets that contain the text can be sniffed and the text read.
- If more than one llSetText is called (By reset,interaction or script state) within a prim the latest call will take priority over the previous.
- text is limited to 254 bytes, if the string is longer it will be truncated to 254 bytes, even if that means the truncation will chop a character in half.
- An unbroken line of text of a great length may be broken automatically into two lines (one above the other).
- Floating text can be seen through walls and other object. Be considerate of neighbors in malls and apartment buildings.
- Visibility distance increases with prim size.
- Removing the script or deactivating it will not remove the prim's floating text.
- Floating text is a prim property and not dependent on a script for its continued existence.
- To remove floating text, use the following:
<lsl>llSetText("", <1.0, 1.0, 1.0>, 1.0);</lsl>
- Shift-copying does not keep the floating text prim property. If the llSetText() script is not triggered when a copy made, the copy will not have the floating text.
- Vertical whitespace is removed from the end of the text string, so if you want vertical whitespace put any character (like a space) on the last line.
- Multiple linebreaks with empty lines are converted to a single linebreak, so add a whitespace character on every line you want to skip:
<lsl>llSetText("Monkeys\n\n\n\n\n", <1.0, 1.0, 1.0>, 1.0);//Bad llSetText("Monkeys\n \n \n \n \n ", <1.0, 1.0, 1.0>, 1.0);//Good</lsl>
Examples
Example of how llSetText could be included in default code to show object's name in green text: <lsl>default {
state_entry()
{
llSay(0, "Hello, Avatar!");
llSetText(llGetObjectName(), <0.0, 1.0, 0.0>, 1.0); // Display the object's current name in green
}
touch_start(integer total_number)
{
llSay(0, "Touched.");
}
}</lsl> By default the floating text will appear on a single line. However, the floating text can be spread over multiple lines by using a line break "\n" (read SplitLine in section 'See Also').
Color & Alpha
| Color | Code |
|---|---|
| White | <1.0, 1.0, 1.0> |
| Grey | <0.5, 0.5, 0.5> |
| Black | <0.0, 0.0, 0.0> |
| Red | <1.0, 0.0, 0.0> |
| Green | <0.0, 1.0, 0.0> |
| Blue | <0.0, 0.0, 1.0> |
The x, y & z components of the vector are used to represent red, green, and blue respectively. The range is different than traditional RGB, instead of being 0 -> 255, LSL uses 0 -> 1. <1.0, 1.0, 1.0>, means "white" and <0.0, 0.0, 0.0> means "black": <lsl>llSetText("I am white", <1.0, 1.0, 1.0>, 1.0);//white text</lsl> <lsl>llSetText("I am black", <0.0, 0.0, 0.0>, 1.0);//black text</lsl> The 1.0 is the alpha setting. 1.0 means fully opaque, and 0.0 would be completely transparent (invisible): <lsl>llSetText("alpha", <0.0, 1.0, 0.0>, 0.5);//50% translucent green text</lsl>
Multiple lines
<lsl>llSetText("I am \n on two lines!", <0.0, 1.0, 0.0>, 1.0);//two lines of green text</lsl>Useful Snippets
Drag this script out of inventory onto an object to erase its set text: <lsl>// http://wiki.secondlife.com/wiki/llSetText default {
state_entry()
{
llSetText("", <1.0, 1.0, 1.0>, 1.0);
llRemoveInventory(llGetScriptName());
}
}</lsl> Code to easily specify appearance of hovertext: <lsl> vector blue = <0,0,1>; vector orange = <1,0.5,0>; vector cyan = <0,1,1>; vector pink = <1,0.5,0.76>; vector green = <0,1,0>; vector red = <1,0,0>; vector white = <1,1,1>; vector yellow = <1,1,0.1>; vector purple = <1,0,1>; vector black = <0,0,0>;
string hoverText = "TEXT GOES HERE"; // Sets the text vector hoverColor = white; // Sets the color the text will show. Use predefined colors or any RGB color vector in float form float hoverAlpha = 1.0; // Sets the text's transparency, 1.0 being SOLID, while 0 would be clear,
default {
state_entry()
{
llSetText(hoverText, hoverColor, hoverAlpha);
}
}</lsl> To make hovertext under linked prims you can use this simple function: <lsl> mySetLinkText(integer linknum, string text, vector color, float alpha) {
llSetLinkPrimitiveParamsFast(linknum,[PRIM_TEXT,text,color,alpha]);
}
// For example:
default {
touch_start(integer total_number)
{
mySetLinkText(LINK_SET, "TEST", <0,1,0>, 0.5);
}
}</lsl>
Notes
See Also
Constants
| • | PRIM_TEXT |
Articles
| • | Limits | – | SL limits and constrictions | |
| • | Color in LSL | |||
| • | Translucent Color | |||
| • | Examples: SplitLine | – | Insert 'new line' escape codes at certain positions of a string | |
| • | Useful snippet: llGetObjectPermMask | – | Label an object with text and newlines to give away or sell |
Deep Notes
All Issues
~ Search JIRA for related Issues
|
|
SVC-4539 | A | llSetText is not working with special characters. |
Footnotes
- ^ Floating text with an alpha set to 0.0 is rendered "invisible"
Signature |
|---|
function void llSetText( string text, vector color, float alpha ); |