Float2Hex
| LSL Portal | Functions | Events | Types | Operators | Constants | Flow Control | Script Library | Categorized Library | Tutorials |
Use to encode floats in hex notation, minimal overhead, does not introduce errors. No special decoder needed. Try it.
Use this instead of (string) when converting floats to strings.
LSL (float) typecast supports C99 hex floats. This is good because with hex you can store floats without the need for a special decoder (just use (float)) and since hex is a power of 2 format, floats can be stored without any loss or rounding errors.
A similar function (also by me) Float to Scientific Notation, works much the same way (except it uses base 10). The trouble is it has to emulates higher precision math, in a scripting language this is a bad solution. Because of the base conversion using logs would introduce a huge accumulated error (read as: floats suck). Resulting in the need to do the shifting with a while loop. This wasn't good enough, even with 32 bits small numbers would still be corrupted by the shifting. An integer and a float (or in one rewrite two integers) were used, one to store the integer portion, and the other the float. This worked, but was slow as all get out for large and small numbers (2 seconds). Finaly some optical approches were used to do the conversion which sped up large numbers. While accurate, the function was slow and used alot of memory.
This function is much faster, it requires about 900 instructions with little deviation from that number. In the sceme of things it's not too costly (on a not too lagged sim that is about 0.12 seconds). There isn't much that can be done to reduce the number of instructions executed, unless LL wants to give us an llInteger2HexString or an llFloat2HexString.
UPDATE:
There was a small bug that would cause the script to crash on numbers that were greater then 0x1.FFFFF8p127. Please update to fix the script crash issue. As a result of the fix, it will be just a bit slower. If you uncomment the "if", then you can set the shift to 23 bits (0x800000 and c - 23)
string hexc="0123456789ABCDEF";//faster
string Float2Hex(float input)
{// Copyright Strife Onizuka, 2006, LGPL, http://www.gnu.org/copyleft/lesser.html
if((integer)input != input)//LL screwed up hex integers support in rotation & vector string typecasting
{//this also keeps zero from hanging the zero stripper.
float unsigned = llFabs(input);//logs don't work on negatives.
integer exponent = llFloor(llLog(unsigned) / 0.69314718055994530941723212145818);//floor(log2(b))
if(exponent > 127) exponent = 127;//catch fatal rounding error in exponent.
integer mantissa = (integer)((unsigned / (float)("0x1p"+(string)exponent)) * 0x1000000);//shift up into integer range
while(!(mantissa & 0x1))
{//strip extra zeros off before converting or they break "p"
mantissa = mantissa >> 1;
exponent = -~exponent;//++c;
}
string str = "p" + (string)(exponent - 24);
do
str = llGetSubString(hexc,15&mantissa,15&mantissa) + str;
while(mantissa = mantissa >> 4);
if(input < 0)
return "-0x" + str;
return "0x" + str;
}//integers pack well so anything that qualifies as an integer we dump as such, supports netative zero
return llDeleteSubString((string)input,-7,-1);//trim off the float portion, return an integer
}
Usage:
string a = Float2Hex(100.000000); // a == 0x19p2 string b = Float2Hex(14353.344727); // b == 0xE04561p-10 float c = (float)a;//c == 100.000000 float d = (float)b;//d == 14353.344727
Helper Functions:
string Rot2Hex(rotation a)
{
return "<"+Float2Hex(a.x)+","+Float2Hex(a.y)+","+Float2Hex(a.z)+","+Float2Hex(a.s)+">";
}
string Vec2Hex(vector a)
{
return "<"+Float2Hex(a.x)+","+Float2Hex(a.y)+","+Float2Hex(a.z)+">";
}
string DumpList2String(list input, string seperator)// for csv use ", " as the seperator.
{
integer b = (input != []);
string c;
string d;
integer e;
if(b)
{
@top;
if((e = llGetListEntryType(input,--b)) == TYPE_FLOAT)
d=Float2Hex(llList2Float(input,b));
else if(e == TYPE ROTATION)
d=Rot2Hex(llList2Rot(input,b));
else if(e == TYPE_VECTOR)
d=Vec2Hex(llList2Vector(input,b));
else
d=llList2String(input,b);
if(b)
{
c = d + (c=seperator) + c;
jump top;
}
}
return (c=d) + c;
}
How it works:
string hexc="0123456789ABCDEF";//faster
string Float2Hex(float a)
{// Copyright Strife Onizuka, 2006, LGPL, http://www.gnu.org/copyleft/lesser.html
//If it's zero, the zero stripper will hang, lets avoid that
if(a)
{//we need to find the exponent, but to do that we need to take the log of the number (or run a while loop)
float b = llFabs(a);//logs don't work on negatives.
string f = "p";//This is a trade off, slightly slower (only slightly) for a couple bytes savings (10)
//To get the exponent we need to round the integer portion down or the log2(b)
// LSL doesn't have log2, so we use one of the laws of logs to get it from the natural log
integer c = llFloor(llLog(b) / 0.69314718055994530941723212145818);//floor(log2(b))
//There is a rounding error in the exponent that causes it to round up, this usualy isn't a problem as the
// exponent only is only used to shift the number. It becomes a problem when dealing with float max as
// it will round up to 128; which will crash llPow.
if(c > 127) c = 127;//catch fatal rounding error in exponent.
//Q: why not do (b * llPow(2,-c))? A: because the range of floats are different at the top and bottom
// at the top it's 2^127 at the bottom it's 2^-149; and if you tried to do this otherwise,
// llPow would crash with an overflow. Then we multiply it by 2 ^ 24, floats only use 23 bits for the mantisa,
// we cannot add it into c because we could overflow llPow; we correct the value of c later.
// Instead of using llPow(2.0, c) we are using (float)("0x1p"+(string)c), it's 10% faster and 16 bytes lighter.
integer d = (integer)((b / (float)("0x1p"+(string)c)) * 0x1000000);//shift up into integer range
while(!(d & 0xf))
{//strip extra zeros off before converting or they break "p"
//a catch22 of sorts, you cannot know exactly how far to shift it till after you have shifted it
d = d >> 4;
c+=4; //for each zero stripped we must adjust the exponent
}
do//convert to hex
f = llGetSubString(hexc,15&d,15&d) + f;
while(d = d >> 4);
if(a < 0)//final formating & c adjustment (from making it an integer)
return "-0x" + f +(string)(c - 24);
return "0x" + f +(string)(c - 24);
}//no point in this getting special formating.
return "0";//zero would hang the zero stripper.
}
This version is perfect, it is slightly slower. It properly handles the exponent bug. It's included for curiosities sake (and a bunch of work went into it and i didn't want to throw it away).
string Float2Hex(float a)
{// Copyright Strife Onizuka, 2006, LGPL, http://www.gnu.org/copyleft/lesser.html
if(a)
{
float b = llFabs(a);
integer c = llFloor(llLog(b) / 0.69314718055994530941723212145818);//floor(log2(b))
string f = "";
if(c > 127) c = 127;
else if(c < -126) c = -126;
else c -= ((float)("0x1p"+(string)c) > b);
integer d = ((integer)(b / (float)("0x.000002p"+(string)c)) & 0x7FFFFF) << 1;
integer m = 6;
while(!(d & 0xf))
{//strip extra zeros off before converting or they break "p"
d = d >> 4;
--m;
}
do
{
f = llGetSubString(hexc, 0xf & d, 0xf & d) + f;
d = d >> 4;
}while(--m);
if(a < 0)
return "-0x"+(string)(b > 1.1754943508222875079687365372222e-38)+"."+f +"p"+(string)(c);
return "0x"+(string)(b > 1.1754943508222875079687365372222e-38)+"."+f +"p"+(string)(c);
}
return "0";//zero would hang the zero stripper.
}