llGetSubString

Template:Needs Translation/LSL/de Template:Needs Translation/LSL/es Template:Needs Translation/LSL/el Template:Needs Translation/LSL/he Template:Needs Translation/LSL/it Template:Needs Translation/LSL/nl Template:Needs Translation/LSL/hu Template:Needs Translation/LSL/no Template:Needs Translation/LSL/da Template:Needs Translation/LSL/sv Template:Needs Translation/LSL/tr Template:Needs Translation/LSL/pl Template:Needs Translation/LSL/pt Template:Needs Translation/LSL/ru Template:Needs Translation/LSL/th Template:Needs Translation/LSL/uk Template:Needs Translation/LSL/zh-Hans Template:Needs Translation/LSL/zh-Hant

/LSL

GetSubString

llGetSubString

Summary

Function: string llGetSubString( string src, integer start, integer end );

0.0	Forced Delay
10.0	Energy

Returns a string that is the substring of src from start to end, leaving the original string intact.

• string	src
• integer	start	–	start index
• integer	end	–	end index

start & end support negative indexes.

Specification

Index	Positive	Negative
First	0	-length
Last	length - 1	-1

Indexes

• Positive indexes count from the beginning, the first item being indexed as 0, the last as (length - 1).

• Negative indexes count from the far end, the first item being indexed as -length, the last as -1.

Caveats

• If either start or end are out of bounds the script continues to execute without an error message.
• start & end will form an exclusion range when start is past end (Approximately: start > end).

Examples

default
{
    state_entry()
    {
        string word = "Hello!";
        llOwnerSay(llGetSubString(word, 0, 0));
        // Object: H
        llOwnerSay(llGetSubString(word, -1, -1));
        // Object: !
        llOwnerSay(llGetSubString(word, 2, 3));
        // Object: ll
    }
}

// display SL time using a script without an 'if'
default
{
    state_entry()
    {
        // synchronise our clock to a fraction of a second
        float fnow = llGetWallclock();
        while (fnow == llGetWallclock() )   ;   // await a change in seconds

        llSetTimerEvent(1.0);
    }

    timer()
    {
        integer seconds = (integer) llGetWallclock();
        integer minutes = seconds / 60;
        seconds = seconds % 60;
        integer hours = minutes / 60;
        minutes = minutes % 60;

        string stringHours   = llGetSubString("0" + (string)hours,   -2, -1);
        string stringMinutes = llGetSubString("0" + (string)minutes, -2, -1);
        string stringSeconds = llGetSubString("0" + (string)seconds, -2, -1);

        string time = stringHours + ":" + stringMinutes + ":" + stringSeconds;

        llSetText(time, <1.0, 1.0, 1.0>, 1.0);
    }
}

Notes

Ranges & Indexes

The easiest way to explain how ranges work is to make all indexes positive. Negative indexes are just a way of counting from the tail end instead of the beginning, all negative indexes have a corresponding equivalent positive index (assuming they are in range). Positive indexes past length (after the last index), or negative indexes past the beginning (before the first index) are valid and the effects are predictable and reliable: the entries are treated as if they were there but were removed just before output.

• If start <= end then the range operated on starts at start and ends at end. [start, end]
• Exclusion range: If start > end then the range operated on starts at 0 and goes to end and then starts again at start and goes to -1. [0, end] + [start, -1]
  • If end is a negative index past the beginning, then the operating range would be [start, -1].
  • If end is a positive index past the end, then the operating range would be [0, end].
  • If both start and end are out of bounds then the function would have no operating range (effectively inverting what the function is supposed to do).

See negative indexes for more information. The counting of the characters starts at 0. Using 0,0 as start and end positions would return the first character only. Using negative numbers causes backwards counting, so -1 is shortform for the last character in a string. Ergo, using 0, -1 as start and end positions would return the entire string.

To ascertain how long a string is, use llStringLength.

See Also

Functions

•	llReplaceSubString
•	llDeleteSubString
•	llInsertString

Articles

•	Negative Index
•	CombinedLibrary: str_replace

Deep Notes

Signature
function string llGetSubString( string src, integer start, integer end );

Haiku

Half a bee buzzing Flying through the air so free With half of its wings Generated by the AI Haiku Generator inspired by the Monty Python song Eric the Half a Bee, which starts with: Half a bee, philosophically Must, ipso facto, half not be But half the bee has got to be A vis-a-vis its entity, you see? But can a bee be said to be Or not to be an entire bee When half the bee is not a bee Due to some ancient injury? If it's not obvious, my twisted mind tried to explain, using analogies, that part of a string extracted from a string is, indeed, a string too; half a string is also a string. Unless you make a serious mistake, that is. — Gwyneth Llewelyn (talk) 07:55, 15 October 2023 (PDT)