At target/ja

From Second Life Wiki
Jump to: navigation, search

説明

イベント: at_target( integer tnum, vector targetpos, vector ourpos ){ ; }

llTarget ライブラリ関数の呼び出しで発生します。

• integer tnum llTarget の復帰値
• vector targetpos llTarget の position パラメタ
• vector ourpos 現在の位置 (llGetPos と類似)

サンプル

integer target_id;
vector target_pos;
 
default
{
    state_entry()
    {
        target_pos = llGetPos() + <1.0, 0.0, 0.0>;
        target_id = llTarget(target_pos, 0.5);
    }
    at_target(integer tnum, vector targetpos, vector ourpos)
    {
        if (tnum == target_id)
        {
            llOwnerSay("object is within range of target");
            llOwnerSay("target position: " + (string)targetpos + ", object is now at: " + (string)ourpos);
            llOwnerSay("this is " + (string)llVecDist(targetpos, ourpos) + " meters from the target");
            llTargetRemove(target_id);
        }
    }
    not_at_target()
    {
        llOwnerSay(
            "not there yet - object is at " + (string)llGetPos() + 
            ", which is " + (string)llVecDist(target_pos, llGetPos()) + 
            " meters from the target (" + (string)target_pos + ")"
        );
    }
}

参考情報

イベント

•  not_at_target
•  at_rot_target
•  not_at_rot_target

関数

•  llTarget 位置目標を登録します
•  llTargetRemove 位置目標を登録解除します
•  llRotTarget 回転目標を登録します
•  llRotTargetRemove 回転目標を登録解除します
この翻訳は 原文 と比べて古いですか?間違いがありますか?読みにくいですか?みんなで 修正 していきましょう! (手順はこちら)
この項目はあなたにとって参考にならない項目ですか?もしかしたらLSL Wikiの関連した項目が参考になるかもしれません。