Second Life Wiki - User contributions [en]

Chat Logger (GPL)

2008-03-15T11:47:24Z

Arda Xi: replace pre tags with lsl for readability

{{LSL Header}}
This code demonstrates several functions in combination. Listens, dialogs, Lists, states, arrays, etc.

'''Preamble''': Code adapted from: http://www.simteach.com/wiki/index.php?title=SL_Chat_Logger (by Patch Lamington) which is covered by GNU Free Documentation License (http://www.gnu.org/copyleft/fdl.html) in the spirit of which this script is GPL'd. Copyright (C) 2007 Nobody Fugazi/T. Rampersad

(This program is free software; you can redistribute it and/or modify it under the terms of the GNU General Public License as published by the Free Software Foundation; either version 2 of the License, or (at your option) any later version. This program is distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License for more details. The GPL license: [http://www.gnu.org/copyleft/gpl.html]

(You should have received a copy of the GNU General Public License along with this program; if not, write to the Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.

Change Log:
January 12, 2007: Text output in HTML, Requests permissions from user before logging chat. (NF/TR)

<lsl>
list names;
list speech;
list colours=["002EB8","FF6633","006600","660066","660033","663300","1A9900","FF14B1","001A99","#B88A00"];
list unique_names;
list ignore_names;
list buffer_await;
integer BUFFERSTRIDE = 2;

list ALLOW_MENU = ["sure", "no way"]; // the main menu
integer CHANNEL = 42; // Life, the Universe, and Everything.
integer HandleDialogListen;

default
{
state_entry()
{
llSetText("This is a GPL Chat Logger.\n We request permission before recording.",<0,0,0>,1.0);
integer i;
integer c;
for (i=0;i<llGetListLength(names);i++)
{
c = llListFindList(unique_names,llList2List(names,i,i) );
while (c >= llGetListLength(colours)) // dont crash if I run out of colours
c -= llGetListLength(colours);
llSetObjectName("<font color=#" + llList2String(colours,c)
+ ">" + llList2String(names,i) );
llOwnerSay( llList2String(speech,i) + "</font>" );
}
names = [];
speech = [];
unique_names = [];
llSetObjectName("GPL ChatLogger 0.1");
}

on_rez(integer i)
{
llResetScript();
}

touch_start(integer total_number)
{
if (llDetectedKey(0) == llGetOwner() )
{
llSay(0, "Beginning Chat Logging.");
state chat_logging;
}
}
}

state chat_logging
{
state_entry()
{
llListen(0,"",NULL_KEY,"");
buffer_await = [];
}

on_rez(integer i)
{
llOwnerSay("Logging still active! Touch to get playback");
}

timer()
{
// If the dialog is hanging out doing nothing too long, kill the llListen
llListenRemove(HandleDialogListen);
}

touch_start(integer total_number)
{
if (llDetectedKey(0) == llGetOwner() )
{
llSay(0, "chat logging now off - replaying log!.");
state default;
}
}

listen(integer channel, string name, key id, string message)
{
// Is this a message from the permissions dialog?
if ((llListFindList(ALLOW_MENU, [message]) != -1) && (channel==CHANNEL))
{
string buffer_temp;
// we'll need this from the strided list.
integer buffer_loc;
list temp_name;
temp_name +=name;
buffer_loc = llListFindList(buffer_await, temp_name);
if (message=="sure")
{
unique_names += name;
llListenRemove(HandleDialogListen);
// buffered message is worthwhile, so add it:
buffer_temp = llList2String(buffer_await, buffer_loc);
names += buffer_temp;
buffer_loc++;
buffer_temp = llList2String(buffer_await, buffer_loc);
speech += buffer_temp;
buffer_loc--;
llDeleteSubList(buffer_await, buffer_loc, BUFFERSTRIDE);
return;
}
else
{
// To Be Safe, even if someone hits ignore
ignore_names += name;
llListenRemove(HandleDialogListen);
// We can delete the buffer without adding stuff.
llDeleteSubList(buffer_await, buffer_loc, BUFFERSTRIDE);
return;
}
}

if(llListFindList(ignore_names,[name]) != -1)
{
return;
}
if(llListFindList(unique_names,[name]) == -1)
{
//Check if avatar will give permissions
HandleDialogListen = llListen(CHANNEL, "", NULL_KEY, "");
llDialog(id, "Hello. This is a chat logger. If you give us permission, your participation will be recorded. May we have your permission?", ALLOW_MENU, CHANNEL);
// Give people 1.5 minutes to respond,
// else kill the llListen in timer()
llSetTimerEvent(90);
//store in strided buffer in case last message is to be permed.
buffer_await +=[name,message];
//we're done here (until the user responds to the dialog).
return;
}
names += name;
speech += message;

}

}

</lsl>
[[Category:LSL Library|Chat Logger (GPL)]]

WarpPos

2008-03-05T18:54:31Z

Arda Xi: Added <lsl> tags

The corresponding forum thread for this can be found [[http://forums.secondlife.com/showthread.php?t=109523 here]].

WarpPos is simply a method by which the 10m limit on non-physical movement can be avoided, by exploiting a glitch in [[llSetPrimitiveParams]] in which multiple parameters are executed in a single server frame.
<lsl>
warpPos( vector destpos )
{ //R&D by Keknehv Psaltery, 05/25/2006
//with a little pokeing by Strife, and a bit more
//some more munging by Talarus Luan
//Final cleanup by Keknehv Psaltery
// Compute the number of jumps necessary
integer jumps = (integer)(llVecDist(destpos, llGetPos()) / 10.0) + 1;
// Try and avoid stack/heap collisions
if (jumps > 100 )
jumps = 100; // 1km should be plenty
list rules = [ PRIM_POSITION, destpos ]; //The start for the rules list
integer count = 1;
while ( ( count = count << 1 ) < jumps)
rules = (rules=[]) + rules + rules; //should tighten memory use.
llSetPrimitiveParams( rules + llList2List( rules, (count - jumps) << 1, count) );
if ( llVecDist( llGetPos(), destpos ) > .001 ) //Failsafe
while ( --jumps )
llSetPos( destpos );
}
</lsl>
A few observations:
Sim crossings are perilous for AVs. Depending on connection speed and whether or not you are connected to the sim (can see it on the mini-map), it may screw up your client. However, it seems like objects, by themselves, can cross great distances. I managed to send an object 4 sims away diagonally. Further testing would help us to understand these things.

The script limits the maximum distance to 1km, in order to prevent stack/heap collisions. Still, this is 100 times what llSetPos was limited to-- and you can, of course, modify it to allow larger distances, but beware.

The average time this function takes to execute is under .2 seconds, which is barely noticeable at all, and can easily be attributed to general lag. A simple optimization for an object with a known destination might be to calculate the list beforehand, and then call llSetPrimitiveParams with that list.

{{LSLC|Library}}

Dialog Control

2008-02-24T20:54:21Z

Arda Xi: Added lsl tags

{{LSL Header}}
This is example of usage and function library needed in each scripts to use this dialog module.

;Functions List:
# Standard dialog with buttons. There can be more than 12 buttons.
#* dialog(key id, string message, list buttons, list returns);

# Normal notification dialog, ie: dialog which requires no response from user.
#* dialogNotify(key id, string message);

# To display current dialog again:
#* dialogReshow();

# To cancel current dialog; Currently displayed dialog will give no response when clicked.
#* dialogCancel();

If anyone uses this module, please IM ''Nargus Asturias'', I'd love to hear what you think.
<lsl>
// Dialog constants
integer lnkDialog = 14001;
integer lnkDialogNotify = 14004;
integer lnkDialogResponse = 14002;
integer lnkDialogTimeOut = 14003;

integer lnkDialogReshow = 14011;
integer lnkDialogCancel = 14012;

string seperator = "||";
integer dialogTimeOut = 0;

// ********** DIALOG FUNCTIONS **********
string packDialogMessage(string message, list buttons, list returns){
string packed_message = message + seperator + (string)dialogTimeOut;

integer i;
integer count = llGetListLength(buttons);
for(i=0; i<count; i++){
string button = llList2String(buttons, i);
if(llStringLength(button) > 24) button = llGetSubString(button, 0, 23);
packed_message += seperator + button + seperator + llList2String(returns, i);
}

return packed_message;
}

dialogReshow(){llMessageLinked(LINK_THIS, lnkDialogReshow, "", NULL_KEY);}
dialogCancel(){
llMessageLinked(LINK_THIS, lnkDialogCancel, "", NULL_KEY);
llSleep(1);
}

dialog(key id, string message, list buttons, list returns){
llMessageLinked(LINK_THIS, lnkDialog, packDialogMessage(message, buttons, returns), id);
}

dialogNotify(key id, string message){
list rows;

llMessageLinked(LINK_THIS, lnkDialogNotify,
message + seperator + (string)dialogTimeOut + seperator,
id);
}
// ********** END DIALOG FUNCTIONS **********

default{
state_entry(){
llSetText("Touch me to show dialog", <1,1,1>, 1);
}

link_message(integer sender_num, integer num, string str, key id){
if(num == lnkDialogTimeOut){
dialogNotify(llGetOwner(), "Menu time-out. Please try again.");
state default;
}else if(num == lnkDialogResponse){
llWhisper(0, str);
}
}

touch(integer num_detected){
dialog(llGetOwner(),

// Dialog message here
"Messages go here",

// List of dialog buttons
[ 1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15, 16, 17, 18, 19, 20, 21, "Close" ],

// List of return value from the buttons, in same order
// Note that this value do not need to be the same as button texts
[ 1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15, 16, 17, 18, 19, 20, 21, "X" ]
);
}
}

Nargus Dialog Control v1.58 (by Nargus Asturias)

// ********** SIMPLE DIALOG MODULE ********** //
// By Nargus Asturias
// Version 1.55
//
// Support only one dialog at a time. DO NOT request multiple dialog at once!
// Use of provided functions are recommented. Instruction here are for hardcore programmers only!
//
// Request: Send MessageLinked to the script. There are 3 dialog modes:
// lnkDialog : Normal dialog with message and buttons
// lnkDialogNumericAdjust : A dialog with buttons can be used to adjust numeric value
// lnkDialogNotify : Just a simple notification dialog. No return value and no buttons.
//
// Send MessageLinked with code lnkDialogReshow to force active dialog to reappear.
// Send MessageLinked with code lnkDialogCancel to force cancel active dialog
//
// If a lnkDialog is requested with more than 12 buttons, multi-pages dialog is used to show the buttons.
//
// [ For lnkDialog ]
// MessageLinked Format:
// String part: List dumped into string, each entry seperated by '||'
// Field 1: Dialog message (512 bytes maximum)
// Field 2: Time-out data (integer)
// Field 3-4: Button#1 and return value pair
// Field 5-6: Button#2 and return value pair
// And go on...
// Key part: Key of AV who attend this dialog
//
// Response: MessageLinked to the prim that requested dialog (but no where else)
// num == lnkDialogResponse: AV click on a button. The buttons value returned as a string
// num == lnkDialogTimeOut: Dialog timeout.
//
// [ For lnkDialogNumericAdjust ]
// MessageLinked Format:
// String part: List dumped into string, each entry seperated by '||'
// Field 1: Dialog message (512 bytes maximum)
// Put {VALUE} where you want the current value to be displayed)
// Field 2: Time-out data (integer)
// Field 3: Most significant value (ie. 100, for +/-100)
// Field 4: String-casted numeric value to be adjusted
// Field 5: 2nd most significant value (ie. 10, for +/-10)
// Field 6: Use '1' to enable "+/-" button, '0' otherwise.
// Field 7: 3nd significant value (ie. 1, for +/-1)
// Field 8: Use '1' for integer, or '0' for float
// Field 9: Least significant value (ie. 0.1, for +/-0.1)
// Field 10: Reserved. Not used.
// Key part: Key of AV who attend this dialog
//
// Response: MessageLinked to the prim that requested dialog (but no where else)
// num == lnkDialogResponse: OK or Cancel button is clicked. The final value returned as string.
// num == lnkDialogTimeOut: Dialog timeout.
//
// ******************************************* //

// Constants
integer lnkDialog = 14001;
integer lnkDialogNumericAdjust = 14005;
integer lnkDialogNotify = 14004;

integer lnkDialogReshow = 14011;
integer lnkDialogCancel = 14012;

integer lnkDialogResponse = 14002; // A button is hit, or OK is hit for lnkDialogNumericAdjust
integer lnkDialogCanceled = 14006; // Cancel is hit for lnkDialogNumericAdjust
integer lnkDialogTimeOut = 14003; // No button is hit, or Ignore is hit

string seperator = "||";

// Dialog variables
integer dialogChannel; // Channel number used to spawn this dialog
string message; // Message to be shown with the dialog
integer timerOut; // Dialog time-out
key keyId; // Key of user who attending this dialog
integer requestedNum; // Link-number of the requested prim
list buttons; // List of dialog buttons
list returns; // List of results from dialog buttons

float numericValue;
integer useInteger;

// Other variables
integer buttonsCount;
integer startItemNo;
integer listenId;

string redirectState;

integer responseInt = -1;
string responseStr;
key responseKey;

// ********** String Functions **********
string replaceString(string pattern, string replace, string source){
integer index = llSubStringIndex(source, pattern);
if(index < 0) return source;

source = llDeleteSubString(source, index, (index + llStringLength(pattern) - 1));
return llInsertString(source, index, replace);
}

// ********** Dialog Functions **********
// Function: createDialog
// Create dialog with given message and buttons, direct to user with give id
integer createDialog(key id, string message, list buttons){
integer channel = -((integer)llFrand(8388608))*(255) - (integer)llFrand(8388608) - 11;

llListenRemove(listenId);
listenId = llListen(channel, "", keyId, "");
llDialog(keyId, message, buttons, channel);

return channel;
}

// Function: createMultiDialog
// Create dialog with multiple pages. Each page has Back, Next, and a Close button. Otherwise same functionality as createDialog() function.
integer createMultiDialog(key id, string message, list buttons, integer _startItemNo){
integer channel = -llRound(llFrand( llFabs(llSin(llGetGMTclock())) * 1000000 )) - 11;

if(_startItemNo < 0) _startItemNo = 0;
if(_startItemNo >= buttonsCount - 1) _startItemNo -= 9;
startItemNo = _startItemNo;

integer vButtonsCount = buttonsCount - 2;

// Generate list of buttons to be shown
string closeButton = llList2String(buttons, buttonsCount - 1);

integer stopItemNo = startItemNo + 8;
if(stopItemNo >= buttonsCount - 1) stopItemNo = vButtonsCount;

list thisButtons = llList2List(buttons, startItemNo, stopItemNo);

// Generate dialog navigation buttons
integer i = stopItemNo - startItemNo + 1;
i = i % 3;
if(i > 0) while(i < 3){
thisButtons += [" "];
++i;
}

if(startItemNo > 0)
thisButtons += ["<< BACK"];
else thisButtons += [" "];

thisButtons += [closeButton];

if(stopItemNo < vButtonsCount)
thisButtons += ["NEXT >>"];
else thisButtons += [" "];

// Append page number to the message
integer pageNumber = (integer)(stopItemNo / 9) + 1;
integer pagesCount = llCeil(vButtonsCount / 9.0);
string vMessage = "PAGE: " + (string)pageNumber + " of " + (string)pagesCount + "\n" +
message;

// Display dialog
llListenRemove(listenId);
listenId = llListen(channel, "", keyId, "");
llDialog(keyId, vMessage, thisButtons, channel);

return channel;
}

// Function: generateNumericAdjustButtons
// Generate numeric adjustment dialog which adjustment values are in given list.
// If useNegative is TRUE, "+/-" button will be available.
list generateNumericAdjustButtons(list adjustValues, integer useNegative){
list dialogControlButtons;
list positiveButtons;
list negativeButtons;
list additionButtons;

dialogControlButtons = ["OK", "Cancel"];

// Config adjustment buttons
integer count = llGetListLength(adjustValues);
integer index;
for(index = 0; (index < count) && (index < 3); index++){
string sValue = llList2String(adjustValues, index);

if((float)sValue != 0){
positiveButtons += ["+" + sValue];
negativeButtons += ["-" + sValue];
}
}

// Check positive/negative button
if(useNegative)
additionButtons = ["+/-"];
else additionButtons = [];

// If there is fourth adjustment button
if(count > 3){
if(llGetListLength(additionButtons) == 0) additionButtons = [" "];

string sValue = llList2String(adjustValues, index);
additionButtons += ["+" + sValue, "-" + sValue];
}else if(additionButtons != []) additionButtons += [" ", " "];

// Return list dialog buttons
return additionButtons + negativeButtons + positiveButtons + dialogControlButtons;
}

setResponse(integer int, string str, key id){
responseInt = int;
responseStr = str;
responseKey = id;
}

checkDialogRequest(integer sender_num, integer num, string str, key id){
if((num == lnkDialogNotify) || (num == lnkDialogNumericAdjust) || (num == lnkDialog)){
list data = llParseString2List(str, [seperator], []);

message = llList2String(data, 0);
timerOut = llList2Integer(data, 1);
keyId = id;
requestedNum = sender_num;
buttons = [];
returns = [];

if(timerOut > 7200) timerOut = 7200;

integer i;
integer count = llGetListLength(data);
for(i=2; i<count;){
buttons += [llList2String(data, i++)];
returns += [llList2String(data, i++)];
}

buttonsCount = llGetListLength(buttons);

if(num == lnkDialogNotify){
dialogChannel = -((integer)llFrand(8388608))*(255) - (integer)llFrand(8388608) - 11;
llDialog(keyId, message, buttons, dialogChannel);
return;
}else if(num == lnkDialogNumericAdjust)
redirectState = "NumericAdjustDialog";
else if(num == lnkDialog){
if(buttonsCount > 12)
redirectState = "MultiDialog";
else redirectState = "Dialog";
}

state StartDialog;
}
}

// ********** States **********
default{
state_entry(){
if(responseInt > 0) llMessageLinked(requestedNum, responseInt, responseStr, responseKey);
}

link_message(integer sender_num, integer num, string str, key id){
checkDialogRequest(sender_num, num, str, id);
}
}

state StartDialog{
state_entry(){
if(redirectState == "Dialog") state Dialog;
else if(redirectState == "MultiDialog") state MultiDialog;
else if(redirectState == "NumericAdjustDialog") state NumericAdjustDialog;
else state default;
}
}

state Dialog{
state_entry(){
responseInt = -1;
dialogChannel = createDialog(keyId, message, buttons);
llSetTimerEvent(timerOut);
}

state_exit(){
llSetTimerEvent(0);
}

on_rez(integer start_param){
state default;
}

timer(){
setResponse(lnkDialogTimeOut, "", keyId);
//llMessageLinked(requestedNum, lnkDialogTimeOut, "", keyId);
state default;
}

link_message(integer sender_num, integer num, string str, key id){
if(num == lnkDialogReshow){
dialogChannel = createDialog(keyId, message, buttons);
llSetTimerEvent(timerOut);
}else if(num == lnkDialogCancel) state default;

else checkDialogRequest(sender_num, num, str, id);
}

listen(integer channel, string name, key id, string msg){
if((channel != dialogChannel) || (id != keyId)) return;

integer index = llListFindList(buttons, [msg]);
setResponse(lnkDialogResponse, llList2String(returns, index), keyId);
//llMessageLinked(requestedNum, lnkDialogResponse, llList2String(returns, index), keyId);
state default;
}
}

state MultiDialog {
state_entry(){
responseInt = -1;
startItemNo = 0;
dialogChannel = createMultiDialog(keyId, message, buttons, startItemNo);
llSetTimerEvent(timerOut);
}

state_exit(){
llSetTimerEvent(0);
}

on_rez(integer start_param){
state default;
}

timer(){
setResponse(lnkDialogTimeOut, "", keyId);
state default;
}

link_message(integer sender_num, integer num, string str, key id){
if(num == lnkDialogReshow){
dialogChannel = createMultiDialog(keyId, message, buttons, startItemNo);
llSetTimerEvent(timerOut);
}else if(num == lnkDialogCancel) state default;

else checkDialogRequest(sender_num, num, str, id);
}

listen(integer channel, string name, key id, string msg){
if((channel != dialogChannel) || (id != keyId)) return;

// Dialog control buttons
if(msg == "<< BACK"){
dialogChannel = createMultiDialog(keyId, message, buttons, startItemNo - 9);
llSetTimerEvent(timerOut);
}else if(msg == "NEXT >>"){
dialogChannel = createMultiDialog(keyId, message, buttons, startItemNo + 9);
llSetTimerEvent(timerOut);
}else if(msg == " "){
dialogChannel = createMultiDialog(keyId, message, buttons, startItemNo);
llSetTimerEvent(timerOut);

// Response buttons
}else{
integer index = llListFindList(buttons, [msg]);
setResponse(lnkDialogResponse, llList2String(returns, index), keyId);
//llMessageLinked(requestedNum, lnkDialogResponse, llList2String(returns, index), keyId);
state default;
}
}
}

state NumericAdjustDialog {
state_entry(){
responseInt = -1;

numericValue = llList2Float(returns, 0);
useInteger = llList2Integer(returns, 2);
buttons = generateNumericAdjustButtons(buttons, llList2Integer(returns, 1));

string vMessage;
if(useInteger)
vMessage = replaceString("{VALUE}", (string)((integer)numericValue), message);
else vMessage = replaceString("{VALUE}", (string)numericValue, message);

dialogChannel = createDialog(keyId, vMessage, buttons);
llSetTimerEvent(timerOut);
}

state_exit(){
llSetTimerEvent(0);
}

on_rez(integer start_param){
state default;
}

timer(){
setResponse(lnkDialogTimeOut, "", keyId);
//llMessageLinked(requestedNum, lnkDialogTimeOut, "", keyId);
state default;
}

link_message(integer sender_num, integer num, string str, key id){
if(num == lnkDialogReshow){
dialogChannel = createDialog(keyId, message, buttons);
llSetTimerEvent(timerOut);
}else if(num == lnkDialogCancel) state default;

else checkDialogRequest(sender_num, num, str, id);
}

listen(integer channel, string name, key id, string msg){
if((channel != dialogChannel) || (id != keyId)) return;

// Dialog control button is hit
if(msg == "OK"){
setResponse(lnkDialogResponse, (string)numericValue, keyId);
//llMessageLinked(requestedNum, lnkDialogResponse, (string)numericValue, keyId);
state default;
}else if(msg == "Cancel"){
setResponse(lnkDialogCanceled, (string)numericValue, keyId);
llMessageLinked(requestedNum, lnkDialogCanceled, (string)numericValue, keyId);
state default;

// Value adjustment button is hit
}else if(msg == "+/-")
numericValue = -numericValue;
else if(llSubStringIndex(msg, "+") == 0)
numericValue += (float)llDeleteSubString(msg, 0, 0);
else if(llSubStringIndex(msg, "-") == 0)
numericValue -= (float)llDeleteSubString(msg, 0, 0);

// Spawn another dialog if no OK nor Cancel is hit
string vMessage;
if(useInteger)
vMessage = replaceString("{VALUE}", (string)((integer)numericValue), message);
else vMessage = replaceString("{VALUE}", (string)numericValue, message);
dialogChannel = createDialog(keyId, vMessage, buttons);
llSetTimerEvent(timerOut);
}
}
</lsl>
{{LSLC|Library|Dialog Control}}

LlScaleTexture

2008-02-23T15:23:05Z

Arda Xi:

{{LSL_Function/face|face|}}{{LSL_Function
|func=llScaleTexture
|sort=ScaleTexture
|func_id=54|func_sleep=0.2|func_energy=10.0
|p1_type=float|p1_name=u
|p2_type=float|p2_name=v
|p3_type=integer|p3_name=face
|func_footnote
|func_desc=Sets the texture '''u''' & '''v''' scales for the chosen '''face'''.
|return_text
|spec=In the default texture mapping mode the scale units are in texture repeats per face. In the planar texture mapping mode the scale units are in texture repeats per half meter. This is in contrast to the in-world editing tool, in which the planar texture scaling units are repeats per meter.
|caveats
|constants
|examples=<lsl>
//Scales the textures on 6 sides
float scale;
default
{
state_entry()
{
integer i;

for( i = 1; i < 7; i++ )
{
scale = scale + .1;
llScaleTexture( (float)scale, (float)scale, i);
}
}
}
</lsl>
|helpers
|also_functions={{LSL DefineRow||[[llGetTextureScale]]}}
|also_tests
|also_events
|also_articles
|notes
|cat1=Texture
|cat2
|cat3
|cat4
}}

LlOffsetTexture

2008-02-23T15:22:21Z

Arda Xi: changed pre into lsl.

{{LSL Function/face|face|}}
{{LSL_Function
|func_id=55|func_sleep=0.2|func_energy=10.0
|func=llOffsetTexture
|p1_type=float|p1_name=u
|p2_type=float|p2_name=v
|p3_type=integer|p3_name=face
|func_desc=Sets the texture '''u''' & '''v''' offsets for the chosen '''face'''
|return_text
|spec
|caveats
|constants
|examples=<lsl>
//Offsets the textures on 6 sides
float offset;
default
{
state_entry()
{
integer i;

for( i = 1; i < 7; i++ )
{
offset = offset + .1;
llOffsetTexture( (float)offset, (float)offset, i);
}
}
}
</lsl>
|helpers
|also_functions
|also_tests
|also_events
|also_articles
|notes
|cat1=Face
|cat2=Texture
|cat3
|cat4
}}

Dataserver API

2008-02-22T22:28:10Z

Arda Xi: Changed pre tags into lsl tags.

{{LSL Header}}
{{RightToc}}
=Dataserver Framework=

===Introduction===

A common problem in SL is reading and parsing notecards by script. One application for this is so a script can be distributed as no-mod but still be configurable.

The below framework demonstrates how to setup such an interface with very little work to retool.

The default state reads the notecard and when it is done it activates the configuration state.

===Testimonial===

The most common problem I find is people asking about dataservers, reading from notecards to bypass variables within a notecard so you can release your script as nomod.
So I setup a simple system that I use time and time again that can be reused in any project.
The class itself is state based meaning the default state reads the notecard and then starts another state when the notecard is read and ready to use I explain this further below.

==Main Script==
<lsl>
string notecard_name = "configuration"; // name of notecard goes here

// internals
integer DEBUG = FALSE;
integer line;
key queryhandle; // to separate Dataserver requests
key notecarduuid;

init()
{
queryhandle = llGetNotecardLine(notecard_name, line = 0);// request line
notecarduuid = llGetInventoryKey(notecard_name);
}

// Config data loaded from notecard, with some sane defaults
integer channel = 1000;
string email_address = "revolution.perenti@skidzpartz.com";
default
{
changed(integer change)
{
// We want to reload channel notecard if it changed
if (change & CHANGED_INVENTORY)
if(notecarduuid != llGetInventoryKey(notecard_name))
init();
}

state_entry()
{
init();
}

dataserver(key query_id, string data)
{
if (query_id == queryhandle)
{
if (data != EOF)
{ // not at the end of the notecard
// yay! Parsing time

// pesky whitespace
data = llStringTrim(data, STRING_TRIM_HEAD);

// is it a comment?
if (llGetSubString (data, 0, 0) != "#")
{
integer s = llSubStringIndex(data, "=");
if(~s)//does it have an "=" in it?
{
string token = llToLower(llStringTrim(llDeleteSubString(data, s, -1), STRING_TRIM));
data = llStringTrim(llDeleteSubString(data, 0, s), STRING_TRIM);

//Insert your token parsers here.
if (token == "email_address")
email_address = data;
else if (token == "channel")
channel = (integer)data;
}
}

queryhandle = llGetNotecardLine(notecard_name, ++line);
if(DEBUG) llOwnerSay("Notecard Data: " + data);
}
else
{
if(DEBUG) llOwnerSay("Done Reading Notecard");
state configuration ;
}
}
}
}

state configuration
{

state_entry()
{
llListen(channel, "", "", "");
llShout(0, "Channel set to " + (string)channel);
llShout(0, "Email set to " + (string)email_address);
}
}
</lsl>

==Notecard==
<lsl>
# This is the configuration file
channel = 1000
email_address = phoenixcms@hotmail.co.uk

# end
</lsl>
Lines that start with "#" are comments.

==How It Works==

The [[default]] [[state]] reads and parses all the lines in the notecard. As it reads the notecard it overwrites the default values with the values in the notecard. More specifically after each line has been validated and tokenized, the token is checked against supported tokens. If the token is supported the specific parser for the token is called, in the above example it is just a simple convert and copy.

For technical support, requests, etc., use the Search under the Groups Tab and search for .::Prototype::.

if you have any problems getting this script to work either contact me inworld [https://wiki.secondlife.com/wiki/User:Revolution_Perenti Revolution Perenti]
or visit out Open Source Section at skidz partz we have many different versions of this system.
[http://slurl.com/secondlife/Snow%20Crash/128/128/23 Snow Crash]

{{LSLC|Library}}{{LSLC|Examples}}

Talk:Money transfer denied

2008-02-22T22:08:34Z

Arda Xi:

Isn't this already possible by first requesting the permission and then using
<lsl>
run_time_permissions (integer perm)
{
if(perm & PERMISSION_DEBIT)
{
//normal code if it is granted.
}
else
{
//code for your transfer denied event
}
}
</lsl>
What would be the difference? [[User:Arda Xi|Arda Xi]] 14:07, 22 February 2008 (PST)

Talk:Money transfer denied

2008-02-22T22:07:25Z

Arda Xi: A comment added

Isn't this already possible by first requesting the permission and then using
<lsl>
run_time_permissions (integer perm)
{
if(perm & PERMISSION_DEBIT)
{
state ready;
}
else
{
//code for your transfer denied event
}
}
</lsl>
What would be the difference? [[User:Arda Xi|Arda Xi]] 14:07, 22 February 2008 (PST)

Self Upgrading Script Enhanced

2008-02-21T14:37:45Z

Arda Xi: changed pre tags into lsl tags.

{{LSL Header}}
Thanks to [[User:Markov Brodsky|Markov Brodsky]]'s Self Upgrading Script and [[User:Jippen Faddoul|Jippen Faddoul]]'s update to the idea, I was inspired to add to the flexibility and usefulness of their original works.

Markov Brodsky's original code is quite good, and I based my own implementation upon it, but it has an admitted flaw: It requires that all the scripts that use it have no spaces within the name. For me this will not do. I like my space ;D

Jippen Faddoul's update is also pretty good, but while it is nicely shortened and optimized, it can't handle being copied into the prim more than 2 times. This makes it unusable for my coding style. (Tweak, save, copy, test, repeat...)

So here's my edition to fix those shortcomings. (You may use this code freely and distribute it freely, but DO NOT even try to SELL it.)

<lsl>
// Self Upgrading Script by Cron Stardust based upon work by Markov Brodsky and Jippen Faddoul.
// If this code is used, these header lines MUST be kept.
upgrade() {
//Get the name of the script
string self = llGetScriptName();

string basename = self;

// If there is a space in the name, find out if it's a copy number and correct the basename.
if (llSubStringIndex(self, " ") >= 0) {
// Get the section of the string that would match this RegEx: /[ ][0-9]+$/
integer start = 2; // If there IS a version tail it will have a minimum of 2 characters.
string tail = llGetSubString(self, llStringLength(self) - start, -1);
while (llGetSubString(tail, 0, 0) != " ") {
start++;
tail = llGetSubString(self, llStringLength(self) - start, -1);
}

// If the tail is a positive, non-zero number then it's a version code to be removed from the basename.
if ((integer)tail > 0) {
basename = llGetSubString(self, 0, -llStringLength(tail) - 1);
}
}

// Remove all other like named scripts.
integer n = llGetInventoryNumber(INVENTORY_SCRIPT);
while (n-- > 0) {
string item = llGetInventoryName(INVENTORY_SCRIPT, n);

// Remove scripts with same name (except myself, of course)
if (item != self && 0 == llSubStringIndex(item, basename)) {
llRemoveInventory(item);
}
}
}

// * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
// * The real start of the universe.
// * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *

default {
state_entry() {
upgrade();
}
}
</lsl>

As far as my testing was able to show, I was able to have spaces in my script names and I was even able to tack on a number at the end of my script for personal version tracking and had no troubles. I was able to copy the script into the same prim over and over again with only the latest ever staying.

'''Note:''' Due to the nature of SL, your script's name will alternate between "scriptname" and "scriptname 1", where "scriptname" is the actual name of your script.

[[Category:LSL Library]]

LlList2String

2008-02-21T14:28:44Z

Arda Xi: changed pre tags into lsl tags.

{{LSL_Function/negative index|true|index}}{{LSL_Function
|func_id=188|func_sleep=0.0|func_energy=10.0
|func=llList2String|return_type=string|p1_type=list|p1_name=src|p2_type=integer|p2_name=index
|func_footnote=If the type of the entry at '''index''' in '''src''' is not a string it is typecast into a string.<br/>If '''index''' is out of range it returns a {{HoverText|null string|null string: ""}}.
|func_desc
|return_text=that is at '''index''' in '''src'''.
|spec
|caveats
|constants
|examples=<lsl>//This code demonstrates the differences in typecasting in LSL (and demonstrates how to use the llList2* functions).
// Best viewed in Chat History (ctrl-h)
default
{
state_entry()
{
list my_list = ["a", "0xFF", "0xFF.FF", "1.0e3", 1, 2.0, <1,2,3>, <1,2,3,4>, llGetOwner()];
integer i = 0;
integer end = llGetListLength(my_list);
for (; i<end; ++i)
{
llOwnerSay("string=" + llList2String(my_list,i)
+ "\n integer=" + (string)llList2Integer(my_list,i) + " OR " +(string)((integer)llList2String(my_list,i))
+ "\n float=" + (string)llList2Float(my_list,i) + " OR " +(string)((float)llList2String(my_list,i))
+ "\n vector=" + (string)llList2Vector(my_list,i) + " OR " +(string)((vector)llList2String(my_list,i))
+ "\n rot=" + (string)llList2Rot(my_list,i) + " OR " +(string)((rotation)llList2String(my_list,i))
+ "\n key=" + (string)llList2Key(my_list,i) + " OR " +(string)((key)llList2String(my_list,i)) );
}
}
}</lsl>
|helpers
|also_functions={{LSL DefineRow||{{LSLG|llGetListEntryType}}|}}
{{LSL DefineRow||{{LSLG|llList2Float}}|}}
{{LSL DefineRow||{{LSLG|llList2Integer}}|}}
{{LSL DefineRow||{{LSLG|llList2Key}}|}}
|also_events
|also_tests
|also_articles
|notes=
To convert a string of hex nybbles to integer, call [[llList2String]] and then type cast that string result to integer.

To convert that integer back to a string of hex nybbles, call [[hex]].
|permission
|cat1=List
|cat2
|cat3
|cat4
}}

Email

2008-02-21T14:14:26Z

Arda Xi: Put in lsl tags

{{LSL_Event
|event_id=21|event_delay
|event=email
|p1_type=string|p1_name=time|p1_desc
|p2_type=string|p2_name=address|p2_desc
|p3_type=string|p3_name=subj|p3_desc|
p4_type=string|p4_name=message|p4_desc
|p5_type=integer|p5_name=num_left|p5_desc
|event_desc=Triggered when task receives email
|constants
|spec
|caveats=*'''time''' is in the (string)[[llGetUnixTime]] format.
*The email queue is limited to 100 emails, any email after that is bounced.
|examples=
This application uses email to have objects check with a central server to see if the owner has the latest version. In the objects:
<lsl>
string version = "1"; //
string type = "lolcube";
default
{
on_rez(integer start_param)
{
llEmail("5a634b27-f032-283f-2df2-55ead7724b23@lsl.secondlife.com",
version,
(string)llGetOwner()+","+type);
}
}</lsl>
The server:
<lsl>
default
{
state_entry()
{
llSetTimerEvent(15);
}

timer()
{
llGetNextEmail("","");
}

email( string time, string address, string version, string message, integer num_left )
{
if ((integer)version < 2)
{
list info = llCSV2List(llDeleteSubString(message, 0, llSubStringIndex(message, "\n\n") + 1));
llGiveInventory(llList2Key(info,0),llList2String(info,1));
}

integer i;
for (i = 0; i < num_left; i++)
{
llGetNextEmail("","");
}
}
}
</lsl>
|helpers
|also_header
|also_events
|also_functions={{LSL DefineRow||[[llEmail]]|}}
{{LSL DefineRow||[[llGetNextEmail]]|}}
|also_articles
|also_footer
|notes
|mode
|deprecated
|cat1=Email
|cat2
|cat3
|cat4
}}