Money

From Second Life Wiki
Revision as of 23:57, 2 August 2007 by Gal Canning (talk | contribs)
Jump to navigation Jump to search
Emblem-important-red.png Security Warning!

Always (ALWAYS!) check the amount paid.

Description

Event: money( key id, integer amount ){ ; }

Triggered when money is paid to the prim/object in the amount by id.

• key id who paid
• integer amount the amount paid

When money is paid to the object, the money is given to the objects owner.
If the object is owned by a group it is divvied up amongst the group members.
Don't forget to turn on the pay-behavior of the prims/objects involved.

Examples

integer price = 10;

default
{
    state_entry()
    {
        llSetPayPrice(PAY_HIDE, [PAY_HIDE ,PAY_HIDE, PAY_HIDE, PAY_HIDE]);
        llRequestPermissions(llGetOwner(), PERMISSION_DEBIT);
    }
    run_time_permissions(integer perm)
    {
        if(perm & PERMISSION_DEBIT)
            state cash;
    }
}

state cash
{
    state_entry()
    {
        llSetPayPrice(price, [price ,PAY_HIDE, PAY_HIDE, PAY_HIDE]);
    }
    money(key id, integer amount)
    {
        if(amount != price)
        {
            llGiveMoney(id, amount);
            llInstantMessage(id, "You paid "+(string)amount+", which is the wrong price, the price is: "+(string)price);
        }
        else
        {
            llInstantMessage(id, "You paid the right price");
        }
    }
}

See Also

Functions

•  llGiveMoney
•  llSetPayPrice

Deep Notes

Signature

event void money( key id, integer amount );