User:Opensource Obscure/Chromutate - Second Life Wiki

User:Opensource Obscure/Chromutate

From Second Life Wiki

Second Life Wiki > Opensource Obscure/Chromutate
Jump to: navigation, search

Go back to Opensource Obscure's userpage



Contents

Overview

Chromutate is a series of interactive installations I have built in Second Life - an excuse to play around with SL Physics, scripting, Reflexive Architecture (see below) and HTTP-in LSL features.

As of 2012, January, a scaled down instance of Chromutate is rezzed and working in my land at the LOL sim.

See Chromutate 1.0 at original size in the Chromutate playlist on YouTube.

Feel free to visit and play with it!
Change the colors of the buildings, rez stuff and send in-world messages from the web page, or walk over it in-world and discover how the installation reacts to your presence (hint: touch orange objects!). Take a copy of the scripted objects if you're inclined so (almost all objects and contents are supposed to be full-perms) and please warn me if something doesn't work.

File:Rossoverde.jpg

Ideas

Tech / code

I use Gridurl to maintain persistent URLs for my LSL scripts. See the code below.
Disclaimer: I'm not a real programmer and your comments and suggestions are welcome.

For the HTML, look the web page source. Here are the LSL scripts.
The main script below receives data from the web page, where you can choose colors and something else through a form. The script then parses those data and does some things with them - it rezzes an object (or not) and it relays the parsed data via chat channels to other objects.

Reflexive Architecture

Virtual architecture, and the context it lives in, differs from physical architecture. It becomes less like a static artifact, and more like a liquid. An architecture truly responsive to its fluid context must be able to shift shape along with it. ([Jon Brouchoud])

For more information about Reflexive Architecture, see User:Dizzy_Banjo#DynaFleur and read archsl.wordpress.com [starting from this page].
Direct links to both video and more free scripts:

Controller script

This manages HTTP calls, talks to Gridurl, receives data from HTML form and sends commands to installation components.

string name1 = "LOL_color_controller";
string name2 = "Someone at http://alisl.org/chromutate just wrote: ";
 
string risposta = "Thanks! Please use the button in your browser to go back.";
key mykey = "eb42408b-5888-42b7-80d6-b00ca2eb9781"; // my SL UUID - change this!
 
string gridurl_key="4ab936c7-36dc-4444-82f9-62e4bf3a5475"; // change this!
string gridurl_indirizzo = "http://gridurl.appspot.com/go/4ab936c7-36dc-4444-82f9-62e4bf3a5475"; // change this!
string baseurl = "http://gridurl.appspot.com/reg?service=";
 
integer chan1 = -20241; // you may want to change this as well
integer chan2 = -20242; // you may want to change this as well
integer chan3 = -20243; // you may want to change this as well
integer channel_avvertore = -20247; // you may want to change this as well
 
 
string strReplace(string str, string search, string replace) 
{
    return llDumpList2String(llParseStringKeepNulls((str = "") + str, [search], []), replace);
}
 
vector  sbColorConvert(string strData) {
    integer mode = -1; // llListFindList(lstHTML, [llToLower(strData)]);
    integer intColor = 0;
 
    {
 
        string strStart = llGetSubString(strData, 0, 1);
        if (strStart != "0x") {
            if (llGetSubString(strStart, 0, 0) == "#") {
                strData = "0x" + llDeleteSubString(strData, 0, 0);
            }
            else {
                vector vecColor = (vector)("<"+strData+">");
                if (vecColor) {
                    return (vector)("<"+strData+">") / 255;
                }
                strData = "0x" + strData;
            }
        }
        intColor = (integer)strData;
        mode = llStringLength(strData);
    }
    if (mode == 8) {//RRGGBB
        return <(intColor >> 16) & 0xFF, (intColor >> 8) & 0xFF, (intColor & 0xFF)> / 0xFF;
    }
    return ZERO_VECTOR;//black
}
 
 
string url;
string query;
string nome;
string t1 = "il mio indirizzo e' ";
key requestid;
integer status = FALSE;
list requests;
vector pos_orig;
 
////////////////////////////////////////////////////////////////////////////////
 
// richiedo un nuovo URL per lo script 
setup()
{
    url = "";
    llRequestURL();
}
 
 
// risponde via HTTP
send_response(key id, string body)
{
    llHTTPResponse(id, 200, risposta);
}
 
 
// http://gridurl.appspot.com/
update_gridurl(string testo)
{
    query = gridurl_key + "&url=" + llEscapeURL(testo) + "/";
    requestid = llHTTPRequest(baseurl + query,[HTTP_METHOD,"GET", HTTP_MIMETYPE,"application/x-www-form-urlencoded"], "");    
}
 
 
 
// fa qualcosa
fa(key id, string asd)
{
    string a = llUnescapeURL(asd);
    send_response(id, a);    
    list variabili = llParseString2List(asd, ["rez=", "&color1=", "&color2=","&color3=", "&a="], [""]);
    integer rez_choice = (integer)llList2String(variabili, 0);
    string color1 = llUnescapeURL(llList2String(variabili, 1));
    string color2 = llUnescapeURL(llList2String(variabili, 2));    
    string color3 = llUnescapeURL(llList2String(variabili, 3));   
    string messaggio = llUnescapeURL(llList2String(variabili, 4));        
    llRegionSay(chan1, (string)sbColorConvert(color1));
    llRegionSay(chan2, (string)sbColorConvert(color2));    
    llRegionSay(chan3, (string)sbColorConvert(color3));          
    //    llOwnerSay("> " + llList2String(variabili, 0));
    if(rez_choice == 1)
    {
        altro();
    }
    if(messaggio)
    {
        messaggio = strReplace(messaggio, "+", " ");
        llSetObjectName(name2);
        llShout(0, messaggio);
        llSetObjectName(name1);
    }                  
    llInstantMessage(mykey, messaggio);                
}
 
 
altro()
{
        string obj = llGetInventoryName(INVENTORY_OBJECT,0);
        // llOwnerSay("Da web mi fanno rezzare");
        llRezObject(obj, pos_orig + <0,0,2>, <0,0,0>, <0,0,0,0>, 1);
        llRegionSay(channel_avvertore,"spara");             
}
 
 
 
default
{
    state_entry()
    {
        setup();
        pos_orig = llGetPos();
    }
 
    on_rez(integer n) 
    {
        setup(); 
    }
 
    changed(integer c)
    {
        if (c & (CHANGED_REGION | CHANGED_REGION_START | CHANGED_TELEPORT) )
        {
            setup();
        }
    }
 
 
// scatta in risposta a setup() cioe' alla richiesta di un nuovo URL  
    http_request(key id, string method, string body)
    {
        // ci e' stato correttamente assegnato un nuovo URL
        if (method == URL_REQUEST_GRANTED)
        {
            url = body;
            llOwnerSay(" nuovo url = " + url);                   
            update_gridurl(body);            
        }
 
        else if (method == URL_REQUEST_DENIED)
        {
            llInstantMessage(mykey, "Something went wrong, no url. " + body);
        }
        // lo script e' stato richiamato (da un browser, cliccando su un link...)
        // fa qualcosa
        else if (method == "GET")
        {
                string asd = llGetHTTPHeader(id, "x-query-string"); 
                //llOwnerSay(" query = " + asd);         
                fa(id,asd);
        }
        else
        {
            llHTTPResponse(id,405,"Unsupported method.");
        }
    }
 
 
// comunico gli URL dello script
    touch_start(integer total_number)
    {
            llInstantMessage(mykey, "Il mio indirizzo attualmente e' " 
            + url + "  - il link permanente per utilizzarmi e' " + gridurl_indirizzo); 
    }    
 
 
 
}

Color change scripts

This listens to the first script and it changes accordingly its color. Chromutate currently uses 3 colors - just reuse the following script and change chat channel to -20242 and -20243.

default
{
    state_entry()
    {
        llListen(-20241, "", "", "");  // you may need to change this, if you changed it in the first script
    }
    listen(integer chan, string name, key id, string msg)  
    {
        llSetLinkColor(-1, (vector)msg, ALL_SIDES);
    }
}

Reflexive Architecture scripts

This listens to the first script and changes accordingly its base color. When an avatar approaches, it changes the object size and color - resuming to original parameters when avatars go away.

// Reflexive Architecture Script 1: Change Size and Color per Avatar Distance
// For Keystone Bouchard. http://www.archsl.wordpress.com for an installation on Architecture Island, September 2007. Scripted by Fumon Kubo
 
//Shared under Creative Commons Attribution-Share Alike 3.0 License
 
integer channel = -20243;
string mittente = "LOL_color_controller";
 
vector NEAR_COL = <1.0, 1.0, 0.0>;
vector FAR_COL; // = <1.0, 4.5, 0.0>;
 
vector NEAR_SIZE = <.6, 10, .6>;
vector FAR_SIZE = <4, 4, 4>;
 
 
float NEAR = 3.0;
float FAR = 9.0;
 
default
{
    state_entry()
    {
        llListen(channel, mittente, "", "");           
        llSensorRepeat("", NULL_KEY, AGENT, FAR, PI, 0.2);
        llSetScale(FAR_SIZE);
    }
 
    listen(integer chan, string name, key id, string msg)  
    {
        FAR_COL = (vector)msg;
        llSetLinkColor(-1, FAR_COL, ALL_SIDES);
    }
 
    sensor(integer total_number)
    {
        float distance = llVecMag(llDetectedPos(0) - llGetPos());
        float scale = (distance - NEAR) / (FAR - NEAR);
        if (scale < 0.0) scale = 0.0;
        llSetScale(NEAR_SIZE + ((FAR_SIZE - NEAR_SIZE) * scale));
        llSetColor(NEAR_COL + ((FAR_COL - NEAR_COL) * scale), ALL_SIDES);
    }
}