LlSameGroup

From Second Life Wiki
Jump to: navigation, search

Summary

Function: integer llSameGroup( key uuid );

Returns an integer boolean, that is TRUE if uuid has the same active group, otherwise FALSE

• key uuid group, avatar or prim UUID that is in the same region

Also returns TRUE if the object is deeded to the same active group as uuid Also returns TRUE if the object is "set to" or deeded to the same group as group UUID (i.e. key OBJECT_GROUP)

Caveats

  • Also returns TRUE if the object is not set to a group (i.e. "(none)") and either the AV with the given key has no group active or the function is called with a NULL_KEY

Important Issues

~ All Issues ~ Search JIRA for related Bugs
   Attachments only change/inherit the active group when they're "rezzed"

Examples

// Gives inventory object only to agents with the same active group
 
default
{
    touch_start(integer total_number)
    {
        key id = llDetectedKey(0);
 
        integer sameGroup = llSameGroup(id);
//      same as llDetectedGroup(i) (with llDetectedGroup, detected does not need to be in the sim)
 
        if (sameGroup)
        {
            integer numberOfObjectsInPrim = llGetInventoryNumber(INVENTORY_OBJECT);
 
            if (numberOfObjectsInPrim)
                llGiveInventory(id, llGetInventoryName(INVENTORY_OBJECT, 0));
        }
        else
        {
            llRegionSayTo(id, 0, "Wrong active group!");
        }
    }
}

Useful Snippets

To determine if an avatar is an object's owner when deeded to group, you should use a function similar to that provided for llGetOwner().

The following uses llSameGroup() to determine if a parcel is rezzable based on the object's active group and parcel details. Useful for preventing unnecessary rez failure notices from various types of attached objects (e.g. guns, water/skywalk HUDs, etc).

/*
  By Aryn Gellner
  pos - position (in region coordinates) to check against.
*/
 
integer is_rezzable(vector pos)
{
    key group_id = llList2Key(llGetParcelDetails(pos, [PARCEL_DETAILS_GROUP]), 0);
 
    integer parcel_flags = llGetParcelFlags(pos);
 
    if(parcel_flags & PARCEL_FLAG_ALLOW_CREATE_OBJECTS)
    {
        return TRUE;
    }
    else if((parcel_flags & PARCEL_FLAG_ALLOW_CREATE_GROUP_OBJECTS) && llSameGroup(group_id))
    {
        return TRUE;
    }
    else
    {
        return FALSE;
    }
}

Notes

Child Prims

It is possible for the group of a child prim to differ from that of the root prim. To build such an object it must first be unlinked, the groups set, and then relinked. Rezzing an objects resets the group of the object to that of the group that the user currently has activated. Changing the group of an object changes the group for the entire object. This may only be an artifact or manifestation of VWR-5044.

See Also

Functions

•  llDetectedGroup Used in conjunction with detection events

Deep Notes

All Issues

~ Search JIRA for related Issues
   Attachments only change/inherit the active group when they're "rezzed"

Tests

•  llSameGroup Test

Signature

function integer llSameGroup( key uuid );

Haiku

Do you belong or
Are you alien, unknown
To us, unwanted?