User:Daemonika Nightfire/Scripts/Access Tutorial

From Second Life Wiki
Jump to: navigation, search

Language: Solution provider flag de.gif Solution provider flag us.gif

Berechtigungen Allgemein

Die ersten 4 Beispiele funktionieren in saemtlichen Events, wo man den AvatarKey (UUID) durch llDetectedKey(0) abfragen kann. Zum einfachen Verstaendniss habe ich mich entschlossen hier nur den touch Event und weiter unten zum Vergleich den listener Event aufzufuehren, weil dort kein llDetectedKey(0) moeglich ist.

Public / Oeffentlich

Wie du siehst, siehst du nichts, zumindest nichts besonderes. Dieses Script ist im grunde nichts anderes, als ein "New Script" was jeder in einem Prim erstellen kann. Es besitzt keinerlei Abfragen oder Beschraenkungen, damit ist die Funktion fuer jeden der das Object klickt ausfuehrbar.

default
{
    state_entry()
    {
 
    }
 
    touch_start(integer total_number)
    {
        llSay(0, "Touched.");
    }
 
    on_rez(integer Dae)
    {
        llResetScript();
    }
}


Owner / Besitzer

Bei diesem Script sieht es schon etwas anders aus. Wenn das Object geklickt wird, ueberprueft es erst, ob der jenige der es klickt auch wirklich der Besitzer ist.

key owner; // globale Variable zum speichern des OwnerKey's
 
default
{
    state_entry()
    {
        owner = llGetOwner(); // speichert den OwnerKey (UUID)
    }
 
    touch_start(integer num_detected)
    {
        if(llDetectedKey(0) == owner) // erkannter Key == (gleich) Owner
        {
            llSay(0, "Touched.");
        }
        else if(llDetectedKey(0) != owner) // erkannter Key != (nicht gleich) Owner
        {
            llSay(0,"Du bist nicht der Besitzer.");
        }
    }
 
    on_rez(integer Dae)
    {
        llResetScript();
    }
}

Folgende alternativen Beispiele setzen vorraus, das der Owner bereitz wie im oberen Script als globale Variable gespeichert wurde, andernfalls muss die Variable 'owner' mit llGetOwner() ersetzt werden.

Alternative Methode 1 Alternative Methode 2
    touch_start(integer num_detected)
    {
        key Avatar = llDetectedKey(0);
        if(Avatar == owner) // erkannter Key == (gleich) Owner
        {
            llSay(0, "Du bist der Besitzer.");
        }
        else if(Avatar != owner) // erkannter Key != (nicht gleich) Owner
        {
            llSay(0,"Du bist nicht der Besitzer.");
        }
    }
    touch_start(integer num_detected)
    {
        key Avatar = llDetectedKey(0);
        string Message = "Du bist nicht der Besitzer.";
        // Solange der Besitzer nicht klickt, gilt die obere Message.
        if(Avatar == owner)
        {
            // Klickt der Besitzer, wird hier die Message ersetzt.
            Message = "Du bist der Besitzer.";
        }
        llSay(0, Message);
    }
Einen Gegenbeweis mittels 'else if' kann man sich eigentlich sparen, wenn nur der Besitzer das Script verwenden darf.
Das erspart dir nicht nur unnoetige Arbeit, sondern spart auch Speicher (memory) fuer wichtigere Funktionen.
Ausser du moechtest unterschiedliche Funktionen fuer unterschiedliche User, dann musst du natuerlich wie in den oberen Beispielen unterscheiden.
    touch_start(integer num_detected)
    {
        key Avatar = llDetectedKey(0);
        if(Avatar == owner) // erkannter Key == (gleich) Owner
        {
            llSay(0, "Du bist der Besitzer.");
        }
    }


Group / Gruppe

Bei diesem Script sieht es wieder etwas anders aus. Wenn das Object geklickt wird, ueberprueft es erst, ob der jenige der es klickt auch die selbe Gruppe traegt. Dabei ist wichtig zu wissen, das es sich um die Gruppe handelt, mit der das Object gerezzt wurde.

Beispiel 1 bessere Methode
// Dieses Beispiel dient nur zum Verstaendniss, was ueberhaupt im touch passiert.
 
default
{
    state_entry()
    {
 
    }
 
    touch_start(integer num_detected)
    {
        // traegt der Avatar die gleiche Gruppe wie das Object?
        if(llSameGroup(llDetectedKey(0)) == TRUE)
        {
            llSay(0, "Touched.");
        }
 
        // traegt der Avatar nicht die gleiche Gruppe wie das Object?
        else if(llSameGroup(llDetectedKey(0)) == FALSE)
        {
            llSay(0,"Du traegst nicht die richtige Gruppe.");
        }
    }
 
    on_rez(integer Dae)
    {
        llResetScript();
    }
}
default
{
    state_entry()
    {
 
    }
 
    touch_start(integer num_detected)
    {
        key Avatar = llDetectedKey(0);
        integer Group = llSameGroup(Avatar);
 
        // traegt der Avatar die gleiche Gruppe wie das Object?
        if(Group)
        {
            llSay(0, "Touched.");
        }
        // traegt der Avatar nicht die gleiche Gruppe wie das Object?
        else if(!Group)
        {
            llSay(0,"Du traegst nicht die richtige Gruppe.");
        }
    }
 
    on_rez(integer Dae)
    {
        llResetScript();
    }
}


VIP / Zugangsliste

Bei diesem Script sieht das Ganze voellig anders aus. Anders als bei den ersten 3 Versionen, bei denen nur alle, der Besitzer oder die ganze Gruppe festgelegt werden, kann man hier mehrere User, unabhaengig von Eigentumsrechten und Gruppenzugehoerigkeit bestimmen. Wenn das Object geklickt wird, ueberprueft es erst ob der Name der Person die es klickt auf der Liste steht.

// User mit Resident als Nachname werden "ohne punkt und ohne Nachname" eingetragen
list VIP = ["daemonika.nightfire", "jane.doe", "john.doe"]; 
 
default
{
    state_entry()
    {
 
    }
 
    touch_start(integer num_detected)
    {
        if(~llListFindList(VIP, llCSV2List(llGetUsername(llDetectedKey(0))))) // sucht hier in der Liste nach dem Namen des klickenden
        {
            llSay(0, "Touched.");
        }
        else //if(!~llListFindList(VIP, llCSV2List(llGetUsername(llDetectedKey(0)))))
        {
            llSay(0,"Du stehst nicht auf der Liste.");
        }
    }
 
    on_rez(integer Dae)
    {
        llResetScript();
    }
}

Von einer Verwendung von Displaynamen kann ich nur abraten, weil diese nicht einzigartig sind.
Besser ist es sich auf Usernamen oder AvatarKey's (UUID) zu konzentrieren.
Dieses Script funktioniert ebenfalls mit Keys, dazu ersetze die entsprechenden Eintraege mit folgenden Beispielen.
// In diese Liste trage die AvatarKey's ein, welche das Scrirpt ausfuehren duerfen.
list VIP = ["61ee201a-81cf-4322-b9a8-a5eb8da777c2", "00000000-0000-0000-0000-000000000000"];
 
// Diese if vergleicht den Key des klickenden mit der Liste.
if(~llListFindList(VIP, llCSV2List(llDetectedKey(0)))) // sucht hier in der Liste nach dem Key (UUID) des klickenden

Berechtigungen im Listener

Die Listener Variante fuehre ich nur auf, weil dort kein llDetectedKey(0) funktioniert, jedoch kann man auch dabei unterscheiden, weil der listener selber die 'id' (UUID) erkennt. Weiterhin funktioniert diese Methode in saemtlichen Events, wo zwar kein llDetectedKey(0) moeglich ist, jedoch die 'id' (UUID) des Avatars auf anderem weg erkannt wird.

Listener - Public / Oeffentlich

Dieses Script verfuegt ueber keinerlei beschraenkungen und reagiert auf jeden Avatar.

default
{
    state_entry()
    {
        llListen(0, "", "", ""); // startet den listener
    }
 
    listen(integer chan, string name, key id, string message)
    {
        if(message == "hallo") // Reagiert auf das wort 'hallo' wenn es im chat geschrieben wird.
        {
            llSay(0, "Hallo " + llGetDisplayName(id));
        }
    }
 
    on_rez(integer Dae)
    {
        llResetScript();
    }
}


Listener - Owner / Besitzer

In diesem Script wird der Owner gleich im llListen Befehl eingetragen. Dadurch reagiert das Script ausschliesslich auf den Owner und im Listener Event sind keine weiteren Abfragen notwendig.

default
{
    state_entry()
    {
        // Wenn das Script ausschliesslich auf den Owner reagieren soll, ist die llGetOwner() Abfrage im llListen Befehl voellig ausreichend.
        llListen(0, "", llGetOwner(), ""); // startet den listener
 
        // Alternativ kann man auch den Owner Namen direkt eintragen.
        // Das wuerde ich aber nicht empfehlen, weil es nicht dynamisch ist und im Falle des Weitergebens nicht auf den neuen Besitzer hoert.
        //llListen(0, "Daemonika Nightfire", "", ""); // startet den listener
    }
 
    listen(integer chan, string name, key id, string message)
    {
        // An dieser Stelle habe ich noch die alternative Methode zum abfragen des Owners inaktiv als Beispiel eingetragen.
        // Diese Methode ist nicht noetig, weil der Listener schon ab dem Befehl oben ausschliesslich auf den Owner reagiert.
 
      // Vorraussetzung dafuer ist ein komplett leerer llListen Befehl oben: llListen(0, "", "", "");
      //if(id == llGetOwner())
      //{
            if(message == "hallo") // Reagiert auf das wort 'hallo' wenn es im chat geschrieben wird.
            {
                llSay(0, "Hallo " + llGetDisplayName(id));
            }
      //}
    }
 
    on_rez(integer Dae)
    {
        llResetScript();
    }
}

Listener - Group / Gruppe

Um die Gruppe abzufragen muss man wie im folgenden Beispiel schon anders vorgehen. Hierbei wird erst im Listener Event die Gruppe des Objects mit der aktiven Gruppe des Avatars verglichen und dann erst auf die Message reagiert.

default
{
    state_entry()
    {
        // hier ist es diesmal nicht moeglich die Gruppe zu vergleichen.
        llListen(0, "", "", ""); // startet den listener
    }
 
    listen(integer chan, string name, key id, string message)
    {
        if(llSameGroup(id) == TRUE) // ist die erkannte Gruppe des Avatars die selbe, wie die des  Objekts RICHTIG?
        {
            if(message == "hallo") // Reagiert auf das wort 'hallo' wenn es im chat geschrieben wird.
            {
                llSay(0, "Hallo " + llGetDisplayName(id));
            }
        }
    }
 
    on_rez(integer Dae)
    {
        llResetScript();
    }
}


Listener - VIP / Zugangsliste

Wie im vorherigen Script, wird auch hier erst im Listener Event eine Zugangsliste verglichen und dann erst auf die Message reagiert.

// In diese Liste trage die AvatarKey's ein, welche das Scrirpt ausfuehren duerfen.
list VIP = ["61ee201a-81cf-4322-b9a8-a5eb8da777c2", "00000000-0000-0000-0000-000000000000"]; 
 
default
{
    state_entry()
    {
        // hier ist es ebenfalls nicht moeglich die Liste zu vergleichen.
        llListen(0, "", "", ""); // startet den listener
    }
 
    listen(integer chan, string name, key id, string message)
    {
        if(~llListFindList(VIP, llCSV2List(id))) // sucht hier in der Liste nach dem Key (UUID) des Avatars
        {
            if(message == "hallo") // Reagiert auf das wort 'hallo' wenn es im chat geschrieben wird.
            {
                llSay(0, "Hallo " + llGetDisplayName(id));
            }
        }
    }
 
    on_rez(integer Dae)
    {
        llResetScript();
    }
}
Wie auch oben beim Touch Beispiel kann man auch hier die Namen der Avatare abfragen.
Dazu ersetze die entsprechenden Eintraege im Script mit folgenden Beispielen.
// User mit Resident als Nachname werden "ohne punkt und ohne Nachname" eingetragen
list VIP = ["daemonika.nightfire", "jane.doe", "john.doe"]; 
 
// Diese if vergleicht den Namen des Avatars mit der Liste.
if(~llListFindList(VIP, llCSV2List(llGetUsername(id)))) // sucht hier in der Liste nach dem Namen des Avatars


Wechselbare Berechtigung als Menue Beispiel

Bevor jetzt wieder jemand meckert, warum ich das Menue so und nicht anders gemacht habe, sollte man sich vor Augen halten, dass dieses nur ein Beispiel ist und es unzaehlige Varianten zum gestalten eines Menues gibt. Hier geht es einzig und allein um die Unterscheidung der Berechtigungen.

key owner; // globale Variable zum speichern des OwnerKey's
 
// In diese Liste trage die AvatarKey's ein, welche das Scrirpt ausfuehren duerfen.
list VIP = ["61ee201a-81cf-4322-b9a8-a5eb8da777c2", "00000000-0000-0000-0000-000000000000"];
 
integer GroupAccess = FALSE;
integer PublicAccess = FALSE;
 
integer menu_handler;
integer menu_channel;
menu(key user,string title,list buttons) // diese Funktion erlaubt dir unentlich viele Dialoge mit einem timer.
{
    llListenRemove(menu_handler); // loescht den letzten bekannten Listener (nuetzlich falls der Timer noch nicht abgelaufen war)
 
    menu_channel = (integer)(llFrand(9999999.0) * -1);  // zufaelliger channel von -9999999.0 bis 9999999.0
    menu_handler = llListen(menu_channel,"","","");     // erstellt hier einen neuen Listener mit dem neuen Channel
    llDialog(user, title, buttons, menu_channel);       // oeffnet hier das Dialog-Fenster fuer den Benutzer
 
    llSetTimerEvent(30.0); // startet hier den Timer, der nach ablauf der Zeit den Listener loescht.
}
 
default
{
    state_entry()
    {
        owner = llGetOwner(); // speichert den OwnerKey (UUID)
    }
 
    touch_start(integer num_detected)
    {
        key Avatar = llDetectedKey(0);
 
        if(Avatar == owner) // erkannter Key == (gleich) Owner
        {
            menu(owner,"Dieses Menue ist fuer den Besitzer.",["Owner","Group","Public","1","2","3","OK"]);
        }
 
        else if(~llListFindList(VIP, llCSV2List(Avatar))) // sucht hier in der Liste nach dem Key (UUID) des klickenden
        {
            menu(Avatar,"Dieses Menue ist fuer VIP's.",["1","2","3","OK"]);
        }
 
        else if(GroupAccess == TRUE)
        {
            integer Group = llSameGroup(Avatar);
            if(Group)
            {
                menu(Avatar,"Dieses Menue ist fuer Gruppenmitglieder",["1","2","3","OK"]);
            }
        }
 
        else if(PublicAccess == TRUE)
        {
            menu(Avatar,"Dieses Menue ist oeffentlich",["OK"]);
        }
    }
 
    listen(integer channel, string name, key id, string message)
    {
        // Diese Optionen koennen nur durch den Besitzer geaendert werden.
        if(message == "Owner")
        {
            GroupAccess = FALSE;
            PublicAccess = FALSE;
            llOwnerSay("Berechtigung: Besitzer");
        }
        else if(message == "Group")
        {
            GroupAccess = TRUE;
            PublicAccess = FALSE;
            llOwnerSay("Berechtigung: Besitzer & Gruppenmitglieder.");
        }
        else if(message == "Public")
        {
            GroupAccess = FALSE;
            PublicAccess = TRUE;
            llOwnerSay("Berechtigung: Alle / oeffentlich");
        }
 
        // Diese Optionen stehen sowohl Besitzer und VIP's als auch Gruppenmitgliedern zur verfuegung.
        else if(message == "1")
        {
            llSay(0,"Besitzer, VIP o. Gruppenmitglied hat die '1' gedrueckt.");
        }
        else if(message == "2")
        {
            llSay(0,"Besitzer, VIP o. Gruppenmitglied hat die '2' gedrueckt.");
        }
        else if(message == "3")
        {
            llSay(0,"Besitzer, VIP o. Gruppenmitglied hat die '3' gedrueckt.");
        }
 
        // Diese Option stehen allen zur verfuegung.
        else if(message == "OK")
        {
            llSay(0,"Es wurde auf 'OK' gedrueckt.");
        }
    }
 
    timer()
    {
        llSetTimerEvent(0.0); // stoppt den Timer
        llListenRemove(menu_handler); // loescht den aktuellen Listener
    }
 
    on_rez(integer Dae)
    {
        llResetScript();
    }
}