Meter2Feet

Function: string Meter2Feet(float meter);

Returns a string of metric value meter converted to feet/inch in common representation, ie. 3' 4 5/16".

• float

meter

–

any valid float, positive or negative

Specification

string Meter2Feet (float meter)
{
	integer negative = FALSE;
	if (meter < 0)
	{	// Use only positive value to simplify the maths
		negative = TRUE;
		meter *= -1;
	}
	float fraction = meter / 0.3048;	// Compute feet
	integer feet = llFloor(fraction);
	fraction = (fraction - feet) * 12;	// Compute inches
	integer inches = llFloor(fraction);
	fraction = llRound((fraction - inches) * 16);	// Compute 1/16 inches
	string strFeet = (string)feet;
	if (negative)	// Reallocate sign to ensure showing up in case feet value is zero
		strFeet = "-" + strFeet;
	string strFraction = "\"";
	if (fraction != 0)	// show fraction value only if not zero
		strFraction = " " + (string)(integer)fraction + "/16" + strFraction;
	return (strFeet + "' " + (string)inches + strFraction);
}

Example

Trivial example to listen to any chat from the object owner for meter values and respond feet/inch value.

string Meter2Feet (float meter)
{
	integer negative = FALSE;
	if (meter < 0)
	{	// Use only positive value to simplify the maths
		negative = TRUE;
		meter *= -1;
	}
	float fraction = meter / 0.3048;	// Compute feet
	integer feet = llFloor(fraction);
	fraction = (fraction - feet) * 12;	// Compute inches
	integer inches = llFloor(fraction);
	fraction = llRound((fraction - inches) * 16);	// Compute 1/16 inches
	string strFeet = (string)feet;
	if (negative)	// Reallocate sign to ensure showing up in case feet value is zero
		strFeet = "-" + strFeet;
	string strFraction = "\"";
	if (fraction != 0)	// show fraction value only if not zero
		strFraction = " " + (string)(integer)fraction + "/16" + strFraction;
	return (strFeet + "' " + (string)inches + strFraction);
}

default
{
	state_entry()
	{
		llOwnerSay("Enter: [m]");
		llListen(0, "", llGetOwner(), "");
	}
	
	listen(integer _chan, string _str, key _id, string _msg)
	{
		float meter = (float)_msg;
		llOwnerSay(Meter2Feet(meter));
	}
}