LlDetectedTouchST/ja

touch された点の、プリム面上の座標のvector値を返します。

• index が正常なインデックス範囲を外れていても、スクリプトはエラー表示を出さずに処理を続けます。
• 以下の場合は TOUCH_INVALID_TEXCOORD が返されます:
  • アバターのビューアが touch 面の検出に対応していない。
    • ビューアの対応は llDetectedTouchFace の戻り値でチェックできます。
  • touch 点がプリムの表面から外れた。
  • touch 点を取得できないほど、touch 点が面の端に近すぎた。
  • この関数を呼び出したイベントが touch 系イベントでない。

default {
 
    touch_start(integer num_detected) {
        integer i = 0;
        for(; i < num_detected; ++i ) {
            vector touchedpos = llDetectedTouchST(i);      
 
            if (llDetectedTouchFace(i) == -1) {
                llWhisper(0, "ビューアが touch 面の検出に対応していません。");
            }
            else if ( touchedpos == TOUCH_INVALID_TEXCOORD ) {
                llWhisper(0, "touch 点を取得できませんでした。");
            }
            else {
                llWhisper(0, (string) touchedpos);
            }
        } // while ...
    } // touch_start
 
}

vector touchedLoc;
 
default {
// touch された点にクロスヘアを描く
 
    touch(integer num_detected) {
        integer i;
        for (i = 0; i < num_detected; i++) {
            touchedLoc = llDetectedTouchST(i); // touch された面座標
            llSetPrimitiveParams([PRIM_TEXTURE, llDetectedTouchFace(i), "5ac7995c-4c24-8b60-ae61-6a837619dc75",
                          <1.0,1.0,0.0>, touchedLoc, 180*DEG_TO_RAD]); /// touch 点をテクスチャ座標として設定する
        }
    }
 
}
 

 
// 指定した列数・行数 (以下では 12x12) でテクスチャをタイル状に敷き詰めておき、
// どの格子に touch されたかを答える。
 
float x=12.0;
float y=12.0;
integer Pos;
 
default{
 
    touch_start(integer total_number){
        if (llDetectedTouchFace(0) == -1)
            llOwnerSay("old client");
        else{
            vector pos = llDetectedTouchST(0);
            Pos = ((llFloor((pos.x*10)*x)/10)*(integer)y)+llCeil(pos.y*y);
            llOwnerSay((string)Pos);
        }
    }
}
 

イベント

関数

項目

経緯