Path update

Template:Needs Translation/LSL/de Template:Needs Translation/LSL/es Template:Needs Translation/LSL/el Template:Needs Translation/LSL/fr Template:Needs Translation/LSL/he Template:Needs Translation/LSL/it Template:Needs Translation/LSL/ko Template:Needs Translation/LSL/nl Template:Needs Translation/LSL/hu Template:Needs Translation/LSL/no Template:Needs Translation/LSL/da Template:Needs Translation/LSL/sv Template:Needs Translation/LSL/tr Template:Needs Translation/LSL/pl Template:Needs Translation/LSL/pt Template:Needs Translation/LSL/ru Template:Needs Translation/LSL/th Template:Needs Translation/LSL/uk Template:Needs Translation/LSL/zh-Hans Template:Needs Translation/LSL/zh-Hant

/LSL

path_update

Description

Event: path_update( integer type, list reserved ){ ; }

	Event ID
	Delay

Event description goes here.

• integer	type	–	A PU_*, it's the path event type
• list	reserved	–	Reserved; not currently used.

Constants	Value	Description
PU_SLOWDOWN_DISTANCE_REACHED	0x00	Character is near current goal.
PU_GOAL_REACHED	0x01	Character has reached the goal and will stop or choose a new goal (if wandering).
PU_FAILURE_INVALID_START	0x02	Character cannot navigate from the current location - e.g., the character is off the navmesh or too high above it.
PU_FAILURE_INVALID_GOAL	0x03	Goal is not on the navmesh and cannot be reached.
PU_FAILURE_UNREACHABLE	0x04	Goal is no longer reachable for some reason - e.g., an obstacle blocks the path.
PU_FAILURE_TARGET_GONE	0x05	Target (for llPursue or llEvade) can no longer be tracked - e.g., it left the region or is an avatar that is now more than about 30m outside the region.
PU_FAILURE_NO_VALID_DESTINATION	0x06	There's no good place for the character to go - e.g., it is patrolling and all the patrol points are now unreachable.
PU_EVADE_HIDDEN	0x07	Triggered when an llEvade character thinks it has hidden from its pursuer.
PU_EVADE_SPOTTED	0x08	Triggered when an llEvade character switches from hiding to running
PU_FAILURE_NO_NAVMESH	0x09	This is a fatal error reported to a character when there is no navmesh for the region. This usually indicates a server failure and users should file a bug report and include the time and region in which they received this message.
PU_FAILURE_DYNAMIC_PATHFINDING_DISABLED	0x0A	Triggered when a character enters a region with dynamic pathfinding disabled. Dynamic pathfinding can be toggled by estate managers via the 'dynamic_pathfinding' option in the Region Debug Console.
PU_FAILURE_PARCEL_UNREACHABLE	0x0B	Triggered when a character failed to enter a parcel because it is not allowed to enter, e.g. because the parcel is already full or because object entry was disabled after the navmesh was baked.
PU_FAILURE_OTHER	0xF4240	Other failure.

Caveats

• Note that if wandering, the "stop" (PU_GOAL_REACHED) type may never occur as a new goal may be chosen when near (PU_SLOWDOWN_DISTANCE_REACHED) the previous goal.
• When the character cannot navigate from the current position (PU_FAILURE_INVALID_START) llNavigateTo with the FORCE_DIRECT_PATH option may be helpful.

Examples

<lsl> default {

   state_entry()
   {
   //  Clear any previous character behaviors
       llDeleteCharacter();

   //  MAX_SPEED is @ 20 by default
       llCreateCharacter([
           CHARACTER_MAX_SPEED, 25.0,
           CHARACTER_DESIRED_SPEED, 15.0]);

       vector currentPosition = llGetPos();
       llWanderWithin(currentPosition, <10.0, 10.0,  10.0>, []);
   }

   path_update(integer type, list reserved)
   {
       string info;

       if (type == PU_SLOWDOWN_DISTANCE_REACHED)
           info = "Near";

       else if (type == PU_GOAL_REACHED)
           info = "Stopping";

       else if (type == PU_FAILURE_INVALID_START)
       {
           info = "Cannot path find from current location! Attempting "
                   + "to go to the center of the region.";

           vector currentPosition = llGetPos();
           llNavigateTo(<128.0, 128.0, llGround(<128.0, 128.0, 0.0> - currentPosition)>, [FORCE_DIRECT_PATH, TRUE]);
       }
       else if (type == PU_FAILURE_INVALID_GOAL)
           info = "Goal not on navmesh!";

       else if (type == PU_FAILURE_UNREACHABLE)
           info = "Goal unreachable!";

       else if (type == PU_FAILURE_TARGET_GONE)
           info = "Target gone!";

       else if (type == PU_FAILURE_NO_VALID_DESTINATION)
           info = "No place to go!";

       else if (type ==  PU_EVADE_HIDDEN)
           info = "Hiding from pursuer...";

       else if (type == PU_EVADE_SPOTTED)
           info = "Switched from hiding to running...";

       else if (type ==  PU_FAILURE_NO_NAVMESH)
           info = "Region has no nav mesh..";

       else if (type == PU_FAILURE_DYNAMIC_PATHFINDING_DISABLED)
           info = "Dynamic pathfinding is disabled in this region.";

       else if (type == PU_FAILURE_PARCEL_UNREACHABLE)
           info = "Parcel entry problem (is the parcel full?).";

       else if (type == PU_FAILURE_OTHER)
           info = "Hit an unspecified failure";

       else
           info = "Unknown failure";

       key owner = llGetOwner();
       llRegionSayTo(owner, PUBLIC_CHANNEL, info);
   }

} </lsl>

See Also

Functions

• llCreateCharacter
• llDeleteCharacter
• llEvade
• llExecCharacterCmd
• llGetClosestNavPoint
• llFleeFrom
• llNavigateTo
• llPatrolPoints
• llPursue
• llUpdateCharacter
• llWanderWithin

Deep Notes

Signature
event void path_update( integer type, list reserved );