llTeleportAgentGlobalCoords

Function: llTeleportAgentGlobalCoords( key agent, vector global_coordinates, vector region_coordinates, vector look_at );


?	Function ID
	Forced Delay
	Energy

Teleports an agent to set of a region_coordinates within a region at the specified global_coordinates. The agent lands facing the direction defined by look_at. A region's global coordinates can be retrieved using llRequestSimulatorData(region_name, DATA_SIM_POS)

• key	agent	–	avatar UUID that is in the same region (avatar to be teleported)
• vector	global_coordinates	–	Global coordinates of the destination region. Can be retrieved by using llRequestSimulatorData(region_name, DATA_SIM_POS).
• vector	region_coordinates	–	position in region coordinates where the avatar should land.
• vector	look_at	–	direction the avatar should be facing on landing (east, west, etc).

To run this function the script must request the PERMISSION_TELEPORT permission with llRequestPermissions and it must be granted by agent. The combination of llRequestSimulatorData and llTeleportAgentGlobalCoords allows agents to be teleported to regions by region name.

Caveats

Permissions

Do not depend upon the auto-grant status of permissions. Always use the run_time_permissions event.
If the script lacks the permission PERMISSION_TELEPORT, the script will shout an error on DEBUG_CHANNEL and the operation fails (but the script continues to run).
If PERMISSION_TELEPORT is granted by anyone other than agent, then when the function is called an error will be shouted on DEBUG_CHANNEL.

Once the PERMISSION_TELEPORT permission is granted there is no way to revoke it except from inside the script (for example, with a new llRequestPermissions call) or the script is reset or deleted.

This function can only teleport the owner of the object (unless part of an Experience).
Teleports are throttled
This function cannot be used in a script in an object attached using llAttachToAvatarTemp.
Sitting avatars cannot be teleported using this function. You must llUnSit them first.
This function does not override a parcel's teleport settings, i.e. if the parcel has a landing zone enabled the agent will be teleported there.
If the script is part of an experience that the avatar has granted permission, then this function may teleport them without being the owner and it will override parcel teleport routing.
look_at is not the coordinates of a point in the region. The look_at vector is <llCos(facing), llSin(facing), 0.0> where facing is the angle towards which the arriving avatar is to look.
- To look at a specific point in the region: look_at = point - region_coordinates

All Issues ~ Search JIRA for related Bugs

Examples

string simName = "Help Island Public";
vector simGlobalCoords;

vector landingPoint = <128.0, 128.0, 24.0>;

key owner;


default
{
    on_rez(integer start_param)
    {
        llResetScript();
    }

    changed(integer change)
    {
        if (change & CHANGED_OWNER)
            llResetScript();
    }

    state_entry()
    {
        owner = llGetOwner();

        llRequestPermissions(owner, PERMISSION_TELEPORT);
        llRequestSimulatorData(simName, DATA_SIM_POS);
    }

    touch_start(integer total_number)
    {
        key id = llDetectedKey(0);

        if (id == owner)
        {
            if (simGlobalCoords == ZERO_VECTOR)
            {
                llOwnerSay("Config error, tp request was denied. Please try again!");
                llResetScript();
            }
            else
            {
                llOwnerSay("Teleporting you to: http://maps.secondlife.com/secondlife/"
                    + llEscapeURL(simName) + "/" + (string)llRound(landingPoint.x)
                    + "/" + (string)llRound(landingPoint.y) + "/" + (string)llRound(landingPoint.z) + "/");

                llTeleportAgentGlobalCoords(owner, simGlobalCoords, landingPoint, ZERO_VECTOR);
            }
        }
        else
        {
            // llRegionSayTo is faster than llInstantMessage and we can assume
            // that the touching avatar is within the same sim

            llRegionSayTo(id, PUBLIC_CHANNEL,
                "Sorry, I can't tp you. You're NOT my owner!");
        }
    }

    run_time_permissions(integer perm)
    {
        // if permission request has been denied (read ! as not)
        if (!(perm & PERMISSION_TELEPORT))
        {
            llOwnerSay("I need permissions to teleport you!");
            llRequestPermissions(owner, PERMISSION_TELEPORT);
        }
    }

//  dataserver event only called if data is returned
//  or in other words, if you request data for a sim that does
//  not exist this event will NOT be called

    dataserver(key query_id, string data)
    {
        simGlobalCoords = (vector)data;
        // llOwnerSay("Sim global coords: " + (string)simGlobalCoords);
    }
}

Deep Notes

History

Date of Release 24/07/2012

All Issues

~ Search JIRA for related Issues

		BUG-4062	A		llTeleportAgent() and llTeleportAgentGlobalCoords() can break any script in any attached object that contains a changed event.
		SVC-7987	A		llTeleportAgent always points in the positive Y direction on teleport

Signature
function void llTeleportAgentGlobalCoords( key agent, vector global_coordinates, vector region_coordinates, vector look_at );

llTeleportAgentGlobalCoords

Contents

Summary

Caveats

Permissions

Examples

See Also

Events

Functions

Articles

Deep Notes

History

All Issues

Signature

Navigation menu

Search

•	llGetPermissions	–	Get the permissions granted
•	llGetPermissionsKey	–	Get the agent who granted permissions
•	llRequestPermissions	–	Request permissions
•	llRequestSimulatorData	–	Useful for requesting simulator position
•	llTeleportAgent	–	Teleporting agents to a landmark or position in the region.