Jump

Template:Needs Translation/LSL/de Template:Needs Translation/LSL/es Template:Needs Translation/LSL/el Template:Needs Translation/LSL/he Template:Needs Translation/LSL/it Template:Needs Translation/LSL/ko Template:Needs Translation/LSL/nl Template:Needs Translation/LSL/hu Template:Needs Translation/LSL/no Template:Needs Translation/LSL/da Template:Needs Translation/LSL/sv Template:Needs Translation/LSL/tr Template:Needs Translation/LSL/pl Template:Needs Translation/LSL/pt Template:Needs Translation/LSL/th Template:Needs Translation/LSL/uk Template:Needs Translation/LSL/zh-Hans Template:Needs Translation/LSL/zh-Hant

/LSL

The correct title of this article is jump. The initial letter is shown capitalized due to technical restrictions.

jump target;

jump target;

• label

target

–

Name of a label inside the same function or event scope.

@target;

• label

target

–

A label that can be jumped to, if the jump is in the same scope or child scope. It isn't possible to jump between scopes (such as between functions, events or states).

Caveats

• In LSO Only: If multiple jump sites are declared for the same target label within scope, then only the first (top to bottom, left to right) will function as expected, all others will silently fail.
• Labels are scoped at the event and function level, meaning that it is not possible to declare duplicate labels within the same event or function, even if the labels are enclosed in different if-statements, loops etc. -- SVC-6712
  • If you attempt this, the script will silently fail to compile.
• If code exists after a return that is not encapsulated in a flow control structure, the compiler will return an error about the code being dead even if the code is accessible with a jump. -- SVC-1929

Examples

integer a = 5;
jump over;
@in;
a = 6;
@over;
llOwnerSay((string)a);
if(a < 6)
    jump in;
//script will say 5 and then 6

integer getLinkWithName(string name)
{
    integer i = llGetLinkNumber() != 0;   // Start at zero (single prim) or 1 (two or more prims)
    integer x = llGetNumberOfPrims() + i; // [0, 1) or [1, llGetNumberOfPrims()]
    for (; i < x; ++i) 
    {
        if (llGetLinkName(i) == name) 
            jump break; // Found it! Exit loop early with result
    }
    i = -1; // No prim with that name, return -1.
    @break;
    return i;
}

More often than not, the rather ugly 'jump' can be avoided, especially in user defined functions, as this version of the above script demonstrates

integer getLinkWithName(string name)
{
    integer i = llGetLinkNumber() != 0;      // Start at zero (single prim) or 1 (two or more prims)
    integer x = llGetNumberOfPrims() + i; // [0, 1) or [1, llGetNumberOfPrims()]
    for (; i < x; ++i) 
    {
        if (llGetLinkName(i) == name) 
            return i;                    // Found it, return its index        
    }
    return -1;     // No prim with that name, return -1.
}

Notes

It is generally considered inadvisable to use jumps (commonly know as gotos) where other flow control structures could be used.

•  Goto
• XKCD:Goto

See Also

Keywords

•	return
•	state

Deep Notes

LSO VM Notes

Multiple Jumps Bug

The following function, jumpy, demonstrates the multiple-jump-sites-to-a-single-target bug. It appears this function should result in an infinite loop, and it does when the script is compiled for the Mono VM. However when compiled for LSO VM because of this bug the second jump never happens and the function returns. LL reported they were unwilling to fix this bug as to do so would be a breaking change. This bug was fixed in the newer Mono VM.

jumpy(){
    jump next;//first jump
    @next;
    jump next;//second jump - BUG never gets executed
    return;
}