LlDetectedTouchST

From Second Life Wiki
Jump to: navigation, search

Summary

Function: vector llDetectedTouchST( integer index );

Returns a vector that is the surface coordinates for where the prim was touched. The x & y vector positions contain the horizontal (s) & vertical (t) face coordinates respectively (<s, t, 0.0>). Each component is usually in the interval [0.0, 1.0] with the origin in the bottom left corner.[1] With some mesh objects, values of less than 0.0 and higher than 1.0 have been observed.

TOUCH_INVALID_TEXCOORD is returned when the surface coordinates cannot be determined. See Caveats for further details.

• integer index Index of detection information

index does not support negative indexes. For the touch category of events only. The prim that was touched may not be the prim receiving the event, use llDetectedLinkNumber to check for this; likewise you can use llDetectedTouchFace to determine which face was touched.

Caveats

  • If index is out of bounds the script continues to execute without an error message.
  • TOUCH_INVALID_TEXCOORD is returned when...
    • The avatar's viewer does not support face touch detection.
    • The touch has moved off the surface of the prim.
    • The touch happened too close to the edge of the face to determine a location.
    • The event triggered is not a touch event.
All Issues ~ Search JIRA for related Bugs

Examples

default
{
    touch_start(integer total_number)
    {
        integer touchFace = llDetectedTouchFace(0);
        vector  touchST   = llDetectedTouchST(0);
 
//      ZERO_VECTOR (<0.0, 0.0, 0.0> ... the origin) is in the bottom left corner of the face
//      touchST.x goes across the face from the left to the right
//      touchST.y goes up the face from the bottom to the top
 
        if (touchFace == -1)
            llWhisper(PUBLIC_CHANNEL, "Sorry, your viewer doesn't support touched faces.");
        else if (touchST == TOUCH_INVALID_TEXCOORD)
            llWhisper(PUBLIC_CHANNEL, "Sorry, the touch position upon the face could not be determined.");
        else
            llSay(PUBLIC_CHANNEL, "llDetectedTouchST(0) = " + (string)touchST
                    + "\ntouchST.x = " + (string)touchST.x
                    + "\ntouchST.y = " + (string)touchST.y);
    }
}
integer numberOfRows    = 12;
integer numberOfColumns = 12;
 
default
{
    touch_start(integer total_number)
    {
        vector  touchST     = llDetectedTouchST(0);
 
//      ZERO_VECTOR (<0.0, 0.0, 0.0> ... the origin) is in the bottom left corner of the face
//      touchST.x goes across the face from the left to the right
//      touchST.y goes up the face from the bottom to the top
 
        integer columnIndex = (integer) (touchST.x * numberOfColumns);
        integer rowIndex    = (integer) (touchST.y * numberOfRows);
        integer cellIndex   = (rowIndex * numberOfColumns) + columnIndex;
 
        llSay(PUBLIC_CHANNEL, "ST grid (" + (string)columnIndex + ", " + (string)rowIndex
                            + ") --> cell " + (string)cellIndex);
    }
}
//  with friendly permission of Supremius Maximus
//  who made the texture used in this script
//
//  click&hold the mouse while dragging across
//  the face of the prim
 
default
{
    touch(integer num_detected)
    {
        integer link    = llDetectedLinkNumber(0);
        integer face    = llDetectedTouchFace(0);
        vector  touchST = llDetectedTouchST(0);
 
//      ZERO_VECTOR (<0.0, 0.0, 0.0> ... the origin) is in the bottom left corner of the face
//      touchST.x goes across the face from the left to the right
//      touchST.y goes across the face from the bottom to the top
 
        string uuid = "23badbe7-6d8c-639b-0131-bb321f8e9db5";
 
        llSetLinkPrimitiveParamsFast(link, [
            PRIM_TEXTURE, face, uuid, <1.0, 1.0, 0.0>, touchST, 0,
            PRIM_FULLBRIGHT, ALL_SIDES, TRUE]);
    }
}

See Also

Deep Notes

History

Search JIRA for related Issues

Footnotes

  1. ^ The ranges in this article are written in Interval Notation.

Signature

function vector llDetectedTouchST( integer index );
This article wasn't helpful for you? Maybe the related article at the LSL Wiki is able to bring enlightenment.