View source for Int2Hex

{{LSL Header|[[:Category:LSL_User-Defined_Functions|User-Defined Functions]]|[[User:Void_Singer|Void's User Page]]}} <!-- please do not remove added links -->
<div style="float:right;">__TOC__</div>
{{void-box
|title=<div style="display:none"><h2>Summary</h2></div>[[:Category:LSL_User-Defined_Functions|User-Defined Function]]: [[string]] uInteger2Hexadecimal( [[integer]] ''vIntBit'' );
|content=
Returns a string that is ''vIntBit'' converted to hexadecimal
* ''vIntBit'': source integer to convert


<h3>Terse</h3>
'''(Leading zeros removed)'''
* LSO: 134 bytes
* MONO: 512 bytes
<!-- Please replace with similarly licensed code only -->
<source lang="lsl2">string uInteger2Hexadecimal( integer vIntBit ){
    string  vStrRtn;
    do{
        vStrRtn = llGetSubString( "0123456789ABCDEF", vIntBit & 0x0000000F, vIntBit & 0x0000000F ) + vStrRtn;
    }while (vIntBit = vIntBit >> 4 & 0x0FFFFFFF);
    return vStrRtn;
}
/*//--                       Anti-License Text                         --//*/
/*//     Contributed Freely to the Public Domain without limitation.     //*/
/*//   2010 (CC0) [ http://creativecommons.org/publicdomain/zero/1.0 ]   //*/
/*//  Void Singer [ https://wiki.secondlife.com/wiki/User:Void_Singer ]  //*/
/*//--                                                                 --//*/</source>

<h3>Labeled Terse</h3>
'''("0x" prefix, Leading zeros removed)'''
* LSO: 140 bytes
* MONO: 512 bytes
<!-- Please replace with similarly licensed code only -->
<source lang="lsl2">string uInteger2Hexadecimal( integer vIntBit ){
    string  vStrRtn;
    do{
        vStrRtn = llGetSubString( "0123456789ABCDEF", vIntBit & 0x0000000F, vIntBit & 0x0000000F ) + vStrRtn;
    }while (vIntBit = vIntBit >> 4 & 0x0FFFFFFF);
    return "0x" + vStrRtn;
}
/*//--                       Anti-License Text                         --//*/
/*//     Contributed Freely to the Public Domain without limitation.     //*/
/*//   2010 (CC0) [ http://creativecommons.org/publicdomain/zero/1.0 ]   //*/
/*//  Void Singer [ https://wiki.secondlife.com/wiki/User:Void_Singer ]  //*/
/*//--                                                                 --//*/</source>

<h3>Full</h3>
'''(Leading zeros included)'''
* LSO: 153 bytes
* MONO: 512 bytes
<!-- Please replace with similarly licensed code only -->
<source lang="lsl2">string uInteger2Hexadecimal( integer vIntBit ){
    string  vStrRtn;
    integer vIntCnt = 8;
    do{
        vStrRtn = llGetSubString( "0123456789ABCDEF", vIntBit & 0x0000000F, vIntBit & 0x0000000F ) + vStrRtn;
        vIntBit = vIntBit >> 4;
    }while (vIntCnt = ~-vIntCnt);
    return vStrRtn;
}
/*//--                       Anti-License Text                         --//*/
/*//     Contributed Freely to the Public Domain without limitation.     //*/
/*//   2010 (CC0) [ http://creativecommons.org/publicdomain/zero/1.0 ]   //*/
/*//  Void Singer [ https://wiki.secondlife.com/wiki/User:Void_Singer ]  //*/
/*//--                                                                 --//*/</source>

<h3>Labeled Full</h3>
'''("0x" prefix, Leading zeros included)'''
* LSO: 159 bytes
* MONO: 512 bytes
<!-- Please replace with similarly licensed code only -->
<source lang="lsl2">string uInteger2Hexadecimal( integer vIntBit ){
    string  vStrRtn;
    integer vIntCnt = 8;
    do{
        vStrRtn = llGetSubString( "0123456789ABCDEF", vIntBit & 0x0000000F, vIntBit & 0x0000000F ) + vStrRtn;
        vIntBit = vIntBit >> 4;
    }while (vIntCnt = ~-vIntCnt);
    return "0x" + vStrRtn;
}
/*//--                       Anti-License Text                         --//*/
/*//     Contributed Freely to the Public Domain without limitation.     //*/
/*//   2010 (CC0) [ http://creativecommons.org/publicdomain/zero/1.0 ]   //*/
/*//  Void Singer [ https://wiki.secondlife.com/wiki/User:Void_Singer ]  //*/
/*//--                                                                 --//*/</source>

<h3>Portable Terse</h3>
'''(Sign prefix, Leading zeros removed)'''
* LSO: 188 bytes
* MONO: 512 bytes
<!-- Please replace with similarly licensed code only -->
<source lang="lsl2">string uInteger2Hexadecimal( integer vIntBit ){
    string vStrSgn;
    if (vIntBit >> 31){
        vStrSgn = "-";
        vIntBit = -vIntBit;
    }
    string vStrRtn;
    do{
        vStrRtn = llGetSubString( "0123456789ABCDEF", vIntBit & 0x0000000F, vIntBit & 0x0000000F ) + vStrRtn;
    }while( vIntBit = vIntBit >> 4 & 0x0FFFFFFF );
    return vStrSgn + vStrRtn;
}
/*//--                       Anti-License Text                         --//*/
/*//     Contributed Freely to the Public Domain without limitation.     //*/
/*//   2010 (CC0) [ http://creativecommons.org/publicdomain/zero/1.0 ]   //*/
/*//  Void Singer [ https://wiki.secondlife.com/wiki/User:Void_Singer ]  //*/
/*//--                                                                 --//*/</source>

<h3>Portable Labeled Terse</h3>
'''(Sign prefix, "0x" prefix, Leading zeros removed)'''
* LSO: 194 bytes
* MONO: 512 bytes
<!-- Please replace with similarly licensed code only -->
<source lang="lsl2">string uInteger2Hexadecimal( integer vIntBit ){
    string vStrSgn;
    if (vIntBit >> 31){
        vStrSgn = "-";
        vIntBit = -vIntBit;
    }
    string vStrRtn;
    do{
        vStrRtn = llGetSubString( "0123456789ABCDEF", vIntBit & 0x0000000F, vIntBit & 0x0000000F ) + vStrRtn;
    }while( vIntBit = vIntBit >> 4 & 0x0FFFFFFF );
    return vStrSgn + "0x" + vStrRtn;
}
/*//--                       Anti-License Text                         --//*/
/*//     Contributed Freely to the Public Domain without limitation.     //*/
/*//   2010 (CC0) [ http://creativecommons.org/publicdomain/zero/1.0 ]   //*/
/*//  Void Singer [ https://wiki.secondlife.com/wiki/User:Void_Singer ]  //*/
/*//--                                                                 --//*/</source>

<h3>Portable Full</h3>
'''(Sign prefix, Leading zeros included)'''
* LSO: 207 bytes
* MONO: 512 bytes
<!-- Please replace with similarly licensed code only -->
<source lang="lsl2">string uInteger2Hexadecimal( integer vIntBit ){
    string vStrSgn;
    //-- Fixed Width alternates of the above line (208 Bytes LSO - 512 Bytes Mono)
    //-- string vStrSgn = " "; //-- Format: "-80000000" to " 7FFFFFFF"
    //-- string vStrSgn = "+"; //-- Format: "-80000000" to "+7FFFFFFF"
    if (vIntBit >> 31){
        vStrSgn = "-";
        vIntBit = -vIntBit;
    }
    integer vIntCnt = 8;
    string vStrRtn;
    do{
        vStrRtn = llGetSubString( "0123456789ABCDEF", vIntBit & 0x0000000F, vIntBit & 0x0000000F ) + vStrRtn;
        vIntBit = vIntBit >> 4;
    }while( vIntCnt = ~-vIntCnt );
    return vStrSgn + vStrRtn;
}
/*//--                       Anti-License Text                         --//*/
/*//     Contributed Freely to the Public Domain without limitation.     //*/
/*//   2010 (CC0) [ http://creativecommons.org/publicdomain/zero/1.0 ]   //*/
/*//  Void Singer [ https://wiki.secondlife.com/wiki/User:Void_Singer ]  //*/
/*//--                                                                 --//*/</source>

<h3>Portable Labeled Full</h3>
'''(Sign prefix, "0x" prefix, Leading zeros included)'''
* LSO: 213 bytes
* MONO: 512 bytes
<!-- Please replace with similarly licensed code only -->
<source lang="lsl2">string uInteger2Hexadecimal( integer vIntBit ){
    string vStrSgn;
    //-- Fixed Width alternates of the above line (214 Bytes LSO - 512 Bytes Mono)
    //-- string vStrSgn = " "; //-- Format: "-0x80000000" to " 0x7FFFFFFF"
    //-- string vStrSgn = "+"; //-- Format: "-0x80000000" to "+0x7FFFFFFF"
    if (vIntBit >> 31){
        vStrSgn = "-";
        vIntBit = -vIntBit;
    }
    integer vIntCnt = 8;
    string vStrRtn;
    do{
        vStrRtn = llGetSubString( "0123456789ABCDEF", vIntBit & 0x0000000F, vIntBit & 0x0000000F ) + vStrRtn;
        vIntBit = vIntBit >> 4;
    }while( vIntCnt = ~-vIntCnt );
    return vStrSgn + "0x" + vStrRtn;
}
/*//--                       Anti-License Text                         --//*/
/*//     Contributed Freely to the Public Domain without limitation.     //*/
/*//   2010 (CC0) [ http://creativecommons.org/publicdomain/zero/1.0 ]   //*/
/*//  Void Singer [ https://wiki.secondlife.com/wiki/User:Void_Singer ]  //*/
/*//--                                                                 --//*/</source>
}}

{{void-box
|title=Notes
|content=
* All Labeled formats can be cast directly to integer within LSL
* Full formats are optimal for fixed width viewing, or packing into raw strings.
* Portable formats are designed for compatibility with outside systems that may use different bit lengths
* Suggest using the smallest compiled version that fits your needs
}}

{{void-box
|title=See Also
|content=
* [[User:Strife_Onizuka/int2hex]] - Another Integer-&gt;Hex function but without using a loop.
<!-- what, no reciprocal linking Zai? =P -->
{{Issues/SVC-6660}}
{{IssueTable}}
}}
[[Category:LSL_User-Defined_Functions]]