View source for LlGetLinkPrimitiveParams

{{LSL_Function
|func_id=354|func_sleep=0.0|func_energy=10.0
|func=llGetLinkPrimitiveParams|sort=GetLinkPrimitiveParams
|return_type=list
|p1_type=integer|p1_name=link|p1_desc=to get the parameters of|p1_hover=to get the parameters of
|p2_type=list|p2_name=params|p2_desc=PRIM_* flags
|func_footnote=PRIM_* flags can be broken into three categories, face flags, prim flags, and object flags.
*Supplying a prim or object flag will return that flags attributes.
*Face flags require the user to also supply a side parameter.
|func_desc=Identical to [[llGetPrimitiveParams]] except acts on the prim specified by the {{LSL Param|link}} number given.
|Return_text=of primitive attributes requested in the '''{{LSL Param|params}}''' list for '''{{LSL Param|link}}'''
|spec
|caveats=*The legacy value of PRIM_TYPE, 1, is not supported by this function as a flag{{Footnote|[[llGetPrimitiveParams]] came after PRIM_TYPE_LEGACY was deprecated.}}.
|constants={{LSL Constants/PrimitiveParams|get}}
|examples=To test whether an object is a point light source, and if so get its parameters:
<lsl>string msg = "Object is ";
integer isLight;
vector colour;
float intensity;
float radius;
float falloff;
list params = llGetLinkPrimitiveParams(LINK_THIS, [PRIM_POINT_LIGHT]);
isLight = llList2Integer(params, 0);
if (isLight == FALSE)
    msg += "not a light source.";
else
{
    colour = llList2Vector(params, 1);
    intensity = llList2Float(params, 2);
    radius = llList2Float(params, 3);
    falloff = llList2Float(params, 4);
    msg += "a point light source.\nColour = "+(string)colour;
    msg += "\nIntensity = "+(string)intensity;
    msg += "\nRadius = "+(string)radius;
    msg += "\nFalloff = "+(string)falloff;
}
llSay(0, msg);</lsl>
<lsl>//example by Kireji Haiku, simplified beyond all recognition by Strife Onizuka
//AreAllPrimsAreGlowing() returns true if all prims in the object have some glow
//(can be single or multi-prim objects)
 
integer AreAllPrimsAreGlowing()
{
    integer link = !!llGetNumberOfPrims();//root prim is either 0 or 1
    integer end = link + llGetObjectPrimCount(llGetKey());
    for(;link < end; ++link)//shame we can't use LINK_SET
        if(llListStatistics(LIST_STAT_MIN, llGetLinkPrimitiveParams(link, [PRIM_GLOW, ALL_SIDES])) <= 0.0)
            return FALSE;
    return TRUE;
}

default
{
    touch_start(integer num_detected)
    {
        if(AreAllPrimsAreGlowing())
            llSay(0, "All prims glowing.");
        else
            llSay(0, "Not all prims glowing.");
    }
}</lsl>
|helpers=<lsl>list GetLinkPrimitiveParams(integer link, list input)
{//Returns a list that can be fed to llSetPrimitiveParams
    list output;
    integer c = ~llGetListLength(input);
    while(0x80000000 & (c = - ~c))
    {
        list flag = (list)llList2Integer(input, c);
        if(~llListFindList([PRIM_BUMP_SHINY, PRIM_COLOR, PRIM_TEXTURE, 
                            PRIM_FULLBRIGHT, PRIM_TEXGEN, PRIM_GLOW], flag ))
        {
            integer side = llList2Integer(input, (c = - ~c));
            if(~side)//pop the stack
                output += flag + side + llGetLinkPrimitiveParams(link, flag + side );
            else
            {
                side = llGetLinkNumberOfSides(link);
                do //we return the sides in reverse order, easier to code; runs faster.
                    output += flag + side + llGetLinkPrimitiveParams(link, flag + (side = ~ -side) );
                while(side);
            }
        }
        else
            output += flag + llGetLinkPrimitiveParams(link, flag );
    }
    return output;
}
//Contributed by Strife Onizuka</lsl>
'''Note:''' Feeding this function a non-existent link number and a parameter with ALL_SIDES will result in an endless loop.

[[User:Anylyn_Hax#SetPrimitiveParams-Example|SetPrimitiveParams-Example]] by {{User|Anylyn Hax}} makes reading primitive parameters easy.

|also_functions=
{{LSL DefineRow||[[llSetLinkPrimitiveParamsFast]]|Set many primitive parameters without delay}}
{{LSL DefineRow||[[llSetLinkPrimitiveParams]]|Set many primitive parameters}}
{{LSL DefineRow||[[llSetPrimitiveParams]]|Set many primitive parameters}}
{{LSL DefineRow||[[llGetPrimitiveParams]]|Get many primitive parameters}}
{{LSL DefineRow||[[llGetObjectDetails]]|}}
|also_tests
|also_events
|also_articles
|notes
|cat1=Prim
|cat2=Movement
|cat3=Texture
|cat4=Status
|cat5=Object
|cat6=PrimitiveParams
|cat7=Link/Get
|cat8=Link
}}