Object to Data v1.4

(http://www.gnu.org/copyleft/fdl.html) in the spirit of which this script is GPL'd. Copyright (C) 2008 Xaviar Czervik

This program is free software; you can redistribute it and/or modify it under the terms of the GNU General Public License as published by the Free Software Foundation; either version 2 of the License, or (at your option) any later version. This program is distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License for more details.

Thanks to DMC Zsigmond for adding the documentation shown below.

Preparation (Parts Required):

1 x Script, named: "Data Main"
1 x Script, named: "Object to Data"
1 x Object, named: "HoloBox"
1 x Notecard, named: "Data Default"
Plus,
1 x Any Object you wish to use these scripts with to turn into data, or re-rez it back again.


Part 1/2 - Instructions to convert an Object to Data
-------------------------------------------------------------

Step 1) Select an Object you wish to turn into data (NB. perhaps start with a single object which is relatively simple). 
Step 2) Rez the Object you wish to turn into data on the ground.
Step 3) Right-click the Object you wish to turn into data, and select edit. Then click on the "Content" tab to view its contents.
Step 4) Open your "Inventory", and create a new folder, called: "Object to Data v1.2".
Step 5) Under the new "Object to Data v1.2" folder, right-click and create a new script, named: "Data Main". Then copy and paste the "Data Main" LSL code on this wiki page into the "Data Main" script you just created under your "Object to Data v1.2" folder. Click on "Save" to compile the "Data Main" script,  and then after that "Data Main" script has successfully compiled, close the script.
Step 6) Repeat Step 5, for both "Object to Data" and "Data to Object" scripts.
Step 7) With the Object you wish to turn into data still selected, and with the "Content" tab highlighted/activated, drag'n'drop" the "Data Main" script you created in your Inventory, from your "Object to Data v1.2" folder into the "Contents" folder of the Object you wish to turn into data.
Step 8) The Object you wish to turn into data will then prompt you with a "Blue Drop-Down Menu" asking you for permission to change the object's links. Accept the permission change by clicking on "YES" on the blue drop-down menu. Information for this permission request can also be viewed on your "Local Chat" window.
Step 9) Now drag'n'drop the "Object to Data" script you created in your Inventory, from your Object to Data v1.2 folder into the "Contents" folder of the Object you wish to turn into data. Your Local Chat window will now inform you that the Object is gathering data, and to please wait...
Step 10) Deselect the Object you wish to turn into data, and then right-click on it, and select, "Take", to take the object back into your inventory.
Step 11) Locate your Object you wish to turn into data from within your "Inventory", and then re-rez it on the ground again. After you re-rez it, it will begin outputting the first details of Object data in your Local Chat Window. 
Step 12) At this point, the Script Creator, requests that you right-click on the "Object" you wish to turn into data and "select" it again.
Step 13) With the Object selected, go to your "Tools" menu on the Second Life (tm) browser, and select "Set Scripts to Running in Selection". A "Set Running Progress" dialogue box will pop up notifying you that the "Object to Data" script inside it, is running - and Done. 
Step 14) Close this dialogue box, and then right-click on the Object you wish to turn into data and select, "Take" to take the object back into your Inventory for a 2nd time.
Step 15) Locate your Object you wish to turn into data from within your "Inventory" for a 2nd time; however, this time, the Object you wish to turn into data WILL NOT APPEAR as the ORIGINAL OBJECT NAME, but instead, as a BLANK OBJECT, named with a  dash "-----". 
Step 16) Re-rez the Object named with a dash, "-----", on the ground for a final time. Wait a few moments until your Local Chat Window outputs the Object's data.
Step 17) Copy the text data from your Local Chat Window (including the time code) from START to END: 

For example: 

[5:43]  -----: #START#
[5:43]  -----: <0,0,0>-=-#I9-=-#I0-=-#I0-=-#V<0,1,0>-=-#F0-=-#V<0,0,0>-=-#V<0,0,0>-=-#V<0,0,0>-=-#I3-=-#I0-=-#I2-=-#I3-=-#I4-=-#I0-=-#I5-=-#I0-=-#I8-=-#R<0,0,0,1>-=-#I7-=-#V<0x900001p-21,0x900001p-21,0x900001p-21>-=
[5:43]  -----: -#I21-=-#I0-=-#I2-=-#F0x4CCCCDp-24-=-#F2-=-#F0-=-#F1-=-#V<0,0,0>-=-#I23-=-#I0-=-#V<1,1,1>-=-#F1-=-#F10-=-#F0x3p-2-=-#I24-=-#I0-=-#I17-=-#I-1-=-#S89556747-24cb-43ed-920b-47caed15465f-=-#V<1,1,0>-=-#V<0
[5:43]  -----: ,0,0>-=-#F0-=-#I19-=-#I-1-=-#I3-=-#I1-=-#I18-=-#I-1-=-#V<0,0,0>-=-#F1-=-#I20-=-#I-1-=-#I0-=-
[5:43]  -----: #END# 

Step 18) Return to your Inventory folder named, "Object to Data v1.2", and then right-click and create a new note (i.e. notecard) called, "Data_Default".
Step 19) Paste the Object code data copied from your Local Chat Window (i.e. as demonstrated above) to the "Data_Default" notecard, and then "Save" it. This notecard now holds the data information for your Object. 

Furthermore, this "Data Default" notecard will later be required to be added to the contents of a new object called, "Data to Object", should you wish to turn your data back into an Object again.

End of Part 1/2.


Part 2/2 Instructions to convert Data to Object
--------------------------------------------------------

Step 1) Create a new Object on the ground, and then right-click on it, and select "Edit".
Step 2) Under the "General" tab, name the Object you just created as, "HoloBox". This object must be inserted into your "Data to Object" object in future to supply the prim that will be converted back into the original Object you once sort to have turned into text/notecard data.
Step 3) Right-click the "Holobox", and select "Take, to take the object back into your inventory.
Step 4) Create a new Object on the ground, right-click it, and select "Edit".
Step 5) Under the "General" tab, name the Object you just created as, "Data to Object".
Step 6) Go the the "Content" tab of the "Data to Object" prim, to view its contents.
Step 7) Drag'n'drop the "Data To Object" script under the "Object to Data v1.2" folder in your Inventory, to the "Contents" folder of the "Data to Object" object you have selected.
Step 8) Drag'n'drop the "Holobox" object you have either in your "Objects" folder in your Inventory or under the "Object to Data v1.2" folder in your Inventory, to the "Contents" folder of the "Data to Object" object you have selected. 
Step 9 Drag'n'drop the "Data_Default" notecard under the "Object to Data v1.2" folder in your Inventory, to the "Contents" folder of the "Data to Object" object you have selected.

With the "Content" tab highlighted/activated, and in the "Contents" folder of your object named, "Data to Object", you should now have the following items contained inside it:

1 x Script, named: "Data to Object"
1 x  Notecard, named: "Data_Default"
1 x Object, named: "HoloBox"

Step 10) Deselect the object, "Data to Object". 
Step 11) Now touch the object, "Data to Object" to begin rebuilding the original Object that you sort to have turned into data. It can now be turned back into an Object again.
Step 12) A "Blue Drop-down Menu" will appear asking for permission to Link and Delink objects again. Select "YES" to accept and begin rebuilding.
Step 13) View your Local Chat window for confirm of the build "Start", and notification when the build is "Done".

The original Object you sort to have turned into data will now rez as a new object above the "Data to Object" prim. 

This object will be empty, ready for use as intended.

End of Part 2/2.

Now that you know how it works, start out by rezing a box and calling it "Data to Object", in it place an empty box called "HoloBox", as well as the following script.

Data to Object <lsl> key qid; integer line = 0; string name = "Data_Default"; string allData; integer prims; vector start;

setLink() {

   list l = llParseString2List(allData, ["-=-"], []);
   vector pos = (vector)llList2String(l, 0);
   pos += start;
   while (llVecDist(llGetPos(), pos) > .01) llSetPos(pos);
   list real;
   integer i = 1;
   while (i < llGetListLength(l)) {
       string this = llList2String(l, i);
       string thisPart = llGetSubString(this, 0, 1);
       if (thisPart == "#S") {
           real += (string)llGetSubString(this, 2, -1);
       } else if (thisPart == "#K") {
           real += (key)llGetSubString(this, 2, -1);
       } else if (thisPart == "#I") {
           real += (integer)llGetSubString(this, 2, -1);
       } else if (thisPart == "#F") {
           real += (float)llGetSubString(this, 2, -1);
       } else if (thisPart == "#V") {
           real += (vector)llGetSubString(this, 2, -1);
       } else if (thisPart == "#R") {
           real += (rotation)llGetSubString(this, 2, -1);
       }
       i++;
   }
   llSetLinkPrimitiveParams(LINK_ALL_OTHERS, real);

}

default {

   touch_start(integer i) {
       start = llGetPos();
       llOwnerSay("Start");
       llRequestPermissions(llGetOwner(), PERMISSION_CHANGE_LINKS);
   }
   run_time_permissions(integer p) {
       if (p & PERMISSION_CHANGE_LINKS) {
          line = 0;
          qid = llGetNotecardLine(name,line); 
       }
   }
   dataserver(key queryId, string data) {
       if (queryId == qid)  {
           if (data != EOF) {
               line += 1;
               data = llList2String(llParseString2List(data, ["-----: "], []), 1);
               if (data == "#START#") {
                   llRezObject("HoloBox", llGetPos() + <0,0,0>, <0,0,0>, <0,0,0,0>, 0);
               } else if (data == "#END#") {
                   setLink();
                   llBreakAllLinks();
                   allData = "";
               } else {
                   allData += data;
               }
               qid = llGetNotecardLine(name,line);
           } else {
               llSetTimerEvent(3);
           }
       }
   }
   timer() {
       llOwnerSay("Done");
       llSetTimerEvent(0);
   }
   object_rez(key k) {
       llCreateLink(k, 1);
   }

} </lsl>

Here are the two scripts required to turn an object into data:

Data Main <lsl> default {

   state_entry() {
       llRequestPermissions(llGetOwner(), PERMISSION_CHANGE_LINKS);
       if (llGetInventoryType("Object to Data") != -1) {
           state run;
       } else {
           llOwnerSay("Accept the permission to change links, and then place the 'Object to Data' script in me.");
       }
   }
   changed(integer num) {
       if (llGetInventoryType("Object to Data") != -1) {
           state run;
       }
   }

}

state run {

   state_entry() {
       llOwnerSay("Gathering data... Please wait. This may take some time.");
       llSetText("Loading...", <1,1,1>, 1);
       integer num = llGetNumberOfPrims();
       list lst;
       integer i = 1;
       while (i <= num) {
           lst += llGetLinkKey(i);
           i++;
       }
       llBreakAllLinks();
       i = 0;
       while (i < num) {
           llSetText((string)(((float)i*100.0)/((float)num)) + "% finished.", <1,1,1>, 1);
           llGiveInventory(llList2Key(lst, i), "Object to Data");
           llCreateLink(llList2Key(lst, i), 1);
           i++;
       }
       llSetText("", <1,1,1>, 1);
       llOwnerSay("Re-Rez this object and then go to 'Tools' -> 'Set Scripts to Running in Selection', and then Re-Rez this object again.");
       llRemoveInventory(llGetScriptName());
   }

} </lsl>

Object to Data <lsl> string hexc="0123456789ABCDEF";//faster

string Float2Hex(float input) {// Copyright Strife Onizuka, 2006-2007, LGPL, http://www.gnu.org/copyleft/lesser.html

   if((integer)input != input)//LL screwed up hex integers support in rotation & vector string typecasting
   {//this also keeps zero from hanging the zero stripper.
       float unsigned = llFabs(input);//logs don't work on negatives.
       integer exponent = llFloor(llLog(unsigned) / 0.69314718055994530941723212145818);//floor(log2(b)) + rounding error
       integer mantissa = (integer)((unsigned / (float)("0x1p"+(string)(exponent -= (exponent == 128)))) * 0x1000000);//shift up into integer range
       integer index = (integer)(llLog(mantissa & -mantissa) / 0.69314718055994530941723212145818);//index of first 'on' bit
       string str = "p" + (string)((exponent += index) - 24);
       mantissa = mantissa >> index;
       do
           str = llGetSubString(hexc,15&mantissa,15&mantissa) + str;
       while(mantissa = mantissa >> 4);
       if(input < 0)
           return "-0x" + str;
       return "0x" + str;
   }//integers pack well so anything that qualifies as an integer we dump as such, supports netative zero
   return llDeleteSubString((string)input,-7,-1);//trim off the float portion, return an integer

}

string safeVector(vector v) {

   return "<"+safeFloat(v.x)+","+safeFloat(v.y)+","+safeFloat(v.z)+">";

}

string safeRotation(rotation v) {

   return "<"+safeFloat(v.x)+","+safeFloat(v.y)+","+safeFloat(v.z)+","+safeFloat(v.s)+">";

}

string safeFloat(float f) {

   return Float2Hex(f);

}

string list2string(list l) {

   string ret;
   integer len = llGetListLength(l);
   integer i;
   
   while (i < len) {
       integer type = llGetListEntryType(l, i);
       if (type == 1) {
           ret += "#I"+(string)llList2Integer(l, i);
       } else if (type == 2) {
           ret += "#F"+safeFloat(llList2Float(l, i));
       } else if (type == 3) {
           ret += "#S"+llList2String(l, i);
       } else if (type == 4) {
           ret += "#K"+(string)llList2Key(l, i);
       } else if (type == 5) {
           ret += "#V"+safeVector(llList2Vector(l, i));        
       } else if (type == 6) {
           ret += "#R"+safeRotation(llList2Rot(l, i));
       }
       ret += "-=-";
       i++;
   }
   return ret;

}

string getTexture() {

   string ret;
   
   integer sides = llGetNumberOfSides();
   
   integer same = 1;
   list texture;
   list repeat;
   list offset;
   list rot;
   
   integer i = 0;
   while (i < sides) {
       list side  = llGetPrimitiveParams([PRIM_TEXTURE, i]);
       texture += llList2String(side, 0);
       repeat  += llList2Vector(side, 1);
       offset  += llList2Vector(side, 2);
       rot     += llList2Float(side, 3);
       
       if (!(llList2String(texture, i) == llList2String(texture, i-1) && llList2Vector(repeat, i) == llList2Vector(repeat, i-1) &&
           llList2Vector(offset, i) == llList2Vector(offset, i-1) && llList2Float(rot, i) == llList2Float(rot, i-1))) {
               same = 0;
       }
       i++;
   }

   if (same) {
       ret += list2string([PRIM_TEXTURE, ALL_SIDES, llList2String(texture, 0), llList2Vector(repeat, 0), llList2Vector(offset, 0), llList2Float(rot, 0)]);
   } else {
       integer j = 0;
       while (j < llGetListLength(texture)) {
           ret += list2string([PRIM_TEXTURE, j, llList2String(texture, j), llList2Vector(repeat, j), llList2Vector(offset, j), llList2Float(rot, j)]);
           j++;
       }
   }        
   
   return ret;

}

string getColor() {

   string ret;

   integer sides = llGetNumberOfSides();
   
   integer same = 1;
   list color;
   list alpha;
   
   integer i = 0;
   while (i < sides) {
       list side  = llGetPrimitiveParams([PRIM_COLOR, i]);
       alpha += llList2Float(side, 1);
       color  += llList2Vector(side, 0);
       
       if (!(llList2String(color, i) == llList2String(color, i-1) && llList2Vector(alpha, i) == llList2Vector(alpha, i-1))) {
               same = 0;
       }
       i++;
   }

   if (same) {
       ret += list2string([PRIM_COLOR, ALL_SIDES, llList2Vector(color, 0), llList2Float(alpha, 0)]);
   } else {
       integer j = 0;
       while (j < llGetListLength(color)) {
           ret += list2string([PRIM_COLOR, j, llList2Vector(color, j), llList2Float(alpha, j)]);
           j++;
       }
   }        
   
   return ret;

}

string getShiny() {

   string ret;

   integer sides = llGetNumberOfSides();
   
   integer same = 1;
   list shiny;
   list bump;
   
   integer i = 0;
   while (i < sides) {
       list side  = llGetPrimitiveParams([PRIM_BUMP_SHINY, i]);
       shiny += llList2Integer(side, 0);
       bump += llList2Integer(side, 1);
       
       if (!(llList2Integer(shiny, i) == llList2Integer(shiny, i-1) && llList2Integer(bump, i) == llList2Integer(bump, i-1))) {
               same = 0;
       }
       i++;
   }

   if (same) {
       ret += list2string([PRIM_BUMP_SHINY, ALL_SIDES, llList2Integer(shiny, 0), llList2Integer(bump, 0)]);
   } else {
       integer j = 0;
       while (j < llGetListLength(shiny)) {
           ret += list2string([PRIM_BUMP_SHINY, j, llList2Integer(shiny, j), llList2Integer(bump, j)]);
           j++;
       }
   }        
   
   return ret;

} string getBright() {

   string ret;

   integer sides = llGetNumberOfSides();
   
   integer same = 1;
   list fullbright;
   
   integer i = 0;
   while (i < sides) {
       list side  = llGetPrimitiveParams([PRIM_FULLBRIGHT, i]);
       fullbright += llList2Integer(side, 0);
       
       if (!(llList2Integer(fullbright, i) == llList2Integer(fullbright, i-1))) {
               same = 0;
       }
       i++;
   }

   if (same) {
       ret += list2string([PRIM_FULLBRIGHT, ALL_SIDES, llList2Integer(fullbright, 0)]);
   } else {
       integer j = 0;
       while (j < llGetListLength(fullbright)) {
           ret += list2string([PRIM_FULLBRIGHT, j, llList2Integer(fullbright, j)]);
           j++;
       }
   }        
   
   return ret;

}

vector getPos() {

   vector pos = llList2Vector(llGetPrimitiveParams([PRIM_POSITION]), 0);
   pos -= llList2Vector(llGetObjectDetails(llGetLinkKey(0), [OBJECT_POS]), 0);
   if (llGetLinkNumber() == 1) {
       pos = <0,0,0>;
   }
   return pos;

}

string getType() {

   list type = [PRIM_TYPE] + llGetPrimitiveParams([PRIM_TYPE]);
   type += [PRIM_PHYSICS] + llGetPrimitiveParams([PRIM_PHYSICS]);
   type += [PRIM_MATERIAL] + llGetPrimitiveParams([PRIM_MATERIAL]);
   type += [PRIM_TEMP_ON_REZ] + llGetPrimitiveParams([PRIM_TEMP_ON_REZ]);
   type += [PRIM_PHANTOM] + llGetPrimitiveParams([PRIM_PHANTOM]);
   type += [PRIM_ROTATION] + llGetPrimitiveParams([PRIM_ROTATION]);
   type += [PRIM_SIZE] + llGetPrimitiveParams([PRIM_SIZE]);
   type += [PRIM_FLEXIBLE] + llGetPrimitiveParams([PRIM_FLEXIBLE]);
   type += [PRIM_POINT_LIGHT] + llGetPrimitiveParams([PRIM_POINT_LIGHT]);
   type += [PRIM_CAST_SHADOWS] + llGetPrimitiveParams([PRIM_CAST_SHADOWS]);
   return list2string(type);

}

string getPrimitiveParams() {

   string ret;
   ret += getType();
   ret += getTexture();
   ret += getShiny();
   ret += getColor();
   ret += getBright();
   return ret;

}

default {

   on_rez(integer i) {
       if (llGetInventoryType("Replicate Main") == -1) {
           string s = getPrimitiveParams();
           s = safeVector(getPos()) + "-=-" + s;
           llSetObjectName("-----");
           llSleep(llGetLinkNumber());
           llOwnerSay("#START#");
           integer i = 0;
           while (i < llStringLength(s)) {
               llOwnerSay((string)llGetSubString(s, i, i+199));
               i += 200;
           }
           llOwnerSay("#END#");
       }
   }

} </lsl> </lsl>