llSensorRemove

Template:Needs Translation/LSL/de Template:Needs Translation/LSL/es Template:Needs Translation/LSL/el Template:Needs Translation/LSL/he Template:Needs Translation/LSL/it Template:Needs Translation/LSL/ko Template:Needs Translation/LSL/nl Template:Needs Translation/LSL/hu Template:Needs Translation/LSL/no Template:Needs Translation/LSL/da Template:Needs Translation/LSL/sv Template:Needs Translation/LSL/tr Template:Needs Translation/LSL/pl Template:Needs Translation/LSL/pt Template:Needs Translation/LSL/ru Template:Needs Translation/LSL/th Template:Needs Translation/LSL/uk Template:Needs Translation/LSL/zh-Hans Template:Needs Translation/LSL/zh-Hant

/LSL

SensorRemove

llSensorRemove

Summary

Function: llSensorRemove( );

0.0	Forced Delay
10.0	Energy

Removes the sensor setup by llSensorRepeat.

There are no parameters or return value for this function, as only one llSensorRepeat can be specified per script.

Caveats

• If called within the sensor event then it also removes all of the sensor data that is accessed by the detection functions.

Examples

The following basic example shows an object that when touched starts scanning for avatars in 10m every 30 seconds, and stops as soon as at least one is found, and returns their name.

default {
    touch_start(integer x) {
        llSensorRepeat("", NULL_KEY, AGENT, 10.0, PI, 30.0);
    }

    sensor(integer x) {
        key id = llDetectedKey(0);
        string name = llGetDisplayName(id);
        if (("" == name) || ("???" == name)) name = llDetectedName(0);

        llSay(PUBLIC_CHANNEL, name + " was found first!");
        llSensorRemove();
    }
}

The next script is a more real-world example of a scanner that when touched will begin listing avatar names and distances, but will stop if no avatars are detected. It demonstrates the use of llSensor() when starting the scan, to avoid the initial delay of an llSensorRepeat() call.

integer scanning = FALSE;
default {
    touch_start(integer x) {
        llSensor("", NULL_KEY, AGENT, 10.0, PI); // Start the scan
    }
 
    sensor(integer x) {
        string text = ""; vector myPos = llGetPos();
        // Loop through avatars from furthest to nearest
        while ((--x) >= 0) {
            key id = llDetectedKey(x);
 
            // Get display name, or use legacy name as a fallback
            string name = llGetDisplayName(id);
            if (("" == name) || ("???" == name)) name = llDetectedName(x);
 
            // Add distance to the name
            name += " (" + (string)((integer)llVecDist(myPos, llDetectedPos(x))) + "m)";
            if (text) name = "\n" + name;
            text += name;
        }
        llSetText(text, <1.0, 1.0, 1.0>, 1.0);
 
        if (!scanning) {
            // Repeat the scan every 30 seconds
            llSensorRepeat("", NULL_KEY, AGENT, 10.0, PI, 30.0);
            scanning = TRUE;
        }
    } no_sensor() {
        // No avatars nearby, lets turn off the scan
        llSetText("", ZERO_VECTOR, 0.0);
        llSensorRemove();
        scanning = FALSE;
    }
}

See Also

Events

•

sensor

Functions

•

llSensorRepeat

–

Scans for agents or objects every time period

Deep Notes

Signature
function void llSensorRemove();

Haiku
Call off the hounds. The quarry has escaped us. Back to the stables.