LlGetLinkKey/fr

Renvoie un key correspondant à la clé de la prim identifiée par le numéro_lien dans l’objet.

• Reconnait les références numéro_lien comprises entre 0 llGetNumberOfPrims inclus tel que LINK_ROOT.
• Ne reconnait pas LINK_THIS, utilisez llGetKey à la place (cf. bug SVC-600)
• Ne reconnait pas les références à plusieurs prims telles que LINK_SET, LINK_ALL_OTHERS ou LINK_ALL_CHILDREN.

Utilisez ce script dans des prims liées ou non liées avec des avatars assis dessus (ou pas). Afin de voir comment se comporte llGetLinkKey par rapport à llGetKey, llGetLinkNumber, llGetNumberOfPrims, LINK_ROOT, etc.

// Renvoie le nom correspond au numéro de lien (sinon renvoie un string vide).
 
string getLinkNumName(integer link)
{
    if (LINK_THIS == link) return "LINK_THIS";
    if (LINK_ALL_CHILDREN == link) return "LINK_ALL_CHILDREN";
    if (LINK_ALL_OTHERS == link) return "LINK_ALL_OTHERS";
    if (LINK_SET == link) return "LINK_SET";
    if (LINK_ROOT == link) return "LINK_ROOT";
    return "";
}
 
// Renvoie la clé de chaque prim liée.
 
default
{
    state_entry()
    {
        integer theLink = llGetLinkNumber();
 
        key theLinkKey = llGetKey();
        key owner = llGetOwner();
        key creator = llGetCreator();
 
        // controle chaque lien
 
        integer link;
        integer primmed = llGetNumberOfPrims();
        for (link = -5; link <= (primmed + 5); ++link)
        {
            key linkKey = llGetLinkKey(link);
 
            // Détaille la clé correspondant au lien.
 
            string line = (string) linkKey; // conversion de la clé en string
 
            if (linkKey == owner) line += " llGetOwner";
            if (linkKey == creator) line += " llGetCreator";
            if (linkKey == theLinkKey) line += " llGetKey";
 
            // Détaille le lien.
 
            line += " @ " + (string) link;
            line += " " + getLinkNumName(link);
            if (link == theLink) line += " llGetLinkNumber";
            if (link == primmed) line += " llGetNumberOfPrims";
 
            // Renvoie la ligne si elle est interessante.
 
            if (linkKey != NULL_KEY)
            {
                llOwnerSay(line);
            }
        }
 
        // Compte toujours le nombre de prims.
 
        llOwnerSay((string) primmed + " llGetNumberOfPrims");
        llOwnerSay("OK");
    }
}

Fonctions

Historique

Bugs

SVC-600

[c]

llGetLinkKey renvoie le mauvais résultat lorsque LINK_THIS est passé en argument!