User:Fred Gandt/Scripts/Functions

My Contributions

I have implemented a V# system to make it more obvious if a function is updated. The V# forms part of the title of each function.

If you have any comments about the content of this page please post them HERE

All my scripting is written for compilation as MONO

More Pages

Free Scripts (content constantly updating)

More Free Scripts (content constantly updating)

Even More Free Scripts (content constantly updating)

Even More More Free Scripts (content constantly updating)

Even More More More Free Scripts (content constantly updating)

Functions for specific tasks (this page)

Legal Stuff

The legal stuff about contributing to this wiki (worth reading).

PJIRA Issue Tracker

The issues I have filed on the PJIRA

Tuition

Tuition scripts, notes, videos and screenshots etc. (hardly any content yet)

Functions

Here is some stuffs wot does fings

GetUniqueListEntries ( V1 )

Feed a list in and get out a list which contains no duplicate entries. Nice and fast.

<lsl>// V1 //

list GetUniqueListEntries(list src) {

   integer index = 0;
   list output = [];
   list entry = [];
   do
   {
       output += (entry = llList2List(src, 0, 0));
       src = llDeleteSubList(src, 0, 0);
       while((index = llListFindList(src, entry)) != -1)
       src = llDeleteSubList(src, index, index);
   }
   while(llGetListLength(src));
   return output;

}</lsl>

MultiListReplace ( V1 )

Replace entries in a list with other entries.

<lsl>// V1 //

list MultiListReplace(list src, list thisnthats) {

   integer index = 0;
   integer lc = 0;
   integer ll = llGetListLength(thisnthats);
   do
   {
       list this = llList2List(thisnthats, lc, lc);
       ++lc;
       while((index = llListFindList(src, this)) != -1)
       src = llListReplaceList(src, llList2List(thisnthats, lc, lc), index, index);
   }
   while((++lc) < ll);
   return src;

}

// Usage Example //

list source = ["How", "much", "wood", "would", "a", "woodchuck", "chuck", "if", "a", "woodchuck", "could", "chuck", "wood", "?"];

default {

   state_entry()
   {
       llOwnerSay(llDumpList2String(MultiListReplace(source, ["woodchuck", "primrezzer", "much", "many", "wood", "prims", "chuck", "rez"]), " "));
       // Return == "Object: How many prims would a primrezzer rez if a primrezzer could rez prims ?"
   }

}</lsl>

MultiStringReplace ( V3 )

Replace parts of a string with other strings.

<lsl>// V3 //

string MultiStringReplace(string src, list thisnthats) {

   integer index = 0;
   integer lc = 0;
   integer ll = llGetListLength(thisnthats);
   do
   {
       string this = llList2String(thisnthats, lc);
       ++lc;
       while((index = llSubStringIndex(src, this)) != -1)
       src = llInsertString(llDeleteSubString(src, index, (index + (llStringLength(this) - 1))),
                            index, llList2String(thisnthats, lc));
   }
   while((++lc) < ll);
   return src;

}

// Usage Examples //

string source = "How much wood would a woodchuck chuck if a woodchuck could chuck wood?";

default {

   state_entry()
   {
       llOwnerSay(MultiStringReplace(source, ["woodchuck", "primrezzer", "much", "many", "wood", "prims", "chuck", "rez"]));
       // Return == "Object: How many prims would a primrezzer rez if a primrezzer could rez prims?"
       
       llOwnerSay(MultiStringReplace(source, ["much", "many", "wood", "prims", "woodchuck", "primrezzer", "chuck", "rez"]));
       // Return == "Object: How many prims would a primsrez rez if a primsrez could rez prims?"
       
       llOwnerSay(MultiStringReplace(source, ["farmers", "primrezzer", "much", "many", "wood", "prims", "chuck", "rez"]));
       // Return == "Object: How many prims would a primsrez rez if a primsrez could rez prims?"
       
       llOwnerSay(MultiStringReplace(source, ["much", "many", "wood", "prims", "farmers", "primrezzer", "chuck", "rez"]));
       // Return == "Object: How many prims would a primsrez rez if a primsrez could rez prims?"
       
       llOwnerSay(MultiStringReplace(source, ["woodchuck", "primrezzer", "much", "many", "wood", "prims", "farmers", "piggies", "chuck", "rez"]));
       // Return == "Object: How many prims would a primrezzer rez if a primrezzer could rez prims?"
   }

}</lsl>

StrideOfList ( V1 )

Get strided entries from a list. And yes, I know about llList2ListStrided. Frankly, this works better.

<lsl>// V1 //

list StrideOfList(list src, integer stride, integer start, integer end) {

   list l = [];
   integer ll = llGetListLength(src);
   if(start < 0)start = (ll + start);
   if(end < 0)end = (ll + end);
   if(end < start) return llList2List(src, start, start); // Better than nothing.
   while(start <= end)
   {
       l += llList2List(src, start, start);
       start += stride;
   }
   return l;

}

// Usage Examples //

list source = ["How", "much", "wood", "would", "a", "woodchuck", "chuck", "if", "a", "woodchuck", "could", "chuck", "wood?"];

default {

   state_entry()
   {
       llOwnerSay(llDumpList2String(StrideOfList(source, 1, 0, -1), ", "));
       // Return == "Object: How, much, wood, would, a, woodchuck, chuck, if, a, woodchuck, could, chuck, wood?"

       llOwnerSay(llDumpList2String(StrideOfList(source, 2, 0, -2), ", "));
       // Return == "Object: How, wood, a, chuck, a, could"

       llOwnerSay(llDumpList2String(StrideOfList(source, 4, 3, -1), ", "));
       // Return == "Object: would, if, chuck"

       llOwnerSay(llDumpList2String(StrideOfList(source, 5, 0, -4), ", "));
       // Return == "Object: How, woodchuck"

       llOwnerSay(llDumpList2String(StrideOfList(source, 3, 6, -7), ", "));
       // Return == "Object: chuck"
       
       llOwnerSay(llDumpList2String(StrideOfList(source, 3, 7, -7), ", "));
       // Return == "Object: How, much, wood, would, a, woodchuck, chuck, if, a, woodchuck, could, chuck, wood?"
   }

}</lsl>