View source for Changed

{{LSL_Event|event_id=30
|event_delay
|event=changed
|p1_type=integer
|p1_name=change 
|p1_desc=[[bit field]] of CHANGED_* flags
|event_footnote=Multiple changes can be represented in a single event, so use bitwise arithmetic.
|event_desc=Various changes to the object/prim trigger this event.
|constants={{LSL Constants Changed}}
|spec
|caveats=
|helpers
|also_header
|also_events
|also_functions
|also_articles
|also_footer
|mode
|notes=
*Always test the value of '''change''', e.g. <code>if(change & CHANGED_INVENTORY){DoStuff();}</code>. New return values and cases could conceivably be added at any time and this list may not in-fact be complete. Scripts should be written under the assumption that they may receive a value they won't recognize.
*See [[llGetOwner]] for a full discussion on " (change & CHANGED_OWNER) "
*If leaving a [[state]] from within a changed event that registers a change just before the [[state]] change, on return to that state the changed event will trigger. For example -
<lsl>default
{
    changed(integer change)
    {
        if(change & CHANGED_LINK)
        {
            integer links = 0;
            if(llGetObjectPrimCount(llGetKey()) < (links = llGetNumberOfPrims()))
            {
                llUnSit(llGetLinkKey(links));
                state whatever;
            }
            else
            llOwnerSay("Some kind of linking or unlinking has changed me but, I am not being sat on.");
            // This will be chatted after returning to the default state.
        }
    }
}
state whatever
{
    state_entry()
    {
        llSetTimerEvent(10.0);
    }
    timer()
    {
        state default;
    }
}</lsl>
|examples=<lsl>default
{
    changed(integer change)
    {
        //note that it's & and not &&... it's bitwise!
        if (change & CHANGED_INVENTORY)         
        {
            llOwnerSay("The inventory has changed.");
        }
        if (change & CHANGED_COLOR) 
        {
            llOwnerSay("The color or alpha changed.");
        }
        if (change & CHANGED_SHAPE) 
        {
            llOwnerSay("The prims shape has changed.");
        }
        if (change & CHANGED_SCALE) 
        {
            llOwnerSay("The prims size has changed.");
        }
        if (change & CHANGED_TEXTURE) 
        {
            llOwnerSay("The prims texture or texture attributes have changed.");
        }
        if (change & CHANGED_LINK) 
        {
            llOwnerSay("The number of links have changed.");
        }
        if (change & CHANGED_ALLOWED_DROP) 
        {
            llOwnerSay("The inventory has changed as a result of a user without mod permissions "+
                       "dropping an item on the prim and it being allowed by the script.");
        }
        if (change & CHANGED_OWNER) 
        {
            llOwnerSay("The owner of the object has changed.");
        }
        if (change & CHANGED_REGION) 
        {
            llOwnerSay("The region the object is in has changed.");
        }
        if (change & CHANGED_TELEPORT) 
        {
            llOwnerSay("The object has been teleported while attached.");
        }
        if (change & CHANGED_REGION_START) 
        {
            llOwnerSay("The regions has just restarted.");
        }
    }
}</lsl>For the same action to be called for multiple changes we can use the following syntax.<lsl>default
{
    changed(integer change)
    {
        if(change & (CHANGED_OWNER | CHANGED_INVENTORY)) // Either of the changes will return true.
            llResetScript();
    }
}</lsl>
|deprecated
|cat1=Inventory
|cat2=Script
|cat3=Color
|cat4=Alpha
|cat5=Texture
|cat6=Link
|cat7=Sit
|cat8=Link/Management
}}{{LSLC|Region}}{{LSLC|Owner}}{{LSLC|Prim}}