LlGetObjectPermMask/de

Bitfeld ist die angefragte Erlaubnismaske mask für das Root Objekt des Linksets in dem sich das Script befindet.

Der Text über einem Objekt verschwindet und kehrt dann zurück um so etwas zu sagen wie:

             Open Object
                 ---
            by Anonymous
                 ---
Open/ Yes Mod/ Yes Copy/ Yes Transfer

Dies geschieht, wenn Du das folgende Script vom Inventar in das Objekt ziehst.

 
// Float a label over an object: its name, description, and permissions.
// http://wiki.secondlife.com/wiki/llGetObjectPermMask
 
string perms2String(integer everyonePerms, integer nextPerms)
{        
    integer PERMS_OPEN = (PERM_MODIFY | PERM_COPY | PERM_TRANSFER);
 
    string line = "Closed";
    if ((nextPerms & PERMS_OPEN) == PERMS_OPEN)
    {
        if (everyonePerms & PERM_COPY)
        {
            line = "Open";
        }
    }
 
    if (nextPerms & PERM_MODIFY)
    {
        line += "/ Yes Mod";
    }
    if (nextPerms & PERM_COPY)
    {
        line += "/ Yes Copy";
    }
    if (nextPerms & PERM_TRANSFER)
    {
        line += "/ Yes Transfer";
    }
 
    return line;
}
 
list getLabels()
{
    string name = llGetObjectName();
    if (name == "Object") { name = "(No Name)"; }
 
    string description = llGetObjectDesc();
    if (description == "") { description = "(No Description)"; }
 
    integer everyonePerms = llGetObjectPermMask(MASK_EVERYONE);
    integer nextPerms = llGetObjectPermMask(MASK_NEXT);
    string permissions = perms2String(everyonePerms, nextPerms);
    return [name, description, permissions];
}
 
floatLabels(list lines)
{
        string label = llDumpList2String(lines, "\n---\n");
        vector color = <1.0, 1.0, 1.0>; // color = <R, G, B>
        float opacity = 1.0; // opacity = alpha = 1.0 - transparency        
        llSetText(label, color, opacity);
}
 
default
{
    state_entry()
    {
        llSetText("", <0.0, 0.0, 0.0>, 0.0);
        llSleep(0.1);
        floatLabels(getLabels());
        llRemoveInventory(llGetScriptName());
    }
}
 

Die Erlaubnis für ein neu erstelltes Objekt ist oft Base = PERM_ALL, Eigentümer = PERM_ALL, nächster Eigentümer = PERM_MOVE oder PERM_TRANSFER, Gruppe = 0 (keine), Jeder = 0 (keine). Das perms2String Beispiel beschreibt diese Erlaubnis als "Closed / Yes Transfer".

Funktionen

Artikel

Tests