Resetting Scripts in a Large Build

If you have a complex build, perhaps sim wide and you need to reset all of the scripts, there isn't an easy way to do this, say from from parcel properties or the region tools.

This presents a few startegies for providing this ability but it does require some forethought.

Region Restart

Detect region restart and restart script.

(or other event)

default
{
    changed(integer change)
    {
        if (change & CHANGED_REGION_START) 
        {
            llOwnerSay("The regions has just restarted, resetting the script.");
            llResetScript();
        }
    }

    state_entry()
    {
        //  setup and do stuff
    }
}

Listener - restart on command

Listen for instruction and restart script.

//  some random negative number
integer chatChannel = -1324628;

//  could consider using a random string for the command to obscure the function
string chatCommand = "reset";

default
{
//  this script sends the command to reset the other scripts to reset.
//  change to use any trigger event that is suitable.

    touch(integer num_detected)
    {
        llRegionSay(chatChannel, chatCommand);//  (3)
    }
}

//  some random negative number
integer chatChannel = -1324628;

//  could consider using a random string for the command to obscure the function
string chatCommand = "reset";

default
{
//  insert the listen into your scripts that need to reset on command

    state_entry()
    {
    //  setup and do stuff
        llListen(chatChannel, "", NULL_KEY, chatCommand);
    }

    listen(integer channel, string name, key id, string message)
    {
        if (message == chatCommand)
            llResetScript();
    }
}

Random Staggered Reset

Script load on the sim may be a concern, if so you could use a random timer in the target script to stagger the reset as follows:

//  some random negative number
integer chatChannel = -1324628;

//  could consider using a random string for the command to obscure the function
string chatCommand = "reset";

default
{
//  insert the listen into your scripts that need to reset on command

    state_entry()
    {
    //setup and do stuff
    llListen(chatChannel, "", NULL_KEY, chatCommand);
    }

    listen(integer channel, string name, key id, string message)
    {
        if (message == chatCommand)
        {
            //random timer within [0.0, 60.0)
            llSetTimerEvent( llFrand(60.0) );
        }
    }

    timer()
    {
        llResetScript();
    }
}

If you need to stagger the resets, perhaps because the order the scripts start is important, use different commands with appropriate pauses between start commands, such as:

//  some random negative number
integer chatChannel = -1324628;

//  could consider using a random string for the command to obscure the function. "reset3" will trigger after 15 seconds.
string chatCommand = "reset3";

default
{
    state_entry()
    {
    //  setup and do stuff
        llListen(chatChannel, "", NULL_KEY, chatCommand);
    }

    listen(integer channel, string name, key id, string message)
    {
        if (message == chatCommand) llResetScript();
    }
}

---

Return to Good_Building_Practices