LlDetectedTouchST

Returns a vector that is the surface coordinates for where the prim was touched. The x & y vector positions contain the horizontal (s) & vertical (t) face coordinates respectively (<s, t, 0.0>). Each component is in the interval [0.0, 1.0].

TOUCH_INVALID_TEXCOORD is returned when the surface coordinates cannot be determined. See Caveats for further details.

index does not support negative indexes. For the touch category of events only. The prim that was touched may not be the prim receiving the event, use llDetectedLinkNumber to check for this; likewise you can use llDetectedTouchFace to determine which face was touched.

• If index is out of bounds the script continues to execute without an error message.
• TOUCH_INVALID_TEXCOORD is returned when...
  • The avatar's viewer does not support face touch detection.
    • To check if face touch detection is supported check the return of llDetectedTouchFace.
  • The touch has moved off the surface of the prim.
  • The touch happened too close to the edge of the face to determine a location.
  • The event triggered is not a touch event.

Search JIRA for related Bugs

default {
 
    touch_start(integer num_detected) {
        integer i = 0;
        for(; i < num_detected; ++i ) {
            vector touchedpos = llDetectedTouchST(i);      
 
            if (llDetectedTouchFace(i) == -1) {
                llWhisper(0, "Sorry, your viewer doesn't support touched faces.");
            }
            else if ( touchedpos == TOUCH_INVALID_TEXCOORD ) {
                llWhisper(0, "Sorry, the surface touch position could not be determined.");
            }
            else {
                llWhisper(0, (string) touchedpos);
            }
        } // while ...
    } // touch_start
 
}

vector touchedLoc;
 
default {
 //Draws a cross-hair at the detected Location on the detected face.
 
    touch(integer num_detected) {
        integer i;
        for (i = 0; i < num_detected; i++) {
            touchedLoc = llDetectedTouchST(i); //What location has been touched?
            llSetPrimitiveParams([PRIM_TEXTURE, llDetectedTouchFace(i), "5ac7995c-4c24-8b60-ae61-6a837619dc75",
                          <1.0,1.0,0.0>, touchedLoc, 180*DEG_TO_RAD]); //Set the Texture Location at the touched location
        }
    }
 
}
 

 
//Sets a grid of x by y, in this case 144 squares and returns that number on touch.
 
float x=12.0;
float y=12.0;
integer Pos;
 
default{
 
    touch_start(integer total_number){
        if (llDetectedTouchFace(0) == -1)
            llOwnerSay("old client");
        else{
            vector pos = llDetectedTouchST(0);
            Pos = ((llFloor((pos.x*10)*x)/10)*(integer)y)+llCeil(pos.y*y);
            llOwnerSay((string)Pos);
        }
    }
}
 

Events

Functions

Articles

History

Issues

Search JIRA for related Issues