llListen

From Second Life Wiki
Revision as of 01:22, 5 January 2014 by Omei Qunhua (talk | contribs) (Undo revision 1186384. I'm sorry, but a note explaining that scripts behave normally, isn't needed.)
Jump to navigation Jump to search

Summary

Function: integer llListen( integer channel, string name, key id, string msg );

Sets a callback for msg on channel from name and id.
Returns a handle (an integer) that can be used to deactivate or remove the listen.

• integer channel input chat channel, any integer value (-2147483648 through 2147483647)
• string name filter for specific prim name or avatar legacy name
• key id filter for specific group, avatar or prim UUID
• string msg filter for specific message

If msg, name or id are blank they are not used to filter incoming messages. If id is an invalid key or a null key, it is considered blank.

Specification

For the listen event to be triggered it must first match the criteria set forth by the filters; only when all the criteria have been met is a listen event generated. First the message must have been transmitted on channel. If id is both a valid key and not a null key then the speaker's key must be equivalent[2] to id. If name is set then the speaker's legacy name must match name exactly (case sensitive). If msg is set then the spoken message must match msg exactly (case sensitive).

Channel Constant Description
DEBUG_CHANNEL 0x7FFFFFFF Chat channel reserved for script debugging and error messages, broadcasts to all nearby users.
PUBLIC_CHANNEL 0x0 Chat channel that broadcasts to all nearby users. This channel is sometimes referred to as: open chat, local chat and public chat.

Caveats

  • Messages sent on channel zero[1] and DEBUG_CHANNEL are throttled to a rate of <200/10sec, per region, per owner/user.
    • Once the rate is exceeded, all following messages on channel zero or DEBUG_CHANNEL will be dropped until the send rate is again below 200/10sec for the previous 10 sec. Dropped messages, despite being dropped still count against the limit.
  • On state change or script reset all listens are removed automatically.
    • A state change can be used as a shortcut to releasing listens.
  • Only 65 listens can simultaneously be open in any single script.
    • If this number is exceeded Script run-time error and Too Many Listens errors occur.
  • The standard SL viewer can only send chat on negative channels through llDialog or llTextBox responses. (Several third party viewers can use these channels from the chat bar.) For maximum compatibility, negative channels are best suited for applications that do not require direct avatar chat.
  • Once a listen is registered its filters cannot be updated, if the listen is registered to llGetOwner, the listen will remain registered to the old owner upon owner change.
    • Owner change can be detected with the changed event.
    • To work around this the old listen will need to be closed and a new one opened for the new owner.
  • A prim cannot hear/listen to chat it generates. It can, however, hear a linked prim.
    • Chat indirectly generated (as a result of llDialog, llTextBox or from a linked prim) can be heard if in range.
All Issues ~ Search JIRA for related Bugs

Examples

Trivial example to listen to any chat from the object owner and respond once. To reduce lag and avoid spamming surrounding users, it is vastly preferable to listen on channels other than 0 and to trigger the listen event by chatting on an alternative channel such as '/5 hello'. <lsl> // says beep to owner the first time owner says something in main chat; integer listenHandle;

default {

   state_entry()
   {
       //  Registers the listen to the current owner of the object at the moment of the call
       //  Change PUBLIC_CHANNEL (0) to another positive number to listen for '/5 hello' style of chat.
       listenHandle = llListen(PUBLIC_CHANNEL, "", llGetOwner(), "");
   }
   listen(integer channel, string name, key id, string message)
   {
       //we filtered to only listen to the current owner in the llListen call above!
       llOwnerSay("beep");
       llListenRemove(listenHandle);// Stop listening until script is reset
   }
   on_rez(integer start_param)// triggered when rezzed from agent's or prim's inventory
   {
       llResetScript();// by resetting on rez, the script registers a new listen handle
   }
   // Registering a new listen handle with the new owner by script reset
   changed(integer change)// triggered by various events that change the task
   {
       if (change & CHANGED_OWNER)// when a new owner is detected
       {
           llResetScript();
       }
   }

}

</lsl>

Notes

  • Avoid channel 0 and set name or id where possible to avoid Lag. llListen(0,"","","") can be extremely laggy as it listens to all chat from everyone in chat range and so it should be avoided at all cost.
  • In November 2007, Kelly Linden offered this explanation to help scripters plan listeners more efficiently:
  1. Chat that is said gets added to a history.
  2. A script that is running and has a listen event will ask the history for a chat message during its slice of run time.
  3. When the script asks the history for a chat message the checks are done in this order:
    • channel
    • self chat (prims can't hear themselves)
    • distance/RegionSay
    • key
    • name
    • message
  4. If a message is found then a listen event is added to the event queue.
The key/name/message checks only happen at all if those are specified of course.
So, the most efficient communication method is llRegionSay on a rarely used channel.
Nowadays, llRegionSayTo is to be preferred, where appropriate.
  • The integer returned can be assigned to a variable (then called a handle) and used to control the listen via llListenRemove or llListenControl. These handles are assigned sequentially starting at 1. If an llListen is repeated with the exact same filters as a currently active listener, then the same handle number is returned. If an llListen's filters do not match any currently active listener, then the next handle in sequence is allocated (it will not re-allocate a recently removed handle).
  • If you are using multiple listens in one script, each listen can be assigned its own handle with which to control it.

See Also

Events

•  listen

Functions

•  llListenRemove Removes a listen
•  llListenControl Enables/Disables a listen
•  llWhisper Sends chat limited to 10 meters
•  llSay Sends chat limited to 20 meters
•  llShout Sends chat limited to 100 meters
•  llRegionSay Sends chat limited current sim
•  llRegionSayTo Sends chat region wide to a specific avatar, or their attachments, or to a rezzed object of known UUID

Deep Notes

All Issues

~ Search JIRA for related Issues
   Listeners in child prims get positioned at root prim position first, then switch to child prim position after re-rez (resulting in wrong listener / whisper radius)
   llTargetSay() - region-wide direct communication
   llListen in linked objects is listening at root instead of linked object local position *after re-rezzing the linkset*

Footnotes

  1. ^ Channel zero is also known as: PUBLIC_CHANNEL, open chat, local chat and public chat
  2. ^ In general terms this means the matching for id is not case sensitive. See key#equivalency for details on key equivalency.

Signature

function integer llListen( integer channel, string name, key id, string msg );