View source for User:Ugleh Ulrik/ListKeyCase

{{LSL_Function
|func=ListKeyCase
|mode=user
|p1_type=list|p1_name=src|p1_desc=List to change case
|p2_type=integer|p2_name=case|p2_desc=1 is Upper, 0 is Lower.
|return_type=list
|return_text=that is a copy of '''src''' with all lower-case letters or all upper-case letters.
|func_footnote=
See also: [[List|Lists]]
|spec=<source lang="lsl2">//This version converts all list items into strings.
list ListKeyCase(list src,integer case){
    list new;
    integer i;
    if (case){
        do
            new += llToUpper(llList2String(src,i));
        while (llGetListLength(src)>++i);
        return new;
    }/*else*/{
        do
            new += llToLower(llList2String(src,i));
        while (llGetListLength(src)>++i);
        return new;
    }
}</source>

<source lang="lsl2">//This version preserves the types of all list items.
list ListKeyCase(list src, integer case) {
    list new;
    integer i = 0;
    integer j = llGetListLength(src);
    integer type;
    if (case) {
        do {
            if(((type = (llGetListEntryType(src, i) - TYPE_STRING))) & -2) {
                new += llList2List(src, i, i);
            } else if(type) {
                new += (key)llToUpper(llList2String(src,i));
            } else {
                new += llToUpper(llList2String(src,i));
            }
        } while (j>++i);
        return new;
    } /*else*/ {
        do {
            if(((type = (llGetListEntryType(src, i) - TYPE_STRING))) & -2) {
                new += llList2List(src, i, i);
            } else if(type) {
                new += (key)llToLower(llList2String(src,i));
            } else {
                new += llToLower(llList2String(src,i));
            }
        } while (j>++i);
        return new;
    }
}
</source>
|caveats=*[[Key]] equality (and inequality) testing is case sensitive.
|examples=<source lang="lsl2">
list test = ["Apples","Bananas","Cranberrys","Donuts"];
list newtest = ListKeyCase(test,0);
//newtest now is ["apples","bananas","cranberrys","donuts"]</source>
|helpers
|notes
|also
|also_functions
|also_articles
|cat1=Examples
|cat2=User-Defined_Functions
|cat3
|cat4
}}