LlRequestPermissions

Ask agent for permission to run certain classes of functions.

• Scripts may hold permissions for only one agent at a time. To hold permissions for multiple agents you must use more then one script.

Request permission to animate an avatar

default
{
    touch_start(integer detected)
    {
        llRequestPermissions(llDetectedKey(0), PERMISSION_TRIGGER_ANIMATION);
    }
    run_time_permissions(integer perm)
    {
        if (perm & PERMISSION_TRIGGER_ANIMATION)
        {
            llStartAnimation("sit");
            llOwnerSay("animation will end in 5 seconds");
            llSetTimerEvent(5.0);
        }
    }
    timer()
    {
        llSetTimerEvent(0.0);
        llStopAnimation("sit");
    }
}

To request two (or more) different permissions at the same time you can using the bitwise OR (|) or precompute the value.

llRequestPermissions(AvatarID, PERMISSION_TAKE_CONTROLS | PERMISSION_TRIGGER_ANIMATION);
 
integer perms = PERMISSION_TAKE_CONTROLS | PERMISSION_TRIGGER_ANIMATION;
llRequestPermissions(AvatarID, perms);

A dialog is presented to the agent to grant these permissions except for a few cases:

• If agent is sitting on object - Control and Camera tracking permissions are granted without notification upon request.
• If object is attached to agent - Control, Attach, and Animate permissions are granted without notification upon request so long as the script is in the root prim. If the script is not in the root prim, the user will see the confirmation dialog.
• Permissions can persist across state changes - You do not need to request permissions in the state_entry() of each state in your script.

Regardless if a dialog is displayed you should always use the run_time_permissions event instead of depending upon this quirk.

Events

Functions

Articles