View source for LlGetObjectDetails

{{LSL_Function
|inject-2=
{{LSL_Function/limits}}{{LSL_Function/uuid|id|sim=*}}
{{Issues/SCR-87}}{{Issues/SVC-7592}}
|func_id=332|func_sleep=0.0|func_energy=10.0
|func=llGetObjectDetails
|p1_type=key|p1_name=id|p1_desc=&#32;or adjacent regions[[#id_Parameter|*]]
|p2_type=list|p2_name=params|p2_desc=OBJECT_* flags
|return_type=list|return_text=of the details for '''id''', specifically those requested in '''params'''. 
|func_footnote=An empty list if '''id''' is not found.{{PBR}}
{{LSL Const|OBJECT_UNKNOWN_DETAIL|integer|-1|c=}} is returned when passed an invalid integer parameter.
|spec=<div style="padding: 1px; float: left;">[[Image:LlGetObjectdetails-avatar-range.png|thumb|none|250px|Avatar detection range for SL Server 1.34]]</div>
<h5 style="margin:0;">id Parameter</h5>
'''id''' holds the UUID of the avatar or prim this function is going to get the details of.

If '''id''' is not found in the region, adjacent regions are searched for avatars which match '''id'''. An avatar is only considered to have been found if it is inside the region, or within a 34 meter zone outside the region boundaries (see diagram). A single valid result may be returned after the avatar leaves this zone.

<h5 style="margin:0;">params Parameter</h5>
The '''params''' list is used to indicate which object attributes of interest. The order they are supplied in determines the order of the corresponding return values in the return list.
{{{!}} cellpadding="0" cellspacing="0"
{{!}}
*If '''params''' contains unsupported integer values, {{LSL Const|OBJECT_UNKNOWN_DETAIL|integer|-1|c=}} is placed in the output list.
*If '''params''' contains non-[[integer]] types, those values will be silently ignored.
{{!}}}
<div style="clear:both;"></div>
|caveats=

*OBJECT_ROT will return an accurate facing for Avatars seated or in mouselook, but only a rough direction otherwise.
*Adjacent regions are not searched for prims which match '''id'''.
*Information for avatars that can no longer be found will still be available for a short period (about 45 seconds) but it is not updated.
*Items in '''params''' that are not integers are silently ignored, {{LSL Const|OBJECT_UNKNOWN_DETAIL|integer|-1|c=}} is not returned.
*This function does not return information about items in inventory.
*[[llTargetOmega]] will only effect the return of [[OBJECT_ROT]] if the object is [[STATUS_PHYSICS|physical]]. If the object is not physical then the original start rotation is returned, [[llTargetOmega]] is a {{LSLGC|Effects|client side effect}}.
*{{LSL Const|OBJECT_SCRIPT_MEMORY|integer|11|c=}} reports the maximum memory that all scripts in an object could use, not the actual amount of real memory currently used.  In particular, Mono scripts only use the amount of memory currently needed, not the max possible.  In practice, this makes the number reported a worst case scenario that will never normally be reached by most objects.
*{{LSL Const|OBJECT_RUNNING_SCRIPT_COUNT|integer|9|c=}} includes crashed scripts in its count.
|examples=
<lsl>default
{
    collision_start(integer i)
    {
        list a = llGetObjectDetails(llDetectedKey(0), ([OBJECT_NAME, 
                    OBJECT_DESC, OBJECT_POS, OBJECT_ROT, OBJECT_VELOCITY,
                    OBJECT_OWNER, OBJECT_GROUP, OBJECT_CREATOR]));
        llWhisper(0,"UUID: "         + (string)llDetectedKey(0) +
                  "\nName: \""       + llList2String(a,0) + "\"" +
                  "\nDescription: \"" + llList2String(a,1) + "\"" +
                  "\nPosition: "     + llList2String(a,2) +
                  "\nRotation: "     + llList2String(a,3) +
                  "\nVelocity: "     + llList2String(a,4) +
                  "\nOwner: "        + llList2String(a,5) +
                  "\nGroup: "        + llList2String(a,6) +
                  "\nCreator: "      + llList2String(a,7));
    }
}</lsl>
<lsl>
// group join inviter
// gets the name of the object's active group from the online group profile

key groupNameRequestId;
key groupKey;
string groupName;

init()
{
    // WARNING:
    // different prims can have different active groups!!!

    // get the key of the root prim's group
    groupKey = llList2Key(llGetObjectDetails(llGetLinkKey(LINK_ROOT), [OBJECT_GROUP]), 0);

    // request the name of the root prim's group
    groupNameRequestId = llHTTPRequest("http://world.secondlife.com/group/" + (string)groupKey, [], "");
}

default
{
    state_entry()
    {
        init();
    }

    touch_start(integer num_detected)
    {
        if (groupKey == NULL_KEY || groupName == "")
            return;

        key id = llDetectedKey(0);
        llInstantMessage(id,
            "Click the link to join the group '" + groupName + "'\n"
            + "secondlife:///app/group/" + (string)groupKey + "/about");
    }

    http_response(key request_id, integer status, list metadata, string body)
    {
        if (request_id != groupNameRequestId)
            return;

        list args = llParseString2List(body, ["title"], []);
        groupName = llList2String(llParseString2List(llList2String(args, 1), [">", "<", "/"], []), 0);
    }
}
</lsl>
<lsl>// aim & shoot
default
{   state_entry()
    {   llRequestPermissions(llGetOwner(), PERMISSION_TAKE_CONTROLS);
    }
    control(key id, integer pressed, integer change) 
    {   if(change & pressed & CONTROL_ML_LBUTTON)
            llSensor("", "", AGENT|PASSIVE|ACTIVE, 96.0, PI/16.0);
    }
    run_time_permissions(integer perm)
    {   if(perm&PERMISSION_TAKE_CONTROLS)
            llTakeControls(CONTROL_ML_LBUTTON, TRUE, TRUE); 
    }
    sensor(integer n)
    {   key uuid=llDetectedKey(0);
        list a = llGetObjectDetails(uuid, ([
            OBJECT_NAME, OBJECT_DESC, OBJECT_POS, OBJECT_ROT,
            OBJECT_VELOCITY,OBJECT_OWNER, OBJECT_GROUP, OBJECT_CREATOR]));
        llOwnerSay("UUID: " + (string)uuid +
            "\nName: \"" + llList2String(a,0)+ "\"" +
            "\nDecription: \"" + llList2String(a,1) + "\"" +
            "\nPosition: " + llList2String(a,2) +
            "\nRotation: " + llList2String(a,3) +
            "\nVelocity: " + llList2String(a,4) +
            "\nOwner: " + llList2String(a,5) +
            "\nGroup: " + llList2String(a,6) +
            "\nCreator: " + llList2String(a,7)
        );
    }
}</lsl>
<lsl>// Object Script Time
default
{
    touch_start(integer num_detected)
    {
        llOwnerSay(llGetObjectName()+" Script Time: "+llList2String(llGetObjectDetails(llGetKey(), [OBJECT_SCRIPT_TIME]), 0));
    }
}
</lsl>
|spec
|constants={{LSL Constants/Object Details}}
|helpers=See {{LSLGC|Link/Get}} for some {{LSLGC|Link|link}} related helper functions. Also see [[llGetLinkPrimitiveParams]] if you need to get the position and rotation of a linked prim.
<lsl>
integer isLindenTreeOrGrass(key id){
    //Check if it's an OPT_OTHER and not an attachment, which makes it a Linden tree or grass!
    list out = llGetObjectDetails(id, [OBJECT_PATHFINDING_TYPE, OBJECT_ATTACHED_POINT]);
    return (llList2Integer(out, 0) == OPT_OTHER) && !llList2Integer(out, 1);
}
</lsl>
|also_functions={{LSL DefineRow||[[llKey2Name]]}}
{{LSL DefineRow||[[llGetPrimitiveParams]]}}
{{LSL DefineRow||[[llSetLinkPrimitiveParams]]}}
{{LSL DefineRow||[[llSetPrimitiveParams]]}}
{{LSL DefineRow||[[llGetParcelDetails]]}}
|also_tests
|also_events
|also_articles={{LSL DefineRow||{{LSLGC|Detected}}}}
{{LSL DefineRow||[[Prim Attribute Overloading]]}}
|notes
|history=Introduced in SL 1.18.3(2)
|cat1=Object
|cat2=Prim
|cat3=Avatar
|cat4=Owner
|cat5=Creator
|cat6=Group
|cat7=Link
|cat8
}}