llDetectedTouchST

From Second Life Wiki
Revision as of 07:45, 23 September 2012 by Kireji Haiku (talk | contribs)
Jump to navigation Jump to search

Summary

Function: vector llDetectedTouchST( integer index );

Returns a vector that is the surface coordinates for where the prim was touched. The x & y vector positions contain the horizontal (s) & vertical (t) face coordinates respectively (<s, t, 0.0>). Each component is in the interval [0.0, 1.0] with the origin in the bottom left corner.[1]

TOUCH_INVALID_TEXCOORD is returned when the surface coordinates cannot be determined. See Caveats for further details.

• integer index Index of detection information

index does not support negative indexes. For the touch category of events only. The prim that was touched may not be the prim receiving the event, use llDetectedLinkNumber to check for this; likewise you can use llDetectedTouchFace to determine which face was touched.

Caveats

  • If index is out of bounds the script continues to execute without an error message.
  • TOUCH_INVALID_TEXCOORD is returned when...
    • The avatar's viewer does not support face touch detection.
    • The touch has moved off the surface of the prim.
    • The touch happened too close to the edge of the face to determine a location.
    • The event triggered is not a touch event.
All Issues ~ Search JIRA for related Bugs

Examples

<lsl> default {

   touch_start(integer num_detected)
   {
       integer detectedFace = llDetectedTouchFace(0);
       vector detectedTouchST = llDetectedTouchST(0);
       // PUBLIC_CHANNEL has the integer value 0
       if (detectedFace == -1)
           llWhisper(PUBLIC_CHANNEL, "Sorry, your viewer doesn't support touched faces.");
       // TOUCH_INVALID_TEXCOORD has the vector value <-1.0, -1.0, 0.0>
       else if (detectedTouchST == TOUCH_INVALID_TEXCOORD)
           llWhisper(PUBLIC_CHANNEL, "Sorry, the surface touch position could not be determined.");
       else
           llWhisper(PUBLIC_CHANNEL, (string)detectedTouchST);
   }

} </lsl> <lsl> // Draws a cross-hair at the detected Location on the detected face.

default {

   touch(integer num_detected)
   {
       integer face = llDetectedTouchFace(0);
       vector touchST = llDetectedTouchST(0);
       // uuid of the texture applied
       string uuid = "5ac7995c-4c24-8b60-ae61-6a837619dc75";
       llSetLinkPrimitiveParamsFast(LINK_THIS,
           [PRIM_TEXTURE, face, uuid, <1.0, 1.0, 0.0>, touchST, 180*DEG_TO_RAD]);
   }

} </lsl> <lsl> // Sets a grid of WIDTH by HEIGHT and returns a unique number. // The cases of the grid are numbered line by line, left to right, // starting from the bottom.

integer WIDTH = 12; integer HEIGHT = 12; // With a grid of 12x12 (144 cases), you get a number from 0 to 143.

default {

   touch_start(integer total_number)
   {
       vector st = llDetectedTouchST(0);
       integer x = llFloor(st.x * WIDTH);
       integer y = llFloor(st.y * HEIGHT);
       integer button = (y * WIDTH) + x;        
       llOwnerSay("(" + (string)x + "," + (string)y + ") --> " + (string)button);
   }

}

</lsl>

See Also

Deep Notes

History

Introduced in Viewer SVN:870 r92872 Branch:Release Wednesday, 23 July 2008, Supported by Beta Server 1.24.0.93754 (Wenesday 6th August 2008), and viewer binary 1.20.15 (93532).
Search JIRA for related Issues

Footnotes

  1. ^ The ranges in this article are written in Interval Notation.

Signature

function vector llDetectedTouchST( integer index );