LlGetNotecardLine

2010-06-01T08:11:27Z

Topaz Emerald:

{{LSL_Function/negative_index|false|line}}{{LSL_Function/notecard|name|uuid=true}}{{LSL_Function
|func_id=217|func_sleep=0.1|func_energy=10.0
|sort=GetNotecardLine
|func=llGetNotecardLine
|return_type=key
|p1_type=string|p1_name=name
|p2_type=integer|p2_name=line|p2_desc=Line number in a notecard (the index starts at zero).
|func_desc=Requests the line '''line''' of the notecard '''name''' from the dataserver.
|return_text=that is the handle for a [[dataserver]] event response.
|func_footnote=If '''line''' is past the end of the notecard [[EOF]] is returned by the [[dataserver]].
|spec
|caveats=* If notecard contains embedded inventory items (such as textures and landmarks), [[EOF]] will be returned, regardless of the line requested.
*If the requested line is longer then 255 bytes the [[dataserver]] will return the first 255 bytes of the line.
|constants
|examples=<lsl>
key kQuery;
integer iLine = 0;
default {

state_entry() {
llSay(0, "Reading notecard...");
kQuery = llGetNotecardLine("My Notecard", iLine); // read in "My Notecard" when you can
}

dataserver(key query_id, string data) {

if (query_id == kQuery) { // were we called to work on "My Notecard"?
// this is a line of our notecard
if (data == EOF) {

llSay(0, "No more lines in notecard, read " + (string)iLine + " lines.");

} else {

llSay(0, "Line " + (string)iLine + ": " + data); // data has the current line from this notecard

//request next line
iLine++; // increment line count
kQuery = llGetNotecardLine("My Notecard", iLine); // read another line when you can

}
}
}
}
</lsl>
|helpers=
<lsl>
/////
// Generic Multi Notecard reader by Brangus Weir
// Given freely and published on wiki.secondlife.com
//
// This script will read three note cards and store the results into three lists.
// It can be modified and extended to as many (or few) cards as you'd like to read.
//

list gOneCard; // All the lines from from the first card
list gTwoCard; // All the lines from from the second card
list gThreeCard; // All the lines from from the third card

string gsCardOneName = "One"; //Set these to the name of the invetory item.
string gsCardTwoName = "Two";
string gsCardThreeName = "Three";

//Temporary variables for processing
string g_sNoteCardName; // Name of the card to be read.
list g_lTempLines; // The resulting data pushed into a list
integer g_iLine; // The line count for the card reader
key g_kQuery; // The key of the card being read

initialize(string _action) {
// Due to the execution order when using dataserver, this function sets the first card to
// be read, and the excetuion finishes when called again with the _action set to "finish".
if (_action == "") {
loadNoteCard(gsCardOneName);
} else if (_action == "finish") {
// All cards have been read into the lists... now you can do any kind of string
// manipulations to get the data you need to set your script.
// But here we will prove that the cards have been read with a loop

g_lTempLines = []; // lets not forget to delete this global, or it will be dead weight.

integer len = llGetListLength(gOneCard); //Always evaluate this once, don't do it
//INSIDE the for loop like noob programers will.
//Reduce lag, THINK ABOUT MACHINE CYCLES!
integer i = 0;
for (; i< len; ++i)
llSay(0, llList2String(gOneCard,i));

len = llGetListLength(gTwoCard);
for (i = 0; i< len; ++i)
llSay(0, llList2String(gTwoCard,i));

len = llGetListLength(gThreeCard);
for (i = 0; i< len; ++i)
llSay(0, llList2String(gThreeCard,i));
}

}

loadNoteCard( string _notecard ) {
g_lTempLines = []; //clear the temp lines
g_sNoteCardName = _notecard;
g_iLine = 0;
g_kQuery = llGetNotecardLine(g_sNoteCardName, g_iLine);

}

notecardFinished(string _notecard){
// Called at the end of each notecard as it is read. The temp results are stored
// and the next card is commanded to be read.
if (_notecard == gsCardOneName) {
gOneCard = g_lTempLines;
loadNoteCard(gsCardTwoName);
} else if (_notecard == gsCardTwoName) {
gTwoCard = g_lTempLines;
loadNoteCard(gsCardThreeName);
} else if (_notecard == gsCardThreeName) {
gThreeCard = g_lTempLines;
initialize("finish"); // Finally pass execution to finish the initialization.
}
}

default
{
state_entry()
{
}

touch_start(integer _num_det){
initialize("");
}

dataserver(key _query_id, string _data)
{
if (_query_id == g_kQuery) {
// this is a line of our notecard
if (_data != EOF) {
g_lTempLines += _data;
//request a next line
++g_iLine; // increment line count
g_kQuery = llGetNotecardLine(g_sNoteCardName, g_iLine);
} else {
//The notecard has been read
//notify end of read
notecardFinished(g_sNoteCardName);
}
}
}
}
</lsl>

<lsl>
/////
// Generic Multi Notecard reader by Randur Source
// Given freely and published on wiki.secondlife.com
//
// This script will read all note cards in sequence and dump the results into chat as an example.
// It can be modified and extended to do other things to the data.
//

integer inventorycnt;
integer notecardlinecnt;
integer notecardlinenumber;
string notecardname;
key linenumberid;
key lineid;

getnextnotecardlinenumber()
{
// first get the number of lines from the notecard
inventorycnt++;
if (inventorycnt < llGetInventoryNumber(INVENTORY_NOTECARD))
{
notecardname = llGetInventoryName(INVENTORY_NOTECARD,inventorycnt);
linenumberid = llGetNumberOfNotecardLines(notecardname);
}
else
llOwnerSay("Done.");
}

getnextnotecardline()
{
// get the next line from the notecard or skip to the next notecard
notecardlinecnt++;
if (notecardlinecnt < notecardlinenumber)
lineid = llGetNotecardLine(notecardname,notecardlinecnt);
else
getnextnotecardlinenumber();
}

default
{
touch_start(integer total_number)
{
if (llDetectedKey(0) != llGetOwner()) return; // allow owner only

inventorycnt = -1;
getnextnotecardlinenumber();
}

dataserver(key queryid,string data)
{
if (queryid == linenumberid) // this was a line number lookup
{
linenumberid = NULL_KEY;
notecardlinenumber = (integer)data;
if (notecardlinenumber == 0)
getnextnotecardlinenumber();
else
{
notecardlinecnt = -1;
getnextnotecardline();
}
}
else if (queryid == lineid) // this was a data line lookup
{
lineid = NULL_KEY;

// Example of what to do with the data:
// Test for valid avatar names, possibly multiple names on each line, separated by ,
// and say them in chat to the owner
list names = llParseString2List(data,[","],[]); // split lines on ,
integer len = llGetListLength(names); // I wouldn't dare to put this inside the for loop
integer cnt;
for (cnt = 0; cnt < len; cnt++)
{
string name = llDumpList2String(llParseString2List(llList2String(names,cnt),[" "],[])," "); // remove extra spaces
if (llGetListLength(llParseString2List(name,[" "],[])) == 2) // check for first + lastname
llOwnerSay(notecardname + ": " + name);
}

getnextnotecardline();
}
}
}

</lsl>
|also_functions={{LSL DefineRow||[[llGetNumberOfNotecardLines]]|}}
|also_events={{LSL DefineRow||[[dataserver]]|}}
|also_articles
|also_tests
|notes=The notecard read can be no modify, or no modify/no copy.
|permission
|cat1=Notecard
|cat2=Dataserver
|cat3=
|cat4=
<lsl>
// by Randur Source

integer inventorycnt;
integer notecardlinecnt;
integer notecardlinenumber;
string notecardname;
key linenumberid;
key lineid;

getnextnotecardlinenumber()
{
inventorycnt++;
if (inventorycnt < llGetInventoryNumber(INVENTORY_NOTECARD))
{
notecardname = llGetInventoryName(INVENTORY_NOTECARD,inventorycnt);
linenumberid = llGetNumberOfNotecardLines(notecardname);
}
else
llOwnerSay("Done.");
}

getnextnotecardline()
{
notecardlinecnt++;
if (notecardlinecnt < notecardlinenumber)
lineid = llGetNotecardLine(notecardname,notecardlinecnt);
else
getnextnotecardlinenumber();
}

default
{
touch_start(integer total_number)
{
if (llDetectedKey(0) != llGetOwner()) return; // owner only

inventorycnt = -1;
getnextnotecardlinenumber();
}

dataserver(key queryid,string data)
{
if (queryid == linenumberid)
{
linenumberid = NULL_KEY;
notecardlinenumber = (integer)data;
if (notecardlinenumber == 0)
getnextnotecardlinenumber();
else
{
notecardlinecnt = -1;
getnextnotecardline();
}
}
else if (queryid == lineid)
{
lineid = NULL_KEY;
// Test for valid names, possibly multiple names on each line, separated by ,
list names = llParseString2List(data,[","],[]); // split lines on ,
integer cnt;
for (cnt = 0; cnt < llGetListLength(names); cnt++)
{
string name = llDumpList2String(llParseString2List(llList2String(names,cnt),[" "],[])," "); // remove extra spaces
if (llGetListLength(llParseString2List(name,[" "],[])) == 2) // check for first + lastname
llOwnerSay(notecardname + ": " + name);
}
getnextnotecardline();
}
}
}
</lsl>
}}

Second Life Wiki - User contributions [en]

LlGetNotecardLine