View source for LlGetNotecardLine/ja

{{LSL_Function/negative_index/ja|false|line}}{{LSL_Function/notecard/ja|name|uuid=true}}{{LSL_Function/ja
|func_id=217|func_sleep=0.1|func_energy=10.0
|sort=GetNotecardLine
|func=llGetNotecardLine
|return_type=key
|p1_type=string|p1_name=name
|p2_type=integer|p2_name=line|p2_desc=ノートカードでの行数 (先頭行は 0 行目です)
|func_desc=ノートカード '''name''' の '''line''' 行目の内容を dataserver イベントを介して問い合わせる。
|return_text={{LSLG/ja|dataserver}} イベントの応答に対応するハンドルのキー
|func_footnote='''line''' がノートカードの末尾を超えている場合 {{LSLG/ja|dataserver}} イベントにて {{LSLG/ja|EOF}} が返されます。
|spec
|caveats=* ノートカードにインベントリのアイテム (テクスチャやランドマークといったもの) が貼り付けられていた場合は、何行目を問い合わせようとも {{LSLG/ja|EOF}} が返ります。
* 問い合わされた行の長さが 255 バイトを超えた場合、{{LSLG/ja|dataserver}} イベントには先頭の 255 バイトだけ渡されます。
|constants
|examples=<lsl>
key kQuery;
integer iLine = 0;
default {
    
    state_entry() {
        llSay(0, "Reading notecard...");
        // 可能ならば "My Notecard" を読む
        kQuery = llGetNotecardLine("My Notecard", iLine);
    }

    dataserver(key query_id, string data) {

        if (query_id == kQuery) {    // 確かに "My Notecard" の処理という事でよいか?
            // 対象となるノートカードの行
            if (data == EOF) {    

                llSay(0, "ノートカードの末尾です。" + (string)iLine + " 行読みました。");

            } else {

                // data にはノートカードの行内容が入っている
                llSay(0, "Line " + (string)iLine + ": " + data);
                
                // 次の行を問い合わせる
                iLine++;   // 行カウンタを増やす
                kQuery = llGetNotecardLine("My Notecard", iLine);   // 可能なら次の行を読む

            }
        }
    }
}
</lsl>
|helpers=
<lsl>
/////
//  Generic Multi Notecard reader by Brangus Weir
//  Given freely and published on wiki.secondlife.com
//
//  三個のノートカードを読み、結果を三個の list 変数へ格納します。
//  ノートカードの個数は、必要に応じて変更できます。
//


list gOneCard;    // 一番目のノートカードの全ての行
list gTwoCard;    // 二番目のノートカードの全ての行
list gThreeCard;  // 三番目のノートカードの全ての行

string gsCardOneName = "One";  // 実際のノートカード名に置き換えてください
string gsCardTwoName = "Two";
string gsCardThreeName = "Three";

// 処理用のテンポラリ変数
string g_sNoteCardName; // 読むノートカードの名前
list g_lTempLines;      // list 変数へ追加するデータ
integer g_iLine;        // 問い合わせに使う行カウンタ
key g_kQuery;           // 問い合わせに使うキー


initialize(string _action) {
    // dataserver を用いる際の実行順により、この関数は最初のノードから読み始め、
    // 再度呼ばれたときに _action が "finish" だった場合は実行を終了します。
    // 

    if (_action == "") {
        loadNoteCard(gsCardOneName);
    } else if (_action == "finish") {
        // 全てのノートカードを list 変数へ読み込んだので、必要な文字列操作を開始できます。
        // ここでは読んだ内容をループを使って出力します。

        // 変数宣言は一度で済ませます。ループの中で宣言するとラグの原因になります。
        integer end = llGetListLength(gOneCard);
        integer i = 0;
        for (; i< end; ++i)
            llSay(0, llList2String(gOneCard,i));
        end = llGetListLength(gTwoCard);
        for (i = 0; i< end; ++i)
            llSay(0, llList2String(gTwoCard,i));
        end = llGetListLength(gThreeCard);
        for (i = 0; i< end; ++i)
            llSay(0, llList2String(gThreeCard,i));
    }

}

loadNoteCard( string _notecard ) {
    g_lTempLines = []; // 処理用のテンポラリ変数を空にします
    g_sNoteCardName = _notecard;
    g_iLine = 0;
    g_kQuery = llGetNotecardLine(g_sNoteCardName, g_iLine);
    
}

notecardFinished(string _notecard){
    // 各々のノートカードが読み終わった際に呼ばれます。テンポラリ変数内容が
    // 本来の list 変数へ移され、次のノードカード読み込みに移ります。
    if (_notecard == gsCardOneName) {
        gOneCard = g_lTempLines;
        loadNoteCard(gsCardTwoName);
    } else if (_notecard == gsCardTwoName) {
        gTwoCard = g_lTempLines;
        loadNoteCard(gsCardThreeName);
    } else if (_notecard == gsCardThreeName) {
        gThreeCard = g_lTempLines;
        initialize("finish");  // 読み込みが終わった旨を伝える
    }
}

default
{
    state_entry()
    {
    }
    
    touch_start(integer _num_det){
        initialize("");
     
    }
     
    dataserver(key _query_id, string _data) 
    {
        if (_query_id == g_kQuery) {
            // ノートカードの行
            if (_data != EOF) {
                g_lTempLines += [_data];
                //次の行を問い合わせる
                g_iLine++;  // 行カウンタを増やす
                g_kQuery = llGetNotecardLine(g_sNoteCardName, g_iLine);
            } else {
                // ノートカードを末尾まで読み終わったので、その旨を伝える
                notecardFinished(g_sNoteCardName);
                
            }
        }
    }
}
</lsl>
|also_functions={{LSL DefineRow||{{LSLG/ja|llGetNumberOfNotecardLines}}|}}
|also_events={{LSL DefineRow||{{LSLG/ja|dataserver}}|}}
|also_articles
|also_tests
|notes=処理対象のノートカードは modify あるいは no modify/no copy でも構いません。
|permission
|cat1=Notecard/ja
|cat2=Dataserver/ja
|cat3=
|cat4=
}}