Second Life Wiki - User contributions [en]

Email

2015-02-19T22:28:20Z

Ponder Song: spelling

{{LSL_Event
|inject-2={{Issues/SVC-23}}{{Issues/SCR-499}}
|event_id=21|event_delay
|event=email
|p1_type=string|p1_name=time|p1_desc=In the <code>(string)[[llGetUnixTime]]</code> format|p1_hover=In the (string)llGetUnixTime format
|p2_type=string|p2_name=address|p2_desc
|p3_type=string|p3_name=subject|p3_desc
|p4_type=string|p4_name=message|p4_desc
|p5_type=integer|p5_name=num_left|p5_desc=The number of emails remaining in the email queue.{{Footnote|The email being processed is not counted as it has already been popped from the queue.}}|p5_hover=The number of emails left in the email queue.
|event_desc=Triggered as a result of calling [[llGetNextEmail]] where there is a matching email in the email queue.
|event_footnote=The email queue is associated with the prim and any script in the prim can access it. <br/> The prim's email address is its key with "@lsl.secondlife.com" appended, <code>[[llGetKey]]() + "@lsl.secondlife.com"</code>{{Footnote|1=Preview grid email address are constructed differently: <code style="font-size: 123%;">[[llGetKey]]() + "@lsl." + grid + ".lindenlab.com"</code>; for the main beta grid set grid to {{String|aditi}}.|2=Beta grid email address are constructed differently: llGetKey() + {{String|@lsl.}} + grid + {{String|.lindenlab.com}}; for the main beta grid set grid to {{String|aditi}}.}}.
|constants
|spec=The email event is triggered as a result of calling [[llGetNextEmail]] when there is an email that matches [[llGetNextEmail]]'s optional filters. The first email that matches the filters is removed from the email queue and its data is used as the parameters for this event. If no email matches the filters but the queue is not empty this event is not triggered. Besides the effects of filtering, the email queue is {{HoverText|FIFO|First In First Out}}.
|caveats=
* The email queue is limited to 100 emails, any email after that is bounced.
* The message field may have a maximum of 1000 single-byte characters. This count includes the header information ('''address''', '''subject''', etc).
* [[llEmail|Emails sent from within SL]] will have their message body prefixed with a header detailing the originating prim. See [[llEmail]] for more details.
* Due to bug {{Jira|SVC-23}} (present since 2005), objects may stop receiving emails completely until either the region is restarted or the object crosses a region boundary (resetting the script doesn't help).

Copiable objects may be drag-copied inworld to create a new duplicate in its place and restarted. The new copy will (usually) work in its place, and the old unworking object may be deleted. (ed. by Nyoko Salome 120816)

Emails sent may eventually be received after a restart/region-cross. Hence, don't rely on this event for reliable inter-region messaging.
|constants
|examples=
<source lang="lsl2">
default
{
state_entry()
{
llSetTimerEvent(5.0);
}

timer()
{
// get next email, don't filter by sender or subject
llGetNextEmail("", "");
}

email( string time, string address, string subject, string message, integer num_left )
{
// if we received an email from an object within Second Life
if (llGetSubString(address, -19, -1) == "@lsl.secondlife.com")
// {
message = llDeleteSubString(message, 0, llSubStringIndex(message, "\n\n") + 1);
// }

// PUBLIC_CHANNEL has the integer value 0
llSay(PUBLIC_CHANNEL, message);

// if there's another email in the queue waiting
// get next email, don't filter by sender or subject
if(num_left)
llGetNextEmail("", "");
}
}
</source>
|helpers
|also_header
|also_events
|also_functions={{LSL DefineRow||[[llEmail]]|}}
{{LSL DefineRow||[[llGetNextEmail]]|}}
|also_articles
|also_footer
|notes=
For tips on how to process emails sent from within SL, see the entry on [[llEmail#Prim2Prim_Email|llEmail]].
|mode
|deprecated
|cat1=Email
|cat2
|cat3
|cat4
}}

Fix Small Prims

2014-02-13T16:58:01Z

Ponder Song: /* About */ grammar.

{{LSL Header}}{{RightToc}}
<div id="box">
== About ==
<div style="padding: 0.5em">
Fix Small Prims by [[User:Emma_Nowhere|Emma Nowhere]]

Now updated to use [https://jira.secondlife.com/browse/SVC-224 LLGetLinkPrimitiveParams].

In Second Life, no prim can be less that .01 meters in any given dimension (width, length, or height). When you try to resize an object, you often find you can't shrink it below a certain size. This is because one of the prims in the object is already at its minimum size in one of it's dimensions. This script checks every prim in an object and slightly increases the sizes of the prims which are already at their smallest possible sizes, so that the overall object that the prim is part of can be scaled down. This usually lets you reduce the object in size by an additional 20%. You can repeat the process several times if you're not able to shrink the object enough on the first try.

In the instructions below, we'll refer to your object that you want to resize, such as a necklace or a tree, as a "linkset". We call it this because the object consists of a linked set of prims, rather than one single prim.

If you're not familiar with how prims and linking work, please read the following wiki pages:

[[Prim]]

[[Link]]

How to use with menu:

#Install this script in the root prim of a linked set of prims (aka "linkset")
#Type /1fsp to show the menu
#Hit the "Fix" button to fix all the small prims
#Resize the linkset object to the desired size with the Viewer Editing Tools
#Type /1fsp to show the menu again
#Hit the "Finish" button to remove the script and finalize prim sizes

(Advanced) How to use with chat commands:

#Install this script in the root prim of a linked set of prims (aka "linkset").
#Type /1fsprun to fix all the small prims
#Resize the linkset object to the desired size with the Viewer Editing Tools
#Type /1fsprestore if you need to return them to their original sizes (you should only use this for no-copy objects, otherwise make a copy before you start)
#Type /1fspcleanup to remove the scripts from the linkset and finalize prim sizes

'''IMPORTANT:''' You should always make a backup copy of the object before using this script.

</div></div>

<div id="box">

== FixSmallPrims ==
<div style="padding: 0.5em">
<lsl>
///////////////////////////////////////////////////////////////////////////////
// FixSmallPrims2
// by Emma Nowhere
//
// Last modified: 5/30/2010
//
// How to use with menu:
// 1. Install this script in the root prim of a linked set of prims (aka "linkset")
// 2. Type /1fsp to show the menu
// 3. Hit the "Fix" button to fix all the small prims
// 4. Resize the linkset object to the desired size with the Editing Tools
// 5. Type /1fsp to show the menu again
// 6. Hit the "Finish" button to remove the script and finalize prim sizes
//
// (Advanced) How to use via chat commands:
// 1. Install this script in the root prim of a linked set of prims (aka "linkset")
// 2. Type /1fsp to show the menu
// 3. Type /1fsprun to fix all the small prims
// 4. Resize the linkset object to the desired size with the Editing Tools
// 5. Type /1fsprestore to return them to their original sizes
// 6. Type /1fspcleanup to remove the script and finalize prim sizes

integer CHANNEL = 1;
integer MENU_CHANNEL = -1001;

list backupScales = [];
integer backupStored = FALSE;

list rescaleFlags = [];

backup() {
if (!backupStored) {
llOwnerSay("Backing up prim sizes");
backupScales = [];
integer p = llGetNumberOfPrims();
integer i = 0;
for (i = 1; i <= p; i++)
{
list params = llGetLinkPrimitiveParams(i, [PRIM_SIZE]);
vector scale = llList2Vector(params, 0);
backupScales = backupScales + [scale];
}
backupStored = TRUE;
llOwnerSay("Prim sizes backed up");
}
}

restore() {
if (backupStored) {
llOwnerSay("Restoring previously backed up prim sizes");
integer p = llGetNumberOfPrims();
integer i = 0;
for (i = 1; i <= p; i++)
{
vector scale = llList2Vector(backupScales, i - 1);
llSetLinkPrimitiveParamsFast(i, [PRIM_SIZE, scale]);
}
llOwnerSay("Previously backed up prim sizes restored");
}
rescaleFlags = [];
}

cleanup() {
llOwnerSay("Cleaning up FixSmallPrims data and finalizing prim sizes");
integer p = llGetNumberOfPrims();
integer i = 0;
for (i = 1; i <= p; i++)
{
vector backupScale = llList2Vector(backupScales, i - 1);
integer rescaleI = (i - 1) * 3;
integer rescaleX = llList2Integer(rescaleFlags, rescaleI);
integer rescaleY = llList2Integer(rescaleFlags, rescaleI + 1);
integer rescaleZ = llList2Integer(rescaleFlags, rescaleI + 2);

list params = llGetLinkPrimitiveParams(i, [PRIM_SIZE]);
vector scale = llList2Vector(params, 0);

if (rescaleX) {
scale.x = backupScale.x;
}

if (rescaleY) {
scale.y = backupScale.y;
}

if (rescaleZ) {
scale.z = backupScale.z;
}

if (rescaleX || rescaleY || rescaleZ) {
llOwnerSay("Cleaning size of linked prim #" + (string)i);
llSetLinkPrimitiveParamsFast(i, [PRIM_SIZE, scale]);
}
}

llOwnerSay("Deleting FixSmallPrims script");
llRemoveInventory(llGetScriptName());
}

process() {
restore();
backup();

llOwnerSay("Starting fixing prims");
rescaleFlags = [];
integer p = llGetNumberOfPrims();
integer i = 0;
for (i = 1; i <= p; i++)
{
list params = llGetLinkPrimitiveParams(i, [PRIM_SIZE]);
vector scale = llList2Vector(params, 0);

integer rescaleX = FALSE;
integer rescaleY = FALSE;
integer rescaleZ = FALSE;

if (scale.x < .015) {
scale.x = .015;
rescaleX = TRUE;
}

if (scale.y < .015) {
scale.y = .015;
rescaleY = TRUE;
}

if (scale.z < .015) {
scale.z = .015;
rescaleZ = TRUE;
}

if (rescaleX || rescaleY || rescaleZ) {
llOwnerSay("Fixing size of linked prim #" + (string)i);
llSetLinkPrimitiveParamsFast(i, [PRIM_SIZE, scale]);
}
rescaleFlags = rescaleFlags + [rescaleX, rescaleY, rescaleZ];
}
llOwnerSay("Done fixing prims\n\nResize your object and type /" + (string)CHANNEL + "fsp for menu when done.\n\n");
}

menu() {
llDialog(llGetOwner(),
"Fix Small Prims\n\nMake a backup of your object first.\n\nPlease choose an option:\n",
["Fix", "Finish"], MENU_CHANNEL);
}

default
{
state_entry()
{
llListen(CHANNEL, "", llGetOwner(), "");
llListen(MENU_CHANNEL, "", llGetOwner(), "");
llOwnerSay("FixSmallPrims Ready");
llOwnerSay("Type /" + (string)CHANNEL + "fsp for menu");
}

on_rez(integer start_param) {
llOwnerSay("FixSmallPrims Installed");
llOwnerSay("Type /" + (string)CHANNEL + "fsp for menu");
}

listen(integer channel, string name, key id, string message)
{
if (message == "fsp") {
menu();
}
else if (message == "fsptest") {
llOwnerSay("FixSmallPrims script is installed and ready");
if (backupStored) {
llOwnerSay("Original prim sizes have been backed up");
}
}
else if (message == "fspbackup") {
backup();
}
else if (message == "fsprestore") {
restore();
}
else if ((message == "fspcleanup") || (message == "Finish")) {
cleanup();
}
else if ((message == "fsprun") || (message == "Fix")) {
process();
}

}
}

</lsl>
</div></div>
{{#vardefine:sort|Fix Small Prims}}{{LSLC|Library}}

How far does my voice carry?

2010-03-20T22:02:58Z

Ponder Song: tyop fix

{{KBmaster}}

{{KB Communication}}Use this guide to help you determine how far you need to be from someone in order for them to hear you talking or typing.

==Text Chat==

Text chat (as seen on the '''Local Chat''' tab of your chat history window) comes in several different flavors, each with its own range:

* '''Normal text chat''' has a range of 20 meters; you must be standing within 20 meters of the source to hear the chat. To use normal text chat, press '''Enter''', input your text into the chat bar, and then press '''Enter''' or press the '''Say''' button.
* '''Shouted text chat''' has a range of 100 meters. If you are addressing a large crowd, or someone very far away, you can use shouted text. To shout, press '''Enter''', input your text into the chat bar, then press '''Ctrl-Enter''' or click the dropdown menu and select '''Shout'''.
* '''Whispered''' text only has a range of 10 meters. To whisper, press '''Enter''', input your text into the chat bar, then click the dropdown menu and select '''Whisper'''. Whispered text is also used by objects that are running Resident-created scripts; oftentimes scripted vending machines will whisper, so as not to disturb other shoppers.
* '''[[How do I Instant Message (IM) someone?|Instant Messages]], [[How do I Instant Message (IM) a group of people at once?|Group Chats, and Friend Conferences]]''' have no arbitrary distance limitations. You can send an instant message to someone who is anywhere in Second Life®!

{{KBtip| Text chat ranges exist for your convenience and sanity; just like in real life, you shouldn't shout unless it's necessary! Otherwise, you may disrupt the conversations of other nearby Residents.
}}

==Voice Chat==

Your listening distance for voice chat is a little trickier to figure out than with text chat:

* In your Voice Chat preferences ('''Edit > Preferences > Voice Chat tab''') you may choose to either '''Hear Voice Chat from camera position''', or '''Hear Voice Chat from avatar position'''. Because this choice determines the location of your "ears" for listening to Voice Chat, it will affect the distance from which you can hear someone speaking.
* You are able to hear Voice Chat up to 60 meters from your listening position. If you have '''Hear Voice Chat from camera position''' selected, this means you can hear Voice Chat from up to 110 meters away (50 meters camera tether + 60 meters from your camera). Under special circumstances, Linden Lab may choose to alter these distance settings on a Region-by-Region basis.
* In ''all cases'', if you are able to hear another Resident, his name will appear in the '''Active Speakers''' window, which you can activate by pressing the button to the left of '''Talk''' on the toolbar at the bottom of your screen. This holds true even if the other Resident is hiding or otherwise invisible.
* Group voice chat and direct calls have no distance limitations. Group voice chat and direct peer-to-peer voice chat will always work, regardless of distance.

For more detailed information on voice chat, see [[How to use voice]].
{{KBtrivia|1= Voice chat distance limits are enforced by our system in such a way that they cannot be overridden by changes to an open source Viewer. In other words: It's impossible to use a modified Second Life Viewer to remove the hearing range limits described in this article.
}}

[[Category:Creators]]
[[Category:Chat and IM]]
[[Category:Coding Scripts]]
[[Category:Educators]]
[[Category:Second Life for Beginners]]
[[Category:General Avatar Information]]
[[Category:Business Owners]]
[[Category:General Second Life Software Information]]

[[Category:Knowledge Base]]