llTextBox

Template:Needs Translation/LSL/es Template:Needs Translation/LSL/el Template:Needs Translation/LSL/he Template:Needs Translation/LSL/it Template:Needs Translation/LSL/ko Template:Needs Translation/LSL/nl Template:Needs Translation/LSL/hu Template:Needs Translation/LSL/no Template:Needs Translation/LSL/da Template:Needs Translation/LSL/sv Template:Needs Translation/LSL/tr Template:Needs Translation/LSL/pl Template:Needs Translation/LSL/pt Template:Needs Translation/LSL/ru Template:Needs Translation/LSL/th Template:Needs Translation/LSL/uk Template:Needs Translation/LSL/zh-Hans Template:Needs Translation/LSL/zh-Hant

/LSL

TextBox

llTextBox

Summary

Function: llTextBox( key avatar, string message, integer channel );

1.0	Forced Delay
10.0	Energy

Shows a dialog box on avatar's screen with the text message. It contains a text box for input, any text that is entered is said by avatar on channel when the "Submit" button is clicked.

• key	avatar	–	avatar UUID that is in the same region
• string	message	–	message to be displayed in the text box
• integer	channel	–	output chat channel, any integer value

Channel Constant		Description
DEBUG_CHANNEL	0x7FFFFFFF	Chat channel reserved for script debugging and error messages, broadcasts to all nearby users.
PUBLIC_CHANNEL	0x0	Chat channel that broadcasts to all nearby users. This channel is sometimes referred to as: open chat, local chat and public chat.

Caveats

• This function causes the script to sleep for 1.0 seconds.
• Not supported in official Linden Labs viewers prior to version 2.4, and some TPVs may not support it. Unsupported viewers will display a dialog box with a single option of "!!llTextBox!!".
• There is no way by script to kill a text box.
• There is no way for the script to detect if the user clicked the small "ignore" button (no chat is generated as a result of pressing this button).
• If the listening prim is out of the 20 meter range of the sending prim when the "Submit" button is pressed, it will not be able to hear the response.
  • This limitation affects attachments too if the wearer moves more than 20 meters from where the listener is located.
• The textbox input is limited to 250 bytes (characters). This can be a problem for larger text input; if the input can be over 250 characters, you will have to accept it through chat.

message limits

• If it exceeds 7 (Viewer 3) or 8 (Viewer 1) lines a scroll bar will appear.
• message must be less than 512 bytes and not empty. Otherwise, it will shout an error on DEBUG_CHANNEL. One easy way to create an empty message is to use a line feed, as in <lsl>llTextBox(avatar_key," \n",dialog_channel);</lsl>

Examples

<lsl> integer listener;

// this is a user-function, it doesn't have a return type remove_listener() {

   llListenRemove(listener);

}

default {

   touch_start(integer total_number)
   {
       key id = llDetectedKey(0);
       remove_listener();

       integer randomChannel = ~(integer)llFrand(1000.0);
       listener = llListen(randomChannel, "", NULL_KEY, "");

       llTextBox(id, "Some info text for the top of the window...", randomChannel);
   }

   listen(integer channel, string name, key id, string message)
   {
       // PUBLIC_CHANNEL has the integer value 0
       llSay(PUBLIC_CHANNEL, "You wrote: " + message);

       remove_listener();
   }

} </lsl> If the user hits "Enter" before clicking the "Submit" button, there will be a final carriage return in the message. This code removes it. <lsl> integer listenHandle;

default {

   touch_start(integer num_detected)
   {
       listenHandle = llListen(91, "", NULL_KEY, "");

       key id = llDetectedKey(0);
       llTextBox(id, "Type a message and click \"Submit\".", 91);
   }

   listen (integer channel, string name, key id, string message)
   {
       llListenRemove(listenHandle);
       integer messageLength = llStringLength(message);
       string lastMessageCharacter = llGetSubString(message, messageLength - 1, messageLength - 1);

       if (lastMessageCharacter == llUnescapeURL("%0A"))
       {
       //  Ignore final carriage return embedded in the message
           message = llGetSubString(message, 0, -2);
           llSay(PUBLIC_CHANNEL, "Final carriage return removed.");
       }

       llSay(PUBLIC_CHANNEL, message);
   }

}

</lsl>

Notes

Instead of mouse clicking: "Submit", you can use keyboard keys: press Tab ⇆ and then Enter ↵

See Also

Events

•

listen

Functions

•	llDialog
•	llListen
•	llSay
•	llWhisper
•	llShout
•	llRegionSay

Deep Notes

History

Introduced in SVN:568 r88085 Trunk Wednesday, 21 May 2008

Source

viewer - indra/llcommon/lllslconstants.h <cpp>// llTextBox() magic token string - yes this is a hack. sue me. const std::string TEXTBOX_MAGIC_TOKEN = "!!llTextBox!!";</cpp>

Footnotes

1. ^ Channel zero is also known as: PUBLIC_CHANNEL, open chat, local chat and public chat

Signature
function void llTextBox( key avatar, string message, integer channel );

<lsl></lsl>