LlMakeExplosion/ja

パーティクルが球状に広がるような爆発を表現します。

• この関数は廃止されているので、代替案としてllParticleSystemを使用してください。
• この関数は0.1秒間、スクリプトを停止します。

バージョン 1.14 以降、それまでの llMakeExplosion によるパーティクルと同等の表現が可能な llParticleSystem が用意されました。

 
llMakeExplosion(integer particle_count,
                float particle_scale,
                float particle_speed,
                float particle_lifetime,
                float source_cone,
                string source_texture_id,
                vector local_offset);
 

 
fakeMakeExplosion(integer particle_count, float particle_scale, float particle_speed, 
                 float particle_lifetime, float source_cone, string source_texture_id, 
                 vector local_offset) 
{
    //local_offset is ignored
    llParticleSystem([
        PSYS_PART_FLAGS,            PSYS_PART_INTERP_COLOR_MASK | PSYS_PART_INTERP_SCALE_MASK | PSYS_PART_EMISSIVE_MASK | PSYS_PART_WIND_MASK,
        PSYS_SRC_PATTERN,           PSYS_SRC_PATTERN_ANGLE_CONE,
        PSYS_PART_START_COLOR,      <1.0, 1.0, 1.0>,
        PSYS_PART_END_COLOR,        <1.0, 1.0, 1.0>,
        PSYS_PART_START_ALPHA,      0.50,
        PSYS_PART_END_ALPHA,        0.25,
        PSYS_PART_START_SCALE,      <particle_scale, particle_scale, 0.0>,
        PSYS_PART_END_SCALE,        <particle_scale * 2 + particle_lifetime, particle_scale * 2 + particle_lifetime, 0.0>,
        PSYS_PART_MAX_AGE,          particle_lifetime,
        PSYS_SRC_ACCEL,             <0.0, 0.0, 0.0>,
        PSYS_SRC_TEXTURE,           source_texture_id,
        PSYS_SRC_BURST_RATE,        1.0,
        PSYS_SRC_ANGLE_BEGIN,       0.0,
        PSYS_SRC_ANGLE_END,         source_cone * PI,
        PSYS_SRC_BURST_PART_COUNT,  particle_count / 2,
        PSYS_SRC_BURST_RADIUS,      0.0,
        PSYS_SRC_BURST_SPEED_MIN,   particle_speed / 3,
        PSYS_SRC_BURST_SPEED_MAX,   particle_speed * 2/3,
        PSYS_SRC_MAX_AGE,           particle_lifetime / 2,
        PSYS_SRC_OMEGA,             <0.0, 0.0, 0.0>
        ]);
}
//    既知の相違点
//    1) llMakeExplosion ではパーティクルの表示持続時間はランダムでした。
//       これは llParticleSystem では、それ単体では実現できません。
//    2) llMakeExplosion ではパーティクルはその表示中、大きくなり続けました。
//       表示持続時間が長い場合、llParticleSystem の限界である 4m よりもさらに大きくなりました。
//    3) llMakeExplosion の引数 'arc' は X 軸を基準にしていましたが、
//       llParticleSystem では Z 軸が基準になります。
//    4) llMakeExplosion ではいくつかの値が語義どおりの意味を持っていませんでした。
//       (例えば '''vel''' は秒速でなく、'''particles''' は本来のパーティクル数からかけ離れていました。)
//       ここで示した例では、近似の表現になるよう一定の比率をあてはめましたが、
//       場合によっては期待通りの表現になっていないかもしれません。
//    5) llMakeExplosion の設定と llParticleSystem の設定の差分を求めることはできません。