LlGetObjectPermMask/ja

要求された、タスクが付与されたルートオブジェクトでの、パーミッションのmaskのinteger値を返します。

             Open Object
                 ---
            by Anonymous
                 ---
Open/ Yes Mod/ Yes Copy/ Yes Transfer

のようなメッセージを、次第に消えては現れるオブジェクト上に浮かぶテキストで見せます。インベントリから以下のスクリプトをドラッグして、オブジェクトに入れます。

 
// Float a label over an object: its name, description, and permissions.
// http://wiki.secondlife.com/wiki/llGetObjectPermMask
 
string perms2String(integer everyonePerms, integer nextPerms)
{        
    integer PERMS_OPEN = (PERM_MODIFY | PERM_COPY | PERM_TRANSFER);
 
    string line = "Closed";
    if ((nextPerms & PERMS_OPEN) == PERMS_OPEN)
    {
        if (everyonePerms & PERM_COPY)
        {
            line = "Open";
        }
    }
 
    if (nextPerms & PERM_MODIFY)
    {
        line += "/ Yes Mod";
    }
    if (nextPerms & PERM_COPY)
    {
        line += "/ Yes Copy";
    }
    if (nextPerms & PERM_TRANSFER)
    {
        line += "/ Yes Transfer";
    }
 
    return line;
}
 
list getLabels()
{
    string name = llGetObjectName();
    if (name == "Object") { name = "(No Name)"; }
 
    string description = llGetObjectDesc();
    if (description == "") { description = "(No Description)"; }
 
    integer everyonePerms = llGetObjectPermMask(MASK_EVERYONE);
    integer nextPerms = llGetObjectPermMask(MASK_NEXT);
    string permissions = perms2String(everyonePerms, nextPerms);
    return [name, description, permissions];
}
 
floatLabels(list lines)
{
        string label = llDumpList2String(lines, "\n---\n");
        vector color = <1.0, 1.0, 1.0>; // color = <R, G, B>
        float opacity = 1.0; // opacity = alpha = 1.0 - transparency        
        llSetText(label, color, opacity);
}
 
default
{
    state_entry()
    {
        llSetText("", <0.0, 0.0, 0.0>, 0.0);
        llSleep(0.1);
        floatLabels(getLabels());
        llRemoveInventory(llGetScriptName());
    }
}
 

新しく作られたオブジェクトの権限は、しばしば初期がPERM_ALL、オーナがPERM_ALL、譲渡されたユーザがPERM_MOVEあるいはPERM_TRANSFER、グループは0(無し)、第三者は0(無し)となります。perm2stringのサンプルは、"Closed / Yes Transfer"のようにしてこれらの権限を記述します。

関数

項目