LlScaleByFactor/ja

/ja

/LSL

ScaleByFactor

llScaleByFactor

要約

関数: integer llScaleByFactor( float scaling_factor );

?	関数ID
0.0	遅延
10.0	エネルギー

プリムのサイズと位置の比率を保持しつつ、全体のオブジェクトをscaling_factorで再サイズしようとします。

再サイズはプリムスケールの制限とリンク可能性の制限が適用されます。リンクセットが物理的である、パスファインディングキャラクターである、キーフレーム化されたモーションの一部である、またはサイズ変更によってパーセルがオーバーフローする場合、この関数はオブジェクトのサイズを変更できません。
成功するとTRUE、失敗するとFALSE。を integer で返します。

• float

scaling_factor

–

プリムサイズおよびそれらのローカル位置と一致するように使用される乗数。

警告

• 浮動小数点の精度の問題により（しばしば、sqrt(x*x) != x）、llGetMinScaleFactorおよびllGetMaxScaleFactorで返される値を使用して再スケーリングしないようにしてください。成功した再スケーリングを保証するには、これらの関数によって返される範囲内の値をわずかに使用してください。

サンプル

//  Touching this script causes the object to double or halve in size.

integer growing;

default
{
    state_entry()
    {
        llSay(PUBLIC_CHANNEL, "Touch to toggle scale.");
    }

    touch_start(integer num_detected)
    {
        growing = !growing;

        float min_factor = llGetMinScaleFactor();
        float max_factor = llGetMaxScaleFactor();

        llSay(PUBLIC_CHANNEL, "min_scale_factor = " + (string)min_factor
                            + "\nmax_scale_factor = " + (string)max_factor);

        integer success;

        if (growing) success = llScaleByFactor(2.0);
        else         success = llScaleByFactor(0.5);

        if (!success) llSay(PUBLIC_CHANNEL, "Scaling failed!");
    }
}

関連項目

関数

•	llScaleByFactor/ja
•	llGetMaxScaleFactor/ja
•	llGetMinScaleFactor/ja

特記事項

この関数はおおよそ以下と同等です：

float VectorAbsStatistics(integer flag, vector a){
    return llListStatistics(flag, [llFabs(a.x), llFabs(a.y), llFabs(a.z)]);
}

integer ScaleByFactor(float scale) {
    vector root = llGetScale() * scale;

    if (VectorAbsStatistics(LIST_STAT_MAX, root) > 64
        || VectorAbsStatistics(LIST_STAT_MIN, root) < 0.01
        || scale <= 0)
    {
        return ERR_MALFORMED_PARAMS;
    }

    integer prims = llGetNumberOfPrims();
    list set = [PRIM_LINK_TARGET, prims > 1, PRIM_SIZE, root];

    if (prims > 1) {
        list get = [];
        integer count = prims;
        do {
            get += [PRIM_LINK_TARGET, count, PRIM_SIZE, PRIM_POS_LOCAL];
        } while(--count);
        get = llGetPrimitiveParams(get);
        count = 0;
        do {
            vector size = llList2Vector(get, ++count) * scale;
            vector pos  = llList2Vector(get, ++count) * scale;

            if (VectorAbsStatistics(LIST_STAT_MAX, size) > 64
                || VectorAbsStatistics(LIST_STAT_MIN, size) < 0.01
                || VectorAbsStatistics(LIST_STAT_MAX, pos) > 54 )
            {
                return ERR_MALFORMED_PARAMS;
            }

            set += [PRIM_LINK_TARGET, prims,
                        PRIM_POS_LOCAL, pos,
                        PRIM_SIZE, size];
        } while(--prims > 1);
    }
    llSetPrimitiveParams(set);
    return TRUE;
}

経緯

• Mentioned in Simulator_User_Group/Transcripts/2013.12.10
• Mentioned in Simulator_User_Group/Transcripts/2013.12.17

Search JIRA for related Issues

Signature
function integer llScaleByFactor( float scaling_factor );

この翻訳は 原文 と比べて古いですか？間違いがありますか？読みにくいですか？みんなで 修正 していきましょう！ (手順はこちら)

この項目はあなたにとって参考にならない項目ですか？もしかしたらLSL Wikiの関連した項目が参考になるかもしれません。