SHA-2

Preforms a SHA2 Hash on the text. Similar to and MD5 hash, although (slightly) more secure. Two versions of the function are provided, one for UTF-8 Strings (all strings in LSL are UTF-8) and the other is for Base64 Strings (you need to tell it how many bits long the data is).

View http://en.wikipedia.org/wiki/SHA1 for more information.

SHA-256

//////////////////////////////////////////////////////////////////////////////////////
//
//	UTF-8 SHA2-256
//	Version 1.0 
//	ESL Compiled: "Oct 25 2007", "02:20:11"
//	Copyright (C) 2007  Strife Onizuka
//	Based on Pseudo-code from http://en.wikipedia.org/wiki/SHA1
//	https://wiki.secondlife.com/wiki/SHA1
//
//	This library is free software; you can redistribute it and/or
//	modify it under the terms of the GNU Lesser General Public License
//	as published by the Free Software Foundation;
//	version 3 of the License.
//	
//	This library is distributed in the hope that it will be useful,
//	but WITHOUT ANY WARRANTY; without even the implied warranty of
//	MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
//	GNU Lesser General Public License for more details.
//	
//	You should have received a copy of the GNU Lesser General Public License
//	along with this library.  If not, see <http://www.gnu.org/licenses/>
//	or write to the Free Software Foundation, Inc., 59 Temple Place, Suite 330,
//	Boston, MA  02111-1307  USA
//	
//////////////////////////////////////////////////////////////////////////////////////

//===================================================//
//                 Combined Library                  //
//             "Oct 25 2007", "02:20:11"             //
//  Copyright (C) 2004-2007, Strife Onizuka (cc-by)  //
//    http://creativecommons.org/licenses/by/3.0/    //
//===================================================//
//{

string TrimRight(string src, string chrs)//Mono Unsafe, LSO Safe
{
    integer i = llStringLength(src);
    do;while(~llSubStringIndex(chrs, llGetSubString(src, (i = ~-i), i)) && i);
    return llDeleteSubString(src, (-~(i)), 0xFFFF);
}

string hexc="0123456789ABCDEF";

//} Combined Library


list k = [ 
    0x428a2f98, 0x71374491, 0xb5c0fbcf, 0xe9b5dba5, 0x3956c25b, 0x59f111f1, 0x923f82a4, 0xab1c5ed5,
    0xd807aa98, 0x12835b01, 0x243185be, 0x550c7dc3, 0x72be5d74, 0x80deb1fe, 0x9bdc06a7, 0xc19bf174,
    0xe49b69c1, 0xefbe4786, 0x0fc19dc6, 0x240ca1cc, 0x2de92c6f, 0x4a7484aa, 0x5cb0a9dc, 0x76f988da,
    0x983e5152, 0xa831c66d, 0xb00327c8, 0xbf597fc7, 0xc6e00bf3, 0xd5a79147, 0x06ca6351, 0x14292967,
    0x27b70a85, 0x2e1b2138, 0x4d2c6dfc, 0x53380d13, 0x650a7354, 0x766a0abb, 0x81c2c92e, 0x92722c85,
    0xa2bfe8a1, 0xa81a664b, 0xc24b8b70, 0xc76c51a3, 0xd192e819, 0xd6990624, 0xf40e3585, 0x106aa070,
    0x19a4c116, 0x1e376c08, 0x2748774c, 0x34b0bcb5, 0x391c0cb3, 0x4ed8aa4a, 0x5b9cca4f, 0x682e6ff3,
    0x748f82ee, 0x78a5636f, 0x84c87814, 0x8cc70208, 0x90befffa, 0xa4506ceb, 0xbef9a3f7, 0xc67178f2];

string UTF8_SHA_256(string plain) {
    integer H1 = 0x6a09e667;
    integer H2 = 0xbb67ae85;
    integer H3 = 0x3c6ef372;
    integer H4 = 0xa54ff53a;
    integer H5 = 0x510e527f;
    integer H6 = 0x9b05688c;
    integer H7 = 0x1f83d9ab;
    integer H8 = 0x5be0cd19;

    //OR on the extra bit.
    integer j = llStringLength(plain) << 3;
    integer b = (~-(((j + 552) & -512) >> 5));
    integer T = llBase64ToInteger(TrimRight(llGetSubString(plain = llStringToBase64(plain), -4, -1),"=")+"AAAA");
    string buf;
    integer i = 0;
    for(;i < 85 ; (i = -~i))
        buf += "A";
    if(j)
    {
        i = 0x800000;
        if(T & 0xFF00)
            i = 0x00000080;
        else if(T & 0xFF0000)
            i = 0x00008000;
    }
    else
        T = i = 0x80000000;//T is corrupt because of https://jira.secondlife.com/browse/SVC-104
//    llOwnerSay(llList2CSV([i,j]));
    plain = llGetSubString( llDeleteSubString(plain, -4, -1) + 
                            llGetSubString(llIntegerToBase64(T | i), 0, 5) + 
                            buf, 0, (b << 4) / 3) + 
            llIntegerToBase64(j << (6 - ((b % 3) << 1)));
    buf = "";
    list x;
    integer S;
    for (i = 0; i < b; i += 16)
    {
        integer A = H1;
        integer B = H2;
        integer C = H3;
        integer D = H4;
        integer E = H5;
        integer F = H6;
        integer G = H7;
        integer H = H8;
        x = [];
        for(j = 0; j < 16; (j = -~j))
        {
            T = ((i + j) << 4) / 3;
            if((S = (((i + j) % 3) << 1)))
                T = ((llBase64ToInteger(llGetSubString(plain, T, T+5)) << S) | 
                     (llBase64ToInteger("A"+llGetSubString(plain, T+2, T+6)) >> (6 - S)));
            else
                T = llBase64ToInteger(llGetSubString(plain, T, T+5));
//            llOwnerSay("W["+(string)j+"]="+hex(T));
            x += T;
            T += H + (((E << 26) | ((E >>  6) & 0x3FFFFFF)) ^ 
                      ((E << 21) | ((E >> 11) & 0x1FFFFF)) ^ 
                      ((E <<  7) | ((E >> 25) & 0x7F))) + 
                     ((E & F) ^ ((~E) & G)) + llList2Integer(k, j);
            H = G;
            G = F;
            F = E;
            E = D + T;
            D = C;
            C = B;
            B = A;
            A = T + (((B << 30) | ((B >>  2) & 0x3FFFFFFF)) ^ 
                     ((B << 19) | ((B >> 13) & 0x7FFFF)) ^ 
                     ((B << 10) | ((B >> 22) & 0x3FF))) + 
                    ((B & C) ^ (B & D) ^ (C & D));
        }
//		llOwnerSay(llList2CSV(hexm(x)));
        for (; j < 64; (j = -~j))
        {
            T = llList2Integer(x, -15);
            S = llList2Integer(x, -2);
            x = llList2List(x + T = llList2Integer(x,  -16) + 
                                    (((T << 25) | ((T >>  7) & 0x1FFFFFF)) ^ 
                                     ((T << 14) | ((T >> 18) & 0x3FFF)) ^ 
                                     ((T >>  3) & 0x1FFFFFFF)) + 
                                    llList2Integer(x,  -7) + 
                                    (((S << 15) | ((S >> 17) & 0x0007FFF)) ^ 
                                     ((S << 13) | ((S >> 19) & 0x1FFF)) ^ 
                                     ((S >> 10) & 0x03FFFFF)), -16, -1);
//            llOwnerSay("W["+(string)j+"]="+hex(T));
            T += H + (((E << 26) | ((E >>  6) & 0x3FFFFFF)) ^ 
                      ((E << 21) | ((E >> 11) & 0x1FFFFF)) ^ 
                      ((E <<  7) | ((E >> 25) & 0x7F))) + 
                     ((E & F) ^ ((~E) & G)) + llList2Integer(k, j);
            H = G;
            G = F;
            F = E;
            E = D + T;
            D = C;
            C = B;
            B = A;
            A = T + (((B << 30) | ((B >>  2) & 0x3FFFFFFF)) ^ 
                     ((B << 19) | ((B >> 13) & 0x7FFFF)) ^ 
                     ((B << 10) | ((B >> 22) & 0x3FF))) + 
                    ((B & C) ^ (B & D) ^ (C & D));
        }
        H1 += A;
        H2 += B;
        H3 += C;
        H4 += D;
        H5 += E;
        H6 += F;
        H7 += G;
        H8 += H;
    }
    x = [H1, H2, H3, H4, H5, H6, H7, H8];
    i = -8;
    do
    {
        T = llList2Integer(x,i);
        j = 32;
        do
            buf += llGetSubString(hexc, b = ((T >> (j -= 4)) & 0xF), b);
        while (j);
    }while ((i = -~i));
    return buf;
}

string Base64_SHA_256(string plain, integer bit_length) {
    integer H1 = 0x6a09e667;
    integer H2 = 0xbb67ae85;
    integer H3 = 0x3c6ef372;
    integer H4 = 0xa54ff53a;
    integer H5 = 0x510e527f;
    integer H6 = 0x9b05688c;
    integer H7 = 0x1f83d9ab;
    integer H8 = 0x5be0cd19;

    //OR on the extra bit.
    integer b = (~-(((bit_length + 552) & -512) >> 5));
    integer T = llBase64ToInteger(TrimRight(llGetSubString(plain = llStringToBase64(plain), -4, -1),"=")+"AAAA");
    string buf;
    integer i = 0;
    for(;i < 85 ; (i = -~i))
        buf += "A";
    if(bit_length)
    {
        i = 0x800000;
        if(T & 0xFF00)
            i = 0x00000080;
        else if(T & 0xFF0000)
            i = 0x00008000;
    }
    else
        T = i = 0x80000000;//T is corrupt because of https://jira.secondlife.com/browse/SVC-104
//    llOwnerSay(llList2CSV([i,bit_length]));
    plain = llGetSubString( llDeleteSubString(plain, -4, -1) + 
                            llGetSubString(llIntegerToBase64(T | i), 0, 5) + 
                            buf, 0, (b << 4) / 3) + 
            llIntegerToBase64(bit_length << (6 - ((b % 3) << 1)));
    buf = "";
    list x;
    integer S;
    for (i = 0; i < b; i += 16)
    {
        integer A = H1;
        integer B = H2;
        integer C = H3;
        integer D = H4;
        integer E = H5;
        integer F = H6;
        integer G = H7;
        integer H = H8;
        x = [];
        for(bit_length = 0; bit_length < 16; (bit_length = -~bit_length))
        {
            T = ((i + bit_length) << 4) / 3;
            if((S = (((i + bit_length) % 3) << 1)))
                T = ((llBase64ToInteger(llGetSubString(plain, T, T+5)) << S) | 
                     (llBase64ToInteger("A"+llGetSubString(plain, T+2, T+6)) >> (6 - S)));
            else
                T = llBase64ToInteger(llGetSubString(plain, T, T+5));
//            llOwnerSay("W["+(string)bit_length+"]="+hex(T));
            x += T;
            T += H + (((E << 26) | ((E >>  6) & 0x3FFFFFF)) ^ 
                      ((E << 21) | ((E >> 11) & 0x1FFFFF)) ^ 
                      ((E <<  7) | ((E >> 25) & 0x7F))) + 
                     ((E & F) ^ ((~E) & G)) + llList2Integer(k, bit_length);
            H = G;
            G = F;
            F = E;
            E = D + T;
            D = C;
            C = B;
            B = A;
            A = T + (((B << 30) | ((B >>  2) & 0x3FFFFFFF)) ^ 
                     ((B << 19) | ((B >> 13) & 0x7FFFF)) ^ 
                     ((B << 10) | ((B >> 22) & 0x3FF))) + 
                    ((B & C) ^ (B & D) ^ (C & D));
        }
//		llOwnerSay(llList2CSV(hexm(x)));
        for (; bit_length < 64; (bit_length = -~bit_length))
        {
            T = llList2Integer(x, -15);
            S = llList2Integer(x, -2);
            x = llList2List(x + T = llList2Integer(x,  -16) + 
                                    (((T << 25) | ((T >>  7) & 0x1FFFFFF)) ^ 
                                     ((T << 14) | ((T >> 18) & 0x3FFF)) ^ 
                                     ((T >> 3) & 0x1FFFFFFF)) + 
                                    llList2Integer(x,  -7) + 
                                    (((S << 15) | ((S >> 17) & 0x7FFF)) ^ 
                                     ((S << 13) | ((S >> 19) & 0x1FFF)) ^ 
                                     ((S >> 10) & 0x3FFFFF)), -16, -1);
//            llOwnerSay("W["+(string)bit_length+"]="+hex(T));
            T += H + (((E << 26) | ((E >>  6) & 0x3FFFFFF)) ^ 
                      ((E << 21) | ((E >> 11) & 0x1FFFFF)) ^ 
                      ((E <<  7) | ((E >> 25) & 0x7F))) + 
                     ((E & F) ^ ((~E) & G)) + llList2Integer(k, bit_length);
            H = G;
            G = F;
            F = E;
            E = D + T;
            D = C;
            C = B;
            B = A;
            A = T + (((B << 30) | ((B >>  2) & 0x3FFFFFFF)) ^ 
                     ((B << 19) | ((B >> 13) & 0x7FFFF)) ^ 
                     ((B << 10) | ((B >> 22) & 0x3FF))) + 
                    ((B & C) ^ (B & D) ^ (C & D));
        }
        H1 += A;
        H2 += B;
        H3 += C;
        H4 += D;
        H5 += E;
        H6 += F;
        H7 += G;
        H8 += H;
    }
    x = [H1, H2, H3, H4, H5, H6, H7, H8];
    i = -8;
    do
    {
        T = llList2Integer(x,i);
        bit_length = 32;
        do
            buf += llGetSubString(hexc, b = ((T >> (bit_length -= 4)) & 0xF), b);
        while (bit_length);
    }while ((i = -~i));
    return buf;
}


default
{
    state_entry()
    {
        llOwnerSay("");
        llOwnerSay(UTF8_SHA_256(""));
        llOwnerSay("E3B0C44298FC1C149AFBF4C8996FB92427AE41E4649B934CA495991B7852B855");
        llOwnerSay("");
        llOwnerSay(UTF8_SHA_256("abc"));
        llOwnerSay("BA7816BF8F01CFEA414140DE5DAE2223B00361A396177A9CB410FF61F20015AD");
        llOwnerSay("");
        llOwnerSay(UTF8_SHA_256("The quick brown fox jumps over the lazy dog"));
        llOwnerSay("D7A8FBB307D7809469CA9ABCB0082E4F8D5651E46D3CDB762D02D0BF37C9E592");
//        llOwnerSay((string)llGetTime());
    }
}

SHA-224

//////////////////////////////////////////////////////////////////////////////////////
//
//	UTF-8 SHA2-224
//	Version 1.0 
//	ESL Compiled: "Oct 25 2007", "02:29:30"
//	Copyright (C) 2007  Strife Onizuka
//	Based on Pseudo-code from http://en.wikipedia.org/wiki/SHA1
//	https://wiki.secondlife.com/wiki/SHA1
//
//	This library is free software; you can redistribute it and/or
//	modify it under the terms of the GNU Lesser General Public License
//	as published by the Free Software Foundation;
//	version 3 of the License.
//	
//	This library is distributed in the hope that it will be useful,
//	but WITHOUT ANY WARRANTY; without even the implied warranty of
//	MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
//	GNU Lesser General Public License for more details.
//	
//	You should have received a copy of the GNU Lesser General Public License
//	along with this library.  If not, see <http://www.gnu.org/licenses/>
//	or write to the Free Software Foundation, Inc., 59 Temple Place, Suite 330,
//	Boston, MA  02111-1307  USA
//	
//////////////////////////////////////////////////////////////////////////////////////

//===================================================//
//                 Combined Library                  //
//             "Oct 25 2007", "02:29:30"             //
//  Copyright (C) 2004-2007, Strife Onizuka (cc-by)  //
//    http://creativecommons.org/licenses/by/3.0/    //
//===================================================//
//{

string TrimRight(string src, string chrs)//Mono Unsafe, LSO Safe
{
    integer i = llStringLength(src);
    do;while(~llSubStringIndex(chrs, llGetSubString(src, (i = ~-i), i)) && i);
    return llDeleteSubString(src, (-~(i)), 0xFFFF);
}

string hexc="0123456789ABCDEF";

//} Combined Library


list k = [ 
    0x428a2f98, 0x71374491, 0xb5c0fbcf, 0xe9b5dba5, 0x3956c25b, 0x59f111f1, 0x923f82a4, 0xab1c5ed5,
    0xd807aa98, 0x12835b01, 0x243185be, 0x550c7dc3, 0x72be5d74, 0x80deb1fe, 0x9bdc06a7, 0xc19bf174,
    0xe49b69c1, 0xefbe4786, 0x0fc19dc6, 0x240ca1cc, 0x2de92c6f, 0x4a7484aa, 0x5cb0a9dc, 0x76f988da,
    0x983e5152, 0xa831c66d, 0xb00327c8, 0xbf597fc7, 0xc6e00bf3, 0xd5a79147, 0x06ca6351, 0x14292967,
    0x27b70a85, 0x2e1b2138, 0x4d2c6dfc, 0x53380d13, 0x650a7354, 0x766a0abb, 0x81c2c92e, 0x92722c85,
    0xa2bfe8a1, 0xa81a664b, 0xc24b8b70, 0xc76c51a3, 0xd192e819, 0xd6990624, 0xf40e3585, 0x106aa070,
    0x19a4c116, 0x1e376c08, 0x2748774c, 0x34b0bcb5, 0x391c0cb3, 0x4ed8aa4a, 0x5b9cca4f, 0x682e6ff3,
    0x748f82ee, 0x78a5636f, 0x84c87814, 0x8cc70208, 0x90befffa, 0xa4506ceb, 0xbef9a3f7, 0xc67178f2];

string UTF8_SHA_224(string plain) {
    integer H1 = 0xC1059ED8;
    integer H2 = 0x367CD507;
    integer H3 = 0x3070DD17;
    integer H4 = 0xF70E5939;
    integer H5 = 0xFFC00B31;
    integer H6 = 0x68581511;
    integer H7 = 0x64F98FA7;
    integer H8 = 0xBEFA4FA4;

    //OR on the extra bit.
    integer j = llStringLength(plain) << 3;
    integer b = (~-(((j + 552) & -512) >> 5));
    integer T = llBase64ToInteger(TrimRight(llGetSubString(plain = llStringToBase64(plain), -4, -1),"=")+"AAAA");
    string buf;
    integer i = 0;
    for(;i < 85 ; (i = -~i))
        buf += "A";
    if(j)
    {
        i = 0x800000;
        if(T & 0xFF00)
            i = 0x00000080;
        else if(T & 0xFF0000)
            i = 0x00008000;
    }
    else
        T = i = 0x80000000;//T is corrupt because of https://jira.secondlife.com/browse/SVC-104
//    llOwnerSay(llList2CSV([i,j]));
    plain = llGetSubString( llDeleteSubString(plain, -4, -1) + 
                            llGetSubString(llIntegerToBase64(T | i), 0, 5) + 
                            buf, 0, (b << 4) / 3) + 
            llIntegerToBase64(j << (6 - ((b % 3) << 1)));
    buf = "";
    list x;
    integer S;
    for (i = 0; i < b; i += 16)
    {
        integer A = H1;
        integer B = H2;
        integer C = H3;
        integer D = H4;
        integer E = H5;
        integer F = H6;
        integer G = H7;
        integer H = H8;
        x = [];
        for(j = 0; j < 16; (j = -~j))
        {
            T = ((i + j) << 4) / 3;
            if((S = (((i + j) % 3) << 1)))
                T = ((llBase64ToInteger(llGetSubString(plain, T, T+5)) << S) | 
                     (llBase64ToInteger("A"+llGetSubString(plain, T+2, T+6)) >> (6 - S)));
            else
                T = llBase64ToInteger(llGetSubString(plain, T, T+5));
//            llOwnerSay("W["+(string)j+"]="+hex(T));
            x += T;
            T += H + (((E << 26) | ((E >>  6) & 0x3FFFFFF)) ^ 
                      ((E << 21) | ((E >> 11) & 0x1FFFFF)) ^ 
                      ((E <<  7) | ((E >> 25) & 0x7F))) + 
                     ((E & F) ^ ((~E) & G)) + llList2Integer(k, j);
            H = G;
            G = F;
            F = E;
            E = D + T;
            D = C;
            C = B;
            B = A;
            A = T + (((B << 30) | ((B >>  2) & 0x3FFFFFFF)) ^ 
                     ((B << 19) | ((B >> 13) & 0x7FFFF)) ^ 
                     ((B << 10) | ((B >> 22) & 0x3FF))) + 
                    ((B & C) ^ (B & D) ^ (C & D));
        }
//		llOwnerSay(llList2CSV(hexm(x)));
        for (; j < 64; (j = -~j))
        {
            T = llList2Integer(x, -15);
            S = llList2Integer(x, -2);
            x = llList2List(x + T = llList2Integer(x,  -16) + 
                                    (((T << 25) | ((T >>  7) & 0x1FFFFFF)) ^ 
                                     ((T << 14) | ((T >> 18) & 0x3FFF)) ^ 
                                     ((T >>  3) & 0x1FFFFFFF)) + 
                                    llList2Integer(x,  -7) + 
                                    (((S << 15) | ((S >> 17) & 0x0007FFF)) ^ 
                                     ((S << 13) | ((S >> 19) & 0x1FFF)) ^ 
                                     ((S >> 10) & 0x03FFFFF)), -16, -1);
//            llOwnerSay("W["+(string)j+"]="+hex(T));
            T += H + (((E << 26) | ((E >>  6) & 0x3FFFFFF)) ^ 
                      ((E << 21) | ((E >> 11) & 0x1FFFFF)) ^ 
                      ((E <<  7) | ((E >> 25) & 0x7F))) + 
                     ((E & F) ^ ((~E) & G)) + llList2Integer(k, j);
            H = G;
            G = F;
            F = E;
            E = D + T;
            D = C;
            C = B;
            B = A;
            A = T + (((B << 30) | ((B >>  2) & 0x3FFFFFFF)) ^ 
                     ((B << 19) | ((B >> 13) & 0x7FFFF)) ^ 
                     ((B << 10) | ((B >> 22) & 0x3FF))) + 
                    ((B & C) ^ (B & D) ^ (C & D));
        }
        H1 += A;
        H2 += B;
        H3 += C;
        H4 += D;
        H5 += E;
        H6 += F;
        H7 += G;
        H8 += H;
    }
    x = [H1, H2, H3, H4, H5, H6, H7];//, H8];
    i = -7;
    do
    {
        T = llList2Integer(x,i);
        j = 32;
        do
            buf += llGetSubString(hexc, b = ((T >> (j -= 4)) & 0xF), b);
        while (j);
    }while ((i = -~i));
    return buf;
}

string Base64_SHA_224(string plain, integer bit_length) {
    integer H1 = 0xC1059ED8;
    integer H2 = 0x367CD507;
    integer H3 = 0x3070DD17;
    integer H4 = 0xF70E5939;
    integer H5 = 0xFFC00B31;
    integer H6 = 0x68581511;
    integer H7 = 0x64F98FA7;
    integer H8 = 0xBEFA4FA4;

    //OR on the extra bit.
    integer b = (~-(((bit_length + 552) & -512) >> 5));
    integer T = llBase64ToInteger(TrimRight(llGetSubString(plain = llStringToBase64(plain), -4, -1),"=")+"AAAA");
    string buf;
    integer i = 0;
    for(;i < 85 ; (i = -~i))
        buf += "A";
    if(bit_length)
    {
        i = 0x800000;
        if(T & 0xFF00)
            i = 0x00000080;
        else if(T & 0xFF0000)
            i = 0x00008000;
    }
    else
        T = i = 0x80000000;//T is corrupt because of https://jira.secondlife.com/browse/SVC-104
//    llOwnerSay(llList2CSV([i,bit_length]));
    plain = llGetSubString( llDeleteSubString(plain, -4, -1) + 
                            llGetSubString(llIntegerToBase64(T | i), 0, 5) + 
                            buf, 0, (b << 4) / 3) + 
            llIntegerToBase64(bit_length << (6 - ((b % 3) << 1)));
    buf = "";
    list x;
    integer S;
    for (i = 0; i < b; i += 16)
    {
        integer A = H1;
        integer B = H2;
        integer C = H3;
        integer D = H4;
        integer E = H5;
        integer F = H6;
        integer G = H7;
        integer H = H8;
        x = [];
        for(bit_length = 0; bit_length < 16; (bit_length = -~bit_length))
        {
            T = ((i + bit_length) << 4) / 3;
            if((S = (((i + bit_length) % 3) << 1)))
                T = ((llBase64ToInteger(llGetSubString(plain, T, T+5)) << S) | 
                     (llBase64ToInteger("A"+llGetSubString(plain, T+2, T+6)) >> (6 - S)));
            else
                T = llBase64ToInteger(llGetSubString(plain, T, T+5));
//            llOwnerSay("W["+(string)bit_length+"]="+hex(T));
            x += T;
            T += H + (((E << 26) | ((E >>  6) & 0x3FFFFFF)) ^ 
                      ((E << 21) | ((E >> 11) & 0x1FFFFF)) ^ 
                      ((E <<  7) | ((E >> 25) & 0x7F))) + 
                     ((E & F) ^ ((~E) & G)) + llList2Integer(k, bit_length);
            H = G;
            G = F;
            F = E;
            E = D + T;
            D = C;
            C = B;
            B = A;
            A = T + (((B << 30) | ((B >>  2) & 0x3FFFFFFF)) ^ 
                     ((B << 19) | ((B >> 13) & 0x7FFFF)) ^ 
                     ((B << 10) | ((B >> 22) & 0x3FF))) + 
                    ((B & C) ^ (B & D) ^ (C & D));
        }
//		llOwnerSay(llList2CSV(hexm(x)));
        for (; bit_length < 64; (bit_length = -~bit_length))
        {
            T = llList2Integer(x, -15);
            S = llList2Integer(x, -2);
            x = llList2List(x + T = llList2Integer(x,  -16) + 
                                    (((T << 25) | ((T >>  7) & 0x1FFFFFF)) ^ 
                                     ((T << 14) | ((T >> 18) & 0x3FFF)) ^ 
                                     ((T >> 3) & 0x1FFFFFFF)) + 
                                    llList2Integer(x,  -7) + 
                                    (((S << 15) | ((S >> 17) & 0x7FFF)) ^ 
                                     ((S << 13) | ((S >> 19) & 0x1FFF)) ^ 
                                     ((S >> 10) & 0x3FFFFF)), -16, -1);
//            llOwnerSay("W["+(string)bit_length+"]="+hex(T));
            T += H + (((E << 26) | ((E >>  6) & 0x3FFFFFF)) ^ 
                      ((E << 21) | ((E >> 11) & 0x1FFFFF)) ^ 
                      ((E <<  7) | ((E >> 25) & 0x7F))) + 
                     ((E & F) ^ ((~E) & G)) + llList2Integer(k, bit_length);
            H = G;
            G = F;
            F = E;
            E = D + T;
            D = C;
            C = B;
            B = A;
            A = T + (((B << 30) | ((B >>  2) & 0x3FFFFFFF)) ^ 
                     ((B << 19) | ((B >> 13) & 0x7FFFF)) ^ 
                     ((B << 10) | ((B >> 22) & 0x3FF))) + 
                    ((B & C) ^ (B & D) ^ (C & D));
        }
        H1 += A;
        H2 += B;
        H3 += C;
        H4 += D;
        H5 += E;
        H6 += F;
        H7 += G;
        H8 += H;
    }
    x = [H1, H2, H3, H4, H5, H6, H7, H8];
    i = -8;
    do
    {
        T = llList2Integer(x,i);
        bit_length = 32;
        do
            buf += llGetSubString(hexc, b = ((T >> (bit_length -= 4)) & 0xF), b);
        while (bit_length);
    }while ((i = -~i));
    return buf;
}


default
{
    state_entry()
    {
        llOwnerSay("");
        llOwnerSay(UTF8_SHA_224(""));
        llOwnerSay("D14A028C2A3A2BC9476102BB288234C415A2B01F828EA62AC5B3E42F");
        llOwnerSay("");
        llOwnerSay(UTF8_SHA_224("abc"));
        llOwnerSay("23097D223405D8228642A477BDA255B32AADBCE4BDA0B3F7E36C9DA7");
        llOwnerSay("");
        llOwnerSay(UTF8_SHA_224("The quick brown fox jumps over the lazy dog"));
        llOwnerSay("730E109BD7A8A32B1CB9D9A09AA2325D2430587DDBC0C38BAD911525");
//        llOwnerSay((string)llGetTime());
    }
}