View source for LlCastRay/ja

{{LSL_Function/ja
|inject-2={{Issues/VWR-1331}}
|func=llCastRay
|func_id=?
|func_sleep
|func_energy

|func_desc=関数は、指定された開始位置 {{LSLP|start}} から終了位置 {{LSLP|end}} までの線分を投射し、物体のデータを取得します。

|return_type=list
|return_text=ヒットがあった場合、成功したヒットごとにキー (uuid) と位置 (position) の 2 つの必須の値を含むストライド値のリストが返され、最後に追加の整数の [[#status_code|status_code]] が含まれます。ストライドは、オプションで link_number と normal を含むことができます（詳細は[[#RC_DATA_FLAGS|RC_DATA_FLAGS]]を参照）。status_code が負であればエラーコードであり、それ以外の場合はヒット数（およびストライド数）です。
|func_footnote=
例（デフォルトオプションの成功したレイキャスト）:
<syntaxhighlight lang="lsl2">
[key object_uuid, vector hit_position, integer status_code]
</syntaxhighlight>
エラーまたは何もヒットしなかった場合の例:
<syntaxhighlight lang="lsl2">
[integer status_code]
</syntaxhighlight>
|p1_type=vector|p1_name=start|p1_desc=starting location 
|p2_type=vector|p2_name=end|p2_desc=ending location 
|p3_type=list|p3_subtype=instructions|p3_name=options|p3_desc=can consists of any number of [[#options|option flag]]s and their parameters.
|constants
|caveats=*{{LSLP|flags}} の値によって（[[#RC_DATA_FLAGS|RC_DATA_FLAGS]]を介して提供される）、ストライド内の値の数とタイプが異なります。詳細は[[#RC_DATA_FLAGS|RC_DATA_FLAGS]]を参照してください。
*[[llGetRot/ja]] はビューアがしきい値以下でアバターの回転を更新しないため、アバターの正確な視覚的な回転を返しません（{{jira|VWR-1331}}を参照）。マウスルック中のアバターの正確な見ている方向を取得するには、代わりに[[llGetCameraRot/ja]]を使用してください。
*[[llCastRay/ja]] は物理形状がないプリム（[[PRIM_PHYSICS_SHAPE_TYPE]] = [[PRIM_PHYSICS_SHAPE_NONE]]）を検出しません。
*[[llCastRay/ja]] は、レイがプリムの内部で始まる場合、そのプリムを検出しません。これにより、プリムの位置を安全に開始位置として使用できます。
*[[llCastRay/ja]] は、開始位置がプリムの外部にある場合、スクリプトが含まれているプリムを検出できます。
この関数の結果は、「エンドポイントが範囲外の場合には信頼性がない」とされています（オブジェクトのヒット数に関係なく、時折ステータスコード0を返すことがあります）。詳細は[https://community.secondlife.com/forums/topic/486603-llcastray-returning-zero-hits-seemingly-at-random/このフォーラム投稿]を参照してください。
|spec=
===={{LSL Param|status_code}}====

{{LSLP|status_code}} は、ストライドリストの末尾に追加される数値で、レイキャストに関する追加情報を提供します。

レイキャストが成功した場合、status_code は0以上になり、ヒット数を示します。

レイキャストが失敗した場合（現時点ではシミュレータのパフォーマンスが低い場合のみ）、status_code は負の値になります。シミュレータ全体の物理時間が高すぎてレイキャストを実行できない場合、RCERR_SIM_PERF_LOW がステータスコードとして使用されます。アイデアは、数フレーム後に再試行する必要があることを知らせることです。

<table class="lltable" border="1" id="error_code">
<caption>'''status_code''' error codes and their meanings.</caption>
<tr>
<th>Status Code</th>
<th title='Value'>V</th>
<th>Description</th>
</tr>
<tr><td>{{LSL Const|RCERR_UNKNOWN|integer|-1}}</td><td>{{#var:value}}</td><td>The raycast failed for an unspecified reason. Please submit a bug report.</td></tr>
<tr><td>{{LSL Const|RCERR_SIM_PERF_LOW|integer|-2}}</td><td>{{#var:value}}</td><td>The raycast failed because simulator performance is low. Wait a while and then try again. If possible reduce the scene complexity.</td></tr>
<tr><td>{{LSL Const|RCERR_CAST_TIME_EXCEEDED|integer|-3}}</td><td>{{#var:value}}</td><td>The raycast failed because the parcel or agent has exceeded the maximum time allowed for raycasting. This resource pool is continually replenished, so waiting a few frames and retrying is likely to succeed.</td></tr>
</table>

=====[[RCERR_CAST_TIME_EXCEEDED]]=====
'''注意:''' [https://jira.secondlife.com/browse/SCR-199 SCR-199] によれば、プールはメイングリッドから削除されたため、このリターンコードは現れないはずです。

'''効率的なレイキャストのためのヒント:'''

*返される最大ヒット数をできるだけ小さく保つ
*制御可能な因子の[[RC_REJECT_TYPES]]をできるだけ設定する（これはおそらく最も影響が大きいでしょう）。たとえば、レイに沿って最も近いエージェントの位置のみを知りたい場合は、<code>[[RC_REJECT_LAND]] {{!}} [[RC_REJECT_PHYSICAL]] {{!}} [[RC_REJECT_NONPHYSICAL]]</code> を使用します。
*可能な限り、プリムの山を通過したり、凹凸のある物理オブジェクトに対してレイキャストを避けるようにします（カット、中空、ねじれなどがあるもの、および分解がなく物理型が「prim」のメッシュオブジェクトなど）。明らかにこれを常に避けることはできませんので、一部のキャストは他のものよりもかなり長くかかるかもしれません。[[RCERR_CAST_TIME_EXCEEDED]] を適切に処理する堅牢なスクリプトを使用して、呼び出しの直後に短時間スリープし、再試行する前に数フレーム待つように計画します。
==== {{LSL Param|options}} parameter ====

<table class=lltable border=1 id="options">
<caption>{{LSLP|options}} flags and their parameters</caption>
<tr>
<th>Flag</th>
<th title='Value'>V</th>
<th>Parameters</th>
<th>Default Value</th>
<th>Description</th>
</tr>
<tr><td>[&nbsp;{{LSL Const|RC_REJECT_TYPES|integer|0}}&nbsp;] </td>
<td>{{#var:value}}</td>
<td>[&nbsp;[[integer]]&nbsp;{{LSLPT|filter}}&nbsp;]</td>
<td>[ 0 ]</td>
<td> Mask used to ignore specific types of objects (and avatars). </td>
</tr>
<tr><td>[&nbsp;{{LSL Const|RC_DATA_FLAGS|integer|2}}&nbsp;] </td>
<td>{{#var:value}}</td>
<td>[&nbsp;[[integer]]&nbsp;{{LSLPT|flags}}&nbsp;]</td>
<td>[ 0 ]</td>
<td> Described in the [[#RC_DATA_FLAGS|RC_DATA_FLAGS]] section. </td>
</tr>
<tr><td>[&nbsp;{{LSL Const|RC_MAX_HITS|integer|3}}&nbsp;] </td>
<td>{{#var:value}}</td>
<td>[&nbsp;[[integer]]&nbsp;{{LSLPT|max_hits}}&nbsp;]</td>
<td>[ 1 ]</td>
<td> Maximum number of hits to return. Maximum value is 256. ''To avoid performance issues, keep it small.''</td>
</tr>
<tr><td>[&nbsp;{{LSL Const|RC_DETECT_PHANTOM|integer|1}}&nbsp;] </td>
<td>{{#var:value}}</td>
<td>[&nbsp;[[integer]]&nbsp;{{LSLPT|detect_phantom}}&nbsp;]</td>
<td>[ [[FALSE]] ]</td>
<td>Set to [[TRUE]] (or nonzero) to detect phantom AND volume detect objects. It is not possible to detect only phantom objects or only volume detect objects. If set to [[TRUE]], phantom and volume detect objects will always be detected, even if [[RC_REJECT_NONPHYSICAL]] and [[RC_REJECT_PHYSICAL]] are set in [[RC_REJECT_TYPES]].</td>
</tr>
</table>

=====[[RC_REJECT_TYPES]]=====

{{LSLP|filter}} is a bitwise-or combination of the following constants: [[RC_REJECT_AGENTS]], [[RC_REJECT_PHYSICAL]], [[RC_REJECT_NONPHYSICAL]], and [[RC_REJECT_LAND]].

<table class="lltable" border="1" id="rc_reject_flags">
<caption>'''RC_REJECT_TYPES''' and their meanings.</caption>
<tr>
<th>Reject Type</th>
<th title='Value'>V</th>
<th>Description</th>
</tr>
<tr><td>{{LSL Const|RC_REJECT_AGENTS|integer|1}}</td><td>{{#var:value}}</td><td>Avatars won't be detected.</td></tr>
<tr><td>{{LSL Const|RC_REJECT_PHYSICAL|integer|2}}</td><td>{{#var:value}}</td><td>[https://wiki.secondlife.com/wiki/Physical Physical] objects won't be detected.</td></tr>
<tr><td>{{LSL Const|RC_REJECT_NONPHYSICAL|integer|4}}</td><td>{{#var:value}}</td><td>The opposite of the above flag. Objects without physics won't be detected. For phantom objects, see [[RC_DETECT_PHANTOM]].</td></tr>
<tr><td>{{LSL Const|RC_REJECT_LAND|integer|8}}</td><td>{{#var:value}}</td><td>Land won't be detected. This refers to actual [https://wiki.secondlife.com/wiki/LlGround ground] only.</td></tr>
</table>

If you reject everything, a script runtime error will be generated (as it makes no sense to do this). Using 0 as the filter value will accept all types (default).

Also note that seated agents are treated like unseated agents. As in, you either get seated and unseated agents in your results, or you use [[RC_REJECT_AGENTS]] and get neither.

=====[[RC_DATA_FLAGS]]=====

{{LSLP|flags}} is a bitwise-or combination of: [[RC_GET_NORMAL]], [[RC_GET_ROOT_KEY]], and [[RC_GET_LINK_NUM]].

<table class="lltable" border="1" id="rc_data_flags">
<caption>'''RC_DATA_FLAGS''' and their meanings.</caption>
<tr>
<th>Data Flag</th>
<th title='Value'>V</th>
<th>Description</th>
</tr>
<tr><td>{{LSL Const|RC_GET_NORMAL|integer|1}}</td><td>{{#var:value}}</td><td>Stride includes the surface normal that was hit.</td></tr>
<tr><td>{{LSL Const|RC_GET_ROOT_KEY|integer|2}}</td><td>{{#var:value}}</td><td>The hit {{LSLP|uuid}} will be replaced by the object's root instead of any child.</td></tr>
<tr><td>{{LSL Const|RC_GET_LINK_NUM|integer|4}}</td><td>{{#var:value}}</td><td>Stride includes the link number that was hit.</td></tr>
</table>

|examples=
<syntaxhighlight lang="lsl2">
integer filter;// default is 0

default
{
    state_entry()
    {
        string ownerName = llKey2Name(llGetOwner());
        llOwnerSay("Hello, " + ownerName + "!");
    }

    touch_start(integer total_number)
    {
        vector start = llGetPos();
        vector end = start - <0.0, -25.0, 0.0>;

        if ( filter > 8 )
            filter = 0;

        llOwnerSay("Filter " + (string)filter);

        list results = llCastRay(start, end, [RC_REJECT_TYPES, filter, RC_MAX_HITS, 4] );

        integer hitNum = 0;
        // Handle error conditions here by checking llList2Integer(results, -1) >= 0
        while (hitNum < llList2Integer(results, -1))
        {
            // Stride is 2 because we didn't request normals or link numbers
            key uuid = llList2Key(results, 2*hitNum);

            string name = "Land"; // if (uuid == NULL_KEY)

            if (uuid != NULL_KEY)
                name = llKey2Name(uuid);

            llOwnerSay("Hit " + name + ".");

            ++hitNum;
        }

        ++filter;
    }
}</syntaxhighlight>
<syntaxhighlight lang="lsl2">

// Fire a weapon at a target, report a hit

integer gTargetChan = -9934917;

default
{
    attach(key id)
    {
        if (id != NULL_KEY)
        { 
            llRequestPermissions(id,PERMISSION_TAKE_CONTROLS|PERMISSION_TRACK_CAMERA);
        }
    }

    run_time_permissions (integer perm)
    {
        if (perm & PERMISSION_TAKE_CONTROLS|PERMISSION_TRACK_CAMERA) 
        {
            llTakeControls(CONTROL_LBUTTON|CONTROL_ML_LBUTTON,TRUE,FALSE);
        }
    }

    control (key id, integer level, integer edge)
    {
        // User must be in mouselook to aim the weapon
        if (level & edge & CONTROL_LBUTTON)
        {
            llSay(0,"You must be in Mouselook to shoot.  Type \"CTRL + M\" or type \"Esc\" and scroll your mouse wheel forward to enter Mouselook.");
        }
        // User IS in mouselook        
        if (level & edge & CONTROL_ML_LBUTTON)
        {
            vector start = llGetCameraPos();
            // Detect only a non-physical, non-phantom object. Report its root prim's UUID.
            list results = llCastRay(start, start+<60.0,0.0,0.0>*llGetCameraRot(),[RC_REJECT_TYPES,RC_REJECT_PHYSICAL|RC_REJECT_AGENTS|RC_REJECT_LAND,RC_DETECT_PHANTOM,FALSE,RC_DATA_FLAGS,RC_GET_ROOT_KEY,RC_MAX_HITS,1]);
            llTriggerSound(llGetInventoryName(INVENTORY_SOUND,0),1.0);
            llSleep(0.03);
            key target = llList2Key(results,0);
            // Tell target that it has been hit. 
            llRegionSayTo(target,gTargetChan,"HIT");
            // Target, scripted to listen on gTargetChan, can explode, change color, fall over .....
        }
    }            
}
</syntaxhighlight>
|notes=
Use [[llDumpList2String]] to see what the output looks like when you try a new set of flags.

To quickly get the status code use <code>[[llList2Integer]](result, -1)</code>.

'''使い方のアイデア''':

*'''武器''' - レイキャストは、プロジェクタイル武器をシミュレートするためのゲーム開発で伝統的に使用されるツールです。これは、プリムをレザリングして武器から発射するよりもはるかに効率的です。
*'''AIオブジェクト''' - アバターや他のオブジェクトの視線検出、または自分自身を中心にレイを追跡して環境を移動するためのツールとして使用されます。例えば、現在の床の表面の高さと角度（法線）を判定するために、直接下向きにレイをキャストして、非物理的なオブジェクトの移動に役立ちます。
*'''インテリジェントなオブジェクト配置''' - 静的なオブジェクトはシーンに配置されますが、環境に合わせて自己調整します。例えば、高い位置にレザリングされたオブジェクトは、その高さを床のレベルに調整したり、低い位置に配置されたコンピュータコンソールは、立ってではなく膝をついて使用するようにアバターに影響を与えたりします。
*'''環境分析''' - 周囲のエリアの制限を判定するために使用できます。例えば、オブジェクトが閉じられた部屋内に配置されているかどうかを判定することができます。頻繁に実行するべきではないテストですが、部屋内に誰もいない場合は効果をオフにするためにオブジェクトによって使用されたりします。家具やオブジェクトを自動調整して壁、床、天井にスナップすることがあります。
|cat1=Physics
|cat2=Light
|history = *Date of Release  [[ Release_Notes/Second_Life_Server/11#11.09.23.241511 | 23/09/2011 ]]
* {{jira|SCR-199}} - fixed - The throttle was too low and thus rendered the function not as useful as it could be.
}}