Difference between revisions of "Category:LSL Avatar/Name"

Revision as of 15:13, 27 February 2020

Names

From an LSL standpoint avatars can have 3 different names.

Naming	Description	Unique	Get (in region)	Request (dataserver)	llSensor(Repeat) flags	detected events
Display Name	The name that is displayed on the screen.	No	llGetDisplayName	llRequestDisplayName	N/A	N/A
Username	The name the users logs in with.	Yes	llGetUsername	llRequestUsername	AGENT_BY_USERNAME	N/A
Legacy Name	An interface predating Display Names.	Yes	llKey2Name	llRequestAgentData	AGENT_BY_LEGACY_NAME	llDetectedName

Name Formats by Account Type
Naming	Modern	Legacy
Default Display Name	"FirstName"	"FirstName LastName"
Username	"firstname"	"firstname.lastname"
Legacy Name	"FirstName Resident"	"FirstName LastName"

Modern and Legacy Accounts

Modern accounts are created by choosing a user name, which consists of one name (no spaces).
Legacy accounts were created by choosing two names: first and last names. These two names are used together to form the username.

To maintain compatibility with legacy scripts (that expect two names), modern accounts are given the legacy last name "Resident".

Default Display Name

The default value of the Display Name depends upon the type of the account. For modern accounts, it is the first part of the Legacy Name (without the space and last name "Resident"; this is the same as the Username with capitalization used at registration time preserved). For legacy accounts, it is the full Legacy Name.

string agentDefaultName(string agentUsername, string agentLegacyName) {
    integer i = llStringLength(agentUsername);
    if (i < llStringLength(agentLegacyName)) {
        // modern account
        return llDeleteSubString(agentLegacyName, i, -1);
    } else {
        // legacy account
        return agentLegacyName;
    }
}

Legacy Name to Username

The relationship between the Username and Legacy Name is simple. The Username for a specific Legacy Name is the Legacy Name in lowercase with the space replaced with a period. If the last name of the Legacy Name is "Resident", then the username is just the Legacy Name first name in lowercase (without the last name or the period).

string agentUsername(string agentLegacyName) {
    return llDumpList2String(llParseString2List(llToLower(agentLegacyName)+" ", [" resident ", " "],[]), ".");
}

If a Username is passed into this function instead of a Legacy Name, the Username will still be returned.

Changed names

If your script has stored an avatar name and someone claims to be that avatar but they have changed their name, it is possible to combine two functions to find out if that is true.

Avoid this problem
Don't store avatars by name because names can change; to remember an avatar, store the key

Get the key for the name they claim to have used in the past using llRequestUserKey. You can compare that to any key for them you already have, or you can convert that key to its current name using llRequestUsername.

Other names

Complete Name

Viewer URI Name Space apparently also defines something called a Complete Name, which seems to be just the Display Name made unique by appending the Username in parenthesis when the Display Name is not set to its default value (and just the Display Name when it is set to its default value).

string agentCompleteName(string agentDisplayName, string agentUsername, string agentLegacyName) {
    if (agentDisplayName == agentDefaultName(agentUsername, agentLegacyName)) {
        return agentDisplayName;
    } else {
        return agentDisplayName + " (" + agentUsername + ")";
    }
}

Web Name

Some Second Life web pages (e.g., friends online: https://secondlife.com/my/account/friends.php or search results from: http://search.secondlife.com/) seem to return another form of naming similar to the Complete Name. This name is also just the Display Name made unique by appending a unique name in parenthesis when the Display Name is not set to its default value. The difference seems to be that the appended unique value is the default Display Name, instead of the Username, so this name always contains the default Display Name (with the current Display Name prepended).

string agentWebName(string agentDisplayName, string agentUsername, string agentLegacyName) {
    string agentDefaultName = agentDefaultName(agentUsername, agentLegacyName);
    if (agentDisplayName == agentDefaultName) {
        return agentDisplayName;
    } else {
        return agentDisplayName + " (" + agentDefaultName + ")";
    }
}

Legacy-Name Only Functions

These functions only take Legacy Names and there are no alternative functions available.

llCollisionFilter
llListen - likewise the listen event only has a Legacy Name parameter.

FAQs

There are a couple of FAQs that go into much more detail about this:

LSL FAQ: Display Names/LSL
General FAQ: Display Names

Subcategories

This category has the following 5 subcategories, out of 5 total.

L

Pages in category "LSL Avatar/Name"

The following 9 pages are in this category, out of 9 total.

D

G

K

LlKey2Name

R

@@ Line 88: / Line 88: @@
 ''If a Username is passed into this function instead of a Legacy Name, the Username will still be returned.''
+=== Changed names ===
+If your script has stored an avatar name and someone claims to be that avatar but they have changed their name, it is possible to combine two functions to find out if that is true.
+{{KBtip|custom=Avoid this problem|<br/>Don't store avatars by name because names can change; to remember an avatar, store the key}}
+Get the key for the name they claim to have used in the past using [[llRequestUserKey]]. You can compare that to any key for them you already have, or you can convert that key to its current name using [[llRequestUsername]].
 === Other names ===