Second Life Wiki - User contributions [en]

User:Tano Toll

2016-02-05T13:11:01Z

Tano Toll:

Some of my work for the public domain:

* [[TMCP]] - Tano's MLP Compatible Pose Scripts - poseball free drop-in replacement for MLPv2

* [[ParcelChatRelay]] - Parcel Chat Relay efficiently allows parcel-wide channel0 talk

* [[Stream_Music_In_PHP]] - Stream a static mp3 stream, synchronized for all listeners, using php

* [[SimpleMLPStylingScript]] - Simple MLP/TMCP compatible styling script example.

* [[User:Tano_Toll/LSL_Tips_and_tricks]] - Some tips and tricks

User:Tano Toll/LSL Tips and tricks

2016-02-05T12:47:17Z

Tano Toll: some tips'n'tricks

Some common, or less common, LSL tips, tricks and `hacks` i'd like to share.

== Hack 1 : Use lists for typecasting to save bytes ==

Problem example:

<source lang="lsl2">
string s = "Amount: "+(string)amount+"L$ by avatar "+name+" with key "+(string)id;
</source>

Hacked solution:

<source lang="lsl2">
string s = (string)["Amount: ", amount, "L$ by avatar ",name," with key ", id];
</source>

Explanation:
Typecasting a list to string will auto-typecast all elements in the list (without spacers). If you need spacers, you could use llDumpList2String(list, seperator)

Example usage:

<source lang="lsl2">
llOwnerSay ((string)["Free memory: ",llGetFreeMemory()]);
</source>

Justification: Only 1 typecast and a list declaration is needed, which saves bytes when you'd have to do many typecasts. Also, it makes your code more readable.

== Hack 2: Abuse sensor event to emulate a 2nd timer. ==
In need of a second and independant timer? Of course you can just multiplex your timer. But, if your script not uses llSensor() or llSensorRepeat() for anything else, you can abuse this as a second timer. Preferably do not use this for timers with a low interval as there is some overhead.

How:
1. Set up an llSensorEvent() with an impossible combination

<source lang="lsl2">
llSensorRepeat ("noname", "invalidkey", AGENT|ACTIVE, 0.0, 0.0, 30.0);
</source>

2. Use the no_sensor() event as alternate timer

<source lang="lsl2">
no_sensor() {
llOwnerSay ("Timer 2");
}
</source>

== Hack 3: Create a better PRNG ==
The pseudo random number generator available to LSL scripts is far from perfect.
A better -albeit slower- way of generating pseudo random numbers is to use llMD5String().

<source lang="lsl2">
string seed="initvalue";
integer rnd() {
seed = llMD5String ("Some constant" + seed, 0); //feed seed to itself. You can add more entropy if you like
return (integer)("0x"+llGetSubString(seed, 0, 6); //will return a positive integer 28-bits wide
//or:
//return (integer)("0x"+llGetSubString(seed, 0, 7); //will return a signed integer 32-bits wide
}
</source>

imperfect usage example:

<source lang="lsl2">
seed="example";
integer A = rnd() % 100; //A = 0..99
</source>

== Hack 4: Use notecards without notecards ==
Not as much a hack, yet an unknown feature by many.
You want to use a configuration or data notecard, but not include a notecard in your product? Totally possible:

1. Create a notecard in your inventory and fill in the data
2. Copy the UUID key of this notecard and paste it in your script as notecard name
3. Your script can read the notecard as normal (as if it was a notecard in the object).

Catch: If you change the contents of the notecard, the key will change!

== Hack 5: Variable parameters ==
Yet again, just an overlooked feature.
Suppose you have a function, and you want it to accept various types as parameter. Much like 'overloaded' functions in typed languages, or typeless functions.

Answer: just use a list!
Example

<source lang="lsl2">
print (list data) {
llSay (0, llList2String(data,0));
}
print ([0]); //prints '0'
print ([1.0]); //prints '1.00000000'
print (["I have a cow"]); //prints 'I have a cow'
</source>
Of course your function has to be type aware (or type-ignorant).

== Hack 6: Formatting floats ==
a short way to imperfectly print floats. May be adequate for many cases.

<source lang="lsl2">
//format float to string
//by Tano Toll 2015 - public domain

//note that this will work for most but not any values. still it serves my needs.
//fails very large numbers (> +- maxint) and for very small negative values of zero.
//so -0.9 will be mistranslated. so will 1e20

//fixed precision (1 decimal after seperator):
string formatFloat (float value) {
return llGetSubString((string) value, 0, llStringLength((string) ((integer) value))+1); //1 bit precision
}

//arbitrary precision (N decimals after decimal seperator)
string formatFloat2 (float value, integer precision) {
return llGetSubString((string) value, 0, llStringLength((string) ((integer) value))+precision); //1 bit precision
}

//example:
default
{
state_entry()
{
llSay(0, (string) [formatFloat(PI)," ", formatFloat(-PI), " ", formatFloat2(-PI, 6), " ", formatFloat (-0.01), " ",
formatFloat (-0.999999999999), " ", formatFloat (1e8), " ",formatFloat (1e9), " ",formatFloat (1e10), " ",
formatFloat (-2e8), " ", formatFloat (-2e9), " ", formatFloat (-2e10), " ", formatFloat (-2e30), " ", formatFloat (1e-30)] );
}

}
</source>

--[[User:Tano Toll|Tano Toll]] ([[User talk:Tano Toll|talk]]) 04:47, 5 February 2016 (PST)

Pseudo-random Number Generator

2013-02-19T22:45:08Z

Tano Toll: /* Seedable PRNG Based On MD5 Hashing */

{{LSL Header}}

See also: [[llFrand]], [[llListRandomize]], [[Seedable_PRNG]]

== Seedable PRNG Based On Multiply/ Add/ Overflow ==

Here's a Pseudo-random Number Generator - I ([[User:Xaviar Czervik|Xaviar Czervik]]) just made it up off the top of my head - so it has no mathematical research behind it to prove it's random... I've tested it for a while and it looks random to me, about the same as llFrand(). But what ever. Sue me. The main reason that I use it so that I can test scripts, and then when it blows up because of a math error, I can just run the script again an it will use the same numbers, in the same order.

I use this for determining a random channel for two (or more) objects to talk on. This allows the scripts to talk without users being able to intercept the messages - and even if they do - then the channel will change in a minute or two - so no harm done.

<lsl>
// IMPORTANT: Change the following numbers before using!
integer seed1 = 0x053FA20C;
integer seed2 = 0x3B1264D5;
integer seed1Mod = 0x71B5F252;
integer seed2Mod = 0x56A0E61D;

integer rand(integer spread) {
seed1 = (seed1 * seed1Mod + 0xB);
seed2 = (seed2 * seed2Mod + 0xB);
seed2Mod = seed1Mod;
seed1Mod = seed1 * seed2;
return seed1Mod % spread;
}

</lsl>
The below code is exactly the same as the above, only it is much faster. Thanks to Strife Onizuka.
<lsl>
integer rand(integer spread) {
seed2 = (seed2 * seed2Mod + 0xB);
return (seed1Mod = ((seed1 = (seed1 * (seed2Mod = seed1Mod) + 0xB)) * seed2)) % spread;
}
</lsl>
Example code to test the randomness (Is that a word?) of the generator.
<lsl>
default {
state_entry() {
integer i = 0;
integer min = 0x7FFFFFFF;
integer max = -0x7FFFFFFF;
integer total = 0;
while (i < 100000000) {
integer r = rand(0x7FFFFFFF);
if (r < min) {
min = r;
}
if (r > max) {
max = r;
}
total += r;
i++;
}
llOwnerSay("Min: " + (string)min);
llOwnerSay("Max: " + (string)max);
llOwnerSay("Average: " + (string)(total/100000000));

}
}
</lsl>

Note: A pattern of digits like yyyymmddnn often works as a seed that changes often enough, ''e.g.'', test with 2007090103 == 2,007,090,103 as the 3rd try of the 1st day of the 9th month of the 2007th year, except you must take care to avoid confusing yourself with integers larger than the 2,147,483,647 limit of 32-bit signed arithmetic.

== Conventional Linear Congruential Seedable PRNG Based On Multiply/ Add/ Overflow ==

Note: Google Groups sci.math cites Knuth & Lewis suggesting the following linear congruential generator for 32-bit arithmetic processors. Someone skilled in the relevant mathematics should be able to prove that these choices of multiplier and addend provides results that feel more random. Someone skilled in Google might find yet more popular choices than these. People say the choose function returning the quotient rather than the remainder matters: try counting odd results and even results from the pseudorandom() routine to see why.

<lsl>
integer seed = 2007090103;

integer pseudorandom()
{
seed = 1664525 * seed + 1013904223;
return seed;
}

integer choose(integer count)
{
integer nonnegative = 0x7fffFFFF;
integer choice = pseudorandom() & nonnegative;
return ((choice / (nonnegative / count)) % count);
}

default
{
state_entry()
{
string line;
integer index;

line = "";
for (index = 0; index < 9; ++index)
{
line += " " + (string) pseudorandom();
}
llOwnerSay(line);

line = "";
for (index = 0; index < 30; ++index)
{
line += " " + (string) (1 + choose(6));
}
llOwnerSay(line);

llOwnerSay("OK");
}
}
</lsl>

== Seedable PRNG Based On MD5 Hashing ==
I haven't noticed any irregular behavior in this one, i would love to know what you guys think - Kyrah Abattoir

<lsl>

string seed = "";//Any String you want as your initial seed.

//this version will pull a random int from 0 to max int
integer NextInt()
{
seed = llMD5String(seed,0);
integer value = (integer)("0x"+llGetSubString(seed,0,6));
return value;
}

//This one will limit the result from 0 to the range indicated
integer NextIntClamped(integer max)
{
max++;
seed = llMD5String(seed,0);
integer value = (integer)("0x"+llGetSubString(seed,0,6))%max;
return value;
}

//0 to 1 duh.
integer NextBool()
{
return NextIntClamped(1);
}

</lsl>

I think MD5 random is just fine. I did some testing with ent and dieharder (random number test suites) based on recursed md5 'random' and it seems to have superior pseudo-random-number charactaristics. The only drawback is the decreased performance, which is usually (for games etc) not an issue at all.
My version (below) added a little extra entropy using timestamps. You could inject other sources of entropy as well. [[User:Tano Toll|Tano Toll]] Tano Toll
<lsl>
string md5="seed";
integer rnd() {
//add in more entropy if you like, like touch position (detectedtouchST etc).
//however, seeding the md5 with itself is already quite sufficient
md5=llMD5String(md5+(string)llGetUnixTime()+(string)llGetTime(), 0x5EED);
return (integer)("0x"+llGetSubString(md5,0,7));
}

float frnd (float max) {
//this suffers a few bit rounding errors
return llFabs(max * rnd()/0x80000000);
}

</lsl>

<pre>
$ ent random.outmd5
Entropy = 7.999961 bits per byte.

Optimum compression would reduce the size
of this 4222048 byte file by 0 percent.

Chi square distribution for 4222048 samples is 231.03, and randomly
would exceed this value 75.00 percent of the times.

Arithmetic mean value of data bytes is 127.4654 (127.5 = random).
Monte Carlo value for Pi is 3.140641831 (error 0.03 percent).
Serial correlation coefficient is 0.000047 (totally uncorrelated = 0.0).

</pre>

{{LSLC|Library}}

Pseudo-random Number Generator

2013-02-19T22:43:32Z

Tano Toll: /* Seedable PRNG Based On MD5 Hashing */

{{LSL Header}}

See also: [[llFrand]], [[llListRandomize]], [[Seedable_PRNG]]

== Seedable PRNG Based On Multiply/ Add/ Overflow ==

Here's a Pseudo-random Number Generator - I ([[User:Xaviar Czervik|Xaviar Czervik]]) just made it up off the top of my head - so it has no mathematical research behind it to prove it's random... I've tested it for a while and it looks random to me, about the same as llFrand(). But what ever. Sue me. The main reason that I use it so that I can test scripts, and then when it blows up because of a math error, I can just run the script again an it will use the same numbers, in the same order.

I use this for determining a random channel for two (or more) objects to talk on. This allows the scripts to talk without users being able to intercept the messages - and even if they do - then the channel will change in a minute or two - so no harm done.

<lsl>
// IMPORTANT: Change the following numbers before using!
integer seed1 = 0x053FA20C;
integer seed2 = 0x3B1264D5;
integer seed1Mod = 0x71B5F252;
integer seed2Mod = 0x56A0E61D;

integer rand(integer spread) {
seed1 = (seed1 * seed1Mod + 0xB);
seed2 = (seed2 * seed2Mod + 0xB);
seed2Mod = seed1Mod;
seed1Mod = seed1 * seed2;
return seed1Mod % spread;
}

</lsl>
The below code is exactly the same as the above, only it is much faster. Thanks to Strife Onizuka.
<lsl>
integer rand(integer spread) {
seed2 = (seed2 * seed2Mod + 0xB);
return (seed1Mod = ((seed1 = (seed1 * (seed2Mod = seed1Mod) + 0xB)) * seed2)) % spread;
}
</lsl>
Example code to test the randomness (Is that a word?) of the generator.
<lsl>
default {
state_entry() {
integer i = 0;
integer min = 0x7FFFFFFF;
integer max = -0x7FFFFFFF;
integer total = 0;
while (i < 100000000) {
integer r = rand(0x7FFFFFFF);
if (r < min) {
min = r;
}
if (r > max) {
max = r;
}
total += r;
i++;
}
llOwnerSay("Min: " + (string)min);
llOwnerSay("Max: " + (string)max);
llOwnerSay("Average: " + (string)(total/100000000));

}
}
</lsl>

Note: A pattern of digits like yyyymmddnn often works as a seed that changes often enough, ''e.g.'', test with 2007090103 == 2,007,090,103 as the 3rd try of the 1st day of the 9th month of the 2007th year, except you must take care to avoid confusing yourself with integers larger than the 2,147,483,647 limit of 32-bit signed arithmetic.

== Conventional Linear Congruential Seedable PRNG Based On Multiply/ Add/ Overflow ==

Note: Google Groups sci.math cites Knuth & Lewis suggesting the following linear congruential generator for 32-bit arithmetic processors. Someone skilled in the relevant mathematics should be able to prove that these choices of multiplier and addend provides results that feel more random. Someone skilled in Google might find yet more popular choices than these. People say the choose function returning the quotient rather than the remainder matters: try counting odd results and even results from the pseudorandom() routine to see why.

<lsl>
integer seed = 2007090103;

integer pseudorandom()
{
seed = 1664525 * seed + 1013904223;
return seed;
}

integer choose(integer count)
{
integer nonnegative = 0x7fffFFFF;
integer choice = pseudorandom() & nonnegative;
return ((choice / (nonnegative / count)) % count);
}

default
{
state_entry()
{
string line;
integer index;

line = "";
for (index = 0; index < 9; ++index)
{
line += " " + (string) pseudorandom();
}
llOwnerSay(line);

line = "";
for (index = 0; index < 30; ++index)
{
line += " " + (string) (1 + choose(6));
}
llOwnerSay(line);

llOwnerSay("OK");
}
}
</lsl>

== Seedable PRNG Based On MD5 Hashing ==
I haven't noticed any irregular behavior in this one, i would love to know what you guys think - Kyrah Abattoir

<lsl>

string seed = "";//Any String you want as your initial seed.

//this version will pull a random int from 0 to max int
integer NextInt()
{
seed = llMD5String(seed,0);
integer value = (integer)("0x"+llGetSubString(seed,0,6));
return value;
}

//This one will limit the result from 0 to the range indicated
integer NextIntClamped(integer max)
{
max++;
seed = llMD5String(seed,0);
integer value = (integer)("0x"+llGetSubString(seed,0,6))%max;
return value;
}

//0 to 1 duh.
integer NextBool()
{
return NextIntClamped(1);
}

</lsl>

I think MD5 random is just fine. I did some testing with ent and dieharder (random number test suites) based on recursed md5 'random' and it seems to have superior pseudo-random-number charactaristics. The only drawback is the decreased performance, which is usually (for games etc) not an issue at all.
My version (below) added a little extra entropy using timestamps. You could inject other sources of entropy as well. [[User:Tano Toll|Tano Toll]] Tano Toll
<lsl>
string md5="seed";
integer rnd() {
//add in more entropy if you like, like touch position (detectedtouchST etc).
//however, seeding the md5 with itself is already quite sufficient
string md5=llMD5String(md5+(string)llGetUnixTime()+(string)llGetTime(), 0x5EED);
return (integer)("0x"+llGetSubString(md5,0,7));
}

float frnd (float max) {
//this suffers a few bit rounding errors
return llFabs(max * rnd()/0x80000000);
}

</lsl>

<pre>
$ ent random.outmd5
Entropy = 7.999961 bits per byte.

Optimum compression would reduce the size
of this 4222048 byte file by 0 percent.

Chi square distribution for 4222048 samples is 231.03, and randomly
would exceed this value 75.00 percent of the times.

Arithmetic mean value of data bytes is 127.4654 (127.5 = random).
Monte Carlo value for Pi is 3.140641831 (error 0.03 percent).
Serial correlation coefficient is 0.000047 (totally uncorrelated = 0.0).

</pre>

{{LSLC|Library}}

Pseudo-random Number Generator

2013-02-19T22:39:51Z

Tano Toll: /* Seedable PRNG Based On MD5 Hashing */

{{LSL Header}}

See also: [[llFrand]], [[llListRandomize]], [[Seedable_PRNG]]

== Seedable PRNG Based On Multiply/ Add/ Overflow ==

Here's a Pseudo-random Number Generator - I ([[User:Xaviar Czervik|Xaviar Czervik]]) just made it up off the top of my head - so it has no mathematical research behind it to prove it's random... I've tested it for a while and it looks random to me, about the same as llFrand(). But what ever. Sue me. The main reason that I use it so that I can test scripts, and then when it blows up because of a math error, I can just run the script again an it will use the same numbers, in the same order.

I use this for determining a random channel for two (or more) objects to talk on. This allows the scripts to talk without users being able to intercept the messages - and even if they do - then the channel will change in a minute or two - so no harm done.

<lsl>
// IMPORTANT: Change the following numbers before using!
integer seed1 = 0x053FA20C;
integer seed2 = 0x3B1264D5;
integer seed1Mod = 0x71B5F252;
integer seed2Mod = 0x56A0E61D;

integer rand(integer spread) {
seed1 = (seed1 * seed1Mod + 0xB);
seed2 = (seed2 * seed2Mod + 0xB);
seed2Mod = seed1Mod;
seed1Mod = seed1 * seed2;
return seed1Mod % spread;
}

</lsl>
The below code is exactly the same as the above, only it is much faster. Thanks to Strife Onizuka.
<lsl>
integer rand(integer spread) {
seed2 = (seed2 * seed2Mod + 0xB);
return (seed1Mod = ((seed1 = (seed1 * (seed2Mod = seed1Mod) + 0xB)) * seed2)) % spread;
}
</lsl>
Example code to test the randomness (Is that a word?) of the generator.
<lsl>
default {
state_entry() {
integer i = 0;
integer min = 0x7FFFFFFF;
integer max = -0x7FFFFFFF;
integer total = 0;
while (i < 100000000) {
integer r = rand(0x7FFFFFFF);
if (r < min) {
min = r;
}
if (r > max) {
max = r;
}
total += r;
i++;
}
llOwnerSay("Min: " + (string)min);
llOwnerSay("Max: " + (string)max);
llOwnerSay("Average: " + (string)(total/100000000));

}
}
</lsl>

Note: A pattern of digits like yyyymmddnn often works as a seed that changes often enough, ''e.g.'', test with 2007090103 == 2,007,090,103 as the 3rd try of the 1st day of the 9th month of the 2007th year, except you must take care to avoid confusing yourself with integers larger than the 2,147,483,647 limit of 32-bit signed arithmetic.

== Conventional Linear Congruential Seedable PRNG Based On Multiply/ Add/ Overflow ==

Note: Google Groups sci.math cites Knuth & Lewis suggesting the following linear congruential generator for 32-bit arithmetic processors. Someone skilled in the relevant mathematics should be able to prove that these choices of multiplier and addend provides results that feel more random. Someone skilled in Google might find yet more popular choices than these. People say the choose function returning the quotient rather than the remainder matters: try counting odd results and even results from the pseudorandom() routine to see why.

<lsl>
integer seed = 2007090103;

integer pseudorandom()
{
seed = 1664525 * seed + 1013904223;
return seed;
}

integer choose(integer count)
{
integer nonnegative = 0x7fffFFFF;
integer choice = pseudorandom() & nonnegative;
return ((choice / (nonnegative / count)) % count);
}

default
{
state_entry()
{
string line;
integer index;

line = "";
for (index = 0; index < 9; ++index)
{
line += " " + (string) pseudorandom();
}
llOwnerSay(line);

line = "";
for (index = 0; index < 30; ++index)
{
line += " " + (string) (1 + choose(6));
}
llOwnerSay(line);

llOwnerSay("OK");
}
}
</lsl>

== Seedable PRNG Based On MD5 Hashing ==
I haven't noticed any irregular behavior in this one, i would love to know what you guys think - Kyrah Abattoir

<lsl>

string seed = "";//Any String you want as your initial seed.

//this version will pull a random int from 0 to max int
integer NextInt()
{
seed = llMD5String(seed,0);
integer value = (integer)("0x"+llGetSubString(seed,0,6));
return value;
}

//This one will limit the result from 0 to the range indicated
integer NextIntClamped(integer max)
{
max++;
seed = llMD5String(seed,0);
integer value = (integer)("0x"+llGetSubString(seed,0,6))%max;
return value;
}

//0 to 1 duh.
integer NextBool()
{
return NextIntClamped(1);
}

</lsl>

I think MD5 random is just fine. I did some testing with ent and dieharder (random number test suites) based on recursed md5 'random' and it seems to have superior pseudo-random-number charactaristics. The only drawback is the decreased performance, which is usually (for games etc) not an issue at all.
My version (below) added a little extra entropy using timestamps. You could inject other sources of entropy as well. [[User:Tano Toll|Tano Toll]] Tano Toll
<lsl>
string md5="seed";
integer rnd() {
//add in more entropy if you like, like touch position (detectedtouchST etc).
//however, seeding the md5 with itself is already quite sufficient
string md5=llMD5String(md5+(string)llGetUnixTime()+(string)llGetTime(), 0x5EED);
return (integer)("0x"+llGetSubString(md5,0,7));
}

float frnd (float max) {
//this suffers a few bit rounding errors
return llFabs(max * rnd()/0x80000000);
}

</lsl>

{{LSLC|Library}}

ParcelChatRelay

2013-01-03T12:06:21Z

Tano Toll: /* Notes: */ Added code for version 2

==Parcel Chat Relay==

===Description:===
Communicate on your land in general chat regardless of distance between avatars. Useful when building, in clubs, for roleplay, etc.

Messages will be intelligently relayed - a listener will never hear a message twice! It will either be heard normally, or relayed. Using the new llRegionSayTo() api, chat messages are only relayed to avatars that are out of range.

===How to use:===
* Rez 1 or more relays on your parcel, in a way that you could hear each avatar (<20m). Do not worry overlapping, but don't overdo it either - less relays will still be less lag.
* If you rez a relay on its' final position, it will immediately be 'tuned' and part of the network.
* If you move or remove a relay, it might take up to 10 minutes for the network to catch up.

===Features:===
* Muliple relays can be rezzed to cover each part of your parcel.
* Dedoubling without any overhead
* Low lag - relays do not have to communicate to dedouble messages

===Limitations:===
* Works only per parcel (by design). Agents on neighboring land will not receive relayed messages.
* Receivers have to be within radar range (96m) of the receiving relay
* Scripts cannot distinguish normal say, whispering and shouting. Normal say is assumed. Shouts may be heard double by the receiver
* Moving avatars might experience 'border' cases - where a message sometimes accidentally is not relayed or double relayed. Due to the fast response time unlikely
* The displayed ('faked') name is the official linden name, and chat is colored like objects, not avatars. Also depends on viewer settings.
Remarks on the parcel limitation.. Other options (sim wide, range based) would be easily possible, but i like the item to be zero-config ('just works'). Feel free to mod the script at your demands.

===License:===
Modified BSD / public domain

This script is also available at marketplace for your convenience: https://marketplace.secondlife.com/p/Parcel-Chat-Relay/3157725

===Notes:===
Possible easy-to-adjust modifications: do not use parcel key but owner key as handle, allowing cross parcel-but-same-owner chat, or specifying a fixed key for region-wide that.

===VERSION 2.0===
Recommended and most efficient version
<lsl>
//PCR Version 2//
//changes:
//* No longer uses radar but llGetAgentList to detect agents
//* Removed hover text and replaced by ownersay spam on updates
//* Added configurable option for coverage (parcel, parcels by same owner, entire region)
//* Made timer faster running in first 10 minutes after rez, to update faster on repositions
//* Some adjustments to allow cross-parcel and region-wide chat; replaced parcel key by owner key in those situations.
//* Overall, this version is more efficient and causes less lag, especially when idling, since agent list is not unneccesary updated by sensor events. It also provides better coverage and automatic support for skyboxes.

//2011-2012 Tano Toll - TSL License//

//Short summorization:
//Relays will know of eachothers existance
//Relays listen to public chat
//The relay _closest_ to sending agent is responsible for relaying the message
//Messages will only be relayed to agents further than 20 meter away from the speaker
//Messages will only be relayed to agents on the same parcel

//USAGE:
//* Edit coverage parameter below to suit your needs
//* place this script in a objects, placed in hearing range of avatars
//* If you do NOT want to relay a certain place, like a skybox, simply place no relay object. However, agents in the skybox will still hear what is said near other relays. If you do not want that, please use version 1 of this script that uses radar to detect agents.

// CONFIGURATION

//choose coverage:
//integer coverage=AGENT_LIST_PARCEL;
integer coverage=AGENT_LIST_PARCEL_OWNER;
//integer coverage=AGENT_LIST_REGION;

//Maximum range from listener object to avatar
integer maxRange=6000; //sim wide, reaches all skyboxes
//integer maxRange=290; //sim wide, ground level
//integer maxRange=100; //radar range, like version 1

//just a hash. change to use several systems on a single parcel.
string tag="+-/";

// NO NEED TO EDIT BELOW THIS LINE. CHANGES AT OWN RISK //

//list of detected nearby agents:
list insim;

//timestamp of last check - to reduce sim load
integer stamp;

//key of the parcel where we are rezzed
key parcelkey;

//key based for handle, depending on setting parcel or owner
key handlebase;

//chat channel handle made with key as base
integer handle;

//list of detected nearby relays
list repeaters;

//for less confusing setup, fast timer first minutes after rez, then slow down to appropiate interval
integer timercount;

announce() {
llRegionSay (handle, tag+(string)handlebase);
}

default
{
state_entry()
{
//llSetText("Chat Relay started...",ZERO_VECTOR,1);
llOwnerSay("Chat Relay started...");
if (llGetAttached()) {
//owner relay only mode
//redundant in this script.
//llListen (0, "", "", "");
} else {
//relay all agents
llListen (0, "", "", "");
}

//scan for nearby agents
//llSensorRepeat ("", "", AGENT, 65, TWO_PI, 20);

//make up a inter-relay channel, so they can find eachother
parcelkey=llList2Key(llGetParcelDetails(llGetPos(), [PARCEL_DETAILS_ID]),0);

//adjust key based on coverage. for single parcel, use parcel key. else use owner key.
//notice that on region-wide coverage, all relays must be rezzed by same owner.

if (coverage==AGENT_LIST_PARCEL)
handlebase=parcelkey;
else
handlebase=llGetOwner();

handle=-10909-(integer)("0x"+llGetSubString(handlebase,1,5));
llListen(handle, "", "", tag+(string)handlebase);

//broadcast our existance about every 5 minutes, but starting with 10 second interval to avoid setup confusion
//llSetTimerEvent(290.0+llFrand (20.0)); //about each 300 seconds, not all at once
llSetTimerEvent (10.0);
announce();
}

on_rez(integer n) {
//simply reset
llResetScript();
}

timer() {
//announce self
announce();

//check interval
timercount++;
if (timercount==60) //after about 10 minutes
llSetTimerEvent(290.0+llFrand (20.0)); //change to 5 minute interval

//and clear list. repeaters with an too old timestamp will be removed.
integer n=llGetListLength(repeaters)-1;
integer t=llGetUnixTime();
while (n>0) {
if ((t-llList2Integer(repeaters, n))>390) { //time out
llOwnerSay ("Lost connection to node at "+(string)llList2Vector(repeaters, n-1));
repeaters=llDeleteSubList(repeaters, n-2, n);
}
n-=3;
}
//llSetText ("Node(s): "+(string)(1+llGetListLength(repeaters)/3), <1,1,1>, 1);
}

listen (integer channel, string name, key id, string m) {

if (!channel) { //channel 0
//only relay agents, not objects
if (llGetAgentSize(id));else
return;

//see if another relay is more nearby
integer n=0;
vector senderpos=llList2Vector(llGetObjectDetails(id, [OBJECT_POS]), 0);
float d=llVecDist(senderpos, llGetPos());
while (n<llGetListLength(repeaters)) {
if (d>llVecDist(senderpos, llList2Vector(repeaters, n+1)))
return;
n+=3;
}
//We are nearest repeater. Our job to relay.

//see if we need to refresh our list - cache it for 15 seconds
if ((llGetUnixTime()-stamp) > 15.0) {
stamp=llGetUnixTime();
insim=llGetAgentList (coverage, []);
}

//relay to everyone in range. that's fixed to minimum 20 mins maximum 60.
//get position of chatter
vector o=llList2Vector(llGetObjectDetails(id, [OBJECT_POS]), 0);

n=llGetListLength(insim);
string oname=llGetObjectName();
llSetObjectName(name);
while (~--n) {
vector t=llList2Vector(llGetObjectDetails(llList2Key(insim, n), [OBJECT_POS]), 0);
float d=llVecDist (o,t);
if (d>=20 && d<=maxRange) {
//same parcel? - edit - check skipped.
//if (parcelkey==llList2Key(llGetParcelDetails(llList2Vector(llGetObjectDetails(llList2Key(insim,n), [OBJECT_POS]),0), [PARCEL_DETAILS_ID]),0))
llRegionSayTo (llList2Key(insim,n), 0, m);
}
}
llSetObjectName(oname);
}
else
if (channel==handle) {
//there's another repeater..
vector pos=llList2Vector(llGetObjectDetails(id, [OBJECT_POS]),0);

integer p=llListFindList(repeaters, [id, pos]);
if (~p)
repeaters=llDeleteSubList(repeaters, p, p+2);
else
llOwnerSay ("New node found at "+(string)pos);
repeaters += [id, pos, llGetUnixTime()];
}

}
}

</lsl>

===VERSION 1.0===
In some cases, you might want to use the original radar-based version. Usually not recommended, listed for completeness.
<lsl>
//2011-2012 Tano Toll - TSL License//

//Short summorization:
//Relays will know of eachothers existance
//Relays listen to public chat
//The relay _closest_ to sending agent is responsible for relaying the message
//Messages will only be relayed to agents further than 20 meter away from the speaker
//Messages will only be relayed to agents on the same parcel

//list of detected nearby agents:
list insim;

//just a hash. change to use several systems on a single parcel.
string tag="+-/";

//key of the parcel where we are rezzed
key parcelkey;

//chat channel handle made with key as base
integer parcelhandle;

//list of detected nearby relays
list repeaters;

announce() {
llRegionSay (parcelhandle, tag+(string)parcelkey);
}

default
{
state_entry()
{
llSetText("Chat Relay started...",ZERO_VECTOR,1);
if (llGetAttached()) {
//owner relay only mode
//redundant in this script.
//llListen (0, "", "", "");
} else {
//relay all agents
llListen (0, "", "", "");
}

//scan for nearby agents
llSensorRepeat ("", "", AGENT, 65, TWO_PI, 20);

//make up a inter-relay channel, so they can find eachother
parcelkey=llList2Key(llGetParcelDetails(llGetPos(), [PARCEL_DETAILS_ID]),0);
parcelhandle=-10909-(integer)("0x"+llGetSubString(parcelkey,1,5));
llListen(parcelhandle, "", "", tag+(string)parcelkey);

//broadcast our existance about every 5 minutes
llSetTimerEvent(290.0+llFrand (20.0)); //about each 300 seconds, not all at once
announce();
}

on_rez(integer n) {
//simply reset
llResetScript();
}

timer() {
//announce self
announce();

//and clear list. repeaters with an too old timestamp will be removed.
integer n=llGetListLength(repeaters)-1;
integer t=llGetUnixTime();
while (n>0) {
if ((t-llList2Integer(repeaters, n))>390) { //time out
repeaters=llDeleteSubList(repeaters, n-2, n);
}
n-=3;
}
llSetText ("Node(s): "+(string)(1+llGetListLength(repeaters)/3), <1,1,1>, 1);
}

sensor (integer n) {
//add detected agents to our list
while (~--n) {
key id=llDetectedKey(n);
if (!~llListFindList(insim, [id]))
insim+=id;
}

//clean up agents that are no longer in sim
n=llGetListLength(insim);
while (~--n)
if (llGetAgentSize(llList2Key(insim,n))); else
insim=llDeleteSubList(insim,n,n);
}

no_sensor() {
insim=[];
/*
//clean up agents that are no longer in sim
integer n=llGetListLength(insim);
while (~--n)
if (llGetAgentSize(llList2Key(insim,n))); else
insim=llDeleteSubList(insim,n,n);
*/
}

listen (integer channel, string name, key id, string m) {

if (!channel) { //channel 0
//only relay agents, not objects
if (llGetAgentSize(id));else
return;

//see if another relay is more nearby
integer n=0;
vector senderpos=llList2Vector(llGetObjectDetails(id, [OBJECT_POS]), 0);
float d=llVecDist(senderpos, llGetPos());
while (n<llGetListLength(repeaters)) {
if (d>llVecDist(senderpos, llList2Vector(repeaters, n+1)))
return;
n+=3;
}
//We are nearest repeater. Our job to relay.

//relay to everyone in range. that's fixed to minimum 20 mins maximum 60.
//get position of chatter
vector o=llList2Vector(llGetObjectDetails(id, [OBJECT_POS]), 0);

n=llGetListLength(insim);
string oname=llGetObjectName();
llSetObjectName(name);
while (~--n) {
vector t=llList2Vector(llGetObjectDetails(llList2Key(insim, n), [OBJECT_POS]), 0);
float d=llVecDist (o,t);
if (d>=20/* && d<=60*/) {
//same parcel?
if (parcelkey==llList2Key(llGetParcelDetails(llList2Vector(llGetObjectDetails(llList2Key(insim,n), [OBJECT_POS]),0), [PARCEL_DETAILS_ID]),0))
llRegionSayTo (llList2Key(insim,n), 0, m);
}
}
llSetObjectName(oname);
}
else
if (channel==parcelhandle) {
//there's another repeater..
vector pos=llList2Vector(llGetObjectDetails(id, [OBJECT_POS]),0);

integer p=llListFindList(repeaters, [id, pos]);
if (~p)
repeaters=llDeleteSubList(repeaters, p, p+2);
repeaters += [id, pos, llGetUnixTime()];
}

}
}

</lsl>
--[[User:Tano Toll|Tano Toll]] 19:54, 11 May 2012 (PDT)

User:Tano Toll

2012-11-22T21:24:49Z

Tano Toll:

SimpleMLPStylingScript

2012-11-22T21:22:22Z

Tano Toll: <code> tag omitted from sl mediawiki, cheated with <lsl> tag.

Ok, bit of old and ugly code here. Publishing anyways as example.

What it does. This is an MLP plugin that allows styling of objects. Textures, colors, shinyness. Those are usually enough for most furniture.

Per link, you must describe in the link properties if it is subject to a particular styling paramaters. Those are: Color1, Color2, Texture and Shiny. They are represent as :C+: :C2+: :T+: and :S+:
So, a linked prim, like a cushion, that is subject to color and texture, would read: :C+:T+:
Another linked prim, like a wooden base, would be subject to color2 (wood shades) and shininess. It's description would read :C2+:S+:

You can activate the plugin by sending commands via a linked message on channel 13335
Example entry in MLP or TMCP notecard:
<lsl>
MENU Styling | OWNER
LINKMSG Light Colors |1,-4,-13335,LightPalette
LINKMSG Dark Colors |1,-4,-13335,Palette
LINKMSG Adjust Color|1,-4,-13335,AdjustColor
LINKMSG Fabric|1,-4,-13335,MenuTexture
LINKMSG Wood Color |1,-4,-13335,WoodPalette
//LINKMSG SomeTexture|0,-4,-13335,SetTexture:<uuid>
//LINKMSG Color Menu|1,-4,-13335,MenuColor
//LINKMSG Gray|0,-4,-13335,SetColor:<0.5,0.5,0.5>
TOMENU Shadow
LINKMSG Shiny Wood|0,-4,-13335,SetShiny:3
LINKMSG Satin Wood|0,-4,-13335,SetShiny:1
LINKMSG Pale Wood|0,-4,-13335,SetShiny:0
TOMENU Size
BACK

MENU Shadow | ALL
This example sets the root prim's alpha.. adjust link number to whatever the shadow texture was
LINKMSG No Shadow|0,-4,-13335,SetAlpha:1:0
LINKMSG Light Shadow|0,-4,-13335,SetAlpha:1:0.5
LINKMSG Full Shadow|0,-4,-13335,SetAlpha:1:1.0
BACK

MENU Size | OWNER
LINKMSG Grow|0,-4,-13335,ObjectGrow
LINKMSG Shrink|0,-4,-13335,ObjectShrink
BACK
</lsl>

The styling script is as follows, and again, sorry for bit messy code.. Publishing anyways, might post an update.
<lsl>
//THIS SCRIPT ASSUMES A FEW THINGS
//* THAT ITS CALLED / INITIATED BY MLP or something else that invokes a linked message
//That the root prim is colorable just like all childs
//That the root prim needs no (re)texturing but all childs do.
//Must customize this script for color palette, textures, and/or menu stuff you want in or out - no external configuration

//+BRIGHT CONTRAST+ +SATURATION
//-BRIGHT CONTRAST- -SATURATION
//+RED //+BLUE //+GREEN
//-RED //-BLUE //-GREEN

//PALETTE

vector myColor; //reads root prim color on startup
integer channel;
integer handle;

list Palette=[ "BORDEAUX", "PINK", "AQUA",
"TEAL", "SKY", "NAVY",
"OKER", "BROWN", "CREAM",
"BLACK", "GREY", "DARKBROWN"];

list PaletteC=[ <0.35,0,0>, <1,0.5,0.5>, <0.3,1.0,0.8>,
<0,0.35,0.6>, <0.7,0.75,1>, <0,0,0.35>,
<0.61,0.6,0.12>, <0.3,0.2,0.05>, <1.0,1.0,0.9>,
<0.01,0.01,0.05>, <0.35,0.35,0.35>, <0.12,0.08,0>];

list PaletteLight=["BLUE1", "BLUE2", "BLUE3",
"PINK1", "PINK2", "PINK3",
"GREEN1", "GREEN2", "CREAM1",
"WHITE", "GREY2", "AMBER" ];

list PaletteL=[ <0.8,0.8,1.0>, <0.9,0.9,1.0>, <0.7,0.8,1.0>,
<1.0,0.7,0.7>, <1.0,0.8,0.8>, <1.0,0.9,0.9>,
<0.7,1.0,0.7>, <0.82,1.0,0.8>, <1.0,0.960,0.879>,
<1.0,1.0,1.0>, <0.75,0.75,0.75>, <1.0, 0.9, 0.6>];

list PaletteWood =[ "Cherry", "Oak", "Mahogany",
"Pine", "Ebony", "Maple",
"OldOak", "Rosewood", "Elm",
"Walnut", "DarkWalnut", "Onyx"];

list PaletteW=[ <0.6,0.28,0.18>, <0.62,0.41,0.21>, <0.26,0.08,0.05>,
<0.76,0.53,0.19>, <0.12,0.11,0.11>, <0.77,0.45,0.26>,
<0.59,0.4,0.24>, <0.3,0.15,0.15>, <0.4,0.25,0.2>,
<0.5,0.40,0.28>, <0.29,0.14,0.05>, <0.22,0.19,0.14>];

list Textures = [
"d14c73dd-9844-3fec-3405-c2cfa6cfae92",
"29e827fe-6d57-e155-eaed-236a58b71244",
//"1ae6c524-9a2e-b3a5-6349-4b99dfd861a3",
//"06811c28-baae-68f8-18b6-38c7819f977f",
"3486effe-7ab4-d955-6b4f-a85a3325a287",
//"9e14c601-a7b0-e0e3-585d-a494c320fa87",
//"80d859fb-dab4-9446-2d79-2d2a9693759d"
"59d84d87-6ff5-a1b7-3f3b-d45c09ac05c1",
"a523d079-6e2e-5832-8ac5-30b8c6092508",
"feddf1ac-8176-11fe-0bc1-696544037253",
"12d82751-1cd1-8f25-166c-5e2bcb2ed2d6",
"24cf6699-b625-c06c-b2cd-984b28eb09e0",
"7b71d0bc-d329-b94e-2fa8-0b584ca0e80c",
"d598017c-0f6a-42ec-52f6-899be6e82878",
"ddd57884-5a7b-f658-c8ab-d34df5d6d38e",
"3fda0baa-d584-7d22-ed54-3943ef26c37f"
];

list TextureNames = [
"Stripes",
"Ghecko",
//"Bleached",
//"Modern",
"LineArt",
//"Flowers",
//"Victorian"
"Leaves",
"Old green",
"Classic Leaves",
"African",
"Worn",
"Abstract",
"Elephant",
"Wave",
"Leather"
];

string colorStr() {
return "\nCurrent: [ R="+(string)llRound(100*myColor.x)+" G="+(string)llRound(100*myColor.y)+" B="+(string)llRound(100*myColor.z)+" ]";
}

menuPalette (key id) {
llDialog (id, "Choose a color"+colorStr(), llListSort(Palette,1,TRUE), channel);
setListen();
}
menuPaletteL (key id) {
llDialog (id, "Choose a color"+colorStr(), llListSort(PaletteLight,1,TRUE), channel);
}
menuWoodPalette (key id) {
llDialog (id, "Choose a color"+colorStr(), llListSort(PaletteWood,1,TRUE), channel);
}

menuAdjust (key id) {
llDialog (id, "Adjust color\nHint: use HUE for small color shifts."+colorStr(),
[
"- SATURATION", "- HUE", "+ HUE",
"+ SATURATION", "- BLUE", "+ BLUE",
"- BRIGHT", "- GREEN", "+ GREEN",
"+ BRIGHT", "- RED", "+ RED"
],
channel);
}
menuColor(key id) {
llDialog(id, "Option", ["Adjust", "Palette", "Palette Light"], channel);
}

menuTexture(key id) {
/*
list l;
integer i=llGetListLength(Textures);
for (;i;i--) {
l+="Fabric "+(string)i;
}
llDialog (id, "Select fabric", l, channel);
*/
llDialog (id, "Select fabric", llListSort(TextureNames,1,TRUE), channel);
}

scale(float s) {
if (s<0.10)
return;
llSetScale(s*llGetScale());
if (llGetNumberOfPrims()>1) {
integer i;
for (i=2; i<=llGetNumberOfPrims(); i++) {
list l=llGetLinkPrimitiveParams(i, [PRIM_POS_LOCAL, PRIM_SIZE]);
//llOwnerSay ("PP:"+(string)l);
vector newpos=s*(llList2Vector(l,0));
vector newscale=s*llList2Vector(l,1);
if (newscale==ZERO_VECTOR) //something went wrong
return;
llSetLinkPrimitiveParamsFast (i, [PRIM_POS_LOCAL, newpos, PRIM_SIZE, newscale]);
}
}
}

setColor (vector c) {
//check bounds
if (c.x < 0) c.x=0;
if (c.x > 1) c.x=1;
if (c.y < 0) c.y=0;
if (c.y > 1) c.y=1;
if (c.z < 0) c.z=0;
if (c.z > 1) c.z=1;
myColor=c;
if (llGetNumberOfPrims()==1)
llSetColor(myColor, ALL_SIDES);
else {
integer i;
for (i=0; i<=llGetNumberOfPrims(); i++) { //root is 0 or 1, silly SL
string d=llList2String(llGetLinkPrimitiveParams(i, [PRIM_DESC]),0);
if (-1!=llSubStringIndex(d, ":C+:"))
llSetLinkColor(i, myColor, ALL_SIDES);
}
}
}

setColor2 (vector c) {
//check bounds
if (c.x < 0) c.x=0;
if (c.x > 1) c.x=1;
if (c.y < 0) c.y=0;
if (c.y > 1) c.y=1;
if (c.z < 0) c.z=0;
if (c.z > 1) c.z=1;
myColor=c;
if (llGetNumberOfPrims()==1)
llSetColor(myColor, ALL_SIDES);
else {
integer i;
for (i=0; i<=llGetNumberOfPrims(); i++) { //root is 0 or 1, silly SL
string d=llList2String(llGetLinkPrimitiveParams(i, [PRIM_DESC]),0);
if (-1!=llSubStringIndex(d, ":C2+:"))
llSetLinkColor(i, myColor, ALL_SIDES);
}
}
}

setTexture (string texture) {
if (llGetNumberOfPrims()==1)
llSetTexture(texture, ALL_SIDES);
else {
integer i;
for (i=0; i<=llGetNumberOfPrims(); i++) { //root is 0 or 1, silly SL
string d=llList2String(llGetLinkPrimitiveParams(i, [PRIM_DESC]),0);
if (-1!=llSubStringIndex(d, ":T+:"))
llSetLinkTexture(i, texture, ALL_SIDES);
}
}
}

setShiny (integer s) {
integer i;
for (i=0; i<=llGetNumberOfPrims(); i++) { //root is 0 or 1, silly SL
string d=llList2String(llGetLinkPrimitiveParams(i, [PRIM_DESC]),0);
if (-1!=llSubStringIndex(d, ":S+:"))
llSetLinkPrimitiveParams(i, [PRIM_BUMP_SHINY, ALL_SIDES,s,
//existing bumpmap:
llList2Integer(llGetLinkPrimitiveParams(i, [PRIM_BUMP_SHINY, ALL_SIDES]),1)
]);
}
}

setListen() {
llListenControl (handle, TRUE);
llSetTimerEvent (0.0);
llSetTimerEvent (120.0);
}

//funky color conv, tx Sally!
vector RGB2HSV( vector rgb )
{
float R = rgb.x;
if (R<0) // catch malformed input
R=0;
else if (R>1)
R=1;
float G = rgb.y;
if (G<0) // catch malformed input
G=0;
else if (G>1)
G=1;
float B = rgb.z;
if (B<0) // catch malformed input
B=0;
else if (B>1)
B=1;

float H;
float S;
float V;

list rgbList = [R, G, B]; // list used to get min and max

float min;
float max;
float achromatic; // =1 if R=G=B
float delta;

vector hsv; // the return HSV vector

min = llListStatistics(LIST_STAT_MIN, rgbList); //MIN of ( R, G, B );
max = llListStatistics(LIST_STAT_MAX, rgbList); //MAX of ( R, G, B );
if (R==G && G==B)
achromatic = 1; // it is a shade of grey, white or black
else
achromatic = 0;

V = max; // V = brightness Value form 0 to 1
delta = max - min;

if( max != 0 )
S = delta / max; // S = saturation from 0 to 1
else {
// R = G = B = 0 // S = 0, V = 0, H = 0
S = 0;
V = 0;
H = 0;

hsv.x = H;
hsv.y = S;
hsv.z = V;
return hsv; //H = S = V = 0
}

if (achromatic == 1)
H = 0;
else if( R == max )
H = 0 + ( G - B ) / delta; // between red & yellow
else if( G == max )
H = 2 + ( B - R ) / delta; // between yellow & cyan
else
H = 4 + ( R - G ) / delta; // between cyan & red

H *= 60; // H is traditionally a figure between 0 and 360 degrees
if( H < 0 )
H += 360;

hsv.x = H;
hsv.y = S;
hsv.z = V;
return hsv;
}

vector HSV2RGB( vector hsv )
{
integer i;

float H = hsv.x;
while (H<0) // catch malformed H input
H+=360;
while (H>=360)
H-=360;
float S = hsv.y;
if (S<0) // catch malformed S input
S=0;
else if (S>1)
S=1;
float V = hsv.z;
if (V<0) // catch malformed V input
V=0;
else if (V>1)
V=1;

float R;
float G;
float B;

float f; // variables for calculating base color mixing around the "spectrum circle"
float p;
float q;
float t;

vector rgb;

if( S == 0 ) { // achromatic (grey) simply set R,G, & B = Value
R = V;
G = V;
B = V;

rgb.x = R;
rgb.y = G;
rgb.z = B;
return rgb;
}

H /= 60; // Hue factored into range 0 to 5
i = llFloor( H ); // integer floor of Hue
f = H - i; // factorial part of H

p = V * ( 1 - S );
q = V * ( 1 - S * f );
t = V * ( 1 - S * ( 1 - f ) );

if (i==0){
R = V;
G = t;
B = p;
} else if (i==1){
R = q;
G = V;
B = p;
} else if (i==2){
R = p;
G = V;
B = t;
} else if (i==3){
R = p;
G = q;
B = V;
} else if (i==4){
R = t;
G = p;
B = V;
} else {
R = V;
G = p;
B = q;
}

rgb.x = R;
rgb.y = G;
rgb.z = B;

return rgb;
}

default
{
state_entry()
{
myColor = llGetColor(ALL_SIDES);
integer i;
for (i=0; i<=llGetNumberOfPrims(); i++) { //root is 0 or 1, silly SL
string d=llList2String(llGetLinkPrimitiveParams(i, [PRIM_DESC]),0);
if (-1!=llSubStringIndex(d, ":C+:")) {
myColor=llList2Vector(llGetLinkPrimitiveParams(i, [PRIM_COLOR, ALL_SIDES]),0);
}
}

//llOwnerSay("Color: "+(string)myColor);
channel=10000+llRound(llFrand(320932));
handle=llListen(channel, "", "", "");
llListenControl(handle, FALSE);
}

on_rez(integer n) {
llResetScript();
}

link_message(integer ch, integer n, string data, key id) {
if (n==-13335) {
//hack.. just don't flood this please (...)
//but we try to get this menu on top of MLP menu
//llSleep (1.0);

list l=llParseString2List(data, [":"], []);
string d=llList2String(l,0);
string p=llList2String(l,1);
//interesting, styling command
setListen();
if (d=="MenuColor")
menuColor(id);
else if (d=="MenuTexture")
menuTexture(id);
else if (d=="ObjectGrow")
scale(1.05);
else if (d=="ObjectShrink")
scale(1.0/1.05);
else if (d=="Palette")
menuPalette(id);
else if (d=="LightPalette")
menuPaletteL(id);
else if (d=="WoodPalette")
menuWoodPalette(id);
else if (d=="AdjustColor")
menuAdjust(id);
else if (d=="SetTexture") {
//we really need a texture handle that'd perfectly fit
setTexture(p);
} else if (d=="SetColor") {
setColor ((vector)p);
} else if (d=="SetColor2") {
setColor2 ((vector)p);
} else if (d=="SetAlpha") {
llSetLinkAlpha((integer)p, (float)llList2String(l, 2), ALL_SIDES);
} else if (d=="SetShiny") {
setShiny((integer)p);
} else if (d=="Shiny") {
llSetLinkPrimitiveParams((integer)p, [PRIM_BUMP_SHINY, ALL_SIDES,(integer)llList2String(l,2),
//existing bumpmap:
llList2Integer(llGetLinkPrimitiveParams((integer)p, [PRIM_BUMP_SHINY, ALL_SIDES]),1)
]);
} else if (d=="Link___") {
//template for any value on any link..
llSetLinkPrimitiveParamsFast((integer)p, [(integer)llList2String(l,2), (float)llList2String(l,3)]);
}

}
}

listen (integer ch, string n, key id, string d) {

//only listen to agents
if (llGetAgentSize(id)); else return;

//user still active; assume no other spam on this channel
setListen();

if (d=="<<BACK")
menuColor(id);
else if (d=="Adjust")
menuAdjust(id);
else if (d=="Palette")
menuPalette(id);
else if (d=="Palette Light")
menuPaletteL(id);
else {
integer i=llListFindList(Palette+PaletteLight, [d]);
if (i>=0) {
//set color to palette entry
setColor(llList2Vector(PaletteC+PaletteL, i));
if (-1!=llListFindList(Palette, [d]))
menuPalette(id);
else
menuPaletteL(id);
return;
}
i=llListFindList(PaletteWood, [d]);
if (i>=0) {
//set color to palette entry
setColor2(llList2Vector(PaletteW, i));
menuWoodPalette(id);
return;
}

list m=llParseString2List(d, [" "], []);
string o=llList2String(m,0);
string p=llList2String(m,1);

if ((o=="-") || (o=="+")) {
float f=-1.0;
if (o=="+")
f=1.0;
if (p=="BRIGHT")
setColor(0.05*f*<1,1,1> + myColor);
else if (p=="SATURATION")
//setColor(myColor + 0.05*f*(myColor-<0.55,0.55,0.55>));
setColor (HSV2RGB(<0,0.075*f,0>+RGB2HSV(myColor)));
else if (p=="RED")
setColor(f*<0.05,0,0> + myColor);
else if (p=="GREEN")
setColor(f*<0,0.05,0> + myColor);
else if (p=="BLUE")
setColor(f*<0,0,0.05> + myColor);
else if (p=="HUE")
setColor (HSV2RGB(<15.0*f,0,0>+RGB2HSV(myColor)));
menuAdjust(id);
return;
}
/*
if (o=="Fabric") {
setTexture(llList2String(Textures, (integer)p-1));
menuTexture(id);
}
*/
i=llListFindList(TextureNames, [d]);
if (i>=0) {
setTexture (llList2String(Textures, i));
menuTexture(id);
}

}
}

timer() {
llSetTimerEvent(0.0);
llListenControl (handle, FALSE);
}
}

</lsl>

Happy scripting.

SimpleMLPStylingScript

2012-11-22T21:20:29Z

Tano Toll: MLP / TMCP simple styling plugin example

Ok, bit of old and ugly code here. Publishing anyways as example.

What it does. This is an MLP plugin that allows styling of objects. Textures, colors, shinyness. Those are usually enough for most furniture.

Per link, you must describe in the link properties if it is subject to a particular styling paramaters. Those are: Color1, Color2, Texture and Shiny. They are represent as :C+: :C2+: :T+: and :S+:
So, a linked prim, like a cushion, that is subject to color and texture, would read: :C+:T+:
Another linked prim, like a wooden base, would be subject to color2 (wood shades) and shininess. It's description would read :C2+:S+:

You can activate the plugin by sending commands via a linked message on channel 13335
Example entry in MLP or TMCP notecard:
<code>
MENU Styling | OWNER
LINKMSG Light Colors |1,-4,-13335,LightPalette
LINKMSG Dark Colors |1,-4,-13335,Palette
LINKMSG Adjust Color|1,-4,-13335,AdjustColor
LINKMSG Fabric|1,-4,-13335,MenuTexture
LINKMSG Wood Color |1,-4,-13335,WoodPalette
//LINKMSG SomeTexture|0,-4,-13335,SetTexture:<uuid>
//LINKMSG Color Menu|1,-4,-13335,MenuColor
//LINKMSG Gray|0,-4,-13335,SetColor:<0.5,0.5,0.5>
TOMENU Shadow
LINKMSG Shiny Wood|0,-4,-13335,SetShiny:3
LINKMSG Satin Wood|0,-4,-13335,SetShiny:1
LINKMSG Pale Wood|0,-4,-13335,SetShiny:0
TOMENU Size
BACK

MENU Shadow | ALL
This example sets the root prim's alpha.. adjust link number to whatever the shadow texture was
LINKMSG No Shadow|0,-4,-13335,SetAlpha:1:0
LINKMSG Light Shadow|0,-4,-13335,SetAlpha:1:0.5
LINKMSG Full Shadow|0,-4,-13335,SetAlpha:1:1.0
BACK

MENU Size | OWNER
LINKMSG Grow|0,-4,-13335,ObjectGrow
LINKMSG Shrink|0,-4,-13335,ObjectShrink
BACK
</code>

The styling script is as follows, and again, sorry for bit messy code.. Publishing anyways, might post an update.
<lsl>
//THIS SCRIPT ASSUMES A FEW THINGS
//* THAT ITS CALLED / INITIATED BY MLP or something else that invokes a linked message
//That the root prim is colorable just like all childs
//That the root prim needs no (re)texturing but all childs do.
//Must customize this script for color palette, textures, and/or menu stuff you want in or out - no external configuration

//+BRIGHT CONTRAST+ +SATURATION
//-BRIGHT CONTRAST- -SATURATION
//+RED //+BLUE //+GREEN
//-RED //-BLUE //-GREEN

//PALETTE

vector myColor; //reads root prim color on startup
integer channel;
integer handle;

list Palette=[ "BORDEAUX", "PINK", "AQUA",
"TEAL", "SKY", "NAVY",
"OKER", "BROWN", "CREAM",
"BLACK", "GREY", "DARKBROWN"];

list PaletteC=[ <0.35,0,0>, <1,0.5,0.5>, <0.3,1.0,0.8>,
<0,0.35,0.6>, <0.7,0.75,1>, <0,0,0.35>,
<0.61,0.6,0.12>, <0.3,0.2,0.05>, <1.0,1.0,0.9>,
<0.01,0.01,0.05>, <0.35,0.35,0.35>, <0.12,0.08,0>];

list PaletteLight=["BLUE1", "BLUE2", "BLUE3",
"PINK1", "PINK2", "PINK3",
"GREEN1", "GREEN2", "CREAM1",
"WHITE", "GREY2", "AMBER" ];

list PaletteL=[ <0.8,0.8,1.0>, <0.9,0.9,1.0>, <0.7,0.8,1.0>,
<1.0,0.7,0.7>, <1.0,0.8,0.8>, <1.0,0.9,0.9>,
<0.7,1.0,0.7>, <0.82,1.0,0.8>, <1.0,0.960,0.879>,
<1.0,1.0,1.0>, <0.75,0.75,0.75>, <1.0, 0.9, 0.6>];

list PaletteWood =[ "Cherry", "Oak", "Mahogany",
"Pine", "Ebony", "Maple",
"OldOak", "Rosewood", "Elm",
"Walnut", "DarkWalnut", "Onyx"];

list PaletteW=[ <0.6,0.28,0.18>, <0.62,0.41,0.21>, <0.26,0.08,0.05>,
<0.76,0.53,0.19>, <0.12,0.11,0.11>, <0.77,0.45,0.26>,
<0.59,0.4,0.24>, <0.3,0.15,0.15>, <0.4,0.25,0.2>,
<0.5,0.40,0.28>, <0.29,0.14,0.05>, <0.22,0.19,0.14>];

list Textures = [
"d14c73dd-9844-3fec-3405-c2cfa6cfae92",
"29e827fe-6d57-e155-eaed-236a58b71244",
//"1ae6c524-9a2e-b3a5-6349-4b99dfd861a3",
//"06811c28-baae-68f8-18b6-38c7819f977f",
"3486effe-7ab4-d955-6b4f-a85a3325a287",
//"9e14c601-a7b0-e0e3-585d-a494c320fa87",
//"80d859fb-dab4-9446-2d79-2d2a9693759d"
"59d84d87-6ff5-a1b7-3f3b-d45c09ac05c1",
"a523d079-6e2e-5832-8ac5-30b8c6092508",
"feddf1ac-8176-11fe-0bc1-696544037253",
"12d82751-1cd1-8f25-166c-5e2bcb2ed2d6",
"24cf6699-b625-c06c-b2cd-984b28eb09e0",
"7b71d0bc-d329-b94e-2fa8-0b584ca0e80c",
"d598017c-0f6a-42ec-52f6-899be6e82878",
"ddd57884-5a7b-f658-c8ab-d34df5d6d38e",
"3fda0baa-d584-7d22-ed54-3943ef26c37f"
];

list TextureNames = [
"Stripes",
"Ghecko",
//"Bleached",
//"Modern",
"LineArt",
//"Flowers",
//"Victorian"
"Leaves",
"Old green",
"Classic Leaves",
"African",
"Worn",
"Abstract",
"Elephant",
"Wave",
"Leather"
];

string colorStr() {
return "\nCurrent: [ R="+(string)llRound(100*myColor.x)+" G="+(string)llRound(100*myColor.y)+" B="+(string)llRound(100*myColor.z)+" ]";
}

menuPalette (key id) {
llDialog (id, "Choose a color"+colorStr(), llListSort(Palette,1,TRUE), channel);
setListen();
}
menuPaletteL (key id) {
llDialog (id, "Choose a color"+colorStr(), llListSort(PaletteLight,1,TRUE), channel);
}
menuWoodPalette (key id) {
llDialog (id, "Choose a color"+colorStr(), llListSort(PaletteWood,1,TRUE), channel);
}

menuAdjust (key id) {
llDialog (id, "Adjust color\nHint: use HUE for small color shifts."+colorStr(),
[
"- SATURATION", "- HUE", "+ HUE",
"+ SATURATION", "- BLUE", "+ BLUE",
"- BRIGHT", "- GREEN", "+ GREEN",
"+ BRIGHT", "- RED", "+ RED"
],
channel);
}
menuColor(key id) {
llDialog(id, "Option", ["Adjust", "Palette", "Palette Light"], channel);
}

menuTexture(key id) {
/*
list l;
integer i=llGetListLength(Textures);
for (;i;i--) {
l+="Fabric "+(string)i;
}
llDialog (id, "Select fabric", l, channel);
*/
llDialog (id, "Select fabric", llListSort(TextureNames,1,TRUE), channel);
}

scale(float s) {
if (s<0.10)
return;
llSetScale(s*llGetScale());
if (llGetNumberOfPrims()>1) {
integer i;
for (i=2; i<=llGetNumberOfPrims(); i++) {
list l=llGetLinkPrimitiveParams(i, [PRIM_POS_LOCAL, PRIM_SIZE]);
//llOwnerSay ("PP:"+(string)l);
vector newpos=s*(llList2Vector(l,0));
vector newscale=s*llList2Vector(l,1);
if (newscale==ZERO_VECTOR) //something went wrong
return;
llSetLinkPrimitiveParamsFast (i, [PRIM_POS_LOCAL, newpos, PRIM_SIZE, newscale]);
}
}
}

setColor (vector c) {
//check bounds
if (c.x < 0) c.x=0;
if (c.x > 1) c.x=1;
if (c.y < 0) c.y=0;
if (c.y > 1) c.y=1;
if (c.z < 0) c.z=0;
if (c.z > 1) c.z=1;
myColor=c;
if (llGetNumberOfPrims()==1)
llSetColor(myColor, ALL_SIDES);
else {
integer i;
for (i=0; i<=llGetNumberOfPrims(); i++) { //root is 0 or 1, silly SL
string d=llList2String(llGetLinkPrimitiveParams(i, [PRIM_DESC]),0);
if (-1!=llSubStringIndex(d, ":C+:"))
llSetLinkColor(i, myColor, ALL_SIDES);
}
}
}

setColor2 (vector c) {
//check bounds
if (c.x < 0) c.x=0;
if (c.x > 1) c.x=1;
if (c.y < 0) c.y=0;
if (c.y > 1) c.y=1;
if (c.z < 0) c.z=0;
if (c.z > 1) c.z=1;
myColor=c;
if (llGetNumberOfPrims()==1)
llSetColor(myColor, ALL_SIDES);
else {
integer i;
for (i=0; i<=llGetNumberOfPrims(); i++) { //root is 0 or 1, silly SL
string d=llList2String(llGetLinkPrimitiveParams(i, [PRIM_DESC]),0);
if (-1!=llSubStringIndex(d, ":C2+:"))
llSetLinkColor(i, myColor, ALL_SIDES);
}
}
}

setTexture (string texture) {
if (llGetNumberOfPrims()==1)
llSetTexture(texture, ALL_SIDES);
else {
integer i;
for (i=0; i<=llGetNumberOfPrims(); i++) { //root is 0 or 1, silly SL
string d=llList2String(llGetLinkPrimitiveParams(i, [PRIM_DESC]),0);
if (-1!=llSubStringIndex(d, ":T+:"))
llSetLinkTexture(i, texture, ALL_SIDES);
}
}
}

setShiny (integer s) {
integer i;
for (i=0; i<=llGetNumberOfPrims(); i++) { //root is 0 or 1, silly SL
string d=llList2String(llGetLinkPrimitiveParams(i, [PRIM_DESC]),0);
if (-1!=llSubStringIndex(d, ":S+:"))
llSetLinkPrimitiveParams(i, [PRIM_BUMP_SHINY, ALL_SIDES,s,
//existing bumpmap:
llList2Integer(llGetLinkPrimitiveParams(i, [PRIM_BUMP_SHINY, ALL_SIDES]),1)
]);
}
}

setListen() {
llListenControl (handle, TRUE);
llSetTimerEvent (0.0);
llSetTimerEvent (120.0);
}

//funky color conv, tx Sally!
vector RGB2HSV( vector rgb )
{
float R = rgb.x;
if (R<0) // catch malformed input
R=0;
else if (R>1)
R=1;
float G = rgb.y;
if (G<0) // catch malformed input
G=0;
else if (G>1)
G=1;
float B = rgb.z;
if (B<0) // catch malformed input
B=0;
else if (B>1)
B=1;

float H;
float S;
float V;

list rgbList = [R, G, B]; // list used to get min and max

float min;
float max;
float achromatic; // =1 if R=G=B
float delta;

vector hsv; // the return HSV vector

min = llListStatistics(LIST_STAT_MIN, rgbList); //MIN of ( R, G, B );
max = llListStatistics(LIST_STAT_MAX, rgbList); //MAX of ( R, G, B );
if (R==G && G==B)
achromatic = 1; // it is a shade of grey, white or black
else
achromatic = 0;

V = max; // V = brightness Value form 0 to 1
delta = max - min;

if( max != 0 )
S = delta / max; // S = saturation from 0 to 1
else {
// R = G = B = 0 // S = 0, V = 0, H = 0
S = 0;
V = 0;
H = 0;

hsv.x = H;
hsv.y = S;
hsv.z = V;
return hsv; //H = S = V = 0
}

if (achromatic == 1)
H = 0;
else if( R == max )
H = 0 + ( G - B ) / delta; // between red & yellow
else if( G == max )
H = 2 + ( B - R ) / delta; // between yellow & cyan
else
H = 4 + ( R - G ) / delta; // between cyan & red

H *= 60; // H is traditionally a figure between 0 and 360 degrees
if( H < 0 )
H += 360;

hsv.x = H;
hsv.y = S;
hsv.z = V;
return hsv;
}

vector HSV2RGB( vector hsv )
{
integer i;

float H = hsv.x;
while (H<0) // catch malformed H input
H+=360;
while (H>=360)
H-=360;
float S = hsv.y;
if (S<0) // catch malformed S input
S=0;
else if (S>1)
S=1;
float V = hsv.z;
if (V<0) // catch malformed V input
V=0;
else if (V>1)
V=1;

float R;
float G;
float B;

float f; // variables for calculating base color mixing around the "spectrum circle"
float p;
float q;
float t;

vector rgb;

if( S == 0 ) { // achromatic (grey) simply set R,G, & B = Value
R = V;
G = V;
B = V;

rgb.x = R;
rgb.y = G;
rgb.z = B;
return rgb;
}

H /= 60; // Hue factored into range 0 to 5
i = llFloor( H ); // integer floor of Hue
f = H - i; // factorial part of H

p = V * ( 1 - S );
q = V * ( 1 - S * f );
t = V * ( 1 - S * ( 1 - f ) );

if (i==0){
R = V;
G = t;
B = p;
} else if (i==1){
R = q;
G = V;
B = p;
} else if (i==2){
R = p;
G = V;
B = t;
} else if (i==3){
R = p;
G = q;
B = V;
} else if (i==4){
R = t;
G = p;
B = V;
} else {
R = V;
G = p;
B = q;
}

rgb.x = R;
rgb.y = G;
rgb.z = B;

return rgb;
}

default
{
state_entry()
{
myColor = llGetColor(ALL_SIDES);
integer i;
for (i=0; i<=llGetNumberOfPrims(); i++) { //root is 0 or 1, silly SL
string d=llList2String(llGetLinkPrimitiveParams(i, [PRIM_DESC]),0);
if (-1!=llSubStringIndex(d, ":C+:")) {
myColor=llList2Vector(llGetLinkPrimitiveParams(i, [PRIM_COLOR, ALL_SIDES]),0);
}
}

//llOwnerSay("Color: "+(string)myColor);
channel=10000+llRound(llFrand(320932));
handle=llListen(channel, "", "", "");
llListenControl(handle, FALSE);
}

on_rez(integer n) {
llResetScript();
}

link_message(integer ch, integer n, string data, key id) {
if (n==-13335) {
//hack.. just don't flood this please (...)
//but we try to get this menu on top of MLP menu
//llSleep (1.0);

list l=llParseString2List(data, [":"], []);
string d=llList2String(l,0);
string p=llList2String(l,1);
//interesting, styling command
setListen();
if (d=="MenuColor")
menuColor(id);
else if (d=="MenuTexture")
menuTexture(id);
else if (d=="ObjectGrow")
scale(1.05);
else if (d=="ObjectShrink")
scale(1.0/1.05);
else if (d=="Palette")
menuPalette(id);
else if (d=="LightPalette")
menuPaletteL(id);
else if (d=="WoodPalette")
menuWoodPalette(id);
else if (d=="AdjustColor")
menuAdjust(id);
else if (d=="SetTexture") {
//we really need a texture handle that'd perfectly fit
setTexture(p);
} else if (d=="SetColor") {
setColor ((vector)p);
} else if (d=="SetColor2") {
setColor2 ((vector)p);
} else if (d=="SetAlpha") {
llSetLinkAlpha((integer)p, (float)llList2String(l, 2), ALL_SIDES);
} else if (d=="SetShiny") {
setShiny((integer)p);
} else if (d=="Shiny") {
llSetLinkPrimitiveParams((integer)p, [PRIM_BUMP_SHINY, ALL_SIDES,(integer)llList2String(l,2),
//existing bumpmap:
llList2Integer(llGetLinkPrimitiveParams((integer)p, [PRIM_BUMP_SHINY, ALL_SIDES]),1)
]);
} else if (d=="Link___") {
//template for any value on any link..
llSetLinkPrimitiveParamsFast((integer)p, [(integer)llList2String(l,2), (float)llList2String(l,3)]);
}

}
}

listen (integer ch, string n, key id, string d) {

//only listen to agents
if (llGetAgentSize(id)); else return;

//user still active; assume no other spam on this channel
setListen();

if (d=="<<BACK")
menuColor(id);
else if (d=="Adjust")
menuAdjust(id);
else if (d=="Palette")
menuPalette(id);
else if (d=="Palette Light")
menuPaletteL(id);
else {
integer i=llListFindList(Palette+PaletteLight, [d]);
if (i>=0) {
//set color to palette entry
setColor(llList2Vector(PaletteC+PaletteL, i));
if (-1!=llListFindList(Palette, [d]))
menuPalette(id);
else
menuPaletteL(id);
return;
}
i=llListFindList(PaletteWood, [d]);
if (i>=0) {
//set color to palette entry
setColor2(llList2Vector(PaletteW, i));
menuWoodPalette(id);
return;
}

list m=llParseString2List(d, [" "], []);
string o=llList2String(m,0);
string p=llList2String(m,1);

if ((o=="-") || (o=="+")) {
float f=-1.0;
if (o=="+")
f=1.0;
if (p=="BRIGHT")
setColor(0.05*f*<1,1,1> + myColor);
else if (p=="SATURATION")
//setColor(myColor + 0.05*f*(myColor-<0.55,0.55,0.55>));
setColor (HSV2RGB(<0,0.075*f,0>+RGB2HSV(myColor)));
else if (p=="RED")
setColor(f*<0.05,0,0> + myColor);
else if (p=="GREEN")
setColor(f*<0,0.05,0> + myColor);
else if (p=="BLUE")
setColor(f*<0,0,0.05> + myColor);
else if (p=="HUE")
setColor (HSV2RGB(<15.0*f,0,0>+RGB2HSV(myColor)));
menuAdjust(id);
return;
}
/*
if (o=="Fabric") {
setTexture(llList2String(Textures, (integer)p-1));
menuTexture(id);
}
*/
i=llListFindList(TextureNames, [d]);
if (i>=0) {
setTexture (llList2String(Textures, i));
menuTexture(id);
}

}
}

timer() {
llSetTimerEvent(0.0);
llListenControl (handle, FALSE);
}
}

</lsl>

Happy scripting.

TMCP

2012-08-15T19:36:17Z

Tano Toll: /* TMCP Sitmanager */

TMCP - Tano's MLP Compatible Pose scripts
*a drop in replacement for MLPv2
*configuration notecard compatible
*Since august 14. 2012 released under the open source BSD license

Collection of scripts as of version 0.37 below, or available on marketplace for your convenience https://marketplace.secondlife.com/p/TMCP-Tanos-MLP-Compatible-Pose-Scripts-Source-Edition/2964611

Resident 'Camden McAndrews' voluntueered as new maintainer. I hope the MLPv2 team will pick it up.

==Features==
* MLPv2 notecard & plugin compatible
* Fast & Stable operation
* Intelligent menu
* No poseballs
* Plenty memory for larger animation sets

==Limitations==
* No facial animations (yet)
* No properties
(Both limitations are relative easily added, yet not implemented in version 0.37)

==TMCP Sitmanager==
<lsl>
//keeps track of sitted target, position them and animate them.

list animPool; //pool of scripts that are able to pose targets

list poolCache; //try re-use same script for same agent, to avoid reasking permissions

list sitted; //strided, holds: AGENT_KEY, logical offset (`ball number`), [animscript?], current animation?, current position?
integer sittedStride=3;

list sittedAgents;
list sitScripts;

integer MSG_AGENT_UNSIT = 380;
integer MSG_ALL_UNSIT =381;
integer MSG_DISABLE_SITTING =382;
integer MSG_REGISTER_SITSCRIPT =383;
integer MSG_QUERY_SITSCRIPT = 385;
integer MSG_RESET =0;
integer MSG_ENABLE_SITTING=0;
integer MSG_SET_SITTARGET=375;
integer MSG_PLAY_ANIM=390;
integer MSG_STOP_ANIM=391;
integer MSG_AGENT_PLAY_ANIM=395; // to notify the slave script
integer MSG_AGENT_STOP_ANIM=396;
integer MSG_ATTACH_AGENT = 398;
integer MSG_DETACH_AGENT = 399;
integer MSG_RUN_ANIMS=379;

integer MSG_DO_STOP=353;
integer MSG_DO_SWAP=354;
integer MSG_MENU_SWAP=355;

integer MSG_MENU_META=333;

integer MSG_MLP_SITTED=-11000;
integer MSG_MLP_UNSITTED=-11001;

integer MSG_MODE_BALLUSERS=366;

integer MSG_DO_DEFAULT_POSE = 358;

integer MSG_RLV_GRAB=308;
integer MSG_RLV_RELEASE=309;
integer MSG_RLV_VICTIM_LIST=307;

integer MSG_DO_MENU_CURRENTMENU = 305;

//keys to controlling:
//animname+index is key to both real animation name and it's position.

list agentAnims;

list agentScripts;
list agentScriptCache;

list agentPoseIdx;

list usedIndexes; //logical pose positions, register in here.

integer MAX_SITTING=1;

string currentAnim;
integer currentAnimSeats;

list menuMeta;

integer mode_ballusers;

key grabberID;

list potentionalVictims;
list victimsWithRelay;

list grabbingVictims; //commanded to, but not yet suited
list grabbedVictims; //victims tagged as victim, sitted

integer CAPTURE_RANGE = 35;
integer RELAY_CHANNEL = -1812221819;
integer relay_handle;

integer timer_reason_versioncheck;
integer rlv_victim_dialog_handle;
integer rlv_victim_dialog_channel;

integer timer_versioncheck=50;
integer timer_closechannel=51;
integer timer_closechannel2=53;
integer timer_defaultpose=52;
integer timer_cleargrabbing=55;

assignScript (key id) {
integer i=llListFindList (agentScripts, [id]);
if (i>=0) //agent already got assignment
return;
i=llListFindList (agentScriptCache, [id]);
string candidate;
if (i>=0) {
candidate=llList2String(agentScriptCache, i+1);
if (-1!=llListFindList(agentScripts, [candidate]))
candidate="";
}
if (candidate);else {
//try to find a new one
for (i=0; i<llGetListLength(sitScripts); i++) {
string ss=llList2String(sitScripts, i);
if (-1==llListFindList(agentScripts, [ss])) {//found free one
candidate=ss;
jump break;
}
}
@break;
}
if (candidate) {
agentScripts+=[id, candidate];
i=llListFindList (agentScriptCache, [candidate]);
if (-1<i)
agentScriptCache=llDeleteSubList(agentScriptCache, i-1, i);
agentScriptCache+=[id, candidate];
//llOwnerSay ((string)id+" attached to "+candidate);
llMessageLinked(LINK_THIS, MSG_ATTACH_AGENT, candidate, id);
} else {
llRegionSayTo (id, 0, "Sorry, but there is no available script to animate your avatar.");
}
}

integer assignPoseIdx (key id) {
//start counting at 1.. just because we can.
integer i=llListFindList (agentPoseIdx, [id]);
if (-1<i)
return llList2Integer(agentPoseIdx, i+1); //agent already got a pose assigned
for (i=1; i<100; i++) {
if (-1==llListFindList(agentPoseIdx, [i])) //found empty one
{
agentPoseIdx+=[id, i];
//llInstantMessage (id, "You are assigned to pose index "+(string)i);
return i;
}
}
return 0;
}

dropAgent (key id) {
//clean up stuff agent had

}

stopAnims(key id) {
llMessageLinked (LINK_THIS, MSG_AGENT_STOP_ANIM, "", id);
}

applyAnims() {
//apply animation (and position?) for all agents involved

//send list of keys with indexes to position. it should know which anim is current.
llMessageLinked (LINK_THIS, MSG_RUN_ANIMS, llList2CSV(agentPoseIdx), "");
//llOwnerSay ("anims/poses "+llList2CSV(agentPoseIdx));

}

cleanUp(key id) {
stopAnims(id);
integer i=llListFindList (agentScripts, [id]);
if (-1<i)
agentScripts = llDeleteSubList (agentScripts, i, i+1);
i=llListFindList (agentPoseIdx, [id]);
if (-1<i)
agentPoseIdx = llDeleteSubList (agentPoseIdx, i, i+1);

i=llListFindList (grabbedVictims, [id]);
if (-1<i)
grabbedVictims = llDeleteSubList (grabbedVictims, i, i);

}

setSitTarget() {
//needs pose info.. so we calculate the first available index, and match info with current pose.. it's for position script, i think.
//linkedmessage (setsittarget, [posename,] index)..
//posename might be cached by positioner and/or set to defaults.
integer idx=1;
//find first available
while (-1<llListFindList(agentPoseIdx, [idx]))
idx++;
if (idx>MAX_SITTING) {
llSitTarget (ZERO_VECTOR, ZERO_ROTATION/llGetRot());
} else {
llSitTarget (<0,0,0.01>, ZERO_ROTATION/llGetRot()); //backup option.
llMessageLinked(LINK_THIS, MSG_SET_SITTARGET, (string)idx, "");
}

}

integer maySit(key id) {
if (!mode_ballusers) //everyone
return TRUE;
if (id==llGetOwner()) //always
return TRUE;
if (mode_ballusers==1) //group
return llSameGroup(id);
return FALSE; //nope
}

broadcastVictims() {
llMessageLinked (LINK_THIS, MSG_RLV_VICTIM_LIST, llList2CSV(grabbedVictims), "");
}

requestMenu(key id) {
llMessageLinked (LINK_THIS, MSG_DO_MENU_CURRENTMENU, "", id);
}

inventarise() {
//someone sitted or unsitted. do the bookkeeping
list agents;
integer i;

//get sitted avatars
for (i=0; i<=llGetNumberOfPrims(); i++) {
key id=llGetLinkKey(i);
if (llGetAgentSize(id)) {
//this is an agent..
agents+=id;
if (-1!=llListFindList(grabbingVictims, [id])) {
//grabbingVictims=[]; //should really do this somewhere else
if (-1==llListFindList(grabbedVictims, [id])) {
rlv_lock(id);
grabbedVictims+=id;
broadcastVictims();
}
}
}
}

//now cross reference against existing agents
//first see, who's all gone
for (i=0;i<llGetListLength(sittedAgents); i++) {
key id=llList2Key(sittedAgents, i);
if (-1==llListFindList(agents, [id])) {
//agent unsitted, remove him
msgUnsit(id, llList2Integer(agentPoseIdx, llListFindList(agentPoseIdx, [id])+1));
if (-1!=llListFindList(grabbedVictims, [id])) {
//rlv catch, unlock it
rlv_release(id);
}
cleanUp(id);
broadcastVictims();
}
}

//now, lets see who's all added
for (i=0;i<llGetListLength(agents); i++) {
key id=llList2Key(agents, i);
if (-1==llListFindList(sittedAgents, [id])) {
//freshy added, assign it a script, if possible, and a logical offset
if (maySit(id)) {
assignScript(id);
msgSit(id, assignPoseIdx(id));
} else {
llUnSit(id);
llWhisper (0, "Sorry "+llKey2Name(id)+" but you cannot use this object.");
}
//play anim

}
}

// if (sittedAgents != agents)
// setSitTarget();
sittedAgents = agents;
setSitTarget();
applyAnims();

// default pose switching on idle
if (agents==[])
scheduleEvent (timer_defaultpose, 120, "");
else
cancelEvent (timer_defaultpose);
}

makeSwapMenu(key id, integer channel) {
//offer nice swap menu
//list sitted avatars
string text="";
integer i;
integer m=10;
list buttons=["<BACK"];
if (MAX_SITTING<m)
m=MAX_SITTING;
for (i=1; i<=m; i++) {
integer j=llListFindList(agentPoseIdx, [i]);
string agent = "<Nobody>";
key aid;
if (-1<j) {
aid=llList2Key(agentPoseIdx, j-1);
agent=llKey2Name(aid);
}
text+=(string)i + ". " + llList2String(menuMeta, i) + " "+agent+"\n";

if (aid!=id)
buttons+=["SWAP::"+(string)i];
}
llDialog (id, text, buttons, channel);
}

//consideration: send out sit/unsit events or not.. i think, might as well not. in order not to confuse rlv.
swapAgent (key id, integer newpos) {
//llSay (0, "Swapping "+llKey2Name(id)+" to position #"+(string)newpos);
integer o=llListFindList(agentPoseIdx, [id]);
if (o<0) {
//llOwnerSay ("swap key not found "+(string)id);
//agent not found. see if we have a rlv target
if (llGetListLength(grabbedVictims)) {
//just default to first best sitted. Stuff gets complex with multiple RLV but who cares that.
id=llList2Key(grabbedVictims,0);
o=llListFindList(agentPoseIdx, [id]);
if (o<0) //OUCH, should nevah happen
return;
}
else return;
}
integer oldidx=llList2Integer(agentPoseIdx, o+1);
if (oldidx==newpos) {
llRegionSayTo (id, 0, "You choosen the same position");
return;
}
agentPoseIdx=llDeleteSubList(agentPoseIdx, o, o+1);
integer topos=llListFindList(agentPoseIdx, [newpos]);
if (-1<topos) {
agentPoseIdx=llDeleteSubList(agentPoseIdx, topos-1, topos) + [llList2Key(agentPoseIdx, topos-1),oldidx];
}
agentPoseIdx += [id, newpos];
applyAnims();
}

unsitAll() {
integer i;
for (i=0; i<=llGetNumberOfPrims(); i++) {
key id=llGetLinkKey(i);
if (llGetAgentSize(id))
llUnSit(id);
}
}

msgSit(key id, integer poseidx) {
//we start count at 1, mlp at zero. fix right here
llMessageLinked(LINK_THIS, MSG_MLP_SITTED, (string)(poseidx-1), id);
}

msgUnsit(key id, integer poseidx) {
//we start count at 1, mlp at zero. fix right here
llMessageLinked(LINK_THIS, MSG_MLP_UNSITTED, (string)(poseidx-1), id);
}

log(string t){
//llOwnerSay(t);
}

RLVGrabMenu(key id) {
grabberID = id;
llSensor("", NULL_KEY, AGENT, CAPTURE_RANGE, TWO_PI);
// llInstantMessage (id, "Scanning ... menu in 5.. 4.. 3..");
}

RLVReleaseAll() {
integer i;
for (i=0; i<llGetListLength(grabbedVictims); i++) {
key id=llList2Key(grabbedVictims,i);
rlv_release (id);
llWhisper (0,"releasing "+llKey2Name(id));
//unsit?
llUnSit(id);
}
grabbedVictims=[];
}

rlv_checkversion (key id) {
rlv_relay(id, "!version=" + (string)1); //version_handle
}

rlv_capture(key avatar)
{
rlv_relay(avatar, "@sit:" + (string)llGetKey() + "=force");
//llSay (menu_ban_channel, "- "+(string)avatar);
llWhisper (0, llKey2Name(grabberID)+" captures "+llKey2Name(avatar));
}

rlv_lock(key avatar)
{
rlv_relay(avatar, "@unsit=n");
}

rlv_release(key avatar)
{
rlv_relay(avatar, "@unsit=y");
rlv_relay(avatar, "!release");
//llSay (menu_ban_channel, "- "+(string)avatar);
}

// write a message to the RLV Relay
rlv_relay(key avatar, string message)
{
if (avatar != NULL_KEY)
{
llSay(RELAY_CHANNEL, llEscapeURL(llGetObjectName()) + "," + (string) avatar + "," + message);
log("RLV: " + llGetObjectName() + "," + (string) avatar + "," + message);
}
}

//scheduler

list events = [];
integer nextEvent = 0;

scheduleEvent(integer id, integer time, string data) {
//adjust timestamp
time+=llGetUnixTime();

//cancel any previous requests, this case we only want one per type, really
cancelEvent(id);

events = llListSort(events + [time, id, data], 3, TRUE);
setTimer(FALSE);
}

cancelEvent(integer id) {
//reasonable failsafe as long as you don't use id's that could be current timestamp.
integer i=llListFindList(events, [id]);
if ((-1<i) && ((i % 3) == 1)) {
//it was an id
events=llDeleteSubList(events, i-1, i+1);

//recurse when found, delete all with said id... ?
cancelEvent(id);

setTimer(FALSE);
}
}

integer setTimer(integer executing) {
if ((events != []) > 0) { // Are there any list items?
integer id = llList2Integer(events, 1);

integer time = llList2Integer(events, 0);
nextEvent = id;

float t = (float)(time - llGetUnixTime());
if (t <= 0.0) {
if (executing) return TRUE;
else t = 0.01;
}
llSetTimerEvent(t);
} else {
llSetTimerEvent(0.0);
nextEvent = -1;
}
return FALSE;
}

handleEvent(integer id, string data) {

if (id==timer_versioncheck) {
//time to display our dialog
if ([]==victimsWithRelay) {
llRegionSayTo (grabberID, 0, "No eligible victims found (they must wear a relay).");
requestMenu(grabberID);
} else {
list nn;
integer i;
for (i=0; (i<llGetListLength(victimsWithRelay)) && (i<23); i+=2) {
string s=llKey2Name(llList2Key(victimsWithRelay, i));
if (s)
nn+=llGetSubString(s,0,23);
}

llListenControl(rlv_victim_dialog_handle, TRUE);
scheduleEvent (timer_closechannel, 90, (string)rlv_victim_dialog_handle);
llDialog (grabberID, "Choose a victim", nn, rlv_victim_dialog_channel);
//scheduleEvent (timer_versioncheck, 5, "");
}

//set timer to new timeout

//llSetTimerEvent(TIMER_TIMEOUT);
//llListenControl (version_handle, FALSE);
//return;
}
else
if ((id==timer_closechannel) || (id==timer_closechannel2)) {
llListenControl ((integer)data, FALSE);
}
else
if (id==timer_defaultpose) {
llMessageLinked(LINK_THIS, MSG_DO_DEFAULT_POSE, "", "");
}
else
if (id==timer_cleargrabbing) {
grabbingVictims=[];
}

}

upgrade() {string self = llGetScriptName(); string basename = self; if (llSubStringIndex(self, " ") >= 0) {integer start = 2; string tail = llGetSubString(self, llStringLength(self) - start, -1); while (llGetSubString(tail, 0, 0) != " ") {start++; tail = llGetSubString(self, llStringLength(self) - start, -1);} if ((integer)tail > 0) {basename = llGetSubString(self, 0, -llStringLength(tail) - 1);}} integer n = llGetInventoryNumber(INVENTORY_SCRIPT); while (n-- > 0) {string item = llGetInventoryName(INVENTORY_SCRIPT, n); if (item != self && 0 == llSubStringIndex(item, basename)) {llRemoveInventory(item);}}}

default
{
state_entry()
{
upgrade();
llOwnerSay ("sitmanager memory free : "+(string)llGetFreeMemory());
state active;
}
}

state active {
state_entry() {
setSitTarget();
llMessageLinked (LINK_THIS, MSG_QUERY_SITSCRIPT, "", "");

rlv_victim_dialog_channel = 124904342+llFloor(llFrand(42902543));
rlv_victim_dialog_handle = llListen(rlv_victim_dialog_channel, "", "", "");
llListenControl (rlv_victim_dialog_handle, FALSE);
relay_handle=llListen(RELAY_CHANNEL, "", "", "");
llListenControl(relay_handle, FALSE);
}
link_message(integer sn, integer n, string m, key id) {

if (n==MSG_RESET)
llResetScript();
else
if (n==MSG_ENABLE_SITTING) {
MAX_SITTING=llGetListLength(sitScripts);
setSitTarget();
}
else
if (n==MSG_AGENT_UNSIT) {
//unsit agent
llUnSit(id);
}
else
if (n==MSG_ALL_UNSIT) {
//just kick everyone
unsitAll();
}
else
if (n==MSG_DISABLE_SITTING) {
//state inactive;
MAX_SITTING=0;
setSitTarget();
}

else
if (n==MSG_REGISTER_SITSCRIPT) {
if (m)
if (INVENTORY_SCRIPT==llGetInventoryType(m))
if (-1==llListFindList(sitScripts, [m])) {
sitScripts+=m;
MAX_SITTING=llGetListLength(sitScripts);
}
}

else
if (n==MSG_PLAY_ANIM) {
currentAnim=m;
applyAnims();
}
else
if (n==MSG_MENU_SWAP) {
makeSwapMenu (id, (integer)m);
}
else
if (n==MSG_DO_SWAP) {
swapAgent(id, (integer)m);
}
else
if (n==MSG_MENU_META) {
menuMeta=llParseString2List(m, ["|", " "], []);
}
else
if (n==MSG_DO_STOP) {
llUnSit(id); //let changed event handle the rest
}
else
if (n==MSG_MODE_BALLUSERS) {
mode_ballusers=(integer)m;
}
else
if (n==MSG_RLV_GRAB) {
RLVGrabMenu(id);
}
else
if (n==MSG_RLV_RELEASE) {
RLVReleaseAll();
}

}

changed (integer c) {
if (c & CHANGED_LINK) {
//don't even bother about getting sitted or not or leaving..
//just fetch all current avatars and match them against our list of known avis
inventarise();
}

}

timer() {
// Clear timer or it might fire again before we're done
llSetTimerEvent(0.0);

do {
// Fire the event
handleEvent(nextEvent, llList2String(events, 2));

// Get rid of the first item as we've executed it
integer l = events != [];
if (l > 0) {
if (l > 3)
events = llList2List((events = []) + events, 3, -1);
else events = [];
}

// Prepare the timer for the next event
} while (setTimer(TRUE));
}

/*
timer() {
/* default pose.. do somewhere else please
llSetTimerEvent(0.);
llMessageLinked(LINK_THIS, MSG_DO_DEFAULT_POSE, "", "");
*/
/*
}
*/

no_sensor()
{
llRegionSayTo (grabberID, 0, "No nearby potentional victims found");
requestMenu(grabberID);
}

// some av in sensor range
sensor(integer total_number)
{
//llListenControl (rlv_victim_dialog_handle, TRUE);
//scheduleEvent (timer_closechannel, 120, (string)rlv_victim_dialog_handle);
llListenControl (relay_handle, TRUE);
scheduleEvent (timer_closechannel2, 7, (string)relay_handle);

potentionalVictims=[];
victimsWithRelay=[];
integer i;
for(i=0; i < total_number; i++)
{
key id = llDetectedKey(i);
string name = llKey2Name(id);
if (llStringLength(name) > 24)
{
name = llGetSubString(name, 0, 23);
}
potentionalVictims+=[id, name];
rlv_checkversion(id);
}

// show dialog if list contains names
/*
if (llGetListLength(sensor_names) > 0)
{
llListenControl(dialog_handle, TRUE);
llSetTimerEvent(TIMER_TIMEOUT);
llDialog(avatar_menu, MSG_CHOOSE_AV, sensor_names, dialog_channel);
}
*/
scheduleEvent (timer_versioncheck, 5, (string)grabberID);
llRegionSayTo (grabberID, 0, "Verifying "+(string)total_number+" potentional victims. Menu in 5.. 4.. 3.."); }

listen (integer ch, string n, key id, string m) {
if (ch==RELAY_CHANNEL) {
if (-1!=llSubStringIndex(m, "version=")) {//bit dirty, we might catch other objects too
//victims+=llGetOwnerKey(id);
//victim selected, grab it
victimsWithRelay+=[llGetOwnerKey(id),llGetSubString(llKey2Name(llGetOwnerKey(id)),0,23)];
}
}
else
if (ch==rlv_victim_dialog_channel) {
//victim selected, grab it
integer i=llListFindList (victimsWithRelay, [m]);
if (-1<i) {
key vid=llList2Key(victimsWithRelay, i-1);
rlv_capture (vid);
if (-1==llListFindList(grabbingVictims, [vid])) {
grabbingVictims+=vid;
}
scheduleEvent (timer_cleargrabbing, 120, (string)id);
}
requestMenu(grabberID);
}

}
}

/*
state inactive {
state_entry() {
llSitTarget(ZERO_VECTOR, ZERO_ROTATION);
}
link_message(integer sn, integer n, string m, key id) {
if (n==MSG_RESET)
llResetScript();
else
if (n=MSG_ENABLE_SITTING)
state active;
}
}
*/
</lsl>

==TMCP - pose==
<lsl>
key ourAgent;
string currentAnim;

integer hasPerms;

integer MSG_AGENT_PLAY_ANIM=395; // to notify the slave script
integer MSG_AGENT_STOP_ANIM=396;
integer MSG_ATTACH_AGENT = 398;
integer MSG_DETACH_AGENT = 399;
integer MSG_REGISTER_SITSCRIPT =383;
integer MSG_QUERY_SITSCRIPT = 385;
integer MSG_SYNC_ANIM=361;

integer MSG_ADJUST_POSROT=520;
integer MSG_TEMPORARY_POSROT=521;

integer MSG_MODE_ADJUST=368;

vector o=ZERO_VECTOR;
vector r=ZERO_VECTOR;
integer hastimer;

integer is_adjusting;
integer cursormode;

stopAnim() {
if (hasPerms) if (currentAnim)
llStopAnimation(currentAnim);
}

runAnim() {
if (hasPerms) if (currentAnim)
llStartAnimation(currentAnim);
}

integer checkPerms() {
if (llGetPermissionsKey()!=ourAgent) {
hasPerms = FALSE;
return FALSE;
}
hasPerms=(PERMISSION_TAKE_CONTROLS|PERMISSION_TRIGGER_ANIMATION) == ((PERMISSION_TAKE_CONTROLS|PERMISSION_TRIGGER_ANIMATION) & llGetPermissions());
return hasPerms;
}

queryPerms() {
if (!checkPerms()) {
//must query them
llRequestPermissions(ourAgent, PERMISSION_TAKE_CONTROLS|PERMISSION_TRIGGER_ANIMATION);
} else {
stopDefAnims();
if (currentAnim)
llStartAnimation(currentAnim);
getControls();
}
}

stopDefAnims() {
//easy way would be:
//llStopAnimation("sit");
//let's go for the hard way
list a=llGetAnimationList(ourAgent);
integer i;
for (i=0; i<llGetListLength(a); i++)
llStopAnimation(llList2Key(a,i));
}

register() {
llMessageLinked (LINK_THIS, MSG_REGISTER_SITSCRIPT, llGetScriptName(), "");
}

getControls() {
llTakeControls (CONTROL_UP|CONTROL_DOWN|CONTROL_LEFT|CONTROL_RIGHT|CONTROL_FWD|CONTROL_BACK|CONTROL_ROT_LEFT|CONTROL_ROT_RIGHT, TRUE, FALSE);
//llInstantMessage (ourAgent, "Adjust your position with PGUP, PGDOWN and cursorkeys. Shift rotates.");
whispHelp(ourAgent);
}

parseControls (integer level, integer edge) {

integer l = level; //hold down

if ((CONTROL_UP|CONTROL_DOWN)==(l & edge & (CONTROL_UP | CONTROL_DOWN))) {
cursormode=!cursormode;
whispHelp(ourAgent);
return;
}

if (is_adjusting) {
integer cm=cursormode;
if (l & edge & CONTROL_LEFT)
cursormode--;
if (l & edge & CONTROL_RIGHT)
cursormode++;
if (cursormode<1)
cursormode=3;
if (cursormode>3)
cursormode=1;
if (cm!=cursormode)
whispHelp(ourAgent);
}

if (cursormode==1) {//fine adjust
if (l & CONTROL_FWD) o+=<0,2,0>;
if (l & CONTROL_BACK) o+=<0,-2,0>;
if (l & CONTROL_ROT_LEFT) o+=<-2,0,0>;
if (l & CONTROL_ROT_RIGHT) o+=<2,0,0>;
if (l & CONTROL_UP) o+=<0,0,2>;
if (l & CONTROL_DOWN) o+=<0,0,-2>;
}
else
if (cursormode==2) {//90 degrees rotation
if (l & edge & CONTROL_FWD) r+=<0,90,0>;
if (l & edge & CONTROL_BACK) r+=<0,-90,0>;
if (l & edge & CONTROL_ROT_LEFT) r+=<0,0,-90>;
if (l & edge & CONTROL_ROT_RIGHT) r+=<0,0,90>;
if (l & edge & CONTROL_UP) r+=<90,0,0>;
if (l & edge & CONTROL_DOWN) r+=<-90,-0,0>;
}
else
if (cursormode==3) {//fine rotation
if (l & CONTROL_FWD) r+=<0,1,0>;
if (l & CONTROL_BACK) r+=<0,-1,0>;
if (l & CONTROL_ROT_LEFT) r+=<0,0,-1>;
if (l & CONTROL_ROT_RIGHT) r+=<0,0,1>;
if (l & CONTROL_UP) r+=<1,0,0>;
if (l & CONTROL_DOWN) r+=<-1,0,0>;
}

//if (l & edge & CONTROL_LEFT) r += <0,0,90>;
//if (l & edge & CONTROL_RIGHT) r += <0,-90,0>;

if (!hastimer) {
llSetTimerEvent (0.25);
hastimer=TRUE;
}
}

whispHelp (key id) {
if (!is_adjusting) {
if (!cursormode) {
llRegionSayTo (id, 0, "Press PAGE-UP and PAGE-DOWN simultanious to fine adjust position");
} else {
llRegionSayTo (id, 0, "Use the cursor keys and up/down to adjust position. Changes made are temporary.");
}
} else {
if (!cursormode)
llRegionSayTo (id, 0, "Use PAGE-UP and PAGE-DOWN to start adjusting");
if (1==cursormode)
llRegionSayTo (id, 0, "Mode: position (fine adjust). Use cursor keys and up/down to adjust position. Shift-left or shift-right to change mode");
if (2==cursormode)
llRegionSayTo (id, 0, "Mode: rotation (90 degrees) . Use cursor keys and up/down to adjust rotation. Shift-left or shift-right to change mode");
if (3==cursormode)
llRegionSayTo (id, 0, "Mode: rotation (fine adjust). Use cursor keys and up/down to adjust rotation. Shift-left or shift-right to change mode");
}
}

upgrade() {string self = llGetScriptName(); string basename = self; if (llSubStringIndex(self, " ") >= 0) {integer start = 2; string tail = llGetSubString(self, llStringLength(self) - start, -1); while (llGetSubString(tail, 0, 0) != " ") {start++; tail = llGetSubString(self, llStringLength(self) - start, -1);} if ((integer)tail > 0) {basename = llGetSubString(self, 0, -llStringLength(tail) - 1);}} integer n = llGetInventoryNumber(INVENTORY_SCRIPT); while (n-- > 0) {string item = llGetInventoryName(INVENTORY_SCRIPT, n); if (item != self && 0 == llSubStringIndex(item, basename)) {llRemoveInventory(item);}}}

default
{
state_entry()
{
//upgrade();
register();
}

link_message(integer sn, integer n, string m, key id) {
if (n==MSG_ATTACH_AGENT) {
if (m==llGetScriptName()) {
if (ourAgent)
stopAnim();
currentAnim="";
ourAgent = id;
queryPerms();
}
}
else
if (n==MSG_DETACH_AGENT) {
if (ourAgent==id) {
llReleaseControls();
stopAnim();
}
ourAgent=NULL_KEY;
currentAnim="";
}
else
if (n==MSG_AGENT_PLAY_ANIM) {
if (ourAgent==id) {
stopAnim();
currentAnim=m;
runAnim();
}
}
else
if (n==MSG_AGENT_STOP_ANIM) {
if (ourAgent==id) {
stopAnim();
currentAnim="";
}
}
else
if (n==MSG_SYNC_ANIM) {
if (ourAgent) {
stopAnim();
runAnim();
}
}
else
if (n==MSG_QUERY_SITSCRIPT) {
register();
//llOwnerSay ("Registering");
}
else
if (n==MSG_MODE_ADJUST) {
is_adjusting = (integer)m;
if (!is_adjusting)
cursormode=0;
else
cursormode=1;
if (id==ourAgent)
whispHelp(id);
}

}

run_time_permissions(integer p) {
if (checkPerms()) {
stopDefAnims();
if (currentAnim)
llStartAnimation(currentAnim);
getControls();
}
}

control (key id, integer level, integer edge) {
if (id!=ourAgent)
return;
parseControls (level, edge);
}

timer () {
llSetTimerEvent (0.);
hastimer=FALSE;
if (ZERO_VECTOR!=(o+r)) {
if (is_adjusting)
llMessageLinked (LINK_THIS, MSG_ADJUST_POSROT, (string)(0.005*o)+"&"+(string)r, ourAgent);
else
llMessageLinked (LINK_THIS, MSG_TEMPORARY_POSROT, (string)(0.005*o)+"&"+(string)r, ourAgent);
}
o=ZERO_VECTOR;
r=ZERO_VECTOR;

}

}

</lsl>

==TMCP - positions==
<lsl>
//basically, we need a large datastore for our command set
list poseNames;
list poseData;

list positionNames;
list positionData;

integer MSG_DATA_MENU=310;
integer MSG_DATA_TYPE=320;
integer MSG_DATA_POSE=330;
integer MSG_DATA_POSITION=331;
integer MSG_DATA_LM=335;

integer MSG_DO_POSE=350;
integer MSG_DO_LM=351;
integer MSG_DO_SPECIAL=352;

integer MSG_SET_RUNNING=390;
integer MSG_STORAGE_RESET=391;

integer MSG_DATA_READY=309;

integer MSG_RUN_ANIMS=379;

integer MSG_AGENT_PLAY_ANIM=395;

integer MSG_SET_SITTARGET=375;

integer MSG_DUMP_POSITIONS=389;
integer MSG_UPDATE_POS=363;

integer MSG_DO_DEFAULT_POSE = 358;
integer MSG_SET_DEFAULT_POSE = 359;

integer MSG_MLP_SETTING = 1;

integer MSG_ADJUST_POSROT=520;
integer MSG_TEMPORARY_POSROT=521;

string currentPose="default";
list currentAnims;
list currentPositions;

list agentPoseIdx;

list agentAdjust;

string defaultPose="default";

runAnims() {
list data=agentPoseIdx;
integer i;
list idpos;
for (i=0; i<llGetListLength(data); i+=2) {
key id=(key)llList2String(data, i);
integer idx=-1+(integer)llList2String(data, i+1);
if (id) if (idx>=0) {
if (idx>=llGetListLength(currentAnims))
llWhisper (0, "No animation available for "+llKey2Name(id));
else {
llMessageLinked (LINK_THIS, MSG_AGENT_PLAY_ANIM, llList2String(currentAnims, idx), id);
//llOwnerSay ("Playing anim "+llList2String(currentAnims, idx)+" on id "+(string)id);
}

if (idx/2>=llGetListLength(currentPositions))
llSay (0, "No position data for "+llKey2Name(id));
else {
//set agents position
idpos+=[id, (vector)llList2String(currentPositions, idx*2),(vector)llList2String(currentPositions, idx*2+1)];
}
} else {
//llOwnerSay ("Corrupt agent anim position request");
}
}
//apply positions
for (i=0; i<=llGetNumberOfPrims(); i++) {
integer j=llListFindList(idpos, [llGetLinkKey(i)]);
if (-1<j) {
vector pos = llList2Vector(idpos, j+1)+(<0,0,0.42+0.01*(integer)llGetObjectDesc()>/llGetRot());
vector rot = llList2Vector(idpos, j+2) * DEG_TO_RAD;
integer l=llListFindList (agentAdjust, [llGetLinkKey(i)]);
if (-1<l) {
pos+=llList2Vector (agentAdjust, l+1);
rot=llRot2Euler(llEuler2Rot(llList2Vector (agentAdjust, l+2)) * llEuler2Rot(rot));
}
llSetLinkPrimitiveParamsFast(i, [PRIM_POS_LOCAL, pos,PRIM_ROT_LOCAL, llEuler2Rot(rot)]);
//llOwnerSay ("Setting position for "+llKey2Name(llGetLinkKey(i))+" position: "+(string)pos+" rotation: "+ (string)rot );
}
}
}

setSitTarget(integer poseidx) {
poseidx--;
vector v=(vector)llList2String(currentPositions, poseidx*2);
vector r=(vector)llList2String(currentPositions, poseidx*2+1);
llSitTarget (v+(<0,0,0.42+0.01*(integer)llGetObjectDesc()>/llGetRot()) , llEuler2Rot(r*DEG_TO_RAD));
//llOwnerSay ("Sit target #"+(string)poseidx+" "+(string)(v+(<0,0,0.42>/llGetRot()))+" "+(string)(r));
}

string shortString (float n) {
string s=(string)n;
while (llStringLength(s)>1) {
integer hasdot=-1!=llSubStringIndex(s, ".");
string d=llGetSubString(s,-1,-1);
if ((hasdot && (d=="0")) || (d=="."))
s=llDeleteSubString(s,-1,-1);
else
jump ok;
}
@ok;
return s;
}

string shortVec (vector v) {
return "<"+shortString(v.x)+","+shortString(v.y)+","+shortString(v.z)+">";
}

dumpPos() {
llOwnerSay ("TMCP Position Dump");
integer i;
for (i=0; i<llGetListLength(positionNames); i++) {
//llOwnerSay ("{"+llList2String(positionNames, i)+"} "+llList2String(positionData, i));
list v=llParseString2List(llList2String(positionData, i), ["&"], []);
string s="{"+llList2String(positionNames, i)+"}";
integer j;
for (j=0; j<llGetListLength(v); j++)
//notice that function shortvec takes string as param
s+=" "+shortVec((vector)llList2String(v, j));
llOwnerSay (s);
}
}

doPose (string m) {
if (m!=currentPose)
agentAdjust=[];

currentPose=m;
currentAnims=[];
currentPositions=[];
integer i=llListFindList(positionNames, [m]);
integer j=llListFindList(poseNames, [m]);
currentAnims=llParseString2List (llList2String(poseData, j), ["|"], []);
currentPositions=llParseString2List (llList2String(positionData, i), ["&"], []);

//fill missing data with defaults
i = llListFindList(positionNames, ["default"]);
j = llListFindList(poseNames, ["default"]);
list animdef=llParseString2List (llList2String(poseData, j), ["|"], []);
list posdef=llParseString2List (llList2String(positionData, i), ["&"], []);
currentAnims+=llList2List (animdef, llGetListLength(currentAnims), -1);
currentPositions+=llList2List(posdef, llGetListLength(currentPositions), -1);

//this should be obsolete now:
if (/*(i>=0) && */(j>=0)) {
//list l=llParseString2List(llList2String(lmAction, i), [","],[]);
//parse pose data. todo.
if (i<0) {
//need to fetch default data... just try it.
i=llListFindList(positionNames, ["default"]);
}
//llOwnerSay ("Do pose "+m+" anims "+llList2String(poseData,j)+" data "+llList2String(positionData, i));
} else {
//llOwnerSay ("No animations defined for "+m);
}

runAnims();
}

setAgentPosRot (key id, string data) {
//set temporary agent adjustment.
list l=llParseString2List(data, ["&"], []);
vector p=(vector)llList2String(l,0);
vector r=DEG_TO_RAD * (vector)llList2String(l,1);
integer i=llListFindList (agentAdjust, [id]);
if (-1<i) {
p+=llList2Vector(agentAdjust, i+1);
r=llRot2Euler(llEuler2Rot(llList2Vector(agentAdjust, i+2))*llEuler2Rot(r));
agentAdjust = llDeleteSubList(agentAdjust, i, i+2);
}
if (llVecMag(p)>1)
p=llVecNorm(p);
agentAdjust+=[id,p,r];
runAnims();
}

adjustPosition (string name, integer index, vector p, vector r) {
//positionNames
integer i=llListFindList (positionNames, [name]);
if (-1<i) {
string data=llList2String(positionData, i);
list pos=llParseString2List(data, ["&"], []);
if (index>0) {
//alter only index
integer j=(index-1)*2;
if (j<llGetListLength(positionData)) {
vector v=(vector)llList2String(pos, j);
v+=p;
vector R0=(vector)llList2String(pos, j+1);
rotation R1=llEuler2Rot(DEG_TO_RAD *R0);
rotation Rd=llEuler2Rot(DEG_TO_RAD * r);
R1 = R1 * Rd;
R0=RAD_TO_DEG * llRot2Euler(R1);
pos=llListReplaceList(pos, [shortVec(v),shortVec(R0)], j, j+1);
}

} else {
//alter all
integer j;
for (j=0; j<llGetListLength(pos); j+=2) {
vector v=(vector)llList2String(pos, j);
v+=p;
vector R0=(vector)llList2String(pos, j+1);
rotation R1=llEuler2Rot(DEG_TO_RAD *R0);
rotation Rd=llEuler2Rot(DEG_TO_RAD * r);
R1 = R1 * Rd;
R0=RAD_TO_DEG * llRot2Euler(R1);
pos=llListReplaceList(pos, [shortVec(v),shortVec(R0)], j, j+1);
}
}
data=llDumpList2String(pos, "&");
//llOwnerSay ("new pos data for "+name+" : "+data);
positionData=llListReplaceList (positionData, [data], i, i);

}
}

adjustAllPositions (vector p, vector r) {
//loop all pose, adjust them
integer i;
for (i=0; i<llGetListLength(positionNames); i++) {
adjustPosition (llList2String(positionNames, i),-1, p,r);
}
}

parseSetting (string m, key id) {
//seperated by =
//might contain ROT or POS adjustments
list l=llParseString2List(m, [" = ", " =", "=", "= ","="],[]);
string cmd=llList2String(l, 0);
string cmd2=llList2String(l,1);
if (cmd=="REORIENT") {
vector v=(vector)llList2String(l,2);
/*
list lv=llParseString2List(llList2String(l,2), ["<",",",">"], []); //rotations come as vector too
llOwnerSay ("P: "+llList2String(l,2)+" : "+llDumpList2String(lv, "*"));
v.x=(float)llList2String(lv,0);
v.y=(float)llList2String(lv,1);
v.z=(float)llList2String(lv,2);
*/

llOwnerSay ("adjust "+cmd2+" "+(string)v);
if (cmd2=="OFF") {
adjustAllPositions (0.01*v, ZERO_VECTOR);
} else
if (cmd2=="ROT") {
adjustAllPositions (ZERO_VECTOR,v);
}

doPose(currentPose);
//runAnims();
}
}

adjustPosRot (key id, string data) {
list l=llParseString2List(data, ["&"], []);
integer i=llListFindList (agentPoseIdx, [(string)id]);
//llOwnerSay ("posrot "+(string)i+" "+(string)id+" "+data);
if ((-1<i)&&(llGetListLength(l)==2)) {
integer lidx=llList2Integer (agentPoseIdx, i+1);
adjustPosition (currentPose, lidx, (vector)llList2String(l,0), (vector)llList2String(l,1));
doPose(currentPose);
}
}

upgrade() {string self = llGetScriptName(); string basename = self; if (llSubStringIndex(self, " ") >= 0) {integer start = 2; string tail = llGetSubString(self, llStringLength(self) - start, -1); while (llGetSubString(tail, 0, 0) != " ") {start++; tail = llGetSubString(self, llStringLength(self) - start, -1);} if ((integer)tail > 0) {basename = llGetSubString(self, 0, -llStringLength(tail) - 1);}} integer n = llGetInventoryNumber(INVENTORY_SCRIPT); while (n-- > 0) {string item = llGetInventoryName(INVENTORY_SCRIPT, n); if (item != self && 0 == llSubStringIndex(item, basename)) {llRemoveInventory(item);}}}

default
{
state_entry()
{
upgrade();
}

link_message (integer sn, integer n, string m, key id) {
if (n==MSG_DATA_POSE) {
//add posedata
poseNames+=m;
poseData+=(string)id;
} else
if (n==MSG_DATA_POSITION) {
positionNames+=m;
positionData+=(string)id;
} else
if (n==MSG_SET_DEFAULT_POSE) {
defaultPose=m;
}
else
if (n==MSG_SET_RUNNING)
state running;
}
}

state running {
state_entry()
{
llOwnerSay ("Position free memory: "+(string)llGetFreeMemory());
doPose(defaultPose);
}
link_message (integer sn, integer n, string m, key id) {
if (n==MSG_DO_POSE) {
doPose(m);
} else
if (n==MSG_STORAGE_RESET)
llResetScript();
else
if (n==MSG_RUN_ANIMS) {
agentPoseIdx=llCSV2List(m);
runAnims();
}
else
if (n==MSG_SET_SITTARGET) {
setSitTarget((integer)m);
}
else
if (n==MSG_DUMP_POSITIONS) {
dumpPos();
}
else
if (n==MSG_UPDATE_POS) {
runAnims();
}
else
if (n==MSG_SET_DEFAULT_POSE)
defaultPose=m;
else
if (n==MSG_DO_DEFAULT_POSE)
doPose(defaultPose);
else
if (n==MSG_MLP_SETTING) {
parseSetting (m, id);
}
else
if (n==MSG_ADJUST_POSROT) {
adjustPosRot(id, m);
}
if (n==MSG_TEMPORARY_POSROT) {
setAgentPosRot(id, m);
}

}

}
</lsl>

==TMCP - actions==
<lsl>
//basically, we need a large datastore for our command set
list lmNames;
list lmAction;

integer MSG_DATA_MENU=310;
integer MSG_DATA_TYPE=320;
integer MSG_DATA_POSE=330;
integer MSG_DATA_LM=335;

integer MSG_DO_POSE=350;
integer MSG_DO_LM=351;
integer MSG_DO_SPECIAL=352;

integer MSG_DO_SOUND=356;

integer MSG_SET_RUNNING=390;
integer MSG_STORAGE_RESET=391;
integer MSG_DATA_READY=309;

upgrade() {string self = llGetScriptName(); string basename = self; if (llSubStringIndex(self, " ") >= 0) {integer start = 2; string tail = llGetSubString(self, llStringLength(self) - start, -1); while (llGetSubString(tail, 0, 0) != " ") {start++; tail = llGetSubString(self, llStringLength(self) - start, -1);} if ((integer)tail > 0) {basename = llGetSubString(self, 0, -llStringLength(tail) - 1);}} integer n = llGetInventoryNumber(INVENTORY_SCRIPT); while (n-- > 0) {string item = llGetInventoryName(INVENTORY_SCRIPT, n); if (item != self && 0 == llSubStringIndex(item, basename)) {llRemoveInventory(item);}}}

default
{
state_entry()
{
upgrade();
}

link_message (integer sn, integer n, string m, key id) {
if (n==MSG_DATA_LM) {
//add action
lmNames+=m;
lmAction+=(string)id;
} else
if (n==MSG_SET_RUNNING)
state running;
}
}

state running {
state_entry()
{
llOwnerSay ("Action manager free memory : "+(string)llGetFreeMemory());
}
link_message (integer sn, integer n, string m, key id) {
if (n==MSG_DO_LM) {
integer i=llListFindList(lmNames, [m]);
if (i>=0) {
list l=llParseString2List(llList2String(lmAction, i), [","],[]);
integer set=(integer)llList2String(l,1);
integer num=(integer)llList2String(l,2);
//string mess=llStringTrim(llList2String(l,3),STRING_TRIM);
string mess=llDumpList2String(llList2List(l,3,-1), ",");
integer nomenu=(integer)llList2String(l,0);
//perform requested action
llMessageLinked (set, num, mess, id);

if (!nomenu) //this will fail when not found, which it shouldnt.
llMessageLinked (LINK_THIS, 370, "", id);
}
} else
if (n==MSG_DO_SOUND) {
//LM list was abused for sound info
integer i=llListFindList(lmNames, [m]);
if (i>=0)
llTriggerSound(llList2String(lmAction, i), 1.);
}
else
if (n==MSG_STORAGE_RESET)
llResetScript();
}

}
</lsl>

==TMCP - menurender==
<lsl>
string version = "TMCP v0.3x";

//Render menu

list menuNames;
list menuEntries; //menus that appear in 'auto' menu
list menuDetails;

//some hardcoded stuff that this script adds, not any menu. prefill.
list itemNames=["<<<",">>>","<BACK"];
list itemTypes=[7,7,7];

list menuHistory;
string currentMenu;
string currentPose="default";
string defaultPose="default";

integer channel=999;
integer listenhandle;

integer mode_chat=1;
integer mode_adjust=0;
integer mode_menu=3; //user
integer mode_ball=0; //all

integer hibernate;

list rlvVictims;

integer TYPE_MENU=1;
integer TYPE_POSE=2;
integer TYPE_LM_NOMENU=3;
integer TYPE_LM_MENU=4;
integer TYPE_IGNORE=5;
integer TYPE_SPECIAL=6;
integer TYPE_UNKNOWN=7;
integer TYPE_SOUND=8;

integer MSG_DATA_MENU=310;
integer MSG_DATA_MENU_DETAILS=311;

integer MSG_DATA_TYPE=320;
integer MSG_DATA_POSE=330;
integer MSG_DATA_POSITION=331;
integer MSG_DATA_LM=335;

integer MSG_DO_POSE=350;
integer MSG_DO_LM=351;
integer MSG_DO_SPECIAL=352;

integer MSG_DO_STOP=353;
integer MSG_DO_SWAP=354;
integer MSG_MENU_SWAP=355;
integer MSG_DO_SOUND=356;

integer MSG_SET_RUNNING=390;
integer MSG_STORAGE_RESET=391;
integer MSG_DATA_READY=309;

integer MSG_DATA_START_READ=301;

integer MSG_MENU_META=333;

integer MSG_DUMP_POSITIONS=389;
integer MSG_MODE_ADJUST=368;
integer MSG_MODE_CHAT=367;
integer MSG_MODE_BALLUSERS=366;
integer MSG_MODE_OFF=365;

integer MSG_UPDATE_POS=363;
integer MSG_ALL_UNSIT =381;

integer MSG_SET_DEFAULT_POSE = 359;
integer MSG_DO_DEFAULT_POSE = 358;

integer MSG_RLV_GRAB=308;
integer MSG_RLV_RELEASE=309;
integer MSG_RLV_VICTIM_LIST=307;

integer MSG_DO_MENU_CURRENTMENU = 305;

//incoming
integer MSG_DO_MENU_COMMAND = -12002;

verbose(string text) {
//llOwnerSay (text);
if (mode_chat)
llSay (0, text);
}

string onOff(integer value) {
if (value) return "On"; else return "Off";
}

string aclMode(integer value) {
if (0==value)
return "ALL";
else
if (1==value)
return "GROUP";
else
if (2==value)
return "OWNER";
else
if (3==value)
return "USER";
else
return "UNKNOWN";
}

reset(integer resetSelf) {
integer i;
for (i=0; i<llGetInventoryNumber(INVENTORY_SCRIPT); i++) {
string s=llGetInventoryName(INVENTORY_SCRIPT, i);
if (-1<llSubStringIndex(s, "~TMCP ")) {
if (s!=llGetScriptName()) {
llResetOtherScript(s);
}
}
}
if (resetSelf)
llResetScript();
}

setRunning(integer running) {
integer i;
for (i=0; i<llGetInventoryNumber(INVENTORY_SCRIPT); i++) {
string s=llGetInventoryName(INVENTORY_SCRIPT, i);
if (-1<llSubStringIndex(s, "~TMCP ")) {
if (s!=llGetScriptName()) {
llSetScriptState (s, running);
}
}
}
}

integer hasDialogAccess(key id) {

//OWNER ALWAYS
if (id==llGetOwner())
return TRUE;

if (-1<llListFindList(rlvVictims, [(string)id]))
return FALSE;

//ALL
if ((!mode_menu)/* || (id==llGetOwner())*/)
return TRUE; //little speed optimalization to avoid call to samegroup

//USER
if (mode_menu==3) {
//user must be sitted to access, or no-one sitted at all
integer someSit=FALSE;
integer i;
for (i=0; i<=llGetNumberOfPrims(); i++) {
if (llGetLinkKey(i)==id)
return TRUE;
if (llGetAgentSize(llGetLinkKey(i)))
someSit=TRUE;
}
return (!someSit);
}

//GROUP
return (mode_menu==1) && llSameGroup(id);
}

integer hasMenuAccess (key id, string menu) {
//supposed to be trimmed already?
if (id==llGetOwner())
return TRUE;
string access=
llStringTrim(
llList2String(
llParseString2List(
llList2String(menuDetails, 1+llListFindList(menuDetails, [menu]) )
, ["|"], [])
, 0)
, STRING_TRIM);
if (access=="OWNER") {
return id==llGetOwner();
}
if (access=="GROUP") {
return (id==llGetOwner()) || llSameGroup(id);
}
if (access=="USER") {
integer i;
for (i=0; i<=llGetNumberOfPrims(); i++)
if (llGetLinkKey(i)==id)
return TRUE;
return FALSE;
}
//defaults to all.. learn to edit notecards if you made an error.
//future options might be a name or some. dunnow.
return TRUE;
}

makeMenu(string name, key id) {

if (id); else return; //might be invoked by remote scripts. can't pop menu's to none-avi's.

//present user a fine menu
integer idx=0;

integer offset;

if ((name==">>>") || (name=="<<<")) {
//offset making
//rename to the last found menu
/*
if (name==">>>")
offset+=10;
if (name=="<<<")
offset-=10;
*/
menuHistory+=name; //next step will fix this
//llOwnerSay ("history: "+(string)menuHistory);
}

integer ho=llGetListLength(menuHistory)-1;
while ((ho>1) && (-1<llListFindList(["<<<", ">>>"], [llList2String(menuHistory, ho)])) ) {
//adjust offset
string s=llList2String(menuHistory, ho);
if (s=="<<<")
offset-=10;
if (s==">>>")
offset+=10;
name=llList2String(menuHistory, ho-1);
ho--;
}

if (name) {
idx=llListFindList(menuNames, [name]);
if (idx<0) {
//llOwnerSay ("No menu entry for "+name);
return;
}

} else {
//make it main menu
name=llList2String(menuNames, 0); //assume at least 1 menu item please.. else its bugged anyways.
menuHistory=[];
}

currentMenu=name;

integer i=llListFindList (menuHistory, [name]);
if (i>=0) {
//truncate rest from history, maybe we went back.
menuHistory = llList2List(menuHistory, 0, i);
} else
menuHistory += name;

list present=llCSV2List(llList2String(menuEntries, idx));

if (llAbs(offset)>=(llGetListLength(present))) offset=0;

integer o=offset;
while (o>0) {
menuHistory += ">>>";
o-=10;
if (o<0)
o=0;
}
while (o<0) {
menuHistory += "<<<";
o+=10;
}

string h=">>";
for (i=0; i<llGetListLength(menuHistory); i++)
h+="> "+llList2String(menuHistory,i)+" ";

if (currentPose)
h+="\n\nCurrent pose: "+currentPose;
//todo somewhere. some better wrap around.

if ((offset) || (llGetListLength(present)>12))
present = llList2List(present, offset, offset+8) + ["<<<", ">>>", "BACK"];

if (llGetListLength(rlvVictims)) {
h+="\nCaptured (RLV): ";
for (i=0; i<llGetListLength(rlvVictims); i++)
h+=llKey2Name((key)llList2String(rlvVictims, i))+"\n";
}

//got our filled up menu here? prolly need to sort it, for now just present it
//llOwnerSay (name+":"+llList2CSV(present));

//invert our list
list p;
for (i=0; i<12; i+=3)
p = p+llList2List (present, -i-3, -i-1);

llDialog (id, version+"\n"+h, p, channel);
}

processCommand (key id, string message) {
integer typeidx=llListFindList (itemNames, [message]);
string param;
integer newMenu=TRUE;

if (typeidx<0) {
list l=llParseString2List(message, ["::"], []);
message=llList2String(l,0);
param=llList2String(l,1);
typeidx=llListFindList (itemNames, [message]);
//llOwnerSay ("Message "+message+" got param "+param);
}

if (typeidx<0) {
//llOwnerSay ("Error - no menu entry for "+message);
return;
}

integer type=llList2Integer(itemTypes, typeidx);
//llOwnerSay ("Type for "+message+" is "+(string)type);
if (type==TYPE_MENU) {
if (hasMenuAccess(id, message)) {
makeMenu(message, id);
newMenu=FALSE;
} else {
llRegionSayTo (id, 0, "Access to menu "+message+" is denied.");
//makeMenu(currentMenu, id);
//return;
}
}
else
if (type==TYPE_POSE) {
llMessageLinked (LINK_THIS, MSG_DO_POSE, message, "");
currentPose=message;
llMessageLinked (LINK_THIS, MSG_MENU_META,llList2String(menuDetails, 1+llListFindList(menuDetails, [currentMenu])), "");
}
else
if (type==TYPE_LM_NOMENU) {
llMessageLinked (LINK_THIS, MSG_DO_LM, message, id);
newMenu=FALSE;
}
else
if (type==TYPE_LM_MENU) {
llMessageLinked (LINK_THIS, MSG_DO_LM, message, id);
}
else
if (type==TYPE_SOUND) {
llMessageLinked (LINK_THIS, MSG_DO_SOUND, message, id);
}
else
//some built in messages
if (type=TYPE_SPECIAL) {

if (message=="SWAP") {

if ((integer)param) {
llMessageLinked (LINK_THIS, MSG_DO_SWAP, param, id);
}
else {
llMessageLinked (LINK_THIS, MSG_MENU_SWAP, (string)channel, id);
newMenu=FALSE;
}
}
else

if (message=="STOP") {
llMessageLinked (LINK_THIS, MSG_DO_STOP, "", id);
newMenu=FALSE;
}
else

if (message=="BACK") {
//check menu history
string newM="";
integer i=llGetListLength (menuHistory)-1;
while ((i>0) && (-1<llListFindList(["<<<", ">>>"], [llList2String(menuHistory, i)]))) i--;
if (i>0) {
menuHistory=llList2List(menuHistory, 0, i);
newM=llList2String(menuHistory,i-1);
}
makeMenu(newM, id);
newMenu=FALSE;
}
else
if ((message=="<<<") || (message==">>>")) {
//previous and next. let menumaker solve this.
makeMenu(message, id);
newMenu=FALSE;
}
else
if (message=="<BACK") {
//makeMenu(currentMenu, id);
}
else
//anything we don't know off for some reason. include it anyways.
if (message=="DUMP") {
llMessageLinked (LINK_THIS, MSG_DUMP_POSITIONS, "", "");
}
else
if (message=="CHAT") {
mode_chat=!mode_chat;
llMessageLinked (LINK_THIS, MSG_MODE_CHAT, (string)mode_chat, id);
llRegionSayTo (id, 0, "Chat "+onOff(mode_chat));
}
else
if (message=="ADJUST") {
mode_adjust=!mode_adjust;
llMessageLinked (LINK_THIS, MSG_MODE_ADJUST, (string)mode_adjust, id);
llRegionSayTo (id, 0, "Adjusting : "+onOff(mode_adjust));
}
else
if (message=="MENUUSERS") {
mode_menu++;
if (mode_menu>3)
mode_menu=0;
llRegionSayTo (id, 0, "Menu access set to "+aclMode(mode_menu));
}
else
if (message=="BALLUSERS") {
mode_ball++;
if (mode_ball>2)
mode_ball=0;
llRegionSayTo (id, 0, "Usage access set to "+aclMode(mode_ball));
llMessageLinked (LINK_THIS, MSG_MODE_BALLUSERS, (string)mode_ball, id);
}
else
if (-1<llListFindList (["RESET", "RESTART", "RELOAD"], [message])) {
llSay (0, "Reset sequence started... Touch me again in a few seconds to reload the configuration.");
reset(TRUE);
newMenu=FALSE;
}
else
if (message=="Z") {
if ("+"==llGetSubString(param,0,0))
param=llGetSubString(param,1,-1);
llSetObjectDesc((string)((integer)llGetObjectDesc()+(integer)param)+llGetSubString(llGetObjectDesc(), llStringLength((string)((integer)llGetObjectDesc())), -1));
llMessageLinked (LINK_THIS, MSG_UPDATE_POS, (string)mode_ball, id);
}
else
if (message=="OFF") {
state Off;
newMenu=FALSE;
}
else
if (message=="SAVE") {
defaultPose=currentPose;
llMessageLinked (LINK_THIS, MSG_SET_DEFAULT_POSE, currentPose, "");

}
else
if (message=="GRAB") {
llMessageLinked (LINK_THIS, MSG_RLV_GRAB, "", id);
newMenu=FALSE;
}
else
if (message=="RELEASE") {
llMessageLinked (LINK_THIS, MSG_RLV_RELEASE, "", id);
}
else {
//forward to whoever handles it
llMessageLinked (LINK_THIS, MSG_DO_SPECIAL, message, id);
}
}

if (newMenu)
makeMenu(currentMenu, id);
}

upgrade() {string self = llGetScriptName(); string basename = self; if (llSubStringIndex(self, " ") >= 0) {integer start = 2; string tail = llGetSubString(self, llStringLength(self) - start, -1); while (llGetSubString(tail, 0, 0) != " ") {start++; tail = llGetSubString(self, llStringLength(self) - start, -1);} if ((integer)tail > 0) {basename = llGetSubString(self, 0, -llStringLength(tail) - 1);}} integer n = llGetInventoryNumber(INVENTORY_SCRIPT); while (n-- > 0) {string item = llGetInventoryName(INVENTORY_SCRIPT, n); if (item != self && 0 == llSubStringIndex(item, basename)) {llRemoveInventory(item);}}}

default
{
state_entry()
{
upgrade();
state WaitTouch;
}
}

state WaitTouch
{
state_entry()
{
reset(FALSE);
llSay (0,"TMCP resetted - Touch me to load the configuration");
}
touch_start (integer n) {
llSay (0,"TMCP startup - reading data");
state reading_data;
}
}

state reading_data
{
state_entry() {
llMessageLinked (LINK_THIS, MSG_DATA_START_READ, "", "");
}
link_message (integer sn, integer n, string m, key id) {
if (n==MSG_DATA_MENU) {
//add action
menuNames+=m;
menuEntries+=(string)id;
} else
if (n==MSG_DATA_MENU_DETAILS) {
//add action
menuDetails+= [m, (string)id];
} else

if (n==MSG_DATA_TYPE) {
//set type
itemNames+=m;
itemTypes+=(integer)((string)id);
}
if (n==MSG_SET_RUNNING)
state running;
}
}

state running {
state_entry()
{
llOwnerSay ("Menu ready. "+(string)llGetFreeMemory());
channel=-(integer)llFrand(1309123)-492345;
listenhandle=llListen (channel, "", "", "");
}

touch_start(integer total_number)
{
key id=llDetectedKey(0);
if (!hasDialogAccess(id)) {
if (mode_chat)
llWhisper (0, "Sorry "+llKey2Name(id)+", but menu usage is limited to "+aclMode(mode_menu));
return;
}
makeMenu("",id);
}

listen (integer ch, string name, key id, string message) {

if (!hasDialogAccess(id)) {
if (mode_chat)
llWhisper (0, "Sorry "+llKey2Name(id)+", but menu usage is limited to "+aclMode(mode_menu));
return;
}

if (hibernate) {
setRunning(TRUE);
hibernate=FALSE;
}

//llSetTimerEvent (3600.);

processCommand (id, message);

}

link_message (integer sn, integer n, string m, key id) {
if (n==MSG_DO_MENU_COMMAND) {
processCommand (id, m);
}
else
if (n==MSG_DO_DEFAULT_POSE) {
currentPose = defaultPose;
}
else
if (n==MSG_RLV_VICTIM_LIST) {
rlvVictims=llCSV2List(m);
}
else
if (n==MSG_DO_MENU_CURRENTMENU) {
makeMenu(currentMenu, id);
}
}

timer() {
//inactivity detected, sleep all other scripts.
llSetTimerEvent(0.);
hibernate=TRUE;
setRunning(FALSE);
}
}

state Off {
state_entry() {
llMessageLinked (LINK_THIS, MSG_ALL_UNSIT, "", "");
llWhisper (0,"Switching off in 10... 9...");
llSleep (5.0);
setRunning(FALSE);
llSleep (5.0);
llSitTarget(ZERO_VECTOR, ZERO_ROTATION);
}

touch_start(integer n) {
key id=llDetectedKey(0);
if (id==llGetOwner())
state running;
if ((mode_menu==1) && llSameGroup(id))
state running;
llRegionSayTo (id, 0, "Sorry, but this object is switched OFF. Ask the owner to turn it on.");
}

state_exit() {
setRunning(TRUE);
hibernate=FALSE;
llWhisper (0, "Switching on");

}

}
</lsl>

==TMCP - notecard reader==
<lsl>
//read MLP notecards
//see how much memory headroom we got after for other stuff

integer notecardidx;
key notecardkey;
integer notecardtype;
integer notecardline;
string notecardname;
list positions;
list tempMenu;
list menuNames;
list menuEntries; //menus that appear in 'auto' menu
list toMenu; //menus with pointers
list linkedMsg;

integer hasReset=FALSE; //indicates if there is a reset option in *some* menu. If absent, we add it for safety.

integer TYPE_MENU=1;
integer TYPE_POSE=2;
integer TYPE_LM_NOMENU=3;
integer TYPE_LM_MENU=4;
integer TYPE_IGNORE=5;
integer TYPE_SPECIAL=6;
integer TYPE_UNKNOWN=7;
integer TYPE_SOUND=8;

integer MSG_DATA_MENU=310;
integer MSG_DATA_MENU_DETAILS=311;
integer MSG_DATA_TYPE=320;
integer MSG_DATA_POSE=330;
integer MSG_DATA_POSITION=331;
integer MSG_DATA_LM=335;

integer MSG_DO_POSE=350;
integer MSG_DO_LM=351;
integer MSG_DO_SPECIAL=352;

integer MSG_DO_STOP=353;
integer MSG_DO_SWAP=354;

integer MSG_SET_RUNNING=390;
integer MSG_STORAGE_RESET=391;
integer MSG_DATA_READY=309;

integer MSG_DATA_START_READ=301;

verbose(string text) {
llOwnerSay (text);
}

startNotecard() {
integer i;
notecardline=0;
for (;notecardidx<llGetInventoryNumber(INVENTORY_NOTECARD); notecardidx++) {
//loop until we found appropiate card
notecardname=llGetInventoryName(INVENTORY_NOTECARD, notecardidx);
if (llGetSubString(notecardname,0,9)==".MENUITEMS") {
//neato. go fetch it
notecardtype=1;
notecardkey=llGetNotecardLine(notecardname, 0);
verbose ("Reading menu from "+notecardname);
return;
}
if (llGetSubString(notecardname,0,9)==".POSITIONS") {
//neato. go fetch it
notecardtype=2;
notecardkey=llGetNotecardLine(notecardname, 0);
verbose ("Reading positions from "+notecardname);
return;
}
verbose ("Skipping "+notecardname);

}
//still here? then we'r done
//verbose ("Done reading all notecards");
postFixMenu();
sendMenuItems();
llSleep (2.0);
llMessageLinked (LINK_THIS, MSG_SET_RUNNING, "", ""); //set to running
verbose ("Ready.");
//llOwnerSay ("Notecard reader free memory: "+(string)llGetFreeMemory());
}

addPose (string name, list data) {
//add pose info.. link to position info exactly when again?
//positions+=[name, data];
llMessageLinked (LINK_THIS, MSG_DATA_POSE, name, llDumpList2String(data, "|"));
}

addMenuDetails (string name, list data) {
//add menu details.. access, color of balls.
llMessageLinked (LINK_THIS, MSG_DATA_MENU_DETAILS, name, llDumpList2String(data, "|"));
}

addLM (string name, string data) {
llMessageLinked (LINK_THIS, MSG_DATA_LM, name, data);
}

setType (string name, integer type) {
llMessageLinked (LINK_THIS, MSG_DATA_TYPE, name, (string)type);
}

parseMenu() {
//parse our temporary menu to a real menu;
//this is where the real stuff happens.
integer i;
string menuName=""; //MLP 1 compatability: don't add stuff to menu as long as menu name is empty. add poses though.
list options;
for (i=0; i<llGetListLength(tempMenu); i++) {
string data=llList2String(tempMenu, i);
integer posspace=llSubStringIndex(data, " ");
string cmd=data;
string param="";
string option="";
if (posspace>0) {
cmd=llGetSubString(data,0,posspace-1);
param=llGetSubString(data, posspace+1, -1);
}
list paramsTmp=llParseString2List(param, ["|"], []);
integer j;
list params;
for (j=0; j<llGetListLength(paramsTmp); j++)
params+=llStringTrim(llList2String(paramsTmp, j), STRING_TRIM);
//params are now nice seperated on |, still allowed to contain spaces in the middle but trimmed from the outside.
string p1=llList2String(params, 0);
string p2=llList2String(params, 1);
string p3=llList2String(params, 2);
//got our set of command and optional parameters now. let's test them.
if (cmd=="MENU") {
addMenuDetails (p1, llDeleteSubList(params,0,0));
//menuEntries+=p1;
menuName=p1; //additional params hint the number of available seats
setType (p1, TYPE_MENU);
} else
if (cmd=="POSE") {
addPose (p1, llDeleteSubList(params,0,0));
option = p1;
setType (p1, TYPE_POSE);
} else
if (cmd=="SOUND") {
addLM (p1, p2);
option = p1;
setType (p1, TYPE_SOUND);
} else
if (-1 != llListFindList (["BACK", "STOP","SWAP","RESET","RESTART", "MENUUSERS", "BALLUSERS","ADJUST", "DUMP", "CHAT", "RELOAD", "OFF"], [cmd])) {
//recognized simple options
option = cmd;
setType (cmd, TYPE_SPECIAL);
if (-1!= llListFindList (["RESET","RESTART", "RELOAD"], [cmd]))
hasReset=TRUE;
} else
if (-1 != llListFindList (["SAVE", "CHECK"], [cmd])) {
//recognized simple options
option = cmd;
setType (cmd, TYPE_IGNORE);
} else
if (cmd=="TOMENU") {
if (p1!="-")
toMenu+=p1;
option=p1;
} else
if (cmd=="LINKMSG") {
//linkedMsg+=[p1,p2];
addLM (p1, p2);
option=p1;
if ((integer)p2)
setType (p1, TYPE_LM_NOMENU);
else
setType (p1, TYPE_LM_MENU);
} else
if (-1<llListFindList(["Z+", "Z-"], [llGetSubString(cmd, 0, 1)])) {
//Z command, we'll rewrite it
option = "Z::"+llGetSubString(cmd, 1, -1);
setType ("Z", TYPE_SPECIAL);
}
else
if (-1<llListFindList (["GRAB", "Grab.Fem"], [cmd])) {
option = "GRAB";
setType ("GRAB", TYPE_SPECIAL);
}
else
if (-1<llListFindList (["Grab.Male","RELEASE"], [cmd])) {
option = "RELEASE";
setType ("RELEASE", TYPE_SPECIAL);
}
//todo.. fill in a bunch of MLP commands here, implemented or not
else
{ //we checked all commands. Anything defined here is considered undefined and we list it just as is.
option = cmd;
//don't set type. it may be defined elsewhere.
//setType (cmd, TYPE_UNKNOWN);
}
if (menuName) if (option)
options+=option;
}
tempMenu=[];
if (options!=[]) {
llOwnerSay ("Menu "+menuName +" ["+(string)llGetListLength(options)+"]");
//menuAll+=options+"!--!";
//menuAll+=[menuName,llList2CSV(options)];
menuNames+=menuName;
menuEntries+=llList2CSV(options);
}
}

addMenuItem(string data) {
integer posslash=llSubStringIndex(data, "//");
if (posslash>=0) {
data=llDeleteSubString(data, posslash, -1);
}
data=llStringTrim(data,STRING_TRIM);
//llOwnerSay ("menu data: "+data);

if (data=="") //comment or some but not empty line, silently ignore
return;

if (llGetSubString (data,0,3+1)=="MENU ") {
//what a surprise, new menu. finish old one.
parseMenu();
}

//what's left, add it to our temp menu. We'l parse it later.
tempMenu+=data;
}

postFixMenu() {
//on failed configurations - add some default stuff
if (!llGetListLength(menuNames)) {

llOwnerSay ("Warning - no reset function found in menu cards. Adding menu 'Reset'.");
//add a default menu with a reset button.

addMenuItem ("MENU Reset...|OWNER");
addMenuItem ("RESET");
parseMenu();
}

//dont add mainmenu
list entries=llDeleteSubList(menuNames,0,0);

integer i;

//llOwnerSay ("PF entries: "+(string)entries);
//llOwnerSay ("PF tomenu: "+(string)toMenu);

for (i=0; i<llGetListLength(toMenu); i++) {
integer j=llListFindList (entries, [llList2String(toMenu, i)]);
if (j>-1) {
entries=llDeleteSubList(entries, j, j);
}
}
//llOwnerSay ("PF entries after: "+(string)entries);

list MainMenu=llCSV2List(llList2String(menuEntries, 0));
for (i=0; i<llGetListLength(entries); i++) {
integer j=llListFindList(MainMenu, ["-"]);
if (j>-1) {
MainMenu=llListReplaceList(MainMenu, [llList2String(entries, i)], j, j);
}
}

i=llListFindList(MainMenu, ["-"]);
while (-1<i) {
MainMenu=llDeleteSubList(MainMenu, i, i);
i=llListFindList(MainMenu, ["-"]);
}

if (MainMenu)
menuEntries = llListReplaceList(menuEntries, [llList2CSV(MainMenu)], 0, 0);
}

sendMenuItems() {
//llOwnerSay ("Applying menu information");

integer i;
for (i=0; i<llGetListLength(menuNames); i++) {
llMessageLinked (LINK_THIS, MSG_DATA_MENU, llList2String(menuNames, i), llList2String(menuEntries, i));
llSleep (0.25);
}

llMessageLinked (LINK_THIS, MSG_DATA_READY, "Done", "TTP");
}

addPosition(string data) {
//some memory optimalization possible here in last half.
integer curlyopen = llSubStringIndex(data, "{");
integer curlyclose = llSubStringIndex(data, "}");
if ((curlyopen<0) || (curlyclose<curlyopen))
return;
string pose=llGetSubString(data, curlyopen+1, curlyclose-1);
data=llGetSubString(data, curlyclose+1, -1);
list posrotsraw=llParseString2List(data, [">"], []);
//llOwnerSay ("raw pos data "+data+" convert to "+(string)posrotsraw);

list posrots;
integer i;
for (i=0; i<llGetListLength(posrotsraw); i++) {
if (-1<llSubStringIndex (llList2String(posrotsraw,i), "<")) {
list v=llParseString2List(llList2String(posrotsraw,i), ["<", ",", " "], []);
posrots += <(float)llList2String(v,0), (float)llList2String(v,1),(float)llList2String(v,2)>;
}
}
//llOwnerSay ("position data for "+pose+" : "+(string)posrots);
//positions+=[pose, llList2CSV(posrots)];
llMessageLinked (LINK_THIS,MSG_DATA_POSITION, pose, llDumpList2String(posrots,"&"));
}

upgrade() {string self = llGetScriptName(); string basename = self; if (llSubStringIndex(self, " ") >= 0) {integer start = 2; string tail = llGetSubString(self, llStringLength(self) - start, -1); while (llGetSubString(tail, 0, 0) != " ") {start++; tail = llGetSubString(self, llStringLength(self) - start, -1);} if ((integer)tail > 0) {basename = llGetSubString(self, 0, -llStringLength(tail) - 1);}} integer n = llGetInventoryNumber(INVENTORY_SCRIPT); while (n-- > 0) {string item = llGetInventoryName(INVENTORY_SCRIPT, n); if (item != self && 0 == llSubStringIndex(item, basename)) {llRemoveInventory(item);}}}

default
{
state_entry() {
upgrade();
//state ReadMenu;
}

link_message (integer sn, integer n, string m, key id) {
if (n==301)
state ReadMenu;
}

}

state ReadMenu
{
state_entry()
{
llMessageLinked (LINK_THIS, MSG_STORAGE_RESET, "", ""); //reset data storage scripts
llSleep (2.0);
//fetch first notecard, go on from there
startNotecard ();
}

dataserver(key id, string data) {
//llOwnerSay ("card "+notecardname+" line "+(string)notecardline+" data "+data);

if (id!=notecardkey)
return; //not for us

if (data==EOF) {
if (notecardtype==1)
parseMenu(); //clean up any menu leftovers
//read next notecard
notecardidx++;
startNotecard();
} else
{
if (notecardtype==1)
addMenuItem(data);
else
addPosition(data);
notecardkey=llGetNotecardLine(notecardname, ++notecardline);

}
}
}
</lsl>

==TMCP RLV extensions (optional)==
<lsl>
//Changes by Tano Toll for seamless MLCP compatability, and to dodge 'double locking':

//*sit and unsit events do not trigger an RLV command (master script already does this)
//*identifier is changed to object name, url encoded.
//*delayed but automatic notecard read on inventory change

// ----------------------------------------------------------------------------------
// MLPV2 Plugin for RLV Script V1.02
//
// Use with a notecard named .RLV with the format:
// Pose|Ball no.: 0,1...*|@RLV-Command
// e.g.
// Missionary|1|@unsit=n
// stand|*|!release
// ----------------------------------------------------------------------------------
// Copyright (c) 2010, Jenni Eales. All rights reserved.
// ----------------------------------------------------------------------------------
// Redistribution and use in source and binary forms, with or without modification,
// are permitted provided that the following conditions are met:
//
// * Redistributions of source code must retain the above copyright notice,
// this list of conditions and the following disclaimer.
// * Redistributions in binary form must reproduce the above copyright notice,
// this list of conditions and the following disclaimer in the documentation
// and/or other materials provided with the distribution.
// * The names of its contributors may not be used to endorse or promote products
// derived from this software without specific prior written permission.
//
// THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY
// EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
// OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
// IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT,
// INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
// BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA,
// OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
// WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
// ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY
// OF SUCH DAMAGE.
//
// Changes:
// ----------------------------------------------------------------------------------
// Version 1.02
// - use | as seperator
// - support multiple lines for one pose
// - additional link message for direct call from ball menu
//
// Version 1.01
// - use ; instead of | as seperator
//
// Version 1.0
// - first version released
// ----------------------------------------------------------------------------------
//
// constants
string NOTECARD = ".RLV"; // name of config notecard
integer DEBUG = FALSE; // switch debug on/off
integer RELAY_CHANNEL = -1812221819; // channel for RLV relay
float TIMER_SEC = 1800.0; // 30 min.
string CMD_RELEASE = "!release"; // release command
integer LM_NUMBER = -1819; // number for link message

// internal use
key kQuery;
integer iLine;

string pose = "stand"; // pose set by the Ball Menu
list poses = []; // configured poses
list balls = []; // configured balls
list commands = []; // configured commands
list avatars = []; // avatars sitting on balls

integer wants_init;

// log a message
log(string message)
{
if(DEBUG) llOwnerSay(message);
}

// only for testing purposes
log_data()
{
log("List:");
integer total_number = llGetListLength(commands);
integer i;
for(i=0; i<total_number; i++)
{
log("- " + llList2String(poses, i) + ": (" + llList2String(balls, i) + ") "+ llList2String(commands, i));
}
}

// write a message to the RLV Relay
relay(key avatar, string message)
{
list tokens = llParseString2List(message, ["|"], [""]);
integer total_number = llGetListLength(tokens);
integer i;
for(i=0; i<total_number; i++)
{
string token = llList2String(tokens, i);
log("RLV: MLPV2," + (string) avatar + "," + token);
llSay(RELAY_CHANNEL, llEscapeURL(llGetObjectName())+"," + (string) avatar + "," + token);
}
}

// find commands for pose and play it for avatars on ball
rlv(string pose)
{
log("command for: " + pose);
llSetTimerEvent(TIMER_SEC);

integer total_number = llGetListLength(poses);
integer i;
for(i=0; i<total_number; i++)
{
if (pose == llList2String(poses, i))
{
string ball = llList2String(balls, i);
log("command for pose: " + pose + " (" + ball + ")");
if (ball == "*")
{
integer b;
for (b=0; b<6; b++)
{
// get avatar for ball index
key avatar = llList2Key(avatars, b);
if(avatar != NULL_KEY) relay(avatar, llList2String(commands, i));
}
}
else
{
key avatar = llList2Key(avatars, (integer) ball);
if(avatar != NULL_KEY) relay(avatar, llList2String(commands, i));
}
}
}
}

// new find: pose and ball needs to match
integer find_pose(string pose, string ball)
{
integer total_number = llGetListLength(poses);
integer i;
for(i=0; i<total_number; i++)
{
if (pose == llList2String(poses, i) && ball == llList2String(balls, i))
{
return i;
}
}
return -1;
}

// add a pose/ball/command entry
add_pose(string pose, string ball, string command)
{
// look for existing entry for pose
integer found = find_pose(pose, ball);
if (found == -1)
{
// add a new pose
poses += [pose];
balls += [ball];
commands += [command];

log("Added from " + NOTECARD + ": " + pose + " | " + ball + " | " + command);
}
else
{
// append to existing pose
string c = llList2String(commands, found) + "|" + command;
commands = llListReplaceList(commands, [c], found, found);

log("Added " + command + " to pose " + pose);
}
}

// parse and store a line
process_line(string line)
{
list tokens = llParseString2List(line, [" | "," | "," | "," | "," |","| ","|"],[""]);
if(llGetListLength(tokens) < 3) return;

string pose = llList2String(tokens, 0);
string ball = llList2String(tokens, 1);

integer total_number = llGetListLength(tokens);
integer i;
for(i=2; i<total_number; i++)
{
add_pose(pose, ball, llList2String(tokens, i));
}
}

// check if object is in the inventory
integer exists_notecard(string notecard) {
return llGetInventoryType(notecard) == INVENTORY_NOTECARD;
}

// initialize me
initialize()
{
log("Initializing...");
poses = [];
balls = [];
commands = [];
avatars = [NULL_KEY, NULL_KEY, NULL_KEY, NULL_KEY, NULL_KEY, NULL_KEY];

if (exists_notecard(NOTECARD))
{
log("Reading " + NOTECARD + "...");
iLine = 0;
kQuery = llGetNotecardLine(NOTECARD, iLine);
}
else
{
llOwnerSay("Not found: " + NOTECARD );
}
}

upgrade() {string self = llGetScriptName(); string basename = self; if (llSubStringIndex(self, " ") >= 0) {integer start = 2; string tail = llGetSubString(self, llStringLength(self) - start, -1); while (llGetSubString(tail, 0, 0) != " ") {start++; tail = llGetSubString(self, llStringLength(self) - start, -1);} if ((integer)tail > 0) {basename = llGetSubString(self, 0, -llStringLength(tail) - 1);}} integer n = llGetInventoryNumber(INVENTORY_SCRIPT); while (n-- > 0) {string item = llGetInventoryName(INVENTORY_SCRIPT, n); if (item != self && 0 == llSubStringIndex(item, basename)) {llRemoveInventory(item);}}}

default
{
// on state entry initialize me
state_entry()
{
upgrade();

initialize();
}

// reset on Inventory change
changed(integer change)
{
if (change & CHANGED_INVENTORY) {
wants_init=TRUE;
llSetTimerEvent (15.0);
}
}

// read a line from notecard
dataserver(key _query_id, string _data) {
// were we called to work on notecard?
if (_query_id == kQuery) {
// this is a line of our notecard
if (_data == EOF) {
if (DEBUG) log_data();
log(NOTECARD + " read.");
} else {
// increment line count
// data has the current line from this notecard
if(_data != "") {
process_line(_data);
}

// request next line
// read another line when you can
iLine++;
kQuery = llGetNotecardLine(NOTECARD, iLine);
}
}
}

timer()
{
if (wants_init) {
wants_init = FALSE;
initialize();
llSetTimerEvent (0.0);
return;
}

integer b;
for (b=0; b<6; b++)
{
// get avatar for ball index
key avatar = llList2Key(avatars, b);

// if not null send command
if(avatar != NULL_KEY) relay(avatar, CMD_RELEASE);
}
llSetTimerEvent(0.0);
}

// link message from MLPV2
link_message(integer sender_number, integer number, string message, key id)
{
/*
// pose from ball menu selected
if (number == 0 && message == "POSEB") {
pose = (string)id;
rlv(pose);
return;
}
*/

// direct call from ball menu
// configure in .MENUITEMS with
// LINKMSG Resctriction | 0,-1,-1819,Restriction
if (number == LM_NUMBER) {
//llOwnerSay ("RLV: -- "+message);
pose = message;
rlv(pose);
return;
}

// unsit avatar
if (number == -11001)
{
integer ball = (integer) message;
log("Avatar unsit from ball " + (string) ball +": " + (string) llList2Key(avatars, ball));
//relay(llList2Key(avatars, ball), CMD_RELEASE);
avatars = llListReplaceList(avatars, [NULL_KEY], ball, ball);
}

// sit avatar
if (number == -11000)
{
list tokens = llParseString2List(message, ["|"], [" "]);
integer ball = llList2Integer(tokens, 0);
log("Avatar sit on ball " + (string) ball +": " + (string) id);
avatars = llListReplaceList(avatars, [id], ball, ball);
//rlv(pose);
}
}
}
</lsl>

User:Tano Toll

2012-08-15T13:38:16Z

Tano Toll:

TMCP

2012-08-15T13:37:08Z

Tano Toll: TMCP - MLP Compatible Pose Scripts - Open source (BSD license)

TMCP - Tano's MLP Compatible Pose scripts
*a drop in replacement for MLPv2
*configuration notecard compatible
*Since august 14. 2012 released under the open source BSD license

Collection of scripts as of version 0.37 below, or available on marketplace for your convenience https://marketplace.secondlife.com/p/TMCP-Tanos-MLP-Compatible-Pose-Scripts-Source-Edition/2964611

Resident 'Camden McAndrews' voluntueered as new maintainer. I hope the MLPv2 team will pick it up.

==TMCP Sitmanager==
<lsl>
//keeps track of sitted target, position them and animate them.

list animPool; //pool of scripts that are able to pose targets

list poolCache; //try re-use same script for same agent, to avoid reasking permissions

list sitted; //strided, holds: AGENT_KEY, logical offset (`ball number`), [animscript?], current animation?, current position?
integer sittedStride=3;

list sittedAgents;
list sitScripts;

integer MSG_AGENT_UNSIT = 380;
integer MSG_ALL_UNSIT =381;
integer MSG_DISABLE_SITTING =382;
integer MSG_REGISTER_SITSCRIPT =383;
integer MSG_QUERY_SITSCRIPT = 385;
integer MSG_RESET =0;
integer MSG_ENABLE_SITTING=0;
integer MSG_SET_SITTARGET=375;
integer MSG_PLAY_ANIM=390;
integer MSG_STOP_ANIM=391;
integer MSG_AGENT_PLAY_ANIM=395; // to notify the slave script
integer MSG_AGENT_STOP_ANIM=396;
integer MSG_ATTACH_AGENT = 398;
integer MSG_DETACH_AGENT = 399;
integer MSG_RUN_ANIMS=379;

integer MSG_DO_STOP=353;
integer MSG_DO_SWAP=354;
integer MSG_MENU_SWAP=355;

integer MSG_MENU_META=333;

integer MSG_MLP_SITTED=-11000;
integer MSG_MLP_UNSITTED=-11001;

integer MSG_MODE_BALLUSERS=366;

integer MSG_DO_DEFAULT_POSE = 358;

integer MSG_RLV_GRAB=308;
integer MSG_RLV_RELEASE=309;
integer MSG_RLV_VICTIM_LIST=307;

integer MSG_DO_MENU_CURRENTMENU = 305;

//keys to controlling:
//animname+index is key to both real animation name and it's position.

list agentAnims;

list agentScripts;
list agentScriptCache;

list agentPoseIdx;

list usedIndexes; //logical pose positions, register in here.

integer MAX_SITTING=1;

string currentAnim;
integer currentAnimSeats;

list menuMeta;

integer mode_ballusers;

key grabberID;

list potentionalVictims;
list victimsWithRelay;

list grabbingVictims; //commanded to, but not yet suited
list grabbedVictims; //victims tagged as victim, sitted

integer CAPTURE_RANGE = 35;
integer RELAY_CHANNEL = -1812221819;
integer relay_handle;

integer timer_reason_versioncheck;
integer rlv_victim_dialog_handle;
integer rlv_victim_dialog_channel;

integer timer_versioncheck=50;
integer timer_closechannel=51;
integer timer_closechannel2=53;
integer timer_defaultpose=52;
integer timer_cleargrabbing=55;

assignScript (key id) {
integer i=llListFindList (agentScripts, [id]);
if (i>=0) //agent already got assignment
return;
i=llListFindList (agentScriptCache, [id]);
string candidate;
if (i>=0) {
candidate=llList2String(agentScriptCache, i+1);
if (-1!=llListFindList(agentScripts, [candidate]))
candidate="";
}
if (candidate);else {
//try to find a new one
for (i=0; i<llGetListLength(sitScripts); i++) {
string ss=llList2String(sitScripts, i);
if (-1==llListFindList(agentScripts, [ss])) {//found free one
candidate=ss;
jump break;
}
}
@break;
}
if (candidate) {
agentScripts+=[id, candidate];
i=llListFindList (agentScriptCache, [candidate]);
if (-1<i)
agentScriptCache=llDeleteSubList(agentScriptCache, i-1, i);
agentScriptCache+=[id, candidate];
//llOwnerSay ((string)id+" attached to "+candidate);
llMessageLinked(LINK_THIS, MSG_ATTACH_AGENT, candidate, id);
} else {
llRegionSayTo (id, 0, "Sorry, but there is no available script to animate your avatar.");
}
}

integer assignPoseIdx (key id) {
//start counting at 1.. just because we can.
integer i=llListFindList (agentPoseIdx, [id]);
if (-1<i)
return llList2Integer(agentPoseIdx, i+1); //agent already got a pose assigned
for (i=1; i<100; i++) {
if (-1==llListFindList(agentPoseIdx, [i])) //found empty one
{
agentPoseIdx+=[id, i];
//llInstantMessage (id, "You are assigned to pose index "+(string)i);
return i;
}
}
return 0;
}

dropAgent (key id) {
//clean up stuff agent had

}

stopAnims(key id) {
llMessageLinked (LINK_THIS, MSG_AGENT_STOP_ANIM, "", id);
}

applyAnims() {
//apply animation (and position?) for all agents involved

//send list of keys with indexes to position. it should know which anim is current.
llMessageLinked (LINK_THIS, MSG_RUN_ANIMS, llList2CSV(agentPoseIdx), "");
//llOwnerSay ("anims/poses "+llList2CSV(agentPoseIdx));

}

cleanUp(key id) {
stopAnims(id);
integer i=llListFindList (agentScripts, [id]);
if (-1<i)
agentScripts = llDeleteSubList (agentScripts, i, i+1);
i=llListFindList (agentPoseIdx, [id]);
if (-1<i)
agentPoseIdx = llDeleteSubList (agentPoseIdx, i, i+1);

i=llListFindList (grabbedVictims, [id]);
if (-1<i)
grabbedVictims = llDeleteSubList (grabbedVictims, i, i);

}

setSitTarget() {
//needs pose info.. so we calculate the first available index, and match info with current pose.. it's for position script, i think.
//linkedmessage (setsittarget, [posename,] index)..
//posename might be cached by positioner and/or set to defaults.
integer idx=1;
//find first available
while (-1<llListFindList(agentPoseIdx, [idx]))
idx++;
if (idx>MAX_SITTING) {
llSitTarget (ZERO_VECTOR, ZERO_ROTATION/llGetRot());
} else {
llSitTarget (<0,0,0.01>, ZERO_ROTATION/llGetRot()); //backup option.
llMessageLinked(LINK_THIS, MSG_SET_SITTARGET, (string)idx, "");
}

}

integer maySit(key id) {
if (!mode_ballusers) //everyone
return TRUE;
if (id==llGetOwner()) //always
return TRUE;
if (mode_ballusers==1) //group
return llSameGroup(id);
return FALSE; //nope
}

broadcastVictims() {
llMessageLinked (LINK_THIS, MSG_RLV_VICTIM_LIST, llList2CSV(grabbedVictims), "");
}

requestMenu(key id) {
llMessageLinked (LINK_THIS, MSG_DO_MENU_CURRENTMENU, "", id);
}

inventarise() {
//someone sitted or unsitted. do the bookkeeping
list agents;
integer i;

//get sitted avatars
for (i=0; i<=llGetNumberOfPrims(); i++) {
key id=llGetLinkKey(i);
if (llGetAgentSize(id)) {
//this is an agent..
agents+=id;
if (-1!=llListFindList(grabbingVictims, [id])) {
//grabbingVictims=[]; //should really do this somewhere else
if (-1==llListFindList(grabbedVictims, [id])) {
rlv_lock(id);
grabbedVictims+=id;
broadcastVictims();
}
}
}
}

//now cross reference against existing agents
//first see, who's all gone
for (i=0;i<llGetListLength(sittedAgents); i++) {
key id=llList2Key(sittedAgents, i);
if (-1==llListFindList(agents, [id])) {
//agent unsitted, remove him
msgUnsit(id, llList2Integer(agentPoseIdx, llListFindList(agentPoseIdx, [id])+1));
if (-1!=llListFindList(grabbedVictims, [id])) {
//rlv catch, unlock it
rlv_release(id);
}
cleanUp(id);
broadcastVictims();
}
}

//now, lets see who's all added
for (i=0;i<llGetListLength(agents); i++) {
key id=llList2Key(agents, i);
if (-1==llListFindList(sittedAgents, [id])) {
//freshy added, assign it a script, if possible, and a logical offset
if (maySit(id)) {
assignScript(id);
msgSit(id, assignPoseIdx(id));
} else {
llUnSit(id);
llWhisper (0, "Sorry "+llKey2Name(id)+" but you cannot use this object.");
}
//play anim

}
}

// if (sittedAgents != agents)
// setSitTarget();
sittedAgents = agents;
setSitTarget();
applyAnims();

// default pose switching on idle
if (agents==[])
scheduleEvent (timer_defaultpose, 120, "");
else
cancelEvent (timer_defaultpose);
}

makeSwapMenu(key id, integer channel) {
//offer nice swap menu
//list sitted avatars
string text="";
integer i;
integer m=10;
list buttons=["<BACK"];
if (MAX_SITTING<m)
m=MAX_SITTING;
for (i=1; i<=m; i++) {
integer j=llListFindList(agentPoseIdx, [i]);
string agent = "<Nobody>";
key aid;
if (-1<j) {
aid=llList2Key(agentPoseIdx, j-1);
agent=llKey2Name(aid);
}
text+=(string)i + ". " + llList2String(menuMeta, i) + " "+agent+"\n";

if (aid!=id)
buttons+=["SWAP::"+(string)i];
}
llDialog (id, text, buttons, channel);
}

//consideration: send out sit/unsit events or not.. i think, might as well not. in order not to confuse rlv.
swapAgent (key id, integer newpos) {
//llSay (0, "Swapping "+llKey2Name(id)+" to position #"+(string)newpos);
integer o=llListFindList(agentPoseIdx, [id]);
if (o<0) {
//llOwnerSay ("swap key not found "+(string)id);
//agent not found. see if we have a rlv target
if (llGetListLength(grabbedVictims)) {
//just default to first best sitted. Stuff gets complex with multiple RLV but who cares that.
id=llList2Key(grabbedVictims,0);
o=llListFindList(agentPoseIdx, [id]);
if (o<0) //OUCH, should nevah happen
return;
}
else return;
}
integer oldidx=llList2Integer(agentPoseIdx, o+1);
if (oldidx==newpos) {
llRegionSayTo (id, 0, "You choosen the same position");
return;
}
agentPoseIdx=llDeleteSubList(agentPoseIdx, o, o+1);
integer topos=llListFindList(agentPoseIdx, [newpos]);
if (-1<topos) {
agentPoseIdx=llDeleteSubList(agentPoseIdx, topos-1, topos) + [llList2Key(agentPoseIdx, topos-1),oldidx];
}
agentPoseIdx += [id, newpos];
applyAnims();
}

unsitAll() {
integer i;
for (i=0; i<=llGetNumberOfPrims(); i++) {
key id=llGetLinkKey(i);
if (llGetAgentSize(id))
llUnSit(id);
}
}

msgSit(key id, integer poseidx) {
//we start count at 1, mlp at zero. fix right here
llMessageLinked(LINK_THIS, MSG_MLP_SITTED, (string)(poseidx-1), id);
}

msgUnsit(key id, integer poseidx) {
//we start count at 1, mlp at zero. fix right here
llMessageLinked(LINK_THIS, MSG_MLP_UNSITTED, (string)(poseidx-1), id);
}

log(string t){
//llOwnerSay(t);
}

RLVGrabMenu(key id) {
grabberID = id;
llSensor("", NULL_KEY, AGENT, CAPTURE_RANGE, TWO_PI);
// llInstantMessage (id, "Scanning ... menu in 5.. 4.. 3..");
}

RLVReleaseAll() {
integer i;
for (i=0; i<llGetListLength(grabbedVictims); i++) {
key id=llList2Key(grabbedVictims,i);
rlv_release (id);
llWhisper (0,"releasing "+llKey2Name(id));
//unsit?
llUnSit(id);
}
grabbedVictims=[];
}

rlv_checkversion (key id) {
rlv_relay(id, "!version=" + (string)1); //version_handle
}

rlv_capture(key avatar)
{
rlv_relay(avatar, "@sit:" + (string)llGetKey() + "=force");
//llSay (menu_ban_channel, "- "+(string)avatar);
llWhisper (0, llKey2Name(grabberID)+" captures "+llKey2Name(avatar));
}

rlv_lock(key avatar)
{
rlv_relay(avatar, "@unsit=n");
}

rlv_release(key avatar)
{
rlv_relay(avatar, "@unsit=y");
rlv_relay(avatar, "!release");
//llSay (menu_ban_channel, "- "+(string)avatar);
}

// write a message to the RLV Relay
rlv_relay(key avatar, string message)
{
if (avatar != NULL_KEY)
{
llSay(RELAY_CHANNEL, llEscapeURL(llGetObjectName()) + "," + (string) avatar + "," + message);
log("RLV: " + llGetObjectName() + "," + (string) avatar + "," + message);
}
}

//scheduler

list events = [];
integer nextEvent = 0;

scheduleEvent(integer id, integer time, string data) {
//adjust timestamp
time+=llGetUnixTime();

//cancel any previous requests, this case we only want one per type, really
cancelEvent(id);

events = llListSort(events + [time, id, data], 3, TRUE);
setTimer(FALSE);
}

cancelEvent(integer id) {
//reasonable failsafe as long as you don't use id's that could be current timestamp.
integer i=llListFindList(events, [id]);
if ((-1<i) && ((i % 3) == 1)) {
//it was an id
events=llDeleteSubList(events, i-1, i+1);

//recurse when found, delete all with said id... ?
cancelEvent(id);

setTimer(FALSE);
}
}

integer setTimer(integer executing) {
if ((events != []) > 0) { // Are there any list items?
integer id = llList2Integer(events, 1);

integer time = llList2Integer(events, 0);
nextEvent = id;

float t = (float)(time - llGetUnixTime());
if (t <= 0.0) {
if (executing) return TRUE;
else t = 0.01;
}
llSetTimerEvent(t);
} else {
llSetTimerEvent(0.0);
nextEvent = -1;
}
return FALSE;
}

handleEvent(integer id, string data) {

if (id==timer_versioncheck) {
//time to display our dialog
if ([]==victimsWithRelay) {
llRegionSayTo (grabberID, 0, "No eligible victims found (they must wear a relay).");
requestMenu(grabberID);
} else {
list nn;
integer i;
for (i=0; (i<llGetListLength(victimsWithRelay)) && (i<23); i+=2) {
string s=llKey2Name(llList2Key(victimsWithRelay, i));
if (s)
nn+=llGetSubString(s,0,23);
}

llListenControl(rlv_victim_dialog_handle, TRUE);
scheduleEvent (timer_closechannel, 90, (string)rlv_victim_dialog_handle);
llDialog (grabberID, "Choose a victim", nn, rlv_victim_dialog_channel);
//scheduleEvent (timer_versioncheck, 5, "");
}

//set timer to new timeout

//llSetTimerEvent(TIMER_TIMEOUT);
//llListenControl (version_handle, FALSE);
//return;
}
else
if ((id==timer_closechannel) || (id==timer_closechannel2)) {
llListenControl ((integer)data, FALSE);
}
else
if (id==timer_defaultpose) {
llMessageLinked(LINK_THIS, MSG_DO_DEFAULT_POSE, "", "");
}
else
if (id==timer_cleargrabbing) {
grabbingVictims=[];
}

}

upgrade() {string self = llGetScriptName(); string basename = self; if (llSubStringIndex(self, " ") >= 0) {integer start = 2; string tail = llGetSubString(self, llStringLength(self) - start, -1); while (llGetSubString(tail, 0, 0) != " ") {start++; tail = llGetSubString(self, llStringLength(self) - start, -1);} if ((integer)tail > 0) {basename = llGetSubString(self, 0, -llStringLength(tail) - 1);}} integer n = llGetInventoryNumber(INVENTORY_SCRIPT); while (n-- > 0) {string item = llGetInventoryName(INVENTORY_SCRIPT, n); if (item != self && 0 == llSubStringIndex(item, basename)) {llRemoveInventory(item);}}}

default
{
state_entry()
{
upgrade();
llOwnerSay ("sitmanager memory free : "+(string)llGetFreeMemory());
state active;
}
}

state active {
state_entry() {
setSitTarget();
llMessageLinked (LINK_THIS, MSG_QUERY_SITSCRIPT, "", "");

rlv_victim_dialog_channel = 124904342+llFloor(llFrand(42902543));
rlv_victim_dialog_handle = llListen(rlv_victim_dialog_channel, "", "", "");
llListenControl (rlv_victim_dialog_handle, FALSE);
relay_handle=llListen(RELAY_CHANNEL, "", "", "");
llListenControl(relay_handle, FALSE);
}
link_message(integer sn, integer n, string m, key id) {

if (n==MSG_RESET)
llResetScript();
else
if (n==MSG_ENABLE_SITTING) {
MAX_SITTING=llGetListLength(sitScripts);
setSitTarget();
}
else
if (n==MSG_AGENT_UNSIT) {
//unsit agent
llUnSit(id);
}
else
if (n==MSG_ALL_UNSIT) {
//just kick everyone
unsitAll();
}
else
if (n==MSG_DISABLE_SITTING) {
//state inactive;
MAX_SITTING=0;
setSitTarget();
}

else
if (n==MSG_REGISTER_SITSCRIPT) {
if (m)
if (INVENTORY_SCRIPT==llGetInventoryType(m))
if (-1==llListFindList(sitScripts, [m])) {
sitScripts+=m;
MAX_SITTING=llGetListLength(sitScripts);
}
}

else
if (n==MSG_PLAY_ANIM) {
currentAnim=m;
applyAnims();
}
else
if (n==MSG_MENU_SWAP) {
makeSwapMenu (id, (integer)m);
}
else
if (n==MSG_DO_SWAP) {
swapAgent(id, (integer)m);
}
else
if (n==MSG_MENU_META) {
menuMeta=llParseString2List(m, ["|", " "], []);
}
else
if (n==MSG_DO_STOP) {
llUnSit(id); //let changed event handle the rest
}
else
if (n==MSG_MODE_BALLUSERS) {
mode_ballusers=(integer)m;
}
else
if (n==MSG_RLV_GRAB) {
RLVGrabMenu(id);
}
else
if (n==MSG_RLV_RELEASE) {
RLVReleaseAll();
}

}

changed (integer c) {
if (c & CHANGED_LINK) {
//don't even bother about getting sitted or not or leaving..
//just fetch all current avatars and match them against our list of known avis
inventarise();
}

}

timer() {
// Clear timer or it might fire again before we're done
llSetTimerEvent(0.0);

do {
// Fire the event
handleEvent(nextEvent, llList2String(events, 2));

// Get rid of the first item as we've executed it
integer l = events != [];
if (l > 0) {
if (l > 3)
events = llList2List((events = []) + events, 3, -1);
else events = [];
}

// Prepare the timer for the next event
} while (setTimer(TRUE));
}

/*
timer() {
/* default pose.. do somewhere else please
llSetTimerEvent(0.);
llMessageLinked(LINK_THIS, MSG_DO_DEFAULT_POSE, "", "");
*/
/*
}
*/

no_sensor()
{
llRegionSayTo (grabberID, 0, "No nearby potentional victims found");
requestMenu(grabberID);
}

// some av in sensor range
sensor(integer total_number)
{
//llListenControl (rlv_victim_dialog_handle, TRUE);
//scheduleEvent (timer_closechannel, 120, (string)rlv_victim_dialog_handle);
llListenControl (relay_handle, TRUE);
scheduleEvent (timer_closechannel2, 7, (string)relay_handle);

potentionalVictims=[];
victimsWithRelay=[];
integer i;
for(i=0; i < total_number; i++)
{
key id = llDetectedKey(i);
string name = llKey2Name(id);
if (llStringLength(name) > 24)
{
name = llGetSubString(name, 0, 23);
}
potentionalVictims+=[id, name];
rlv_checkversion(id);
}

// show dialog if list contains names
/*
if (llGetListLength(sensor_names) > 0)
{
llListenControl(dialog_handle, TRUE);
llSetTimerEvent(TIMER_TIMEOUT);
llDialog(avatar_menu, MSG_CHOOSE_AV, sensor_names, dialog_channel);
}
*/
scheduleEvent (timer_versioncheck, 5, (string)grabberID);
llRegionSayTo (grabberID, 0, "Verifying "+(string)total_number+" potentional victims. Menu in 5.. 4.. 3.."); }

listen (integer ch, string n, key id, string m) {
if (ch==RELAY_CHANNEL) {
if (-1!=llSubStringIndex(m, "version=")) {//bit dirty, we might catch other objects too
//victims+=llGetOwnerKey(id);
//victim selected, grab it
victimsWithRelay+=[llGetOwnerKey(id),llGetSubString(llKey2Name(llGetOwnerKey(id)),0,23)];
}
}
else
if (ch==rlv_victim_dialog_channel) {
//victim selected, grab it
integer i=llListFindList (victimsWithRelay, [m]);
if (-1<i) {
key vid=llList2Key(victimsWithRelay, i-1);
rlv_capture (vid);
if (-1==llListFindList(grabbingVictims, [vid])) {
grabbingVictims+=vid;
}
scheduleEvent (timer_cleargrabbing, 120, (string)id);
}
requestMenu(grabberID);
}

}
}

/*
state inactive {
state_entry() {
llSitTarget(ZERO_VECTOR, ZERO_ROTATION);
}
link_message(integer sn, integer n, string m, key id) {
if (n==MSG_RESET)
llResetScript();
else
if (n=MSG_ENABLE_SITTING)
state active;
}
}
*/
</lsl>

==TMCP - pose==
<lsl>
key ourAgent;
string currentAnim;

integer hasPerms;

integer MSG_AGENT_PLAY_ANIM=395; // to notify the slave script
integer MSG_AGENT_STOP_ANIM=396;
integer MSG_ATTACH_AGENT = 398;
integer MSG_DETACH_AGENT = 399;
integer MSG_REGISTER_SITSCRIPT =383;
integer MSG_QUERY_SITSCRIPT = 385;
integer MSG_SYNC_ANIM=361;

integer MSG_ADJUST_POSROT=520;
integer MSG_TEMPORARY_POSROT=521;

integer MSG_MODE_ADJUST=368;

vector o=ZERO_VECTOR;
vector r=ZERO_VECTOR;
integer hastimer;

integer is_adjusting;
integer cursormode;

stopAnim() {
if (hasPerms) if (currentAnim)
llStopAnimation(currentAnim);
}

runAnim() {
if (hasPerms) if (currentAnim)
llStartAnimation(currentAnim);
}

integer checkPerms() {
if (llGetPermissionsKey()!=ourAgent) {
hasPerms = FALSE;
return FALSE;
}
hasPerms=(PERMISSION_TAKE_CONTROLS|PERMISSION_TRIGGER_ANIMATION) == ((PERMISSION_TAKE_CONTROLS|PERMISSION_TRIGGER_ANIMATION) & llGetPermissions());
return hasPerms;
}

queryPerms() {
if (!checkPerms()) {
//must query them
llRequestPermissions(ourAgent, PERMISSION_TAKE_CONTROLS|PERMISSION_TRIGGER_ANIMATION);
} else {
stopDefAnims();
if (currentAnim)
llStartAnimation(currentAnim);
getControls();
}
}

stopDefAnims() {
//easy way would be:
//llStopAnimation("sit");
//let's go for the hard way
list a=llGetAnimationList(ourAgent);
integer i;
for (i=0; i<llGetListLength(a); i++)
llStopAnimation(llList2Key(a,i));
}

register() {
llMessageLinked (LINK_THIS, MSG_REGISTER_SITSCRIPT, llGetScriptName(), "");
}

getControls() {
llTakeControls (CONTROL_UP|CONTROL_DOWN|CONTROL_LEFT|CONTROL_RIGHT|CONTROL_FWD|CONTROL_BACK|CONTROL_ROT_LEFT|CONTROL_ROT_RIGHT, TRUE, FALSE);
//llInstantMessage (ourAgent, "Adjust your position with PGUP, PGDOWN and cursorkeys. Shift rotates.");
whispHelp(ourAgent);
}

parseControls (integer level, integer edge) {

integer l = level; //hold down

if ((CONTROL_UP|CONTROL_DOWN)==(l & edge & (CONTROL_UP | CONTROL_DOWN))) {
cursormode=!cursormode;
whispHelp(ourAgent);
return;
}

if (is_adjusting) {
integer cm=cursormode;
if (l & edge & CONTROL_LEFT)
cursormode--;
if (l & edge & CONTROL_RIGHT)
cursormode++;
if (cursormode<1)
cursormode=3;
if (cursormode>3)
cursormode=1;
if (cm!=cursormode)
whispHelp(ourAgent);
}

if (cursormode==1) {//fine adjust
if (l & CONTROL_FWD) o+=<0,2,0>;
if (l & CONTROL_BACK) o+=<0,-2,0>;
if (l & CONTROL_ROT_LEFT) o+=<-2,0,0>;
if (l & CONTROL_ROT_RIGHT) o+=<2,0,0>;
if (l & CONTROL_UP) o+=<0,0,2>;
if (l & CONTROL_DOWN) o+=<0,0,-2>;
}
else
if (cursormode==2) {//90 degrees rotation
if (l & edge & CONTROL_FWD) r+=<0,90,0>;
if (l & edge & CONTROL_BACK) r+=<0,-90,0>;
if (l & edge & CONTROL_ROT_LEFT) r+=<0,0,-90>;
if (l & edge & CONTROL_ROT_RIGHT) r+=<0,0,90>;
if (l & edge & CONTROL_UP) r+=<90,0,0>;
if (l & edge & CONTROL_DOWN) r+=<-90,-0,0>;
}
else
if (cursormode==3) {//fine rotation
if (l & CONTROL_FWD) r+=<0,1,0>;
if (l & CONTROL_BACK) r+=<0,-1,0>;
if (l & CONTROL_ROT_LEFT) r+=<0,0,-1>;
if (l & CONTROL_ROT_RIGHT) r+=<0,0,1>;
if (l & CONTROL_UP) r+=<1,0,0>;
if (l & CONTROL_DOWN) r+=<-1,0,0>;
}

//if (l & edge & CONTROL_LEFT) r += <0,0,90>;
//if (l & edge & CONTROL_RIGHT) r += <0,-90,0>;

if (!hastimer) {
llSetTimerEvent (0.25);
hastimer=TRUE;
}
}

whispHelp (key id) {
if (!is_adjusting) {
if (!cursormode) {
llRegionSayTo (id, 0, "Press PAGE-UP and PAGE-DOWN simultanious to fine adjust position");
} else {
llRegionSayTo (id, 0, "Use the cursor keys and up/down to adjust position. Changes made are temporary.");
}
} else {
if (!cursormode)
llRegionSayTo (id, 0, "Use PAGE-UP and PAGE-DOWN to start adjusting");
if (1==cursormode)
llRegionSayTo (id, 0, "Mode: position (fine adjust). Use cursor keys and up/down to adjust position. Shift-left or shift-right to change mode");
if (2==cursormode)
llRegionSayTo (id, 0, "Mode: rotation (90 degrees) . Use cursor keys and up/down to adjust rotation. Shift-left or shift-right to change mode");
if (3==cursormode)
llRegionSayTo (id, 0, "Mode: rotation (fine adjust). Use cursor keys and up/down to adjust rotation. Shift-left or shift-right to change mode");
}
}

upgrade() {string self = llGetScriptName(); string basename = self; if (llSubStringIndex(self, " ") >= 0) {integer start = 2; string tail = llGetSubString(self, llStringLength(self) - start, -1); while (llGetSubString(tail, 0, 0) != " ") {start++; tail = llGetSubString(self, llStringLength(self) - start, -1);} if ((integer)tail > 0) {basename = llGetSubString(self, 0, -llStringLength(tail) - 1);}} integer n = llGetInventoryNumber(INVENTORY_SCRIPT); while (n-- > 0) {string item = llGetInventoryName(INVENTORY_SCRIPT, n); if (item != self && 0 == llSubStringIndex(item, basename)) {llRemoveInventory(item);}}}

default
{
state_entry()
{
//upgrade();
register();
}

link_message(integer sn, integer n, string m, key id) {
if (n==MSG_ATTACH_AGENT) {
if (m==llGetScriptName()) {
if (ourAgent)
stopAnim();
currentAnim="";
ourAgent = id;
queryPerms();
}
}
else
if (n==MSG_DETACH_AGENT) {
if (ourAgent==id) {
llReleaseControls();
stopAnim();
}
ourAgent=NULL_KEY;
currentAnim="";
}
else
if (n==MSG_AGENT_PLAY_ANIM) {
if (ourAgent==id) {
stopAnim();
currentAnim=m;
runAnim();
}
}
else
if (n==MSG_AGENT_STOP_ANIM) {
if (ourAgent==id) {
stopAnim();
currentAnim="";
}
}
else
if (n==MSG_SYNC_ANIM) {
if (ourAgent) {
stopAnim();
runAnim();
}
}
else
if (n==MSG_QUERY_SITSCRIPT) {
register();
//llOwnerSay ("Registering");
}
else
if (n==MSG_MODE_ADJUST) {
is_adjusting = (integer)m;
if (!is_adjusting)
cursormode=0;
else
cursormode=1;
if (id==ourAgent)
whispHelp(id);
}

}

run_time_permissions(integer p) {
if (checkPerms()) {
stopDefAnims();
if (currentAnim)
llStartAnimation(currentAnim);
getControls();
}
}

control (key id, integer level, integer edge) {
if (id!=ourAgent)
return;
parseControls (level, edge);
}

timer () {
llSetTimerEvent (0.);
hastimer=FALSE;
if (ZERO_VECTOR!=(o+r)) {
if (is_adjusting)
llMessageLinked (LINK_THIS, MSG_ADJUST_POSROT, (string)(0.005*o)+"&"+(string)r, ourAgent);
else
llMessageLinked (LINK_THIS, MSG_TEMPORARY_POSROT, (string)(0.005*o)+"&"+(string)r, ourAgent);
}
o=ZERO_VECTOR;
r=ZERO_VECTOR;

}

}

</lsl>

==TMCP - positions==
<lsl>
//basically, we need a large datastore for our command set
list poseNames;
list poseData;

list positionNames;
list positionData;

integer MSG_DATA_MENU=310;
integer MSG_DATA_TYPE=320;
integer MSG_DATA_POSE=330;
integer MSG_DATA_POSITION=331;
integer MSG_DATA_LM=335;

integer MSG_DO_POSE=350;
integer MSG_DO_LM=351;
integer MSG_DO_SPECIAL=352;

integer MSG_SET_RUNNING=390;
integer MSG_STORAGE_RESET=391;

integer MSG_DATA_READY=309;

integer MSG_RUN_ANIMS=379;

integer MSG_AGENT_PLAY_ANIM=395;

integer MSG_SET_SITTARGET=375;

integer MSG_DUMP_POSITIONS=389;
integer MSG_UPDATE_POS=363;

integer MSG_DO_DEFAULT_POSE = 358;
integer MSG_SET_DEFAULT_POSE = 359;

integer MSG_MLP_SETTING = 1;

integer MSG_ADJUST_POSROT=520;
integer MSG_TEMPORARY_POSROT=521;

string currentPose="default";
list currentAnims;
list currentPositions;

list agentPoseIdx;

list agentAdjust;

string defaultPose="default";

runAnims() {
list data=agentPoseIdx;
integer i;
list idpos;
for (i=0; i<llGetListLength(data); i+=2) {
key id=(key)llList2String(data, i);
integer idx=-1+(integer)llList2String(data, i+1);
if (id) if (idx>=0) {
if (idx>=llGetListLength(currentAnims))
llWhisper (0, "No animation available for "+llKey2Name(id));
else {
llMessageLinked (LINK_THIS, MSG_AGENT_PLAY_ANIM, llList2String(currentAnims, idx), id);
//llOwnerSay ("Playing anim "+llList2String(currentAnims, idx)+" on id "+(string)id);
}

if (idx/2>=llGetListLength(currentPositions))
llSay (0, "No position data for "+llKey2Name(id));
else {
//set agents position
idpos+=[id, (vector)llList2String(currentPositions, idx*2),(vector)llList2String(currentPositions, idx*2+1)];
}
} else {
//llOwnerSay ("Corrupt agent anim position request");
}
}
//apply positions
for (i=0; i<=llGetNumberOfPrims(); i++) {
integer j=llListFindList(idpos, [llGetLinkKey(i)]);
if (-1<j) {
vector pos = llList2Vector(idpos, j+1)+(<0,0,0.42+0.01*(integer)llGetObjectDesc()>/llGetRot());
vector rot = llList2Vector(idpos, j+2) * DEG_TO_RAD;
integer l=llListFindList (agentAdjust, [llGetLinkKey(i)]);
if (-1<l) {
pos+=llList2Vector (agentAdjust, l+1);
rot=llRot2Euler(llEuler2Rot(llList2Vector (agentAdjust, l+2)) * llEuler2Rot(rot));
}
llSetLinkPrimitiveParamsFast(i, [PRIM_POS_LOCAL, pos,PRIM_ROT_LOCAL, llEuler2Rot(rot)]);
//llOwnerSay ("Setting position for "+llKey2Name(llGetLinkKey(i))+" position: "+(string)pos+" rotation: "+ (string)rot );
}
}
}

setSitTarget(integer poseidx) {
poseidx--;
vector v=(vector)llList2String(currentPositions, poseidx*2);
vector r=(vector)llList2String(currentPositions, poseidx*2+1);
llSitTarget (v+(<0,0,0.42+0.01*(integer)llGetObjectDesc()>/llGetRot()) , llEuler2Rot(r*DEG_TO_RAD));
//llOwnerSay ("Sit target #"+(string)poseidx+" "+(string)(v+(<0,0,0.42>/llGetRot()))+" "+(string)(r));
}

string shortString (float n) {
string s=(string)n;
while (llStringLength(s)>1) {
integer hasdot=-1!=llSubStringIndex(s, ".");
string d=llGetSubString(s,-1,-1);
if ((hasdot && (d=="0")) || (d=="."))
s=llDeleteSubString(s,-1,-1);
else
jump ok;
}
@ok;
return s;
}

string shortVec (vector v) {
return "<"+shortString(v.x)+","+shortString(v.y)+","+shortString(v.z)+">";
}

dumpPos() {
llOwnerSay ("TMCP Position Dump");
integer i;
for (i=0; i<llGetListLength(positionNames); i++) {
//llOwnerSay ("{"+llList2String(positionNames, i)+"} "+llList2String(positionData, i));
list v=llParseString2List(llList2String(positionData, i), ["&"], []);
string s="{"+llList2String(positionNames, i)+"}";
integer j;
for (j=0; j<llGetListLength(v); j++)
//notice that function shortvec takes string as param
s+=" "+shortVec((vector)llList2String(v, j));
llOwnerSay (s);
}
}

doPose (string m) {
if (m!=currentPose)
agentAdjust=[];

currentPose=m;
currentAnims=[];
currentPositions=[];
integer i=llListFindList(positionNames, [m]);
integer j=llListFindList(poseNames, [m]);
currentAnims=llParseString2List (llList2String(poseData, j), ["|"], []);
currentPositions=llParseString2List (llList2String(positionData, i), ["&"], []);

//fill missing data with defaults
i = llListFindList(positionNames, ["default"]);
j = llListFindList(poseNames, ["default"]);
list animdef=llParseString2List (llList2String(poseData, j), ["|"], []);
list posdef=llParseString2List (llList2String(positionData, i), ["&"], []);
currentAnims+=llList2List (animdef, llGetListLength(currentAnims), -1);
currentPositions+=llList2List(posdef, llGetListLength(currentPositions), -1);

//this should be obsolete now:
if (/*(i>=0) && */(j>=0)) {
//list l=llParseString2List(llList2String(lmAction, i), [","],[]);
//parse pose data. todo.
if (i<0) {
//need to fetch default data... just try it.
i=llListFindList(positionNames, ["default"]);
}
//llOwnerSay ("Do pose "+m+" anims "+llList2String(poseData,j)+" data "+llList2String(positionData, i));
} else {
//llOwnerSay ("No animations defined for "+m);
}

runAnims();
}

setAgentPosRot (key id, string data) {
//set temporary agent adjustment.
list l=llParseString2List(data, ["&"], []);
vector p=(vector)llList2String(l,0);
vector r=DEG_TO_RAD * (vector)llList2String(l,1);
integer i=llListFindList (agentAdjust, [id]);
if (-1<i) {
p+=llList2Vector(agentAdjust, i+1);
r=llRot2Euler(llEuler2Rot(llList2Vector(agentAdjust, i+2))*llEuler2Rot(r));
agentAdjust = llDeleteSubList(agentAdjust, i, i+2);
}
if (llVecMag(p)>1)
p=llVecNorm(p);
agentAdjust+=[id,p,r];
runAnims();
}

adjustPosition (string name, integer index, vector p, vector r) {
//positionNames
integer i=llListFindList (positionNames, [name]);
if (-1<i) {
string data=llList2String(positionData, i);
list pos=llParseString2List(data, ["&"], []);
if (index>0) {
//alter only index
integer j=(index-1)*2;
if (j<llGetListLength(positionData)) {
vector v=(vector)llList2String(pos, j);
v+=p;
vector R0=(vector)llList2String(pos, j+1);
rotation R1=llEuler2Rot(DEG_TO_RAD *R0);
rotation Rd=llEuler2Rot(DEG_TO_RAD * r);
R1 = R1 * Rd;
R0=RAD_TO_DEG * llRot2Euler(R1);
pos=llListReplaceList(pos, [shortVec(v),shortVec(R0)], j, j+1);
}

} else {
//alter all
integer j;
for (j=0; j<llGetListLength(pos); j+=2) {
vector v=(vector)llList2String(pos, j);
v+=p;
vector R0=(vector)llList2String(pos, j+1);
rotation R1=llEuler2Rot(DEG_TO_RAD *R0);
rotation Rd=llEuler2Rot(DEG_TO_RAD * r);
R1 = R1 * Rd;
R0=RAD_TO_DEG * llRot2Euler(R1);
pos=llListReplaceList(pos, [shortVec(v),shortVec(R0)], j, j+1);
}
}
data=llDumpList2String(pos, "&");
//llOwnerSay ("new pos data for "+name+" : "+data);
positionData=llListReplaceList (positionData, [data], i, i);

}
}

adjustAllPositions (vector p, vector r) {
//loop all pose, adjust them
integer i;
for (i=0; i<llGetListLength(positionNames); i++) {
adjustPosition (llList2String(positionNames, i),-1, p,r);
}
}

parseSetting (string m, key id) {
//seperated by =
//might contain ROT or POS adjustments
list l=llParseString2List(m, [" = ", " =", "=", "= ","="],[]);
string cmd=llList2String(l, 0);
string cmd2=llList2String(l,1);
if (cmd=="REORIENT") {
vector v=(vector)llList2String(l,2);
/*
list lv=llParseString2List(llList2String(l,2), ["<",",",">"], []); //rotations come as vector too
llOwnerSay ("P: "+llList2String(l,2)+" : "+llDumpList2String(lv, "*"));
v.x=(float)llList2String(lv,0);
v.y=(float)llList2String(lv,1);
v.z=(float)llList2String(lv,2);
*/

llOwnerSay ("adjust "+cmd2+" "+(string)v);
if (cmd2=="OFF") {
adjustAllPositions (0.01*v, ZERO_VECTOR);
} else
if (cmd2=="ROT") {
adjustAllPositions (ZERO_VECTOR,v);
}

doPose(currentPose);
//runAnims();
}
}

adjustPosRot (key id, string data) {
list l=llParseString2List(data, ["&"], []);
integer i=llListFindList (agentPoseIdx, [(string)id]);
//llOwnerSay ("posrot "+(string)i+" "+(string)id+" "+data);
if ((-1<i)&&(llGetListLength(l)==2)) {
integer lidx=llList2Integer (agentPoseIdx, i+1);
adjustPosition (currentPose, lidx, (vector)llList2String(l,0), (vector)llList2String(l,1));
doPose(currentPose);
}
}

upgrade() {string self = llGetScriptName(); string basename = self; if (llSubStringIndex(self, " ") >= 0) {integer start = 2; string tail = llGetSubString(self, llStringLength(self) - start, -1); while (llGetSubString(tail, 0, 0) != " ") {start++; tail = llGetSubString(self, llStringLength(self) - start, -1);} if ((integer)tail > 0) {basename = llGetSubString(self, 0, -llStringLength(tail) - 1);}} integer n = llGetInventoryNumber(INVENTORY_SCRIPT); while (n-- > 0) {string item = llGetInventoryName(INVENTORY_SCRIPT, n); if (item != self && 0 == llSubStringIndex(item, basename)) {llRemoveInventory(item);}}}

default
{
state_entry()
{
upgrade();
}

link_message (integer sn, integer n, string m, key id) {
if (n==MSG_DATA_POSE) {
//add posedata
poseNames+=m;
poseData+=(string)id;
} else
if (n==MSG_DATA_POSITION) {
positionNames+=m;
positionData+=(string)id;
} else
if (n==MSG_SET_DEFAULT_POSE) {
defaultPose=m;
}
else
if (n==MSG_SET_RUNNING)
state running;
}
}

state running {
state_entry()
{
llOwnerSay ("Position free memory: "+(string)llGetFreeMemory());
doPose(defaultPose);
}
link_message (integer sn, integer n, string m, key id) {
if (n==MSG_DO_POSE) {
doPose(m);
} else
if (n==MSG_STORAGE_RESET)
llResetScript();
else
if (n==MSG_RUN_ANIMS) {
agentPoseIdx=llCSV2List(m);
runAnims();
}
else
if (n==MSG_SET_SITTARGET) {
setSitTarget((integer)m);
}
else
if (n==MSG_DUMP_POSITIONS) {
dumpPos();
}
else
if (n==MSG_UPDATE_POS) {
runAnims();
}
else
if (n==MSG_SET_DEFAULT_POSE)
defaultPose=m;
else
if (n==MSG_DO_DEFAULT_POSE)
doPose(defaultPose);
else
if (n==MSG_MLP_SETTING) {
parseSetting (m, id);
}
else
if (n==MSG_ADJUST_POSROT) {
adjustPosRot(id, m);
}
if (n==MSG_TEMPORARY_POSROT) {
setAgentPosRot(id, m);
}

}

}
</lsl>

==TMCP - actions==
<lsl>
//basically, we need a large datastore for our command set
list lmNames;
list lmAction;

integer MSG_DATA_MENU=310;
integer MSG_DATA_TYPE=320;
integer MSG_DATA_POSE=330;
integer MSG_DATA_LM=335;

integer MSG_DO_POSE=350;
integer MSG_DO_LM=351;
integer MSG_DO_SPECIAL=352;

integer MSG_DO_SOUND=356;

integer MSG_SET_RUNNING=390;
integer MSG_STORAGE_RESET=391;
integer MSG_DATA_READY=309;

upgrade() {string self = llGetScriptName(); string basename = self; if (llSubStringIndex(self, " ") >= 0) {integer start = 2; string tail = llGetSubString(self, llStringLength(self) - start, -1); while (llGetSubString(tail, 0, 0) != " ") {start++; tail = llGetSubString(self, llStringLength(self) - start, -1);} if ((integer)tail > 0) {basename = llGetSubString(self, 0, -llStringLength(tail) - 1);}} integer n = llGetInventoryNumber(INVENTORY_SCRIPT); while (n-- > 0) {string item = llGetInventoryName(INVENTORY_SCRIPT, n); if (item != self && 0 == llSubStringIndex(item, basename)) {llRemoveInventory(item);}}}

default
{
state_entry()
{
upgrade();
}

link_message (integer sn, integer n, string m, key id) {
if (n==MSG_DATA_LM) {
//add action
lmNames+=m;
lmAction+=(string)id;
} else
if (n==MSG_SET_RUNNING)
state running;
}
}

state running {
state_entry()
{
llOwnerSay ("Action manager free memory : "+(string)llGetFreeMemory());
}
link_message (integer sn, integer n, string m, key id) {
if (n==MSG_DO_LM) {
integer i=llListFindList(lmNames, [m]);
if (i>=0) {
list l=llParseString2List(llList2String(lmAction, i), [","],[]);
integer set=(integer)llList2String(l,1);
integer num=(integer)llList2String(l,2);
//string mess=llStringTrim(llList2String(l,3),STRING_TRIM);
string mess=llDumpList2String(llList2List(l,3,-1), ",");
integer nomenu=(integer)llList2String(l,0);
//perform requested action
llMessageLinked (set, num, mess, id);

if (!nomenu) //this will fail when not found, which it shouldnt.
llMessageLinked (LINK_THIS, 370, "", id);
}
} else
if (n==MSG_DO_SOUND) {
//LM list was abused for sound info
integer i=llListFindList(lmNames, [m]);
if (i>=0)
llTriggerSound(llList2String(lmAction, i), 1.);
}
else
if (n==MSG_STORAGE_RESET)
llResetScript();
}

}
</lsl>

==TMCP - menurender==
<lsl>
string version = "TMCP v0.3x";

//Render menu

list menuNames;
list menuEntries; //menus that appear in 'auto' menu
list menuDetails;

//some hardcoded stuff that this script adds, not any menu. prefill.
list itemNames=["<<<",">>>","<BACK"];
list itemTypes=[7,7,7];

list menuHistory;
string currentMenu;
string currentPose="default";
string defaultPose="default";

integer channel=999;
integer listenhandle;

integer mode_chat=1;
integer mode_adjust=0;
integer mode_menu=3; //user
integer mode_ball=0; //all

integer hibernate;

list rlvVictims;

integer TYPE_MENU=1;
integer TYPE_POSE=2;
integer TYPE_LM_NOMENU=3;
integer TYPE_LM_MENU=4;
integer TYPE_IGNORE=5;
integer TYPE_SPECIAL=6;
integer TYPE_UNKNOWN=7;
integer TYPE_SOUND=8;

integer MSG_DATA_MENU=310;
integer MSG_DATA_MENU_DETAILS=311;

integer MSG_DATA_TYPE=320;
integer MSG_DATA_POSE=330;
integer MSG_DATA_POSITION=331;
integer MSG_DATA_LM=335;

integer MSG_DO_POSE=350;
integer MSG_DO_LM=351;
integer MSG_DO_SPECIAL=352;

integer MSG_DO_STOP=353;
integer MSG_DO_SWAP=354;
integer MSG_MENU_SWAP=355;
integer MSG_DO_SOUND=356;

integer MSG_SET_RUNNING=390;
integer MSG_STORAGE_RESET=391;
integer MSG_DATA_READY=309;

integer MSG_DATA_START_READ=301;

integer MSG_MENU_META=333;

integer MSG_DUMP_POSITIONS=389;
integer MSG_MODE_ADJUST=368;
integer MSG_MODE_CHAT=367;
integer MSG_MODE_BALLUSERS=366;
integer MSG_MODE_OFF=365;

integer MSG_UPDATE_POS=363;
integer MSG_ALL_UNSIT =381;

integer MSG_SET_DEFAULT_POSE = 359;
integer MSG_DO_DEFAULT_POSE = 358;

integer MSG_RLV_GRAB=308;
integer MSG_RLV_RELEASE=309;
integer MSG_RLV_VICTIM_LIST=307;

integer MSG_DO_MENU_CURRENTMENU = 305;

//incoming
integer MSG_DO_MENU_COMMAND = -12002;

verbose(string text) {
//llOwnerSay (text);
if (mode_chat)
llSay (0, text);
}

string onOff(integer value) {
if (value) return "On"; else return "Off";
}

string aclMode(integer value) {
if (0==value)
return "ALL";
else
if (1==value)
return "GROUP";
else
if (2==value)
return "OWNER";
else
if (3==value)
return "USER";
else
return "UNKNOWN";
}

reset(integer resetSelf) {
integer i;
for (i=0; i<llGetInventoryNumber(INVENTORY_SCRIPT); i++) {
string s=llGetInventoryName(INVENTORY_SCRIPT, i);
if (-1<llSubStringIndex(s, "~TMCP ")) {
if (s!=llGetScriptName()) {
llResetOtherScript(s);
}
}
}
if (resetSelf)
llResetScript();
}

setRunning(integer running) {
integer i;
for (i=0; i<llGetInventoryNumber(INVENTORY_SCRIPT); i++) {
string s=llGetInventoryName(INVENTORY_SCRIPT, i);
if (-1<llSubStringIndex(s, "~TMCP ")) {
if (s!=llGetScriptName()) {
llSetScriptState (s, running);
}
}
}
}

integer hasDialogAccess(key id) {

//OWNER ALWAYS
if (id==llGetOwner())
return TRUE;

if (-1<llListFindList(rlvVictims, [(string)id]))
return FALSE;

//ALL
if ((!mode_menu)/* || (id==llGetOwner())*/)
return TRUE; //little speed optimalization to avoid call to samegroup

//USER
if (mode_menu==3) {
//user must be sitted to access, or no-one sitted at all
integer someSit=FALSE;
integer i;
for (i=0; i<=llGetNumberOfPrims(); i++) {
if (llGetLinkKey(i)==id)
return TRUE;
if (llGetAgentSize(llGetLinkKey(i)))
someSit=TRUE;
}
return (!someSit);
}

//GROUP
return (mode_menu==1) && llSameGroup(id);
}

integer hasMenuAccess (key id, string menu) {
//supposed to be trimmed already?
if (id==llGetOwner())
return TRUE;
string access=
llStringTrim(
llList2String(
llParseString2List(
llList2String(menuDetails, 1+llListFindList(menuDetails, [menu]) )
, ["|"], [])
, 0)
, STRING_TRIM);
if (access=="OWNER") {
return id==llGetOwner();
}
if (access=="GROUP") {
return (id==llGetOwner()) || llSameGroup(id);
}
if (access=="USER") {
integer i;
for (i=0; i<=llGetNumberOfPrims(); i++)
if (llGetLinkKey(i)==id)
return TRUE;
return FALSE;
}
//defaults to all.. learn to edit notecards if you made an error.
//future options might be a name or some. dunnow.
return TRUE;
}

makeMenu(string name, key id) {

if (id); else return; //might be invoked by remote scripts. can't pop menu's to none-avi's.

//present user a fine menu
integer idx=0;

integer offset;

if ((name==">>>") || (name=="<<<")) {
//offset making
//rename to the last found menu
/*
if (name==">>>")
offset+=10;
if (name=="<<<")
offset-=10;
*/
menuHistory+=name; //next step will fix this
//llOwnerSay ("history: "+(string)menuHistory);
}

integer ho=llGetListLength(menuHistory)-1;
while ((ho>1) && (-1<llListFindList(["<<<", ">>>"], [llList2String(menuHistory, ho)])) ) {
//adjust offset
string s=llList2String(menuHistory, ho);
if (s=="<<<")
offset-=10;
if (s==">>>")
offset+=10;
name=llList2String(menuHistory, ho-1);
ho--;
}

if (name) {
idx=llListFindList(menuNames, [name]);
if (idx<0) {
//llOwnerSay ("No menu entry for "+name);
return;
}

} else {
//make it main menu
name=llList2String(menuNames, 0); //assume at least 1 menu item please.. else its bugged anyways.
menuHistory=[];
}

currentMenu=name;

integer i=llListFindList (menuHistory, [name]);
if (i>=0) {
//truncate rest from history, maybe we went back.
menuHistory = llList2List(menuHistory, 0, i);
} else
menuHistory += name;

list present=llCSV2List(llList2String(menuEntries, idx));

if (llAbs(offset)>=(llGetListLength(present))) offset=0;

integer o=offset;
while (o>0) {
menuHistory += ">>>";
o-=10;
if (o<0)
o=0;
}
while (o<0) {
menuHistory += "<<<";
o+=10;
}

string h=">>";
for (i=0; i<llGetListLength(menuHistory); i++)
h+="> "+llList2String(menuHistory,i)+" ";

if (currentPose)
h+="\n\nCurrent pose: "+currentPose;
//todo somewhere. some better wrap around.

if ((offset) || (llGetListLength(present)>12))
present = llList2List(present, offset, offset+8) + ["<<<", ">>>", "BACK"];

if (llGetListLength(rlvVictims)) {
h+="\nCaptured (RLV): ";
for (i=0; i<llGetListLength(rlvVictims); i++)
h+=llKey2Name((key)llList2String(rlvVictims, i))+"\n";
}

//got our filled up menu here? prolly need to sort it, for now just present it
//llOwnerSay (name+":"+llList2CSV(present));

//invert our list
list p;
for (i=0; i<12; i+=3)
p = p+llList2List (present, -i-3, -i-1);

llDialog (id, version+"\n"+h, p, channel);
}

processCommand (key id, string message) {
integer typeidx=llListFindList (itemNames, [message]);
string param;
integer newMenu=TRUE;

if (typeidx<0) {
list l=llParseString2List(message, ["::"], []);
message=llList2String(l,0);
param=llList2String(l,1);
typeidx=llListFindList (itemNames, [message]);
//llOwnerSay ("Message "+message+" got param "+param);
}

if (typeidx<0) {
//llOwnerSay ("Error - no menu entry for "+message);
return;
}

integer type=llList2Integer(itemTypes, typeidx);
//llOwnerSay ("Type for "+message+" is "+(string)type);
if (type==TYPE_MENU) {
if (hasMenuAccess(id, message)) {
makeMenu(message, id);
newMenu=FALSE;
} else {
llRegionSayTo (id, 0, "Access to menu "+message+" is denied.");
//makeMenu(currentMenu, id);
//return;
}
}
else
if (type==TYPE_POSE) {
llMessageLinked (LINK_THIS, MSG_DO_POSE, message, "");
currentPose=message;
llMessageLinked (LINK_THIS, MSG_MENU_META,llList2String(menuDetails, 1+llListFindList(menuDetails, [currentMenu])), "");
}
else
if (type==TYPE_LM_NOMENU) {
llMessageLinked (LINK_THIS, MSG_DO_LM, message, id);
newMenu=FALSE;
}
else
if (type==TYPE_LM_MENU) {
llMessageLinked (LINK_THIS, MSG_DO_LM, message, id);
}
else
if (type==TYPE_SOUND) {
llMessageLinked (LINK_THIS, MSG_DO_SOUND, message, id);
}
else
//some built in messages
if (type=TYPE_SPECIAL) {

if (message=="SWAP") {

if ((integer)param) {
llMessageLinked (LINK_THIS, MSG_DO_SWAP, param, id);
}
else {
llMessageLinked (LINK_THIS, MSG_MENU_SWAP, (string)channel, id);
newMenu=FALSE;
}
}
else

if (message=="STOP") {
llMessageLinked (LINK_THIS, MSG_DO_STOP, "", id);
newMenu=FALSE;
}
else

if (message=="BACK") {
//check menu history
string newM="";
integer i=llGetListLength (menuHistory)-1;
while ((i>0) && (-1<llListFindList(["<<<", ">>>"], [llList2String(menuHistory, i)]))) i--;
if (i>0) {
menuHistory=llList2List(menuHistory, 0, i);
newM=llList2String(menuHistory,i-1);
}
makeMenu(newM, id);
newMenu=FALSE;
}
else
if ((message=="<<<") || (message==">>>")) {
//previous and next. let menumaker solve this.
makeMenu(message, id);
newMenu=FALSE;
}
else
if (message=="<BACK") {
//makeMenu(currentMenu, id);
}
else
//anything we don't know off for some reason. include it anyways.
if (message=="DUMP") {
llMessageLinked (LINK_THIS, MSG_DUMP_POSITIONS, "", "");
}
else
if (message=="CHAT") {
mode_chat=!mode_chat;
llMessageLinked (LINK_THIS, MSG_MODE_CHAT, (string)mode_chat, id);
llRegionSayTo (id, 0, "Chat "+onOff(mode_chat));
}
else
if (message=="ADJUST") {
mode_adjust=!mode_adjust;
llMessageLinked (LINK_THIS, MSG_MODE_ADJUST, (string)mode_adjust, id);
llRegionSayTo (id, 0, "Adjusting : "+onOff(mode_adjust));
}
else
if (message=="MENUUSERS") {
mode_menu++;
if (mode_menu>3)
mode_menu=0;
llRegionSayTo (id, 0, "Menu access set to "+aclMode(mode_menu));
}
else
if (message=="BALLUSERS") {
mode_ball++;
if (mode_ball>2)
mode_ball=0;
llRegionSayTo (id, 0, "Usage access set to "+aclMode(mode_ball));
llMessageLinked (LINK_THIS, MSG_MODE_BALLUSERS, (string)mode_ball, id);
}
else
if (-1<llListFindList (["RESET", "RESTART", "RELOAD"], [message])) {
llSay (0, "Reset sequence started... Touch me again in a few seconds to reload the configuration.");
reset(TRUE);
newMenu=FALSE;
}
else
if (message=="Z") {
if ("+"==llGetSubString(param,0,0))
param=llGetSubString(param,1,-1);
llSetObjectDesc((string)((integer)llGetObjectDesc()+(integer)param)+llGetSubString(llGetObjectDesc(), llStringLength((string)((integer)llGetObjectDesc())), -1));
llMessageLinked (LINK_THIS, MSG_UPDATE_POS, (string)mode_ball, id);
}
else
if (message=="OFF") {
state Off;
newMenu=FALSE;
}
else
if (message=="SAVE") {
defaultPose=currentPose;
llMessageLinked (LINK_THIS, MSG_SET_DEFAULT_POSE, currentPose, "");

}
else
if (message=="GRAB") {
llMessageLinked (LINK_THIS, MSG_RLV_GRAB, "", id);
newMenu=FALSE;
}
else
if (message=="RELEASE") {
llMessageLinked (LINK_THIS, MSG_RLV_RELEASE, "", id);
}
else {
//forward to whoever handles it
llMessageLinked (LINK_THIS, MSG_DO_SPECIAL, message, id);
}
}

if (newMenu)
makeMenu(currentMenu, id);
}

upgrade() {string self = llGetScriptName(); string basename = self; if (llSubStringIndex(self, " ") >= 0) {integer start = 2; string tail = llGetSubString(self, llStringLength(self) - start, -1); while (llGetSubString(tail, 0, 0) != " ") {start++; tail = llGetSubString(self, llStringLength(self) - start, -1);} if ((integer)tail > 0) {basename = llGetSubString(self, 0, -llStringLength(tail) - 1);}} integer n = llGetInventoryNumber(INVENTORY_SCRIPT); while (n-- > 0) {string item = llGetInventoryName(INVENTORY_SCRIPT, n); if (item != self && 0 == llSubStringIndex(item, basename)) {llRemoveInventory(item);}}}

default
{
state_entry()
{
upgrade();
state WaitTouch;
}
}

state WaitTouch
{
state_entry()
{
reset(FALSE);
llSay (0,"TMCP resetted - Touch me to load the configuration");
}
touch_start (integer n) {
llSay (0,"TMCP startup - reading data");
state reading_data;
}
}

state reading_data
{
state_entry() {
llMessageLinked (LINK_THIS, MSG_DATA_START_READ, "", "");
}
link_message (integer sn, integer n, string m, key id) {
if (n==MSG_DATA_MENU) {
//add action
menuNames+=m;
menuEntries+=(string)id;
} else
if (n==MSG_DATA_MENU_DETAILS) {
//add action
menuDetails+= [m, (string)id];
} else

if (n==MSG_DATA_TYPE) {
//set type
itemNames+=m;
itemTypes+=(integer)((string)id);
}
if (n==MSG_SET_RUNNING)
state running;
}
}

state running {
state_entry()
{
llOwnerSay ("Menu ready. "+(string)llGetFreeMemory());
channel=-(integer)llFrand(1309123)-492345;
listenhandle=llListen (channel, "", "", "");
}

touch_start(integer total_number)
{
key id=llDetectedKey(0);
if (!hasDialogAccess(id)) {
if (mode_chat)
llWhisper (0, "Sorry "+llKey2Name(id)+", but menu usage is limited to "+aclMode(mode_menu));
return;
}
makeMenu("",id);
}

listen (integer ch, string name, key id, string message) {

if (!hasDialogAccess(id)) {
if (mode_chat)
llWhisper (0, "Sorry "+llKey2Name(id)+", but menu usage is limited to "+aclMode(mode_menu));
return;
}

if (hibernate) {
setRunning(TRUE);
hibernate=FALSE;
}

//llSetTimerEvent (3600.);

processCommand (id, message);

}

link_message (integer sn, integer n, string m, key id) {
if (n==MSG_DO_MENU_COMMAND) {
processCommand (id, m);
}
else
if (n==MSG_DO_DEFAULT_POSE) {
currentPose = defaultPose;
}
else
if (n==MSG_RLV_VICTIM_LIST) {
rlvVictims=llCSV2List(m);
}
else
if (n==MSG_DO_MENU_CURRENTMENU) {
makeMenu(currentMenu, id);
}
}

timer() {
//inactivity detected, sleep all other scripts.
llSetTimerEvent(0.);
hibernate=TRUE;
setRunning(FALSE);
}
}

state Off {
state_entry() {
llMessageLinked (LINK_THIS, MSG_ALL_UNSIT, "", "");
llWhisper (0,"Switching off in 10... 9...");
llSleep (5.0);
setRunning(FALSE);
llSleep (5.0);
llSitTarget(ZERO_VECTOR, ZERO_ROTATION);
}

touch_start(integer n) {
key id=llDetectedKey(0);
if (id==llGetOwner())
state running;
if ((mode_menu==1) && llSameGroup(id))
state running;
llRegionSayTo (id, 0, "Sorry, but this object is switched OFF. Ask the owner to turn it on.");
}

state_exit() {
setRunning(TRUE);
hibernate=FALSE;
llWhisper (0, "Switching on");

}

}
</lsl>

==TMCP - notecard reader==
<lsl>
//read MLP notecards
//see how much memory headroom we got after for other stuff

integer notecardidx;
key notecardkey;
integer notecardtype;
integer notecardline;
string notecardname;
list positions;
list tempMenu;
list menuNames;
list menuEntries; //menus that appear in 'auto' menu
list toMenu; //menus with pointers
list linkedMsg;

integer hasReset=FALSE; //indicates if there is a reset option in *some* menu. If absent, we add it for safety.

integer TYPE_MENU=1;
integer TYPE_POSE=2;
integer TYPE_LM_NOMENU=3;
integer TYPE_LM_MENU=4;
integer TYPE_IGNORE=5;
integer TYPE_SPECIAL=6;
integer TYPE_UNKNOWN=7;
integer TYPE_SOUND=8;

integer MSG_DATA_MENU=310;
integer MSG_DATA_MENU_DETAILS=311;
integer MSG_DATA_TYPE=320;
integer MSG_DATA_POSE=330;
integer MSG_DATA_POSITION=331;
integer MSG_DATA_LM=335;

integer MSG_DO_POSE=350;
integer MSG_DO_LM=351;
integer MSG_DO_SPECIAL=352;

integer MSG_DO_STOP=353;
integer MSG_DO_SWAP=354;

integer MSG_SET_RUNNING=390;
integer MSG_STORAGE_RESET=391;
integer MSG_DATA_READY=309;

integer MSG_DATA_START_READ=301;

verbose(string text) {
llOwnerSay (text);
}

startNotecard() {
integer i;
notecardline=0;
for (;notecardidx<llGetInventoryNumber(INVENTORY_NOTECARD); notecardidx++) {
//loop until we found appropiate card
notecardname=llGetInventoryName(INVENTORY_NOTECARD, notecardidx);
if (llGetSubString(notecardname,0,9)==".MENUITEMS") {
//neato. go fetch it
notecardtype=1;
notecardkey=llGetNotecardLine(notecardname, 0);
verbose ("Reading menu from "+notecardname);
return;
}
if (llGetSubString(notecardname,0,9)==".POSITIONS") {
//neato. go fetch it
notecardtype=2;
notecardkey=llGetNotecardLine(notecardname, 0);
verbose ("Reading positions from "+notecardname);
return;
}
verbose ("Skipping "+notecardname);

}
//still here? then we'r done
//verbose ("Done reading all notecards");
postFixMenu();
sendMenuItems();
llSleep (2.0);
llMessageLinked (LINK_THIS, MSG_SET_RUNNING, "", ""); //set to running
verbose ("Ready.");
//llOwnerSay ("Notecard reader free memory: "+(string)llGetFreeMemory());
}

addPose (string name, list data) {
//add pose info.. link to position info exactly when again?
//positions+=[name, data];
llMessageLinked (LINK_THIS, MSG_DATA_POSE, name, llDumpList2String(data, "|"));
}

addMenuDetails (string name, list data) {
//add menu details.. access, color of balls.
llMessageLinked (LINK_THIS, MSG_DATA_MENU_DETAILS, name, llDumpList2String(data, "|"));
}

addLM (string name, string data) {
llMessageLinked (LINK_THIS, MSG_DATA_LM, name, data);
}

setType (string name, integer type) {
llMessageLinked (LINK_THIS, MSG_DATA_TYPE, name, (string)type);
}

parseMenu() {
//parse our temporary menu to a real menu;
//this is where the real stuff happens.
integer i;
string menuName=""; //MLP 1 compatability: don't add stuff to menu as long as menu name is empty. add poses though.
list options;
for (i=0; i<llGetListLength(tempMenu); i++) {
string data=llList2String(tempMenu, i);
integer posspace=llSubStringIndex(data, " ");
string cmd=data;
string param="";
string option="";
if (posspace>0) {
cmd=llGetSubString(data,0,posspace-1);
param=llGetSubString(data, posspace+1, -1);
}
list paramsTmp=llParseString2List(param, ["|"], []);
integer j;
list params;
for (j=0; j<llGetListLength(paramsTmp); j++)
params+=llStringTrim(llList2String(paramsTmp, j), STRING_TRIM);
//params are now nice seperated on |, still allowed to contain spaces in the middle but trimmed from the outside.
string p1=llList2String(params, 0);
string p2=llList2String(params, 1);
string p3=llList2String(params, 2);
//got our set of command and optional parameters now. let's test them.
if (cmd=="MENU") {
addMenuDetails (p1, llDeleteSubList(params,0,0));
//menuEntries+=p1;
menuName=p1; //additional params hint the number of available seats
setType (p1, TYPE_MENU);
} else
if (cmd=="POSE") {
addPose (p1, llDeleteSubList(params,0,0));
option = p1;
setType (p1, TYPE_POSE);
} else
if (cmd=="SOUND") {
addLM (p1, p2);
option = p1;
setType (p1, TYPE_SOUND);
} else
if (-1 != llListFindList (["BACK", "STOP","SWAP","RESET","RESTART", "MENUUSERS", "BALLUSERS","ADJUST", "DUMP", "CHAT", "RELOAD", "OFF"], [cmd])) {
//recognized simple options
option = cmd;
setType (cmd, TYPE_SPECIAL);
if (-1!= llListFindList (["RESET","RESTART", "RELOAD"], [cmd]))
hasReset=TRUE;
} else
if (-1 != llListFindList (["SAVE", "CHECK"], [cmd])) {
//recognized simple options
option = cmd;
setType (cmd, TYPE_IGNORE);
} else
if (cmd=="TOMENU") {
if (p1!="-")
toMenu+=p1;
option=p1;
} else
if (cmd=="LINKMSG") {
//linkedMsg+=[p1,p2];
addLM (p1, p2);
option=p1;
if ((integer)p2)
setType (p1, TYPE_LM_NOMENU);
else
setType (p1, TYPE_LM_MENU);
} else
if (-1<llListFindList(["Z+", "Z-"], [llGetSubString(cmd, 0, 1)])) {
//Z command, we'll rewrite it
option = "Z::"+llGetSubString(cmd, 1, -1);
setType ("Z", TYPE_SPECIAL);
}
else
if (-1<llListFindList (["GRAB", "Grab.Fem"], [cmd])) {
option = "GRAB";
setType ("GRAB", TYPE_SPECIAL);
}
else
if (-1<llListFindList (["Grab.Male","RELEASE"], [cmd])) {
option = "RELEASE";
setType ("RELEASE", TYPE_SPECIAL);
}
//todo.. fill in a bunch of MLP commands here, implemented or not
else
{ //we checked all commands. Anything defined here is considered undefined and we list it just as is.
option = cmd;
//don't set type. it may be defined elsewhere.
//setType (cmd, TYPE_UNKNOWN);
}
if (menuName) if (option)
options+=option;
}
tempMenu=[];
if (options!=[]) {
llOwnerSay ("Menu "+menuName +" ["+(string)llGetListLength(options)+"]");
//menuAll+=options+"!--!";
//menuAll+=[menuName,llList2CSV(options)];
menuNames+=menuName;
menuEntries+=llList2CSV(options);
}
}

addMenuItem(string data) {
integer posslash=llSubStringIndex(data, "//");
if (posslash>=0) {
data=llDeleteSubString(data, posslash, -1);
}
data=llStringTrim(data,STRING_TRIM);
//llOwnerSay ("menu data: "+data);

if (data=="") //comment or some but not empty line, silently ignore
return;

if (llGetSubString (data,0,3+1)=="MENU ") {
//what a surprise, new menu. finish old one.
parseMenu();
}

//what's left, add it to our temp menu. We'l parse it later.
tempMenu+=data;
}

postFixMenu() {
//on failed configurations - add some default stuff
if (!llGetListLength(menuNames)) {

llOwnerSay ("Warning - no reset function found in menu cards. Adding menu 'Reset'.");
//add a default menu with a reset button.

addMenuItem ("MENU Reset...|OWNER");
addMenuItem ("RESET");
parseMenu();
}

//dont add mainmenu
list entries=llDeleteSubList(menuNames,0,0);

integer i;

//llOwnerSay ("PF entries: "+(string)entries);
//llOwnerSay ("PF tomenu: "+(string)toMenu);

for (i=0; i<llGetListLength(toMenu); i++) {
integer j=llListFindList (entries, [llList2String(toMenu, i)]);
if (j>-1) {
entries=llDeleteSubList(entries, j, j);
}
}
//llOwnerSay ("PF entries after: "+(string)entries);

list MainMenu=llCSV2List(llList2String(menuEntries, 0));
for (i=0; i<llGetListLength(entries); i++) {
integer j=llListFindList(MainMenu, ["-"]);
if (j>-1) {
MainMenu=llListReplaceList(MainMenu, [llList2String(entries, i)], j, j);
}
}

i=llListFindList(MainMenu, ["-"]);
while (-1<i) {
MainMenu=llDeleteSubList(MainMenu, i, i);
i=llListFindList(MainMenu, ["-"]);
}

if (MainMenu)
menuEntries = llListReplaceList(menuEntries, [llList2CSV(MainMenu)], 0, 0);
}

sendMenuItems() {
//llOwnerSay ("Applying menu information");

integer i;
for (i=0; i<llGetListLength(menuNames); i++) {
llMessageLinked (LINK_THIS, MSG_DATA_MENU, llList2String(menuNames, i), llList2String(menuEntries, i));
llSleep (0.25);
}

llMessageLinked (LINK_THIS, MSG_DATA_READY, "Done", "TTP");
}

addPosition(string data) {
//some memory optimalization possible here in last half.
integer curlyopen = llSubStringIndex(data, "{");
integer curlyclose = llSubStringIndex(data, "}");
if ((curlyopen<0) || (curlyclose<curlyopen))
return;
string pose=llGetSubString(data, curlyopen+1, curlyclose-1);
data=llGetSubString(data, curlyclose+1, -1);
list posrotsraw=llParseString2List(data, [">"], []);
//llOwnerSay ("raw pos data "+data+" convert to "+(string)posrotsraw);

list posrots;
integer i;
for (i=0; i<llGetListLength(posrotsraw); i++) {
if (-1<llSubStringIndex (llList2String(posrotsraw,i), "<")) {
list v=llParseString2List(llList2String(posrotsraw,i), ["<", ",", " "], []);
posrots += <(float)llList2String(v,0), (float)llList2String(v,1),(float)llList2String(v,2)>;
}
}
//llOwnerSay ("position data for "+pose+" : "+(string)posrots);
//positions+=[pose, llList2CSV(posrots)];
llMessageLinked (LINK_THIS,MSG_DATA_POSITION, pose, llDumpList2String(posrots,"&"));
}

upgrade() {string self = llGetScriptName(); string basename = self; if (llSubStringIndex(self, " ") >= 0) {integer start = 2; string tail = llGetSubString(self, llStringLength(self) - start, -1); while (llGetSubString(tail, 0, 0) != " ") {start++; tail = llGetSubString(self, llStringLength(self) - start, -1);} if ((integer)tail > 0) {basename = llGetSubString(self, 0, -llStringLength(tail) - 1);}} integer n = llGetInventoryNumber(INVENTORY_SCRIPT); while (n-- > 0) {string item = llGetInventoryName(INVENTORY_SCRIPT, n); if (item != self && 0 == llSubStringIndex(item, basename)) {llRemoveInventory(item);}}}

default
{
state_entry() {
upgrade();
//state ReadMenu;
}

link_message (integer sn, integer n, string m, key id) {
if (n==301)
state ReadMenu;
}

}

state ReadMenu
{
state_entry()
{
llMessageLinked (LINK_THIS, MSG_STORAGE_RESET, "", ""); //reset data storage scripts
llSleep (2.0);
//fetch first notecard, go on from there
startNotecard ();
}

dataserver(key id, string data) {
//llOwnerSay ("card "+notecardname+" line "+(string)notecardline+" data "+data);

if (id!=notecardkey)
return; //not for us

if (data==EOF) {
if (notecardtype==1)
parseMenu(); //clean up any menu leftovers
//read next notecard
notecardidx++;
startNotecard();
} else
{
if (notecardtype==1)
addMenuItem(data);
else
addPosition(data);
notecardkey=llGetNotecardLine(notecardname, ++notecardline);

}
}
}
</lsl>

==TMCP RLV extensions (optional)==
<lsl>
//Changes by Tano Toll for seamless MLCP compatability, and to dodge 'double locking':

//*sit and unsit events do not trigger an RLV command (master script already does this)
//*identifier is changed to object name, url encoded.
//*delayed but automatic notecard read on inventory change

// ----------------------------------------------------------------------------------
// MLPV2 Plugin for RLV Script V1.02
//
// Use with a notecard named .RLV with the format:
// Pose|Ball no.: 0,1...*|@RLV-Command
// e.g.
// Missionary|1|@unsit=n
// stand|*|!release
// ----------------------------------------------------------------------------------
// Copyright (c) 2010, Jenni Eales. All rights reserved.
// ----------------------------------------------------------------------------------
// Redistribution and use in source and binary forms, with or without modification,
// are permitted provided that the following conditions are met:
//
// * Redistributions of source code must retain the above copyright notice,
// this list of conditions and the following disclaimer.
// * Redistributions in binary form must reproduce the above copyright notice,
// this list of conditions and the following disclaimer in the documentation
// and/or other materials provided with the distribution.
// * The names of its contributors may not be used to endorse or promote products
// derived from this software without specific prior written permission.
//
// THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY
// EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
// OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
// IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT,
// INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
// BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA,
// OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
// WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
// ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY
// OF SUCH DAMAGE.
//
// Changes:
// ----------------------------------------------------------------------------------
// Version 1.02
// - use | as seperator
// - support multiple lines for one pose
// - additional link message for direct call from ball menu
//
// Version 1.01
// - use ; instead of | as seperator
//
// Version 1.0
// - first version released
// ----------------------------------------------------------------------------------
//
// constants
string NOTECARD = ".RLV"; // name of config notecard
integer DEBUG = FALSE; // switch debug on/off
integer RELAY_CHANNEL = -1812221819; // channel for RLV relay
float TIMER_SEC = 1800.0; // 30 min.
string CMD_RELEASE = "!release"; // release command
integer LM_NUMBER = -1819; // number for link message

// internal use
key kQuery;
integer iLine;

string pose = "stand"; // pose set by the Ball Menu
list poses = []; // configured poses
list balls = []; // configured balls
list commands = []; // configured commands
list avatars = []; // avatars sitting on balls

integer wants_init;

// log a message
log(string message)
{
if(DEBUG) llOwnerSay(message);
}

// only for testing purposes
log_data()
{
log("List:");
integer total_number = llGetListLength(commands);
integer i;
for(i=0; i<total_number; i++)
{
log("- " + llList2String(poses, i) + ": (" + llList2String(balls, i) + ") "+ llList2String(commands, i));
}
}

// write a message to the RLV Relay
relay(key avatar, string message)
{
list tokens = llParseString2List(message, ["|"], [""]);
integer total_number = llGetListLength(tokens);
integer i;
for(i=0; i<total_number; i++)
{
string token = llList2String(tokens, i);
log("RLV: MLPV2," + (string) avatar + "," + token);
llSay(RELAY_CHANNEL, llEscapeURL(llGetObjectName())+"," + (string) avatar + "," + token);
}
}

// find commands for pose and play it for avatars on ball
rlv(string pose)
{
log("command for: " + pose);
llSetTimerEvent(TIMER_SEC);

integer total_number = llGetListLength(poses);
integer i;
for(i=0; i<total_number; i++)
{
if (pose == llList2String(poses, i))
{
string ball = llList2String(balls, i);
log("command for pose: " + pose + " (" + ball + ")");
if (ball == "*")
{
integer b;
for (b=0; b<6; b++)
{
// get avatar for ball index
key avatar = llList2Key(avatars, b);
if(avatar != NULL_KEY) relay(avatar, llList2String(commands, i));
}
}
else
{
key avatar = llList2Key(avatars, (integer) ball);
if(avatar != NULL_KEY) relay(avatar, llList2String(commands, i));
}
}
}
}

// new find: pose and ball needs to match
integer find_pose(string pose, string ball)
{
integer total_number = llGetListLength(poses);
integer i;
for(i=0; i<total_number; i++)
{
if (pose == llList2String(poses, i) && ball == llList2String(balls, i))
{
return i;
}
}
return -1;
}

// add a pose/ball/command entry
add_pose(string pose, string ball, string command)
{
// look for existing entry for pose
integer found = find_pose(pose, ball);
if (found == -1)
{
// add a new pose
poses += [pose];
balls += [ball];
commands += [command];

log("Added from " + NOTECARD + ": " + pose + " | " + ball + " | " + command);
}
else
{
// append to existing pose
string c = llList2String(commands, found) + "|" + command;
commands = llListReplaceList(commands, [c], found, found);

log("Added " + command + " to pose " + pose);
}
}

// parse and store a line
process_line(string line)
{
list tokens = llParseString2List(line, [" | "," | "," | "," | "," |","| ","|"],[""]);
if(llGetListLength(tokens) < 3) return;

string pose = llList2String(tokens, 0);
string ball = llList2String(tokens, 1);

integer total_number = llGetListLength(tokens);
integer i;
for(i=2; i<total_number; i++)
{
add_pose(pose, ball, llList2String(tokens, i));
}
}

// check if object is in the inventory
integer exists_notecard(string notecard) {
return llGetInventoryType(notecard) == INVENTORY_NOTECARD;
}

// initialize me
initialize()
{
log("Initializing...");
poses = [];
balls = [];
commands = [];
avatars = [NULL_KEY, NULL_KEY, NULL_KEY, NULL_KEY, NULL_KEY, NULL_KEY];

if (exists_notecard(NOTECARD))
{
log("Reading " + NOTECARD + "...");
iLine = 0;
kQuery = llGetNotecardLine(NOTECARD, iLine);
}
else
{
llOwnerSay("Not found: " + NOTECARD );
}
}

upgrade() {string self = llGetScriptName(); string basename = self; if (llSubStringIndex(self, " ") >= 0) {integer start = 2; string tail = llGetSubString(self, llStringLength(self) - start, -1); while (llGetSubString(tail, 0, 0) != " ") {start++; tail = llGetSubString(self, llStringLength(self) - start, -1);} if ((integer)tail > 0) {basename = llGetSubString(self, 0, -llStringLength(tail) - 1);}} integer n = llGetInventoryNumber(INVENTORY_SCRIPT); while (n-- > 0) {string item = llGetInventoryName(INVENTORY_SCRIPT, n); if (item != self && 0 == llSubStringIndex(item, basename)) {llRemoveInventory(item);}}}

default
{
// on state entry initialize me
state_entry()
{
upgrade();

initialize();
}

// reset on Inventory change
changed(integer change)
{
if (change & CHANGED_INVENTORY) {
wants_init=TRUE;
llSetTimerEvent (15.0);
}
}

// read a line from notecard
dataserver(key _query_id, string _data) {
// were we called to work on notecard?
if (_query_id == kQuery) {
// this is a line of our notecard
if (_data == EOF) {
if (DEBUG) log_data();
log(NOTECARD + " read.");
} else {
// increment line count
// data has the current line from this notecard
if(_data != "") {
process_line(_data);
}

// request next line
// read another line when you can
iLine++;
kQuery = llGetNotecardLine(NOTECARD, iLine);
}
}
}

timer()
{
if (wants_init) {
wants_init = FALSE;
initialize();
llSetTimerEvent (0.0);
return;
}

integer b;
for (b=0; b<6; b++)
{
// get avatar for ball index
key avatar = llList2Key(avatars, b);

// if not null send command
if(avatar != NULL_KEY) relay(avatar, CMD_RELEASE);
}
llSetTimerEvent(0.0);
}

// link message from MLPV2
link_message(integer sender_number, integer number, string message, key id)
{
/*
// pose from ball menu selected
if (number == 0 && message == "POSEB") {
pose = (string)id;
rlv(pose);
return;
}
*/

// direct call from ball menu
// configure in .MENUITEMS with
// LINKMSG Resctriction | 0,-1,-1819,Restriction
if (number == LM_NUMBER) {
//llOwnerSay ("RLV: -- "+message);
pose = message;
rlv(pose);
return;
}

// unsit avatar
if (number == -11001)
{
integer ball = (integer) message;
log("Avatar unsit from ball " + (string) ball +": " + (string) llList2Key(avatars, ball));
//relay(llList2Key(avatars, ball), CMD_RELEASE);
avatars = llListReplaceList(avatars, [NULL_KEY], ball, ball);
}

// sit avatar
if (number == -11000)
{
list tokens = llParseString2List(message, ["|"], [" "]);
integer ball = llList2Integer(tokens, 0);
log("Avatar sit on ball " + (string) ball +": " + (string) id);
avatars = llListReplaceList(avatars, [id], ball, ball);
//rlv(pose);
}
}
}
</lsl>

User:Tano Toll

2012-05-12T03:01:43Z

Tano Toll: Added links

Some of my work for the public domain:

* [[ParcelChatRelay]] - Parcel Chat Relay efficiently allows parcel-wide channel0 talk

* [[Stream_Music_In_PHP]] - Stream a static mp3 stream, synchronized for all listeners, using php

ParcelChatRelay

2012-05-12T02:54:26Z

Tano Toll: Parcel Chat Relay - Communications helper script - description&code

User:Tano Toll

2012-05-12T02:46:01Z

Tano Toll:

Some of my work for the public domain:

* [[ParcelChatRelay]] - Parcel Chat Relay efficiently allows parcel-wide channel0 talk

User:Tano Toll

2012-05-12T02:45:41Z

Tano Toll: Created page with "Some of my work for the public domain: * ParcelChatRelay - Parcel Chat Relay efficiently allows parcel-wide channel0 talk"

Some of my work for the public domain:

* ParcelChatRelay - Parcel Chat Relay efficiently allows parcel-wide channel0 talk

Stream Music In PHP

2011-10-17T12:54:39Z

Tano Toll: typo and extra warning

Various residents host their own music for the parcel. Quite often, this is just a big MP3 file. The issues of hosting such big MP3 are, that the viewer will download the file 'as-is'. While this is no issue for short files (a few megabyte), it is when the podcast is several hours in length.

To be able to stream my own parcel music, without the use of (commercial/difficult to setup/) streamers like icecast, i written a simple PHP script that streams a huge mp3 file. It performs some extra tricks to make the listening experience glitch-free for SL viewers. This very script has been tested for quite a while, and it does just what it needs to do: host hassle free music for my parcel.

You will need to prepare your own podcast / mp3 stream, as a single file. This script will not serve a playlist, it will just endlessly loop a big MP3 file, whilst synchronizing listeners. Make sure you have appropiate bandwith. Also, usage is only recommended for the more experienced web server admins, if you do not know what 'LAMP' means, have no scripting experience, or have no root access to the server you are hosting this on (in case of a malfunction), please refrain from using this code.

----

<?
//GPL3

//MP3 STREAMING FROM PHP
//This script streams a big MP3 file at an appropiate speed
//Also, it will synchronize several listeners to the same position in the mp3

//Quick usage: Edit the 3 variables below in the 'settings' section, host this script together with a big MP3 on a lamp server.

//This script was optimized for Second Life music streaming, issues dodged:
//* The mp3 is actively streamed, instead of sent as a whole file at once
//* Listeners are synchronized, so they actually will hear the same song whilst being on the same parcel
//* MP3 is nicely (instead of arbitrary) split in chunks to dodge 'skipping' errors that SL viewers tend to behave
//* Insignificant server load(** up to a reasonable amount of viewers, say, <20)
//* Tested for over a year for proper functioning without raising issues

//Limitations
//Requires an MPEG1 LAYER III file as input (the most common MP3 format)
//Assumes a single big file (''podcast''). This script was not made to stream a playlist.
//The file should be properly encoded to avoid issues with the SL player:
//* VBR _might_ work but is not recommended due to the viewers' real-time broadcast skipping
//* If the encoder supports 'bit buckets' - make sure they are disabled as they are incompatible with SL's player(**)
//(**) When streaming 'live' - SL player seems to understand if the whole file was downloaded instead of streamed.
//The resolution of the synchronisation is not precise, though generally <1 second. As listeners join, slight offsets might accumulate
//This script is ment as example how to stream using proper timekeeping and chunking.
//It is missing features as streaming multiple files from a directory, though such behaviour is easily customized.

//Feature, not bug
//With zero listeners, the stream will not progress, instead it'll 'wait' at current position untill at least 1 listener joins

//Issues:
//If the mp3 exists but has zero length, the script may end in an endless loop eating 100% cpu time. please fix.

//Requirements:
//LAP(Linux, Apache, PHP) configuration
//(WAP(Windows) may work but untested, potentional issues revolve around microtime(), fastcgi and locked temporary files).
//PHP configuration that allows overriding script run time to infinite
//Writeable TMP directory
//Properly created MP3 stream (''podcast''), preferably several hours in length:
// * Simply concatting files may work for testing but is not recommended and may lead to audible glitches
// * The prefered way is to either: stream your playlist with an audio player like winamp, then output the stream as .mp3
// * Or use an editor (like audacity) to create your podcast, output as single file
// * Any other means or software to create a podcast
//The intention of this script is to generate a glitch-free audio experience, using no more bandwidth than required

//CHANGE HISTORY
//0.01 - initial version
//0.02 - removed dependancy from external mp3 header library. please set bitrate manually. auto-detect wasn't reliable anyways
//0.03 - documented some more and cleaned up code a tiny bit. might release it as GPL

//settings, please fill this variables with your own
$mp3="bigstreamfile.mp3";
$bitrate=128;

//adjust for your system. use a unique lock file for each mp3 you serve.
//$tmp="/tmp/${mp3}.posinfo";
$tmp="/tmp/stream1pos";

//Enable debug to get textual output in a browser. The stream is not listenable with debug enabled.
$debug=0; //false; //true;

//disable error reporting if you like
error_reporting (E_ALL);

// NO EDITING REQUIRED BELOW THIS LINE, EDIT AT OWN RESPONSABILITY //

//SUPPORT FUNCTIONS
function writePos() {
global $h, $timekeeper;
$fff=fopen ($tmp, "w");
fputs ($fff, "".ftell ($h)."\n");
fputs ($fff, $timekeeper."\n");
fclose ($fff);
}

//global $buffcache;

function sendBuff($bff) {
print $bff;
flush();
return;
}

function readBuffs($fh) {
$b="";
for ($i = 0; $i<22; $i++) {
$b.=readBuff($fh);
}
return $b;
}

function readBuff($fh) {
global $framesize;
//read from file untill we receive a $FF marker
$m="";
do {
$m=fread($fh, 4);
if (feof($fh))
return "";
//requiring mpeg1 layer 3. Adjust for other containers / chunkmarkers / right here
} while (($m[0]!=chr(255)) || !(($m[1]==chr(250)) || ($m[1]==chr(251))) );
$bl=$framesize-4;
if (ord($m[2]) & 2) //padding
$bl++;
$m.=fread ($fh, $bl);
return $m;
}

//`main()`

$file=$mp3;
if (!file_exists($file))
die();
$framesize=floor (144000.0 * $bitrate / 44100);
$blocksize=16384;
$playspeed=1000.0 * $bitrate / 8.0;
$sleeptime = (1.0 * $blocksize / ($playspeed));

if ($debug)
header ("Content-Type: text/plain");
else {
header ("Content-Type: audio/mpeg");
header ("Content-Transfer-Encoding: binary");
header ("Pragma: no-cache");
header ("icy-br: ".$bitrate);
}

//request unlimited runtime
set_time_limit(0);
if ($debug)
print ("framesize: ".$framesize);

$h=fopen($file, "rb");

if (file_exists ($tmp)) {
//read our position from file.
$ff=fopen ($tmp, "r");
$position=fgets($ff);
$postime=fgets($ff);
fclose ($ff);
}

//increase position by elapsed time for syncing listeners.
if ($postime) {
$elapsed = microtime(true)-$postime;
//we force to float to bypass a 32 bit integer limit
//looping for multiple days if needed (its not an issue)
$position += 1.0 * $elapsed * ($bitrate / 8);
$fs=filesize($file);
while ($position>$fs) {
$position-=$fs;
}
}
fseek ($h, $position);
//send a reasonable buffer to start
for ($j=0; $j<3; $j++) {
$buff=readBuffs($h).readBuffs($h).readBuffs($h);
print $buff;
}

$buff=readBuffs($h);
$timekeeper=microtime(true);
$counter=0;

//main loop:
while (($buff!="") && !connection_aborted()) {
if ($debug) {
echo "Buff size: ".strlen($buff)." first chars: ".ord($buff[0])." ".ord($buff[1])." ".ord($buff[2])." ".ord($buff[3])." file pointer ".ftell($h)."\n";
} else
echo ($buff);
flush();
$counter++;
if (!($counter%30))
writePos();
$bwl=strlen($buff);
$buff=readBuffs($h);
if ($buff=="") {
fseek ($h, 0);
$buff=readBuff($h);
}
$timekeeper=$timekeeper+1.0*$bwl/$playspeed;
time_sleep_until($timekeeper);
}

writePos();
fclose($h);

?>

--[[User:Tano Toll|Tano Toll]] 06:05, 15 October 2011 (PDT)

Stream Music In PHP

2011-10-15T13:05:17Z

Tano Toll: Streaming parcel music with simple php script

Various residents host their own music for the parcel. Quite often, this is just a big MP3 file. The issues of hosting such big MP3 are, that the viewer will download the file 'as-is'. While this is no issue for short files (a few megabyte), it is when the podcast is several hours in length.

To be able to stream my own parcel music, without the use of (commercial/difficult to setup/) streamers like icecast, i written a simple PHP script that streams a huge mp3 file. It performs some extra tricks to make the listening experience glitch-free for SL viewers. This very script has been tested for quite a while, and it does just what it needs to do: host hassle free music for my parcel.

You will need to prepare your own podcast / mp3 stream, as a single file. This script will not serve a playlist, it will just endlessly loop a big MP3 file, whilst synchronizing listeners. Make sure you have appropiate bandwith. Also, usage is only recommended for the more experienced web server admins, if you do not know what 'LAMP' means, please refrain from using this code.

----

<?
//GPL3

//MP3 STREAMING FROM PHP
//This script streams a big MP3 file at an appropiate speed
//Also, it will synchronize several listeners to the same position in the mp3

//Quick usage: Edit the 3 variables below in the 'settings' section, host this script together with a big MP3 on a lamp server.

//This script was optimized for Second Life music streaming, issues dodged:
//* The mp3 is actively streamed, instead of sent as a whole file at once
//* Listeners are synchronized, so they actually will hear the same song whilst being on the same parcel
//* MP3 is nicely (instead of arbitrary) split in chunks to dodge 'skipping' errors that SL viewers tend to behave
//* Insignificant server load(** up to a reasonable amount of viewers, say, <20)
//* Tested for over a year for proper functioning without raising issues

//Limitations
//Requires an MPEG1 LAYER III file as input (the most common MP3 format)
//Assumes a single big file (''podcast''). This script was not made to stream a playlist.
//The file should be properly encoded to avoid issues with the SL player:
//* VBR _might_ work but is not recommended due to the viewers' real-time broadcast skipping
//* If the encoder supports 'bit buckets' - make sure they are enabled as they are incompatible with SL's player(**)
//(**) When streaming 'live' - SL player seems to understand if the whole file was downloaded instead of streamed.
//The resolution of the synchronisation is not precise, though generally <1 second. As listeners join, slight offsets might accumulate
//This script is ment as example how to stream using proper timekeeping and chunking.
//It is missing features as streaming multiple files from a directory, though such behaviour is easily customized.

//Feature, not bug
//With zero listeners, the stream will not progress, instead it'll 'wait' at current position untill at least 1 listener joins

//Issues:
//If the mp3 exists but has zero length, the script may end in an endless loop eating 100% cpu time. please fix.

//Requirements:
//LAP(Linux, Apache, PHP) configuration
//(WAP(Windows) may work but untested, potentional issues revolve around microtime(), fastcgi and locked temporary files).
//PHP configuration that allows overriding script run time to infinite
//Writeable TMP directory
//Properly created MP3 stream (''podcast''), preferably several hours in length:
// * Simply concatting files may work for testing but is not recommended and may lead to audible glitches
// * The prefered way is to either: stream your playlist with an audio player like winamp, then output the stream as .mp3
// * Or use an editor (like audacity) to create your podcast, output as single file
// * Any other means or software to create a podcast
//The intention of this script is to generate a glitch-free audio experience, using no more bandwidth than required

//CHANGE HISTORY
//0.01 - initial version
//0.02 - removed dependancy from external mp3 header library. please set bitrate manually. auto-detect wasn't reliable anyways
//0.03 - documented some more and cleaned up code a tiny bit. might release it as GPL

//settings, please fill this variables with your own
$mp3="bigstreamfile.mp3";
$bitrate=128;

//adjust for your system. use a unique lock file for each mp3 you serve.
//$tmp="/tmp/${mp3}.posinfo";
$tmp="/tmp/stream1pos";

//Enable debug to get textual output in a browser. The stream is not listenable with debug enabled.
$debug=0; //false; //true;

//disable error reporting if you like
error_reporting (E_ALL);

// NO EDITING REQUIRED BELOW THIS LINE, EDIT AT OWN RESPONSABILITY //

//SUPPORT FUNCTIONS
function writePos() {
global $h, $timekeeper;
$fff=fopen ($tmp, "w");
fputs ($fff, "".ftell ($h)."\n");
fputs ($fff, $timekeeper."\n");
fclose ($fff);
}

//global $buffcache;

function sendBuff($bff) {
print $bff;
flush();
return;
}

function readBuffs($fh) {
$b="";
for ($i = 0; $i<22; $i++) {
$b.=readBuff($fh);
}
return $b;
}

function readBuff($fh) {
global $framesize;
//read from file untill we receive a $FF marker
$m="";
do {
$m=fread($fh, 4);
if (feof($fh))
return "";
//requiring mpeg1 layer 3. Adjust for other containers / chunkmarkers / right here
} while (($m[0]!=chr(255)) || !(($m[1]==chr(250)) || ($m[1]==chr(251))) );
$bl=$framesize-4;
if (ord($m[2]) & 2) //padding
$bl++;
$m.=fread ($fh, $bl);
return $m;
}

//`main()`

$file=$mp3;
if (!file_exists($file))
die();
$framesize=floor (144000.0 * $bitrate / 44100);
$blocksize=16384;
$playspeed=1000.0 * $bitrate / 8.0;
$sleeptime = (1.0 * $blocksize / ($playspeed));

if ($debug)
header ("Content-Type: text/plain");
else {
header ("Content-Type: audio/mpeg");
header ("Content-Transfer-Encoding: binary");
header ("Pragma: no-cache");
header ("icy-br: ".$bitrate);
}

//request unlimited runtime
set_time_limit(0);
if ($debug)
print ("framesize: ".$framesize);

$h=fopen($file, "rb");

if (file_exists ($tmp)) {
//read our position from file.
$ff=fopen ($tmp, "r");
$position=fgets($ff);
$postime=fgets($ff);
fclose ($ff);
}

//increase position by elapsed time for syncing listeners.
if ($postime) {
$elapsed = microtime(true)-$postime;
//we force to float to bypass a 32 bit integer limit
//looping for multiple days if needed (its not an issue)
$position += 1.0 * $elapsed * ($bitrate / 8);
$fs=filesize($file);
while ($position>$fs) {
$position-=$fs;
}
}
fseek ($h, $position);
//send a reasonable buffer to start
for ($j=0; $j<3; $j++) {
$buff=readBuffs($h).readBuffs($h).readBuffs($h);
print $buff;
}

$buff=readBuffs($h);
$timekeeper=microtime(true);
$counter=0;

//main loop:
while (($buff!="") && !connection_aborted()) {
if ($debug) {
echo "Buff size: ".strlen($buff)." first chars: ".ord($buff[0])." ".ord($buff[1])." ".ord($buff[2])." ".ord($buff[3])." file pointer ".ftell($h)."\n";
} else
echo ($buff);
flush();
$counter++;
if (!($counter%30))
writePos();
$bwl=strlen($buff);
$buff=readBuffs($h);
if ($buff=="") {
fseek ($h, 0);
$buff=readBuff($h);
}
$timekeeper=$timekeeper+1.0*$bwl/$playspeed;
time_sleep_until($timekeeper);
}

writePos();
fclose($h);

?>

--[[User:Tano Toll|Tano Toll]] 06:05, 15 October 2011 (PDT)

String Compare

2009-10-17T11:51:25Z

Tano Toll: /* Notes: */

{{LSL Header}}
=== String compare ===
Created by [[User:Xaviar Czervik|Xaviar Czervik]]. Do whatever you wish with this function: Sell it (good luck), use it, or modify it.

The following code returns 1, -1 or 0. The 1 and -1 are essentially random, however it will return the same value every time the script is executed. 0 Is returned when, and only when, the strings are exactly equal. Completely re-designed to use a few tricks I learned in the past months. Also much easier to read now.

I have used this script for comparing the [[Key|Keys]] of two objects in a dynamic set of sensors, to decide which one should be the "Master" in the region to tell me information. I'm sure there can be more uses to this...

<lsl>
integer compare(string s1, string s2) {
if (s1 == s2) {
return 0;
} else if (llStringLength(s1) < llStringLength(s2)) {
return 1;
} else if (llStringLength(s1) > llStringLength(s2)) {
return -1;
} else {
list l = [s1, s2];
l = llListSort(l, 0, 1);
if (s1 == llList2String(l, 0))
return 1;
return -1;
}
}
</lsl>

=== Notes: ===
I'm not sure why the string length comparison is in above function, it is not needed for string comparison functions where you rely on alphabetical order. The concept is nice though. I've modified this function. Given strings s1 and s2, it'l return 1 if s1>s2, -1 if s1<s2 and 0 if they are equal:

<lsl>
integer compare(string s1, string s2) {
if (s1 == s2) {
return 0;
} else {
list l = [s1, s2];
l = llListSort(l, 1, FALSE);
if (s1 == llList2String(l, 0)) //s1>s2
return 1;
return -1;
}
}
</lsl>
Above function not extensively tested, but it seems to suit my purpose (having users enter a set of characters within certain range, filter out anything else since it will be submitted to a webpage).
If only linden would give us 'normal' string comparison functions like any other language, instead of spending expensive cpu cycles to validate user input.

{{LSLC|Library}}
{{LSLC|Examples}}

String Compare

2009-10-17T11:46:36Z

Tano Toll: /* String compare */

{{LSL Header}}
=== String compare ===
Created by [[User:Xaviar Czervik|Xaviar Czervik]]. Do whatever you wish with this function: Sell it (good luck), use it, or modify it.

The following code returns 1, -1 or 0. The 1 and -1 are essentially random, however it will return the same value every time the script is executed. 0 Is returned when, and only when, the strings are exactly equal. Completely re-designed to use a few tricks I learned in the past months. Also much easier to read now.

I have used this script for comparing the [[Key|Keys]] of two objects in a dynamic set of sensors, to decide which one should be the "Master" in the region to tell me information. I'm sure there can be more uses to this...

<lsl>
integer compare(string s1, string s2) {
if (s1 == s2) {
return 0;
} else if (llStringLength(s1) < llStringLength(s2)) {
return 1;
} else if (llStringLength(s1) > llStringLength(s2)) {
return -1;
} else {
list l = [s1, s2];
l = llListSort(l, 0, 1);
if (s1 == llList2String(l, 0))
return 1;
return -1;
}
}
</lsl>

=== Notes: ===
I'm not sure why the string length comparison is in above function, it is not needed. The concept is nice though. I've modified this function. Given strings s1 and s2, it'l return 1 if s1>s2, -1 if s1<s2 and 0 if they are equal:
<lsl>
integer compare(string s1, string s2) {
if (s1 == s2) {
return 0;
} else {
list l = [s1, s2];
l = llListSort(l, 1, FALSE);
if (s1 == llList2String(l, 0)) //s1>s2
return 1;
return -1;
}
}
</lsl>
{{LSLC|Library}}
{{LSLC|Examples}}