Second Life Wiki - User contributions [en]

Color conversion scripts

2014-02-23T19:31:50Z

Clematide Oyen:

{{LSL Header|ml=*}}{{#vardefine:header_title|Color conversion scripts}}

The following functions convert between LSL [[color]] in Red Green Blue (RGB) format and color in Hue Saturation Value (HSV) format.
The functions are based on "c" algorithms from [http://www.cs.rit.edu/~ncs/color/t_convert.html c color conversion] but required some debugging and extensive re-working to fit them in to LSL. For a discussion of HSV color format please see the wikipedia entry at [http://en.wikipedia.org/wiki/HSV_color_space HSV Color]

==RGB to HSV==

<lsl>
// by [[Sally LaSalle]], code released to the public domain under GNU GPL version 3.0 license.
// you are free to use, and you are free to donate to me if you wish!! :P

// takes an RGB color as a vector, with range <float R[0,1], float G[0,1], float B[0,1]>
// returns a vector with HSV ranged from <float H[0,360], float S[0,1], float V[0,1]>
// H ranges smoothly from Red=0, Yellow=60, Green=120, Cyan=180, Blue=240, Violet=300 and back to Red

vector RGBtoHSV( vector rgb )
{
float R = rgb.x;
if (R<0) // catch malformed input
R=0;
else if (R>1)
R=1;
float G = rgb.y;
if (G<0) // catch malformed input
G=0;
else if (G>1)
G=1;
float B = rgb.z;
if (B<0) // catch malformed input
B=0;
else if (B>1)
B=1;

float H;
float S;
float V;

list rgbList = [R, G, B]; // list used to get min and max

float min;
float max;
float achromatic; // =1 if R=G=B
float delta;

vector hsv; // the return HSV vector

min = llListStatistics(LIST_STAT_MIN, rgbList); //MIN of ( R, G, B );
max = llListStatistics(LIST_STAT_MAX, rgbList); //MAX of ( R, G, B );
if (R==G && G==B)
achromatic = 1; // it is a shade of grey, white or black
else
achromatic = 0;

V = max; // V = brightness Value form 0 to 1
delta = max - min;

if( max != 0 )
S = delta / max; // S = saturation from 0 to 1
else {
// R = G = B = 0 // S = 0, V = 0, H = 0
S = 0;
V = 0;
H = 0;

hsv.x = H;
hsv.y = S;
hsv.z = V;
return hsv; //H = S = V = 0
}

if (achromatic == 1)
H = 0;
else if( R == max )
H = 0 + ( G - B ) / delta; // between red & yellow
else if( G == max )
H = 2 + ( B - R ) / delta; // between yellow & cyan
else
H = 4 + ( R - G ) / delta; // between cyan & red

H *= 60; // H is traditionally a figure between 0 and 360 degrees
if( H < 0 )
H += 360;

hsv.x = H;
hsv.y = S;
hsv.z = V;
return hsv;
}
</lsl>

==HSV to RGB==

<lsl>
// by Sally LaSalle, code released to the public domain under GNU GPL version 3.0 license.
// you are free to use, and you are free to donate to me if you wish!! :P

// takes a vector encoded Hue Saturation Value (HSV) triplet
// HSV should be entered with floats the ranges: <float H(0 to 360), float S(0 to 1),float V(0 to 1)>
// And Returns a vector encode Red Green Blue (RGB) color triplet
// RGB will be returned with floats in ranges <float R(0 to 1),float G(0 to 1),float B(0 to 1)>

vector HSVtoRGB( vector hsv )
{
integer i;

float H = hsv.x;
if (H<0) // catch malformed H input
H=0;
else if (H>=360)
H=0;
float S = hsv.y;
if (S<0) // catch malformed S input
S=0;
else if (S>1)
S=1;
float V = hsv.z;
if (V<0) // catch malformed V input
V=0;
else if (V>1)
V=1;

float R;
float G;
float B;

float f; // variables for calculating base color mixing around the "spectrum circle"
float p;
float q;
float t;

vector rgb;

if( S == 0 ) { // achromatic (grey) simply set R,G, & B = Value
R = V;
G = V;
B = V;

rgb.x = R;
rgb.y = G;
rgb.z = B;
return rgb;
}

H /= 60; // Hue factored into range 0 to 5
i = llFloor( H ); // integer floor of Hue
f = H - i; // factorial part of H

p = V * ( 1 - S );
q = V * ( 1 - S * f );
t = V * ( 1 - S * ( 1 - f ) );

if (i==0){
R = V;
G = t;
B = p;
} else if (i==1){
R = q;
G = V;
B = p;
} else if (i==2){
R = p;
G = V;
B = t;
} else if (i==3){
R = p;
G = q;
B = V;
} else if (i==4){
R = t;
G = p;
B = V;
} else {
R = V;
G = p;
B = q;
}

rgb.x = R;
rgb.y = G;
rgb.z = B;

return rgb;
}
</lsl>

==HSL to RGB==

<lsl>
//HSL to RGB conversion function. By Cobalt Arkright. Released to the public under GNU GPL version 3.0 license.
//Takes a vector encoded HSL triplet and outputs a vector encoded RGB triplet.

//Input values should be in the following ranges: <float H(0 to 1), float S(0 to 1), float L(0 to 1)>. In this case, set h360 to "false."
//If you wish to use H(0 to 360), leave the boolean value "h360" set to true.

//Edit 12/27/2009: Cleaned up readability, played around a little bit with value calculation, and hopefully everything is more accurate now. failthfulll Moonwall brought it to my attention that the script wasn't working properly when using H ranges of 0 to 360. Based on my testing, it works now. If anyone else has a problem, feel free to PM me.

vector HSLtoRGB (vector hsl){
integer h360 = TRUE;

if (h360){
//Catch malformed H input for H(0 to 360)
if (hsl.x < 0)
hsl.x = 0;

else if (hsl.x > 360)
hsl.x = 360;
hsl.x = hsl.x / 360;
}

else{
//Catch malformed H input for H(0 to 1)
if (hsl.x < 0)
hsl.x = 0;

else if (hsl.x > 1.0)
hsl.x = 1.0;
}

//Catch malformed S input
if (hsl.y < 0)
hsl.y = 0;

else if (hsl.y > 1.0)
hsl.y = 1.0;

//Catch malformed L input
if (hsl.z < 0)
hsl.z = 0;

else if (hsl.z > 1.0)
hsl.z = 1.0;

//Declare required variables
vector rgb;
float q;
float p;
float tr;
float tg;
float tb;

//Special case: When S = 0, the result is monochromatic, and R = B = G = L.
if (hsl.y == 0){
rgb.x = rgb.y = rgb.z = hsl.z;
return rgb;
}

//Set up temporary values for conversion
if (hsl.z < 0.5)
q = hsl.z * (1.0 + hsl.y);

else if (hsl.z >= 0.5)
q = hsl.z + hsl.y - (hsl.z * hsl.y);

p = 2 * hsl.z - q;

tr = hsl.x + (1.0 / 3.0);
tg = hsl.x;
tb = hsl.x - (1.0 / 3.0);

//Normalize temporary R value
if (tr < 0)
tr = tr + 1.0;

else if (tr > 1.0)
tr = tr - 1.0;

//Normalize temporary G value
if (tg < 0)
tg = tg + 1.0;

else if (tg > 1.0)
tg = tg - 1.0;

//Normalize temporary B value
if (tb < 0)
tb = tb + 1.0;

else if (tb > 1.0)
tb = tb - 1.0;

//Calculate R value
if (tr < (1.0 / 6.0))
rgb.x = p + ((q - p) * 6 * tr);

else if ((1.0 / 6.0) <= tr && tr < 0.5)
rgb.x = q;

else if (0.5 <= tr && tr < (2.0 / 3.0))
rgb.x = p + ((q - p) * 6 * ((2.0 / 3.0) - tr));

else
rgb.x = p;

//Calculate G value
if (tg < (1.0 / 6.0))
rgb.y = p + ((q - p) * 6 * tg);

else if ((1.0 / 6.0) <= tg && tg < 0.5)
rgb.y = q;

else if (0.5 <= tg && tg < (2.0 / 3.0))
rgb.y = p + (( q - p) * 6 * ((2.0 / 3.0) - tg));

else
rgb.y = p;

//Caluclate B value
if (tb < (1.0 / 6.0))
rgb.z = p + ((q - p) * 6 * tb);

else if ((1.0 / 6.0) <= tb && tb < 0.5)
rgb.z = q;

else if (0.5 <= tb && tb < (2.0 / 3.0))
rgb.z = p + ((q - p) * 6 * ((2.0 / 3.0) - tb));

else
rgb.z = p;

//Return the result
return rgb;
}
</lsl>

Amazing what a little bit of readability does. If I ever submit anything else that poorly formatted again, someone please smack me upside the head and tell me to come fix it, please.

==HSV to HSL==

For more info about the difference between HSL and HSV, see the wikipedia entry: [http://en.wikipedia.org/wiki/HSL_and_HSV HSL and HSV]

Original code most likely from: [http://ariya.blogspot.com/2008/07/converting-between-hsl-and-hsv.html converting-between-hsl-and-hsv.html]

<lsl>
// Convert from HSV (hue, saturation, value) to HSL (hue, saturation, luminosity)
// Created by Michaelangelo David code released to the public domain under GNU GPL version 3.0 license.

vector hsv_to_hsl( vector HSV )
{
vector HSL;

HSL.x = HSV.x;
HSL.z = (2 - HSV.y) * HSV.z;
HSL.y = HSV.y * HSV.z;
if (HSL.z <= 1) HSL.y /= HSL.z;
else HSL.y /= (2 - HSL.z);
HSL.z /= 2;

return HSL;
}
</lsl>

==HSL to HSV==

<lsl>
// Convert from HSL (hue, saturation, luminosity) to HSV (hue, saturation, value)
// Created by Michaelangelo David, code released to the public domain under GNU GPL version 3.0 license.
vector hsl_to_hsv( vector HSL )
{
vector HSV;
HSV.x = HSL.x;
HSL.z *= 2;
if (HSL.z <= 1) HSL.y *= HSL.z;
else HSL.y *= ( 2 - HSL.z);

HSV.z = (HSL.z + HSL.y) / 2;
HSV.y = (2 * HSL.y) / (HSL.z + HSL.y);

return HSV;
}
</lsl>

== HSL to RGB ==
I wrote the following two functions since the RGBtoHSL By Cobalt Arkright had a strange bug (math error) when some values was passed to the functions. And I couldn't find a reverse function for RGB to HSL.
I tried to find out where the error was but I didn't succeded in fixing it so i wrote them from the beginning with a different approach. The functions are similar however, just something different in the
coding.

<lsl>
// HSL to RGB conversion function. By Clematide Oyen (Laura Aastha Bondi).
// Inspired by a function written by Alec Thilenius in this article: http://stackoverflow.com/questions/2353211/hsl-to-rgb-color-conversion
// Released to the public under GNU GPL version 3.0 license.
// Takes a vector encoded HSL triplet and outputs a vector encoded RGB triplet.
// Input HSL values should be in the standard format used in the LSL with the following ranges: <float H (0 to 1), float S (0 to 1), float L (0 to 1)>.
// Output is RGB values in the standard format used in the LSL with the following ranges: <float R (0 to 1), float G (0 to 1), float B (0 to 1)>.

vector HslToRgb(vector hsl)
{
float r;
float g;
float b;

if (hsl.y == 0.0) // If saturation is 0 the image is monochrome
r = g = b = hsl.z;
else
{
float q;
if (hsl.z < 0.5)
q = hsl.z * (1.0 + hsl.y);
else
q = hsl.z + hsl.y - hsl.z * hsl.y;

float p = 2.0 * hsl.z - q;

r = HueToRgb(p, q, hsl.x + 1.0 / 3.0);
g = HueToRgb(p, q, hsl.x);
b = HueToRgb(p, q, hsl.x - 1.0 / 3.0);
}
return <(r), (g), (b)>;
}

float HueToRgb(float p, float q, float t)
{
if (t < 0.0) t += 1.0;
if (t > 1.0) t -= 1.0;
if (t < 1.0 / 6.0) return p + (q - p) * 6.0 * t;
if (t < 1.0 / 2.0) return q;
if (t < 2.0 / 3.0) return p + (q - p) * (2.0 / 3.0 - t) * 6.0;
return p;
}
</lsl>

== RGB to HSL ==

<lsl>
// RGB to HSL conversion function. By Clematide Oyen (Laura Aastha Bondi).
// Inspired by a function written by Alec Thilenius in this article: http://stackoverflow.com/questions/2353211/hsl-to-rgb-color-conversion
// Released to the public under GNU GPL version 3.0 license.
// Takes a vector encoded RGB triplet and outputs a vector encoded HSL triplet.
// Input RGB values should be in the standard format used in the LSL with the following ranges: <float R (0 to 1), float G (0 to 1), float B (0 to 1)>.
// Output is HSL values in the standard format used in the LSL with the following ranges: <float H (0 to 1), float S (0 to 1), float L (0 to 1)>.

vector RgbToHsl(vector rgb)
{
float r = rgb.x;
float g = rgb.y;
float b = rgb.z;
float h;
float s;
float l;
float max;
float min;

// Looking for the max value among r, g and b
if (r > g && r > b) max= r;
else if (g > b) max = g;
else max = b;

// Looking for the min value among r, g and b
if (r < g && r < b) min = r;
else if (g < b) min = g;
else min = b;

l = (max + min) / 2.0;

if (max == min)
{
h = 0.0;
s = 0.0;
}
else
{
float d = max - min;

if (l > 0.5) s = d / (2.0 - max - min);
else s = d / (max + min);

if (max == r) {
if (g < b) h = (g - b) / d + 6.0;
else h = (g - b) / d;
}
else if (max == g)
h = (b - r) / d + 2.0;
else
h = (r - g) / d + 4.0;
h /= 6.0;
}

return <h, s, l>;
}
</lsl>

{{LSLC|Library}}
{{LSLC|Examples}}

Talk:Third Party Viewer Directory

2012-07-21T23:45:34Z

Clematide Oyen:

'''Viewer Use''': can we get a percentage of users now in mesh capable viewers? [[User:Nalates Urriah|Nalates Urriah]]

In the Firestorm preferences I seen there is an option to send crash reports to phoenixviewer.com
If the users selected this option, are the crash reports sent to Linden too? If not, can this alter the result of crash statistic for firestorm? How can Linden Lab knows the real number of crashes for firestorm users?

Talk:Third Party Viewer Directory

2011-11-11T23:47:06Z

Clematide Oyen:

'''Viewer Use''': can we get a percentage of users now in mesh capable viewers? [[User:Nalates Urriah|Nalates Urriah]]

Talk:Third Party Viewer Directory

2011-09-27T13:22:41Z

Clematide Oyen: Wrong releases assignments.

Emergency is not 3.0.3 based viewer. It is 1.23 (1.4).
Imprudence is not 3.0.3 based viewer. It is 1.23 (1.4).
Firestorm is not 3.0.3 based viewer. It is 3.0.1.
Ascent project seems dead, web page and download page are unavailable.
Dolphin viewer is a 3.0.6 based viewer.

User:Anylyn Hax

2010-11-17T10:55:49Z

Clematide Oyen: /* Viewer 2 and privacy issues */

{| style="color:pink;background-color:#ffeeee;" cellpadding="20" cellspacing="0" border="0" width="100%"
!width="100" align="left"|[[Image:Anylyn_256_002.jpg|Anylyn Hax, 500 L$ / 30 min]]
!valign="top" align="left"|
___TOC___
|}

== StartAnimation Example ==

For those avatars who need to use another walking animation, other then the one supplied by LL here is a small goodie.
<lsl>
// I like to use Antoinette Lioncourt's sexywalk
// UUID:51e4d6c1-0bf0-f7b9-2cc7-8d7b46baf35b
// place this script in one of your shoes together with the sexywalk
default
{
state_entry()
{
llRequestPermissions(llGetOwner(),PERMISSION_TRIGGER_ANIMATION );
}

run_time_permissions(integer perm)
{
if(PERMISSION_TRIGGER_ANIMATION & perm)
{
llSetTimerEvent(.1);
}
}
timer()
{
vector vel = llGetVel();
if( llFabs(vel.x) > 0.1)llStartAnimation("sexywalk");
if( llFabs(vel.x)<= 0.1)llStopAnimation("sexywalk");
}
}
</lsl>
Anylyn Hax 21:43, 1 June 2007 (PDT)

== llSetPrimitiveParams() Example1 (Human readable output) ==

<lsl>
// This ugly hack gives out a piece of Human Readable Code, as demanded
// by llSetPrimitiveParams. The result of this program comes via llOwnerSay
// on the chat channel. Its a good idea to cut objectname and date out ;)
// created by Anylyn Hax in the hot summer of 2007.
//
// This program is free software: you can redistribute it and/or modify
// it under the terms of the GNU General Public License as published by
// the Free Software Foundation, either version 3 of the License, or
// (at your option) any later version.
//
// This program is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
// GNU General Public License for more details.
//
// You should have received a copy of the GNU General Public License
// along with this program. If not, see <http://www.gnu.org/licenses/>.

default
{
state_entry()
{
integer i = 0;
integer ce_side = llGetNumberOfSides();

list booleans = ([
"FALSE", // 0
"TRUE" // 1
]);

list texgens = ([
"PRIM_TEXGEN_DEFAULT", // 0
"PRIM_TEXGEN_PLANAR" // 1
]);

list holeshape = ([
"PRIM_HOLE_DEFAULT", // 0 default (matches the prim type: square for box, circle for cylinder, etc.)
"","","","","","","","","","","","","","","",
"PRIM_HOLE_CIRCLE", // 16 circle
"","","","","","","","","","","","","","","",
"PRIM_HOLE_SQUARE", // 32 square
"","","","","","","","","","","","","","","",
"PRIM_HOLE_TRIANGLE" // 48 triangle
]);

list sculpttype = ([
"PRIM_SCULPT_TYPE_SPHERE", // 1 sphere (Converge top & bottom, stitch left side to right)
"PRIM_SCULPT_TYPE_TORUS", // 2 torus (Stitch top to bottom, stitch left side to right)
"PRIM_SCULPT_TYPE_PLANE", // 3 plane (No stitching or converging)
"PRIM_SCULPT_TYPE_CYLINDER" // 4 cylinder (Stitch left side to right, leave top and bottom open)
]);

list bumpmapping = ([
"PRIM_BUMP_NONE", // 0 none: no bump map
"PRIM_BUMP_BRIGHT", // 1 brightness: generate bump map from highlights
"PRIM_BUMP_DARK", // 2 darkness: generate bump map from lowlights
"PRIM_BUMP_WOOD", // 3 woodgrain
"PRIM_BUMP_BARK", // 4 bark
"PRIM_BUMP_BRICKS", // 5 bricks
"PRIM_BUMP_CHECKER", // 6 checker
"PRIM_BUMP_CONCRETE", // 7 concrete
"PRIM_BUMP_TILE", // 8 crustytile
"PRIM_BUMP_STONE", // 9 cutstone: blocks
"PRIM_BUMP_DISKS", // 10 discs: packed circles
"PRIM_BUMP_GRAVEL", // 11 gravel
"PRIM_BUMP_SIDING", // 13 siding
"PRIM_BUMP_LARGETILE", // 14 stonetile
"PRIM_BUMP_STUCCO", // 15 stucco
"PRIM_BUMP_SUCTION", // 16 suction: rings
"PRIM_BUMP_WEAVE" // 17 weave
]);

list shinys = ([
"PRIM_SHINY_NONE", // 0 none
"PRIM_SHINY_LOW", // 1 low
"PRIM_SHINY_MEDIUM", // 2 medium
"PRIM_SHINY_HIGH" // 3 high
]);

list materials =([
"PRIM_MATERIAL_STONE", // 0 stone
"PRIM_MATERIAL_METAL", // 1 metal
"PRIM_MATERIAL_GLASS", // 2 glass
"PRIM_MATERIAL_WOOD", // 3 wood
"PRIM_MATERIAL_FLESH", // 4 flesh
"PRIM_MATERIAL_PLASTIC", // 5 plastic
"PRIM_MATERIAL_RUBBER", // 6 rubber
"PRIM_MATERIAL_LIGHT" // 7 light
]);

llOwnerSay("llSetPrimitiveParams([");

list ce_prim_flexible = llGetPrimitiveParams([PRIM_FLEXIBLE]); // 21
llOwnerSay("PRIM_FLEXIBLE"+
", "+(string)llList2String(booleans ,llList2Integer(ce_prim_flexible,0))+ // true / false
", "+(string)llList2Integer(ce_prim_flexible,1)+ // softness
", "+(string)llList2Float(ce_prim_flexible,2)+ // gravity
", "+(string)llList2Float(ce_prim_flexible,3)+ // friction
", "+(string)llList2Float(ce_prim_flexible,4)+ // wind
", "+(string)llList2Float(ce_prim_flexible,5)+ // tension
", "+(string)llList2Vector(ce_prim_flexible,6)+", "); // force
ce_prim_flexible =[];

list ce_prim_material = llGetPrimitiveParams([PRIM_MATERIAL]); // 2
llOwnerSay("PRIM_MATERIAL, "+(string)llList2String(materials ,llList2Integer(ce_prim_material,0))+", ");
ce_prim_material = [];

list ce_prim_phantom = llGetPrimitiveParams([PRIM_PHANTOM]); // 5
llOwnerSay("PRIM_PHANTOM, "+(string)llList2String(booleans ,llList2Integer(ce_prim_phantom ,0))+", ");
ce_prim_phantom = [];

list ce_prim_physiks = llGetPrimitiveParams([PRIM_PHYSICS]); // 3
llOwnerSay("PRIM_PHYSICS, "+(string)llList2String(booleans ,llList2Integer(ce_prim_physiks ,0))+", ");
ce_prim_physiks = [];

list ce_prim_point_light = llGetPrimitiveParams([PRIM_POINT_LIGHT]); // 23
llOwnerSay("PRIM_POINT_LIGHT"+
", "+(string)llList2String(booleans ,llList2Integer(ce_prim_point_light,0))+ // true / false
", "+(string)llList2Vector(ce_prim_point_light,1)+ // color
", "+(string)llList2Float(ce_prim_point_light,2)+ // intensity
", "+(string)llList2Float(ce_prim_point_light,3)+ // radius
", "+(string)llList2Float(ce_prim_point_light,4)+", "); // falloff
ce_prim_point_light = [];

list ce_prim_position = llGetPrimitiveParams([PRIM_POSITION]); // 6
llOwnerSay("PRIM_POSITION, "+(string)llList2Vector(ce_prim_position ,0)+", ");
ce_prim_position = [];

list ce_prim_rotation = llGetPrimitiveParams([PRIM_ROTATION]); // 8
llOwnerSay("PRIM_ROTATION, "+(string)llList2Rot(ce_prim_rotation ,0)+", ");
ce_prim_rotation = [];

list ce_prim_size = llGetPrimitiveParams([PRIM_SIZE]); // 7
llOwnerSay("PRIM_SIZE, "+(string)llList2Vector(ce_prim_size ,0)+", ");
ce_prim_size = [];

list ce_prim_temp_on_rez = llGetPrimitiveParams([PRIM_TEMP_ON_REZ]); // 4
llOwnerSay("PRIM_TEMP_ON_REZ, "+(string)llList2String(booleans ,llList2Integer(ce_prim_temp_on_rez ,0))+", ");
ce_prim_temp_on_rez = [];

list ce_prim_type = llGetPrimitiveParams([PRIM_TYPE]); // 9
if(llList2Integer(ce_prim_type,0)==0){llOwnerSay("PRIM_TYPE, PRIM_TYPE_BOX"+", "+(string)llList2String(holeshape ,llList2Integer(ce_prim_type,1))+", "+(string)llList2Vector(ce_prim_type,2)+", "+(string)llList2Float(ce_prim_type,3)+", "+(string)llList2Vector(ce_prim_type,4)+", "+(string)llList2Vector(ce_prim_type,5)+", "+(string)llList2Vector(ce_prim_type,6)+", ");}
if(llList2Integer(ce_prim_type,0)==1){llOwnerSay("PRIM_TYPE, PRIM_TYPE_CYLINDER"+", "+(string)llList2String(holeshape ,llList2Integer(ce_prim_type,1))+", "+(string)llList2Vector(ce_prim_type,2)+", "+(string)llList2Float(ce_prim_type,3)+", "+(string)llList2Vector(ce_prim_type,4)+", "+(string)llList2Vector(ce_prim_type,5)+", "+(string)llList2Vector(ce_prim_type,6)+", ");}
if(llList2Integer(ce_prim_type,0)==2){llOwnerSay("PRIM_TYPE, PRIM_TYPE_PRISM"+", "+(string)llList2String(holeshape ,llList2Integer(ce_prim_type,1))+", "+(string)llList2Vector(ce_prim_type,2)+", "+(string)llList2Float(ce_prim_type,3)+", "+(string)llList2Vector(ce_prim_type,4)+", "+(string)llList2Vector(ce_prim_type,5)+", "+(string)llList2Vector(ce_prim_type,6)+", ");}
if(llList2Integer(ce_prim_type,0)==3){llOwnerSay("PRIM_TYPE, PRIM_TYPE_SPHERE"+", "+(string)llList2Integer(ce_prim_type,1)+", "+(string)llList2Vector(ce_prim_type,2)+", "+(string)llList2Float(ce_prim_type,3)+", "+(string)llList2Vector(ce_prim_type,4)+", "+(string)llList2Vector(ce_prim_type,5)+", ");}
if(llList2Integer(ce_prim_type,0)==4){llOwnerSay("PRIM_TYPE, PRIM_TYPE_TORUS"+", "+(string)llList2String(holeshape ,llList2Integer(ce_prim_type,1))+", "+(string)llList2Vector(ce_prim_type,2)+", "+(string)llList2Float(ce_prim_type,3)+", "+(string)llList2Vector(ce_prim_type,4)+", "+(string)llList2Vector(ce_prim_type,5)+", "+(string)llList2Vector(ce_prim_type,6)+", "+(string)llList2Vector(ce_prim_type,7)+", "+(string)llList2Vector(ce_prim_type,8)+", "+(string)llList2Float(ce_prim_type,9)+", "+(string)llList2Float(ce_prim_type,10)+", "+(string)llList2Float(ce_prim_type,11)+", ");}
if(llList2Integer(ce_prim_type,0)==5){llOwnerSay("PRIM_TYPE, PRIM_TYPE_TUBE"+", "+(string)llList2String(holeshape ,llList2Integer(ce_prim_type,1))+", "+(string)llList2Vector(ce_prim_type,2)+", "+(string)llList2Float(ce_prim_type,3)+", "+(string)llList2Vector(ce_prim_type,4)+", "+(string)llList2Vector(ce_prim_type,5)+", "+(string)llList2Vector(ce_prim_type,6)+", "+(string)llList2Vector(ce_prim_type,7)+", "+(string)llList2Vector(ce_prim_type,8)+", "+(string)llList2Float(ce_prim_type,9)+", "+(string)llList2Float(ce_prim_type,10)+", "+(string)llList2Float(ce_prim_type,11)+", ");}
if(llList2Integer(ce_prim_type,0)==6){llOwnerSay("PRIM_TYPE, PRIM_TYPE_RING"+", "+(string)llList2String(holeshape ,llList2Integer(ce_prim_type,1))+", "+(string)llList2Vector(ce_prim_type,2)+", "+(string)llList2Float(ce_prim_type,3)+", "+(string)llList2Vector(ce_prim_type,4)+", "+(string)llList2Vector(ce_prim_type,5)+", "+(string)llList2Vector(ce_prim_type,6)+", "+(string)llList2Vector(ce_prim_type,7)+", "+(string)llList2Vector(ce_prim_type,8)+", "+(string)llList2Float(ce_prim_type,9)+", "+(string)llList2Float(ce_prim_type,10)+", "+(string)llList2Float(ce_prim_type,11)+", ");}
if(llList2Integer(ce_prim_type,0)==7){llOwnerSay("PRIM_TYPE, PRIM_TYPE_SCULPT"+", "+(string)llList2String(ce_prim_type,1)+", "+(string)llList2Integer(ce_prim_type,2)+", ");}
ce_prim_type = [];

i = 0;
list ce_prim_fullbright;
while(i <= ce_side) {
ce_prim_fullbright = llGetPrimitiveParams([PRIM_FULLBRIGHT,i]); // 20
if (ce_prim_fullbright != []) {
llOwnerSay("PRIM_FULLBRIGHT, "+(string)i+", "+(string)llList2String(booleans ,llList2Integer(ce_prim_fullbright,0))+", ");
ce_prim_fullbright = [];
}
i++;
}

i = 0;
list ce_prim_bump_shiny;
while(i <= ce_side) {
ce_prim_bump_shiny = llGetPrimitiveParams([PRIM_BUMP_SHINY,i]); // 19
if (ce_prim_bump_shiny != []) {
llOwnerSay("PRIM_BUMP_SHINY, "+(string)i+", "+llList2String(shinys,llList2Integer(ce_prim_bump_shiny,0))+ // shiny
", "+llList2String(bumpmapping ,llList2Integer(ce_prim_bump_shiny,1))+", ");// bumpmaping
ce_prim_bump_shiny = [];
}
i++;
}

i = 0;
list ce_prim_color;
while(i <= ce_side) {
ce_prim_color = llGetPrimitiveParams([PRIM_COLOR,i]); // 18
if (ce_prim_color != []) {
llOwnerSay("PRIM_COLOR, "+(string)i+", "+(string)llList2Vector(ce_prim_color,0)+", "+(string)llList2Float(ce_prim_color,1)+", ");
ce_prim_color = [];
}
i++;
}

i = 0;
list ce_prim_texgen;
while(i <= ce_side) {
ce_prim_texgen = llGetPrimitiveParams([PRIM_TEXGEN ,i]); // 22
if (ce_prim_texgen != []) {
llOwnerSay("PRIM_TEXGEN, "+(string)i+", "+llList2String(texgens,llList2Integer(ce_prim_texgen,0))+", "); // type
ce_prim_texgen = [];
}
i++;
}

i = 0;
string koma = "";
list ce_prim_texture;
while(i <= ce_side) {
ce_prim_texture = llGetPrimitiveParams([PRIM_TEXTURE,i]); // 17
if(i < ce_side -1) { koma = ", "; } // we dont put everywhere a komata
if (ce_prim_texture != []) {
llOwnerSay("PRIM_TEXTURE, "+(string)i+
", "+(string)llList2String(ce_prim_texture,0)+ // name
", "+(string)llList2Vector(ce_prim_texture,1)+ // repeats
", "+(string)llList2Vector(ce_prim_texture,2)+ // offsets
", "+(string)llList2Float(ce_prim_texture,3) + koma); // rotation
ce_prim_texture = [];
koma = "";
}
i++;
}

llOwnerSay("]);");
llOwnerSay("//This Script used " + (string)((16384 - llGetFreeMemory())/1024) + " kBytes");
}
}
</lsl>

... and outputs something like this:

<pre>
[23:00] Object: llSetPrimitiveParams([
[23:00] Object: PRIM_FLEXIBLE, TRUE, 2.000000, 0.300000, 2.000000, 0.000000, 1.000000, <0.01000, 0.00000, 0.01000>,
[23:00] Object: PRIM_MATERIAL, PRIM_MATERIAL_WOOD,
[23:00] Object: PRIM_PHANTOM, TRUE,
[23:00] Object: PRIM_PHYSICS, FALSE,
[23:00] Object: PRIM_POINT_LIGHT, TRUE, <1.00000, 1.00000, 1.00000>, 1.000000, 10.000000, 0.750000,
[23:00] Object: PRIM_POSITION, <57.18748, 200.57619, 21.45186>,
[23:00] Object: PRIM_ROTATION, <0.00000, 0.00000, 0.00000, 1.00000>,
[23:00] Object: PRIM_SIZE, <0.76611, 0.76611, 0.76611>,
[23:00] Object: PRIM_TEMP_ON_REZ, FALSE,
[23:00] Object: PRIM_TYPE, PRIM_TYPE_BOX, PRIM_HOLE_CIRCLE, <0.00000, 1.00000, 0.00000>, 0.099900, <0.00000, 0.00000, 0.00000>, <1.00000, 1.00000, 0.00000>, <0.00000, 0.00000, 0.00000>,
[23:00] Object: PRIM_FULLBRIGHT, 0, TRUE,
[23:00] Object: PRIM_FULLBRIGHT, 1, TRUE,
[23:00] Object: PRIM_FULLBRIGHT, 2, TRUE,
[23:00] Object: PRIM_FULLBRIGHT, 3, TRUE,
[23:00] Object: PRIM_FULLBRIGHT, 4, TRUE,
[23:00] Object: PRIM_FULLBRIGHT, 5, TRUE,
[23:00] Object: PRIM_FULLBRIGHT, 6, TRUE,
[23:00] Object: PRIM_BUMP_SHINY, 0, PRIM_SHINY_MEDIUM, PRIM_BUMP_CHECKER,
[23:00] Object: PRIM_BUMP_SHINY, 1, PRIM_SHINY_MEDIUM, PRIM_BUMP_CHECKER,
[23:00] Object: PRIM_BUMP_SHINY, 2, PRIM_SHINY_MEDIUM, PRIM_BUMP_CHECKER,
[23:00] Object: PRIM_BUMP_SHINY, 3, PRIM_SHINY_MEDIUM, PRIM_BUMP_CHECKER,
[23:00] Object: PRIM_BUMP_SHINY, 4, PRIM_SHINY_MEDIUM, PRIM_BUMP_CHECKER,
[23:00] Object: PRIM_BUMP_SHINY, 5, PRIM_SHINY_MEDIUM, PRIM_BUMP_CHECKER,
[23:00] Object: PRIM_BUMP_SHINY, 6, PRIM_SHINY_MEDIUM, PRIM_BUMP_CHECKER,
[23:00] Object: PRIM_COLOR, 0, <1.00000, 1.00000, 1.00000>, 1.000000,
[23:00] Object: PRIM_COLOR, 1, <1.00000, 1.00000, 1.00000>, 1.000000,
[23:00] Object: PRIM_COLOR, 2, <1.00000, 1.00000, 1.00000>, 1.000000,
[23:00] Object: PRIM_COLOR, 3, <1.00000, 1.00000, 1.00000>, 1.000000,
[23:00] Object: PRIM_COLOR, 4, <1.00000, 1.00000, 1.00000>, 1.000000,
[23:00] Object: PRIM_COLOR, 5, <1.00000, 1.00000, 1.00000>, 1.000000,
[23:00] Object: PRIM_COLOR, 6, <1.00000, 1.00000, 1.00000>, 1.000000,
[23:00] Object: PRIM_TEXGEN, 0, PRIM_TEXGEN_PLANAR,
[23:00] Object: PRIM_TEXGEN, 1, PRIM_TEXGEN_PLANAR,
[23:00] Object: PRIM_TEXGEN, 2, PRIM_TEXGEN_PLANAR,
[23:00] Object: PRIM_TEXGEN, 3, PRIM_TEXGEN_PLANAR,
[23:00] Object: PRIM_TEXGEN, 4, PRIM_TEXGEN_PLANAR,
[23:00] Object: PRIM_TEXGEN, 5, PRIM_TEXGEN_PLANAR,
[23:00] Object: PRIM_TEXGEN, 6, PRIM_TEXGEN_PLANAR,
[23:00] Object: PRIM_TEXTURE, 0, 89556747-24cb-43ed-920b-47caed15465f, <1.00000, 1.00000, 0.00000>, <0.00000, 0.00000, 0.00000>, 0.000000,
[23:00] Object: PRIM_TEXTURE, 1, 89556747-24cb-43ed-920b-47caed15465f, <1.00000, 1.00000, 0.00000>, <0.00000, 0.00000, 0.00000>, 0.000000,
[23:00] Object: PRIM_TEXTURE, 2, 89556747-24cb-43ed-920b-47caed15465f, <1.00000, 1.00000, 0.00000>, <0.00000, 0.00000, 0.00000>, 0.000000,
[23:00] Object: PRIM_TEXTURE, 3, 89556747-24cb-43ed-920b-47caed15465f, <1.00000, 1.00000, 0.00000>, <0.00000, 0.00000, 0.00000>, 0.000000,
[23:00] Object: PRIM_TEXTURE, 4, 89556747-24cb-43ed-920b-47caed15465f, <1.00000, 1.00000, 0.00000>, <0.00000, 0.00000, 0.00000>, 0.000000,
[23:00] Object: PRIM_TEXTURE, 5, 89556747-24cb-43ed-920b-47caed15465f, <1.00000, 1.00000, 0.00000>, <0.00000, 0.00000, 0.00000>, 0.000000,
[23:00] Object: PRIM_TEXTURE, 6, 89556747-24cb-43ed-920b-47caed15465f, <1.00000, 1.00000, 0.00000>, <0.00000, 0.00000, 0.00000>, 0.000000
[23:00] Object: ]);
</pre>

Anylyn Hax 15:58, 8 August 2007 (PDT)

== llSetPrimitiveParams() Example2 Human readable using ALL_SIDES ==

2.07.2010 was simply to hot to walk outside :) so I reworked this old script. Don't worry its mostly cosmetics. 
- Due to mono we can now try some more tricks because we have 64k memory to use. 
- The functions FormatFloat and FormatVector should simplify the output by using ALL_SIDES and another call with the differences on other sides. 
- I used a function called strReplace by Haravikk Mistral for doing string replace. 
- The code removes for running time the prim name in order to not have it in your chat output. 
- If you want to not have the Timestamp in your output modify this in your Viewer.(Preferences/Text Chat/Chat Options/Show Timestamp in local Chat) 
IN this way the output shorts itself dramatically. 
Manny thanks to Krull Aeon for pointing the bugs in the last version, regarding the using of double quotes for keys. 
Manny thanks also to Flavio Dayafter for the trick to remove the ":" llOwnerSay("/me ....... 

<lsl>
// This ugly hack gives out a piece of Human Readable Code, as demanded
// by llSetPrimitiveParams. The result of this program comes via llOwnerSay
// on the chat channel. Its a good idea to cut objectname and date out ;)
// created by Anylyn Hax in the hot summer of 2007, and reworked in 2010.
//
// This program is free software: you can redistribute it and/or modify
// it under the terms of the GNU General Public License as published by
// the Free Software Foundation, either version 3 of the License, or
// (at your option) any later version.
//
// This program is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
// GNU General Public License for more details.
//
// You should have received a copy of the GNU General Public License
// along with this program. If not, see <http://www.gnu.org/licenses/>.

// strReplace by Haravikk Mistral
string strReplace(string str, string search, string replace) {
return llDumpList2String(llParseStringKeepNulls((str = "") + str, [search], []), replace);
}

string FormatFloat(float number, integer precision)
{
float roundingValue = llPow(10, -precision)*0.5;
float rounded;
if (number < 0) rounded = number - roundingValue;
else rounded = number + roundingValue;

if (precision < 1) { precision = 1; } // float is float

string result = llGetSubString((string)rounded, 0, llSubStringIndex((string)rounded, ".") + precision);
result = strReplace(result, ".000", ".0");
result = strReplace(result, "00,", "0,");
return result;
}

string FormatVector(vector hector, integer precision)
{
if(hector == ZERO_VECTOR) { return "ZERO_VECTOR";} else {
if (precision < 1) { precision = 1; } // a vector contains floats
float roundingValue = llPow(10, -precision)*0.5;
float relx; float rely; float relz; float elx; float ely; float elz;
elx = hector.x; ely = hector.y; elz = hector.z;

if (elx < 0) {relx = elx - roundingValue;} else {relx = elx + roundingValue;}
if (ely < 0) {rely = ely - roundingValue;} else {rely = ely + roundingValue;}
if (elz < 0) {relz = elz - roundingValue;} else {relz = elz + roundingValue;}

string result = "<"+llGetSubString((string)relx, 0, llSubStringIndex((string)relx, ".") + precision)+","+
llGetSubString((string)rely, 0, llSubStringIndex((string)rely, ".") + precision)+","+
llGetSubString((string)relz, 0, llSubStringIndex((string)relz, ".") + precision)+">";
result = strReplace(result, ".000", ".0");
result = strReplace(result, "00,", "0,");
result = strReplace(result, "00>", "0>");
return result;
}
}

default
{
state_entry()
{

string ce_primname = llGetObjectName(); llSetObjectName(""); // thats for you to not cut so much from the chat
integer i = 0; integer j =0;
integer ce_side = llGetNumberOfSides();

list booleans = ([
"FALSE", // 0
"TRUE" // 1
]);

list texgens = ([
"PRIM_TEXGEN_DEFAULT", // 0
"PRIM_TEXGEN_PLANAR" // 1
]);

list holeshape = ([
"PRIM_HOLE_DEFAULT", // 0 default (matches the prim type: square for box, circle for cylinder, etc.)
"","","","","","","","","","","","","","","",
"PRIM_HOLE_CIRCLE", // 16 circle
"","","","","","","","","","","","","","","",
"PRIM_HOLE_SQUARE", // 32 square
"","","","","","","","","","","","","","","",
"PRIM_HOLE_TRIANGLE" // 48 triangle
]);

list sculpttype = ([
"PRIM_SCULPT_TYPE_SPHERE", // 1 sphere (Converge top & bottom, stitch left side to right)
"PRIM_SCULPT_TYPE_TORUS", // 2 torus (Stitch top to bottom, stitch left side to right)
"PRIM_SCULPT_TYPE_PLANE", // 3 plane (No stitching or converging)
"PRIM_SCULPT_TYPE_CYLINDER" // 4 cylinder (Stitch left side to right, leave top and bottom open)
]);

list bumpmapping = ([
"PRIM_BUMP_NONE", // 0 none: no bump map
"PRIM_BUMP_BRIGHT", // 1 brightness: generate bump map from highlights
"PRIM_BUMP_DARK", // 2 darkness: generate bump map from lowlights
"PRIM_BUMP_WOOD", // 3 woodgrain
"PRIM_BUMP_BARK", // 4 bark
"PRIM_BUMP_BRICKS", // 5 bricks
"PRIM_BUMP_CHECKER", // 6 checker
"PRIM_BUMP_CONCRETE", // 7 concrete
"PRIM_BUMP_TILE", // 8 crustytile
"PRIM_BUMP_STONE", // 9 cutstone: blocks
"PRIM_BUMP_DISKS", // 10 discs: packed circles
"PRIM_BUMP_GRAVEL", // 11 gravel
"PRIM_BUMP_SIDING", // 13 siding
"PRIM_BUMP_LARGETILE", // 14 stonetile
"PRIM_BUMP_STUCCO", // 15 stucco
"PRIM_BUMP_SUCTION", // 16 suction: rings
"PRIM_BUMP_WEAVE" // 17 weave
]);

list shinys = ([
"PRIM_SHINY_NONE", // 0 none
"PRIM_SHINY_LOW", // 1 low
"PRIM_SHINY_MEDIUM", // 2 medium
"PRIM_SHINY_HIGH" // 3 high
]);

list materials =([
"PRIM_MATERIAL_STONE", // 0 stone
"PRIM_MATERIAL_METAL", // 1 metal
"PRIM_MATERIAL_GLASS", // 2 glass
"PRIM_MATERIAL_WOOD", // 3 wood
"PRIM_MATERIAL_FLESH", // 4 flesh
"PRIM_MATERIAL_PLASTIC", // 5 plastic
"PRIM_MATERIAL_RUBBER", // 6 rubber
"PRIM_MATERIAL_LIGHT" // 7 light
]);

llOwnerSay("/me llSetPrimitiveParams([");

list ce_prim_flexible = llGetPrimitiveParams([PRIM_FLEXIBLE]); // 21
llOwnerSay("/me\t PRIM_FLEXIBLE"+
", "+llList2String(booleans ,llList2Integer(ce_prim_flexible,0))+ // true / false
", "+(string)llList2Integer(ce_prim_flexible,1)+ // softness
", "+FormatFloat(llList2Float(ce_prim_flexible,2),3)+ // gravity
", "+FormatFloat(llList2Float(ce_prim_flexible,3),3)+ // friction
", "+FormatFloat(llList2Float(ce_prim_flexible,4),3)+ // wind
", "+FormatFloat(llList2Float(ce_prim_flexible,5),3)+ // tension
", "+FormatVector(llList2Vector(ce_prim_flexible,6),3)); // force
ce_prim_flexible =[];

list ce_prim_material = llGetPrimitiveParams([PRIM_MATERIAL]); // 2
llOwnerSay("/me\t, PRIM_MATERIAL, "+llList2String(materials ,llList2Integer(ce_prim_material,0)));
ce_prim_material = [];

list ce_prim_phantom = llGetPrimitiveParams([PRIM_PHANTOM]); // 5
llOwnerSay("/me\t, PRIM_PHANTOM, "+llList2String(booleans ,llList2Integer(ce_prim_phantom ,0)));
ce_prim_phantom = [];

list ce_prim_physiks = llGetPrimitiveParams([PRIM_PHYSICS]); // 3
llOwnerSay("/me\t, PRIM_PHYSICS, "+llList2String(booleans ,llList2Integer(ce_prim_physiks ,0)));
ce_prim_physiks = [];

list ce_prim_point_light = llGetPrimitiveParams([PRIM_POINT_LIGHT]); // 23
llOwnerSay("/me\t, PRIM_POINT_LIGHT"+
", "+llList2String(booleans ,llList2Integer(ce_prim_point_light,0))+ // true / false
", "+FormatVector(llList2Vector(ce_prim_point_light,1),3)+ // color
", "+FormatFloat(llList2Float(ce_prim_point_light,2),3)+ // intensity
", "+FormatFloat(llList2Float(ce_prim_point_light,3),3)+ // radius
", "+FormatFloat(llList2Float(ce_prim_point_light,4),3)); // falloff
ce_prim_point_light = [];

list ce_prim_position = llGetPrimitiveParams([PRIM_POSITION]); // 6
llOwnerSay("/me\t, PRIM_POSITION, "+FormatVector(llList2Vector(ce_prim_position ,0),3));
ce_prim_position = [];

list ce_prim_rotation = llGetPrimitiveParams([PRIM_ROTATION]); // 8
llOwnerSay("/me\t, PRIM_ROTATION, "+(string)llList2Rot(ce_prim_rotation ,0));
ce_prim_rotation = [];

list ce_prim_size = llGetPrimitiveParams([PRIM_SIZE]); // 7
llOwnerSay("/me\t, PRIM_SIZE, "+FormatVector(llList2Vector(ce_prim_size ,0),3));
ce_prim_size = [];

list ce_prim_temp_on_rez = llGetPrimitiveParams([PRIM_TEMP_ON_REZ]); // 4
llOwnerSay("/me\t, PRIM_TEMP_ON_REZ, "+llList2String(booleans ,llList2Integer(ce_prim_temp_on_rez ,0)));
ce_prim_temp_on_rez = [];

list ce_prim_type = llGetPrimitiveParams([PRIM_TYPE]); // 9
if(llList2Integer(ce_prim_type,0)==0){llOwnerSay("/me\t, PRIM_TYPE, PRIM_TYPE_BOX"+", "+llList2String(holeshape ,llList2Integer(ce_prim_type,1))+", "+FormatVector(llList2Vector(ce_prim_type,2),3)+", "+FormatFloat(llList2Float(ce_prim_type,3),3)+", "+FormatVector(llList2Vector(ce_prim_type,4),3)+", "+FormatVector(llList2Vector(ce_prim_type,5),3)+", "+FormatVector(llList2Vector(ce_prim_type,6),3));}
if(llList2Integer(ce_prim_type,0)==1){llOwnerSay("/me\t, PRIM_TYPE, PRIM_TYPE_CYLINDER"+", "+llList2String(holeshape ,llList2Integer(ce_prim_type,1))+", "+FormatVector(llList2Vector(ce_prim_type,2),3)+", "+FormatFloat(llList2Float(ce_prim_type,3),3)+", "+FormatVector(llList2Vector(ce_prim_type,4),3)+", "+FormatVector(llList2Vector(ce_prim_type,5),3)+", "+FormatVector(llList2Vector(ce_prim_type,6),3));}
if(llList2Integer(ce_prim_type,0)==2){llOwnerSay("/me\t, PRIM_TYPE, PRIM_TYPE_PRISM"+", "+llList2String(holeshape ,llList2Integer(ce_prim_type,1))+", "+FormatVector(llList2Vector(ce_prim_type,2),3)+", "+FormatFloat(llList2Float(ce_prim_type,3),3)+", "+FormatVector(llList2Vector(ce_prim_type,4),3)+", "+FormatVector(llList2Vector(ce_prim_type,5),3)+", "+FormatVector(llList2Vector(ce_prim_type,6),3));}
if(llList2Integer(ce_prim_type,0)==3){llOwnerSay("/me\t, PRIM_TYPE, PRIM_TYPE_SPHERE"+", "+(string)llList2Integer(ce_prim_type,1)+", "+FormatVector(llList2Vector(ce_prim_type,2),3)+", "+FormatFloat(llList2Float(ce_prim_type,3),3)+", "+FormatVector(llList2Vector(ce_prim_type,4),3)+", "+FormatVector(llList2Vector(ce_prim_type,5),3));}
if(llList2Integer(ce_prim_type,0)==4){llOwnerSay("/me\t, PRIM_TYPE, PRIM_TYPE_TORUS"+", "+llList2String(holeshape ,llList2Integer(ce_prim_type,1))+", "+FormatVector(llList2Vector(ce_prim_type,2),3)+", "+FormatFloat(llList2Float(ce_prim_type,3),3)+", "+FormatVector(llList2Vector(ce_prim_type,4),3)+", "+FormatVector(llList2Vector(ce_prim_type,5),3)+", "+FormatVector(llList2Vector(ce_prim_type,6),3)+", "+FormatVector(llList2Vector(ce_prim_type,7),3)+", "+FormatVector(llList2Vector(ce_prim_type,8),3)+", "+FormatFloat(llList2Float(ce_prim_type,9),3)+", "+FormatFloat(llList2Float(ce_prim_type,10),3)+", "+FormatFloat(llList2Float(ce_prim_type,11),3));}
if(llList2Integer(ce_prim_type,0)==5){llOwnerSay("/me\t, PRIM_TYPE, PRIM_TYPE_TUBE"+", "+llList2String(holeshape ,llList2Integer(ce_prim_type,1))+", "+FormatVector(llList2Vector(ce_prim_type,2),3)+", "+FormatFloat(llList2Float(ce_prim_type,3),3)+", "+FormatVector(llList2Vector(ce_prim_type,4),3)+", "+FormatVector(llList2Vector(ce_prim_type,5),3)+", "+FormatVector(llList2Vector(ce_prim_type,6),3)+", "+FormatVector(llList2Vector(ce_prim_type,7),3)+", "+FormatVector(llList2Vector(ce_prim_type,8),3)+", "+FormatFloat(llList2Float(ce_prim_type,9),3)+", "+FormatFloat(llList2Float(ce_prim_type,10),3)+", "+FormatFloat(llList2Float(ce_prim_type,11),3));}
if(llList2Integer(ce_prim_type,0)==6){llOwnerSay("/me\t, PRIM_TYPE, PRIM_TYPE_RING"+", "+llList2String(holeshape ,llList2Integer(ce_prim_type,1))+", "+FormatVector(llList2Vector(ce_prim_type,2),3)+", "+FormatFloat(llList2Float(ce_prim_type,3),3)+", "+FormatVector(llList2Vector(ce_prim_type,4),3)+", "+FormatVector(llList2Vector(ce_prim_type,5),3)+", "+FormatVector(llList2Vector(ce_prim_type,6),3)+", "+FormatVector(llList2Vector(ce_prim_type,7),3)+", "+FormatVector(llList2Vector(ce_prim_type,8),3)+", "+FormatFloat(llList2Float(ce_prim_type,9),3)+", "+FormatFloat(llList2Float(ce_prim_type,10),3)+", "+FormatFloat(llList2Float(ce_prim_type,11),3));}
if(llList2Integer(ce_prim_type,0)==7){llOwnerSay("/me\t, PRIM_TYPE, PRIM_TYPE_SCULPT"+", \""+llList2String(ce_prim_type,1)+"\", "+(string)llList2Integer(ce_prim_type,2));}
ce_prim_type = [];

//fullbright
list ce_prim_fullbright0 = llGetPrimitiveParams([PRIM_FULLBRIGHT,0]);list ce_prim_fullbright; // 20
llOwnerSay("/me\t, PRIM_FULLBRIGHT, ALL_SIDES, "+llList2String(booleans ,llList2Integer(ce_prim_fullbright0,0)) );
for(i = 0;i <= ce_side; i++) {
ce_prim_fullbright = llGetPrimitiveParams([PRIM_FULLBRIGHT,i]);
if (ce_prim_fullbright != [] && ce_prim_fullbright0 !=ce_prim_fullbright) {
llOwnerSay("/me\t, PRIM_FULLBRIGHT, "+(string)i+", "+llList2String(booleans ,llList2Integer(ce_prim_fullbright,0)) );
}
} ce_prim_fullbright0 = [];ce_prim_fullbright = [];

//shiny & bumpmaping
list ce_prim_bump_shiny0 = llGetPrimitiveParams([PRIM_BUMP_SHINY,0]);list ce_prim_bump_shiny;
llOwnerSay("/me\t, PRIM_BUMP_SHINY, ALL_SIDES, "+llList2String(shinys,llList2Integer(ce_prim_bump_shiny0,0))+ // shiny
", "+llList2String(bumpmapping ,llList2Integer(ce_prim_bump_shiny0,1)) ); // bumpmaping
for(i = 0;i <= ce_side; i++) {
ce_prim_bump_shiny = llGetPrimitiveParams([PRIM_BUMP_SHINY,i]); // 19
if (ce_prim_bump_shiny != [] && ce_prim_bump_shiny0 != ce_prim_bump_shiny) {
llOwnerSay("/me\t, PRIM_BUMP_SHINY, "+(string)i+", "+llList2String(shinys,llList2Integer(ce_prim_bump_shiny,0))+ // shiny
", "+llList2String(bumpmapping ,llList2Integer(ce_prim_bump_shiny,1)) ); // bumpmaping
}
} ce_prim_bump_shiny0 = []; ce_prim_bump_shiny = [];

//color
list ce_prim_color0 = llGetPrimitiveParams([PRIM_COLOR ,0]);list ce_prim_color;
llOwnerSay("/me\t, PRIM_COLOR, ALL_SIDES, "+FormatVector(llList2Vector(ce_prim_color0,0),3)+", "+FormatFloat(llList2Float(ce_prim_color0,1),3));
for(i=0;i <= ce_side;i++) {
ce_prim_color = llGetPrimitiveParams([PRIM_COLOR,i]); // 18
if (ce_prim_color != [] && ce_prim_color0 !=ce_prim_color) {
llOwnerSay("/me\t, PRIM_COLOR, "+(string)i+", "+FormatVector(llList2Vector(ce_prim_color,0),3)+", "+FormatFloat(llList2Float(ce_prim_color,1),3) );
}
}ce_prim_color = [];ce_prim_color0 = [];

//texgen
list ce_prim_texgen0 = llGetPrimitiveParams([PRIM_TEXGEN ,0]);list ce_prim_texgen;
llOwnerSay("/me\t, PRIM_TEXGEN, ALL_SIDES, "+llList2String(texgens,llList2Integer(ce_prim_texgen0,0)));
for(i = 0;i <= ce_side ;i++ ) {
ce_prim_texgen = llGetPrimitiveParams([PRIM_TEXGEN ,i]); // 22
if (ce_prim_texgen != [] && ce_prim_texgen0!=ce_prim_texgen) {
llOwnerSay("/me\t, PRIM_TEXGEN, "+(string)i+", "+llList2String(texgens,llList2Integer(ce_prim_texgen,0)) ); // type
}
}ce_prim_texgen = [];ce_prim_texgen0 = [];

//texture
list ce_prim_texture0 = llGetPrimitiveParams([PRIM_TEXTURE,0]);list ce_prim_texture;
llOwnerSay("/me\t, PRIM_TEXTURE, ALL_SIDES"+
", \""+llList2String(ce_prim_texture0,0)+ // name
"\", "+FormatVector(llList2Vector(ce_prim_texture0,1),3)+ // repeats
", "+FormatVector(llList2Vector(ce_prim_texture0,2),3)+ // offsets
", "+FormatFloat(llList2Float(ce_prim_texture0,3),3)); // rotation
for(i = 0;i <= ce_side;i++) {
ce_prim_texture = llGetPrimitiveParams([PRIM_TEXTURE,i]); // we dont put everywhere a komata
if ( ce_prim_texture != [] &&
(
llList2String(ce_prim_texture0,0) != llList2String(ce_prim_texture,0) ||
llList2Vector(ce_prim_texture0,1) != llList2Vector(ce_prim_texture,1) ||
llList2Vector(ce_prim_texture0,2) != llList2Vector(ce_prim_texture,2) ||
llList2Float(ce_prim_texture0,3) != llList2Float(ce_prim_texture,3)
)
) {
llOwnerSay("/me\t, PRIM_TEXTURE, "+(string)i+
", \""+llList2String(ce_prim_texture,0)+ // name
"\", "+FormatVector(llList2Vector(ce_prim_texture,1),3)+ // repeats
", "+FormatVector(llList2Vector(ce_prim_texture,2),3)+ // offsets
", "+FormatFloat(llList2Float(ce_prim_texture,3),3) ); // rotation
}
}ce_prim_texture0 = [];ce_prim_texture = [];

llOwnerSay("/me ]);");
llOwnerSay("/me //This Script used " + (string)(((4*16384) - llGetFreeMemory())/1024) + " kBytes");
llSetObjectName(ce_primname); // what you take you must give back
}
}
</lsl>

would output something like this:

<pre>
[20:31] llSetPrimitiveParams([
[20:31] PRIM_FLEXIBLE, FALSE, 0, 0.0, 0.0, 0.0, 0.0, ZERO_VECTOR
[20:31] , PRIM_MATERIAL, PRIM_MATERIAL_WOOD
[20:31] , PRIM_PHANTOM, FALSE
[20:31] , PRIM_PHYSICS, FALSE
[20:31] , PRIM_POINT_LIGHT, FALSE, ZERO_VECTOR, 0.0, 0.0, 0.0
[20:31] , PRIM_POSITION, <192.339,170.855,87.438>
[20:31] , PRIM_ROTATION, <-0.50509, 0.49964, 0.49491, 0.50031>
[20:31] , PRIM_TEMP_ON_REZ, FALSE
[20:31] , PRIM_TYPE, PRIM_TYPE_BOX, PRIM_HOLE_DEFAULT, <0.20,0.705,0.0>, 0.950, ZERO_VECTOR, <1.0,1.0,0.0>, ZERO_VECTOR
[20:31] , PRIM_FULLBRIGHT, ALL_SIDES, FALSE
[20:31] , PRIM_BUMP_SHINY, ALL_SIDES, PRIM_SHINY_NONE, PRIM_BUMP_NONE
[20:31] , PRIM_COLOR, ALL_SIDES, <1.0,1.0,1.0>, 1.0
[20:31] , PRIM_TEXGEN, ALL_SIDES, PRIM_TEXGEN_DEFAULT
[20:31] , PRIM_SIZE, <10.0,10.0,10.0>
[20:31] , PRIM_TEXTURE, ALL_SIDES, "d45e98e8-f54c-c6c5-6012-6431184d0a16", <0.50,2.0,0.0>, ZERO_VECTOR, 1.571
[20:31] , PRIM_TEXTURE, 1, "d45e98e8-f54c-c6c5-6012-6431184d0a16", <2.0,2.0,0.0>, ZERO_VECTOR, 1.571
[20:31] , PRIM_TEXTURE, 2, "d45e98e8-f54c-c6c5-6012-6431184d0a16", <2.0,2.0,0.0>, ZERO_VECTOR, 1.571
[20:31] , PRIM_TEXTURE, 3, "d45e98e8-f54c-c6c5-6012-6431184d0a16", <2.0,2.0,0.0>, ZERO_VECTOR, 1.571
[20:31] , PRIM_TEXTURE, 4, "6501bbbc-f754-bfff-dfbe-41f7492a077b", <1.0,2.10,0.0>, <0.0,0.450,0.0>, 1.571
[20:31] , PRIM_TEXTURE, 6, "d45e98e8-f54c-c6c5-6012-6431184d0a16", <0.50,0.20,0.0>, <0.40,0.280,0.0>, 1.571
[20:31] ]);
[20:31] //This Script used 40 kBytes
</pre>

If your client does not support to turn of the time you still have to cut cut out "[20:31] " from the beginning of each line in order to use the output in a code.
Anylyn Hax 18:50, 4 July 2010 (UTC)

== Spinning DanceBall with random colors ==

People keep asking me how to make a danceball, so I thought I might publish one here and show same time a exemple of how to use the upper Human Readable Output script. 
- remember to cut out the PRIM_POSITION and possible the PRIM_ROTATION stanza. 
- remember to make (or by) some dances and fill the danceball with up to 11 such animations. 
If you like to try to do some animations like dances or other by yourself, I recommend the fantastic work of Vince Invincible and Zi Ree the QAvimator. It is a free alternative to Poser and Maya, and it runs on Windows, Mac OS X, and Linux. http://www.qavimator.org/

<lsl>
list anis;
integer CHANNEL;
integer lisi;

MakeTheBall()
{
llSetTimerEvent(10);
llSetPrimitiveParams([
PRIM_FLEXIBLE, FALSE, 0, 0.0, 0.0, 0.0, 0.0, ZERO_VECTOR
, PRIM_MATERIAL, PRIM_MATERIAL_WOOD
, PRIM_PHANTOM, FALSE
, PRIM_PHYSICS, FALSE
, PRIM_POINT_LIGHT, FALSE, ZERO_VECTOR, 0.0, 0.0, 0.0
, PRIM_SIZE, <1.5,1.5,1.5>
, PRIM_TEMP_ON_REZ, FALSE
, PRIM_TYPE, PRIM_TYPE_SPHERE, 0, <0.0,1.0,0.0>, 0.0, ZERO_VECTOR, <0.0,1.0,0.0>
, PRIM_FULLBRIGHT, ALL_SIDES, TRUE
, PRIM_BUMP_SHINY, ALL_SIDES, PRIM_SHINY_HIGH, PRIM_BUMP_NONE
, PRIM_COLOR, ALL_SIDES, <0.705,0.449,0.807>, 1.0
, PRIM_TEXGEN, ALL_SIDES, PRIM_TEXGEN_DEFAULT
, PRIM_TEXTURE, ALL_SIDES, "42d9ac0b-d423-94f0-9fd5-db3162b0d4ea", <4.0,12.0,0.0>, <0,0,0>, 0.5
]);
llSetTextureAnim(ANIM_ON | SMOOTH | LOOP , ALL_SIDES, 0, 1, 0.0, 1.0, 0.1);
anis = ["STOP"];
integer a=0;
while(a<llGetInventoryNumber(INVENTORY_ANIMATION) && a<9){anis+=llGetInventoryName(INVENTORY_ANIMATION,a++);};
return;
}

default
{
state_entry(){MakeTheBall();}
changed(integer change){if (change & CHANGED_INVENTORY){MakeTheBall();}}
timer()
{
float rot = llFrand(1.0);
float gruen = llFrand(1.0);
float blau = llFrand(1.0);
//llSetColor(<rot,gruen,blau> , ALL_SIDES );
llSetLinkPrimitiveParamsFast(LINK_THIS,[PRIM_COLOR, ALL_SIDES, <rot,gruen,blau>, 1.0]);
llSetTimerEvent(llFrand(25.0));
}
touch_start(integer total_number){llRequestPermissions(llDetectedKey(0), PERMISSION_TRIGGER_ANIMATION);}
run_time_permissions(integer perm)
{
if (perm & PERMISSION_TRIGGER_ANIMATION)
{
CHANNEL = llRound(llFrand(-99999999.9));
lisi = llListen(CHANNEL,"","","");
llDialog(llGetPermissionsKey(), "Choose the dance ",anis,CHANNEL);
}
}
listen(integer chan, string name, key id, string mess)
{
if ( chan==CHANNEL && id == llGetPermissionsKey() && mess != "STOP")
{llStartAnimation(mess);llListenRemove(lisi);}
if ( chan==CHANNEL && id == llGetPermissionsKey() && mess == "STOP")
{
integer x = 0; while(x < llGetInventoryNumber(INVENTORY_ANIMATION))
{llStopAnimation(llGetInventoryName(INVENTORY_ANIMATION, x++));}
llListenRemove(lisi);
}
}
}
</lsl>

== Viewer 2 and privacy issues ==

We can see that the viewer 2 is very hardly pushed by the Lindens this days.
But there are some privacy issues when you let everybody run java scripts on your system.
As long as the integrated browser accepts all cookies and runs all java scripts, I is not just stupid but irresponsible to use the viewer2.
Under this light can someone explain me why I should use the viewer ?

{{Jira Reporter}}{{Skills}}
----

Why should you use Internet Explore or Firefox or Opera as internet browser? They allow javascripts as the LL integrated browser. Do you judge a viewer bad because it just integrate an internet browser working like all the other internet browsers in the world?. Just disable cookies and javascripts in the Preferences. There is no reason to NOT use the new great LL viewer. Anyway I wonder where this informations are useful here. Just for gossip?
There is no Viewer 2 privacy issues. If you are worried about this, start to remove al your internet browsers.