Restrained Life viewer v1.10.1 Relay Protocol Specification

VERSION 1.000

By Marine Kelley

Audience

This document is meant for people who want to create or modify in-world objects to use the features of someone else's RestrainedLife viewer, typically cages and pieces of furniture, which per definition are usually not owned by that person.

Introduction

The RestrainedLife viewer only executes commands issued through llOwnerSay () messages. Therefore, in order to issue commands to someone using the viewer who does not own the object, that person must wear an attachment that relays commands after some security checks.

Why this spec ?

Now that the RestrainedLife viewer v1.10.1 is out, many cages and furniture creators are interested in using its features such as sit, outfit, tp etc. These objects can be found in public places, or owned by friends... but as they are usually not owned by the user, the relay has to implement some basic security in order to avoid griefing. On top of it, the user does not want to be forced to switch to another relay when going to the next piece of furniture.

This is the purpose of this specification : to lay common rules so all the relays implementing it are compatible with all the furnitures implementing it too. Without such a specification, one cage/furniture would talk to the relay specifically made to operate with it and that's all, eventually making the creator stay behind because people rather use standard objects than proprietary closed ones.

Basic principle

Here is a sample use case :

User is wearing a Relay
User enters a cage in a public area
Cage sends a chat message on a known private channel (for instance "@tploc=n")
Relay receives the message, decides to repeat the command to the user and blocks their ability to teleport from the map with an llOwnerSay ("@tploc=n");
User is allowed to get out after some time, the cage issues a "@tploc=y" command, immediately repeated by the relay

Without the relay, the cage could never prevent the user from teleporting since it doesn't belong to them.

Requirements

Here are the informal requirements for a relay (formal requirements below).

Security

Any object sending commands over the channel the relay listens to is likely to harm the user if there is no security implemented in the former. For instance, one could rez an object that sends a "@remoutfit=force" command over the chat channel to force an avatar to get naked in front of everyone without a warning. Of course nobody wants that, so basic security is needed.

User-friendliness

Security often implies control (access lists, switch, permissions...) so the user must be given some basic control over what kind of objects are allowed to issue commands.

Versatility

Some users will prefer wearing a dedicated attachment that they can unwear any time they want, others will be required to have the relay locked on them so they cannot detach them, others will want the script only... It is important to keep those differences in mind when deciding about the permissions of the relay. However, it is the user's responsibility to choose the relay that suits their needs best.

Licensing

According to the level of complexity and support of the relay, the creator is allowed to either provide it for free (open/close source) or to sell it, as long as it implements all the formal requirements.

Common questions

How hard is it to implement such a specification ?

That depends on what you do. Furniture/cage makers will find it very easy for it only comes down to sending commands over a chat channel and getting feedback. Relay makers will find it harder but then again, that depends on the level of security and user-friendliness they wish to offer. But make no mistake, the relay is what does almost all the job (along with the viewer), because there will be many more kinds of furnitures and cages than relays around.

Why do other people need to write such a relay ? Couldn't you write it yourself and publish it ?

Of course I could, and there is even a working code for a basic relay at the end of this page. However :

The protocol is likely to improve because nobody sees the future
One object only would not suit everyone's needs
It would have to implement perfect security and perfect user-friendliness, in all cases
It would of course have to be perfectly scripted, without any bug whatsoever

The security and user-friendliness are the key parts here. Some users will prefer to be safe from griefing, others will prefer a good user interface, others will like a lot of features, others will want to move the script elsewhere... Everyone has their own tastes so there can be no one-size-fits-all relay.

Protocol

In-world objects send chat message over a channel (common to every relay and furniture), that the relay(s) acknowledges or not. If the message is a correct command and passes whatever security checks the relay implements, the latter repeats it as an llOwnerSay ().

When the session ends, possibly after several relogs, the object clears all the restrictions it has put the user under.

Example

Here is a basic example of messages exchanged between an object (id "9213...") and a relay (id "7adf...") :

Object : CmdTest,9213f69a-ed7d-4a70-907a-7dba88c8831a,@tploc=n
Relay executes llOwnerSay ("@tploc=n");
Relay : CmdTest,7adf6218-ab26-8566-8387-660133840794,@tploc=n,ok

Object : BunchoCommands,9213f69a-ed7d-4a70-907a-7dba88c8831a,@tploc=n|@tplm=n|@tplure=n|@remoutfit:shoes=force
Relay executes llOwnerSay ("@tploc=n");
Relay executes llOwnerSay ("@tplm=n");
Relay executes llOwnerSay ("@tplure=n");
Relay : BunchoCommands,7adf6218-ab26-8566-8387-660133840794,@tploc=n,ok
Relay : BunchoCommands,7adf6218-ab26-8566-8387-660133840794,@tplm=n,ok
Relay : BunchoCommands,7adf6218-ab26-8566-8387-660133840794,@tplure=n,ok
Relay : BunchoCommands,7adf6218-ab26-8566-8387-660133840794,@remoutfit:shoes=force,ko

Formal requirements

Common requirements to the Relay and the in-world object

The chat channel used by both the Relay and the in-world object is -1812221819. That's "RLVRS" ("RestrainedLife Viewer Relay Script") translated from alphabet to numbers.
Messages on this channel are sent with llSay (), no llShout () nor llWhisper () are allowed. This ensures that when closer than 20 m the command is heard, so if no ack is received that means the avatar does not want to play or is already busy.

Messages on the channel are described here in a pseudo Backus-Naur Form :

- Messages from in-world object to Relay :
  - message ::= <cmd_name>,<user_uuid>,<list_of_commands>
  - list_of_commands ::= <command>[|<list_of_commands>] (list_of_commands is *lowercase*)
  - command ::= <rl_command> or <metacommand>
  - rl_command ::= @behav[:option][=param]
  - metacommand ::= !version or !release

- Acknowledgments from Relay to in-world object :
  - message ::= <cmd_name>,<object_uuid>,<command>,<reply> (cmd_name is equal to the one in the incoming message)
  - reply ::= "ok" or "ko" or <protocol_version>
  - protocol_version ::= integer (it is the version of the specification, not of the script)

The effect of the "!release" metacommand is to wipe out all the restrictions issued by the object which sends it.
The effect of the "!version" metacommand is to send the version of the protocol the Relay implements. See below.
Notice that acknowledgments do not apply to the list of commands but to one command only. Therefore a list of N commands gives N acknowledgment messages in return (at most).

In plain English :

<cmd_name> is the name of the command, decided by the object. It will be used to find out which command has been acknowledged, therefore it must be repeated exactly by the Relay (without changing its case).
<user_uuid> is the UUID of the avatar owning the Relay.
<object_uuid> is the UUID of the in-world object. Notice that we never need the UUID of the Relay as it's usually an attachment, prone to change its id after each relog.
<list_of_commands> is a list of RL commands separated by pipes ('|'). It can be a single command.
<command> is either a regular RL command (@behav:option=param) or a metacommand, aimed at the Relay itself (!version and !release)
Commands are separated by pipes ('|') here, but if they must be sent in the same llOwnerSay to the viewer they must be separated by commas (','). This is on purpose, to force the Relay to parse them and check them one by one, as well as facilitate the parsing of the whole message coming from the in-world object.

"!release" metacommand

This metacommand is meant to make the Relay clear all the restrictions linked to the object issuing it. It is better to use it than to issue "counter-commands" to lift every restriction without forgetting any.

"!Version" metacommand

When receiving this metacommand, the Relay must send a special acknowledgment that contains the version of the protocol it implements, on 4 digits. This number must be an integer, equal to the version of this specification, written just after the title on this very page, times 1000. For instance, "1.120" would translate to "1120". It makes it easier to compare versions without fear of losing information with a float cast to a string and back to a float.
Do not mistake the version of the viewer with the version of the protocol and the version of the scripts.

Relay requirements

Send the exact @behav:option=param part in an llOwnerSay (), without any change whatsoever.
Retain list of restrictions and their sources for relog.
Force sit if unsit is prevented when relogging.
The name of the script must contain "RLVnnn" where nnn is the minimal version of the viewer it is compatible with (ex : RLV110). The user must have access to that information (dialog, message, object name...) to check everything works correctly.

In-world object requirements

Never rely on an answer from the Relay, requests can be denied silently, the Relay can be unworn, the avatar can TP out or crash... => use timeouts.
Don't poll the dataserver for online status, the Relay takes care of the relog part.

Sample code of a basic working relay

This particular example that anyone can distribute freely as open-source only (you are not allowed to sell this code) and including the header comments is just meant to give an idea of how a relay basically works.

What it does

Implements the specification described hereabove.
Commented to facilitate reading and learning.
Tested and working with test objects and with real cages.

What it doesn't do

Error-checking.
Access lists.
Lock on the avatar.
Handle more than one object.
Check that the object still exists.
Reject some commands by nature.
And so much more that makes good scripts stand out in the crowd.

How to use it

Create a prim in which you put a script containing this code (don't forget to name it correctly by following the "RLVnnn" requirement).
Wear the prim, it says its current on/off status
Click on the prim to switch from "Off" to "On with permission" to "On without permission" and back to "Off"
Find an object that implements this specification and test.

Special thanks

Chorazin Allen for reviewing the code, giving ideas, coding and re-coding his own scripts to make sure everything works properly between the relay and the cage, and for not killing me every time I change my mind here and there on the spec.

<lsl>

//~ RestrainedLife Viewer Relay Script example code //~ By Marine Kelley //~ 2008-02-03 //~ v1.1 //~ This code is provided AS-IS, OPEN-SOURCE and holds NO WARRANTY of accuracy, //~ completeness or performance. It may only be distributed in its full source code, //~ this header and disclaimer and is not to be sold.

integer RLVRS_PROTOCOL_VERSION = 1000; // version of the protocol, stated on the specification page

string PREFIX_RL_COMMAND = "@"; string PREFIX_METACOMMAND = "!"; integer RLVRS_CHANNEL = -1812221819; //RLVRS in numbers integer DIALOG_CHANNEL = -1812220409; //RLVDI in numbers

list lRestrictions; // restrictions currently applied (without the "=n" part)

key kSource; // UUID of the object I'm commanded by, always equal to NULL_KEY if lRestrictions is empty, always set if not string sPendingName; // name of initiator of pending request (first request of a session in mode 1) key sPendingId; // UUID of initiator of pending request (first request of a session in mode 1) string sPendingMessage; // message of pending request (first request of a session in mode 1) integer nMode; // 0:off, 1:accept on authorization, 2:accept all

Ack (string cmd_id, key id, string cmd, string ack) { // acknowledge or reject

 llSay (RLVRS_CHANNEL, cmd_id+","+(string)id+","+cmd+","+ack);

}

SendRLCmd (string cmd) { // cmd begins with a '@'

 llOwnerSay (cmd);

}

integer IsSimpleRequest (string cmd) {

 // cmd ends with "=" and a number (@version, @getoutfit, @getattach)
 integer ind=llSubStringIndex (cmd, "=");
 if (ind>-1 && llSubStringIndex (cmd, "|")<0) { // there is a "=" and this is not a list of commands
   string param=llGetSubString (cmd, ind+1, -1);
   if ((integer)param!=0 || param=="0") return 1;
 }
 return 0;

}

Execute (string name, key id, string message) {

 // execute a non-parsed message, we are sure the message has been accepted regarding its source (authorization, on/off)
 // this command can still be denied, but this time there will be an acknowledgement
 list tokens=llParseString2List (message, [","], []);
 if (llGetListLength (tokens)==3) { // this is a normal command
   string cmd_id=llList2String (tokens, 0); // CheckAttach
   key target=llList2Key (tokens, 1); // UUID
   if (target==llGetOwner ()) { // talking to me ?
     key my_parcel_group=llList2Key (llGetParcelDetails (llGetPos (), [PARCEL_DETAILS_GROUP]), 0);
     key its_group=llList2Key (llGetObjectDetails (id, [OBJECT_GROUP]), 0);
     key owner_key=llGetOwnerKey (id);
     if (owner_key==llGetOwner ()                          // IF I am the owner of the object
     || its_group==my_parcel_group                         // OR its group is the same as the parcel I'm on
     ) {
       list list_of_commands=llParseString2List (llList2String (tokens, 2), ["|"], []);
       integer len=llGetListLength (list_of_commands);
       integer i;
       string command;
       string prefix;
       string behav;
       string param;
       for (i=0; i<len; ++i) { // execute every command one by one
         // a command can be a RL command if it starts with '@' or a metacommand if it starts with '!'
         command=llList2String (list_of_commands, i);
         prefix=llGetSubString (command, 0, 0);
         if (prefix==PREFIX_RL_COMMAND) { // this is a RL command
           // we need to know whether whether is a rule or a simple command
           list tokens_command=llParseString2List (command, ["="], []);
           behav=llList2String (tokens_command, 0); // @getattach:skull
           param=llList2String (tokens_command, 1); // 2222
           integer ind=llListFindList (lRestrictions, [behav]);
           if (param=="n" || param=="add") { // add to lRestrictions
             if (ind<0) lRestrictions+=[behav];
             kSource=id; // we know that kSource is either NULL_KEY or id already
           } else if (param=="y" || param=="rem") { // remove from lRestrictions
             if (ind>-1) lRestrictions=llDeleteSubList (lRestrictions, ind, ind);
             if (llGetListLength (lRestrictions)==0) kSource=NULL_KEY;
           }
           SendRLCmd (command); // execute command
           Ack (cmd_id, id, command, "ok"); // acknowledge
         } else if (prefix==PREFIX_METACOMMAND) { // this is a metacommand, aimed at the relay itself
           if (command==PREFIX_METACOMMAND+"version") { // checking relay version
             Ack (cmd_id, id, command, (string)RLVRS_PROTOCOL_VERSION);
           } else if (behav==PREFIX_METACOMMAND+"release") { // release all the restrictions (end session)
             ReleaseRestrictions ();
             Ack (cmd_id, id, command, "ok");
           }
         }
       }
     } else {
       // denied, Nack each every command in the list
       list list_of_commands=llParseString2List (llList2String (tokens, 2), ["|"], []);
       integer len=llGetListLength (list_of_commands);
       integer i;
       for (i=0; i<len; ++i) {
         Ack (cmd_id, id, llList2String (list_of_commands, i), "ko");
       }
     }
   }
 }

}

ReleaseRestrictions () {

 kSource=NULL_KEY;
 integer i;
 integer len=llGetListLength (lRestrictions);
 for (i=0; i<len; ++i) {
   SendRLCmd (llList2String (lRestrictions, i)+"=y");
 }

}

string GetMode () {

 if (nMode==0) return "RLV Relay is OFF"; 
 else if (nMode==1) return "RLV Relay is ON (permission needed)"; 
 else return "RLV Relay is ON (auto-accept)";

}

Init () {

 nMode=1;
 kSource=NULL_KEY;
 lRestrictions=[];
 sPendingId=NULL_KEY;
 sPendingName="";
 sPendingMessage="";
 llListen (RLVRS_CHANNEL, "", "", "");
 llListen (DIALOG_CHANNEL, "", llGetOwner (), "");
 llOwnerSay (GetMode ());

}

default {

 state_entry () {
   Init ();
 }
 
 on_rez(integer start_param) {
   if (nMode) {
     integer i;
     integer len=llGetListLength (lRestrictions);
     string restr;
     for (i=0; i<len; ++i) {
       restr=llList2String (lRestrictions, i);
       SendRLCmd (restr+"=n");
       if (restr=="@unsit") {
         SendRLCmd ("@sit:"+(string)kSource+"=force");
       }
     }
   }
   llOwnerSay (GetMode ());
 }
 
 listen(integer channel, string name, key id, string message) {
   if (channel==RLVRS_CHANNEL) { // CheckAttach,UUID,@getattach:skull=2222
     // do a basic check without parsing the command, reject without any acknowledgement when needed
     if (nMode==0) return; // mode is 0 (off) => reject
     if (kSource!=NULL_KEY && kSource!=id) return; // already used by another object => reject
     if (IsSimpleRequest (message)) { // simple harmless command such as @version, @getoutfit or @getattach
       Execute (name, id, message);
       return;
     }
     if (nMode==1) {
       if (kSource==NULL_KEY) {
         if (sPendingId==NULL_KEY) { // not under operation yet, prompt the user, delay reply until they accept or reject
           sPendingId=id;
           sPendingName=name;
           sPendingMessage=message;
           llDialog (llGetOwner (), name+" would like to connect to your RLV Relay and send commands to your viewer.\n\nDo you accept ?", ["Yes", "No"], DIALOG_CHANNEL);
         }
       } else if (kSource==id) { // already operated by this object, accept automatically
         Execute (name, id, message);
       }
     } else if (nMode==2 && (kSource==NULL_KEY || kSource==id)) { // accept automatically
       Execute (name, id, message);
     }
   } else if (channel==DIALOG_CHANNEL) {
     if (sPendingId!=NULL_KEY) {
       if (message=="Yes") { // pending request authorized => process it
         Execute (sPendingName, sPendingId, sPendingMessage);
       } else if (message=="No") { // denied => do nothing at all
         
       }
       // clear pending request
       sPendingName="";
       sPendingId=NULL_KEY;
       sPendingMessage="";
     }
   }
 }
 
 touch_start(integer num_detected) {
   key toucher=llDetectedKey (0);
   if (toucher==llGetOwner ()) {
     ++nMode;
     if (nMode>2) nMode=0;
     if (nMode==0) ReleaseRestrictions ();
     llOwnerSay (GetMode ());
   }
 }

 changed(integer change) {
   if (change & CHANGED_OWNER) llResetScript ();
 }

}

</lsl>

LSL Protocol/Restrained Love Relay/Reference Implementation

Contents