LlList2ListStrided

Template:Needs Translation/LSL/de Template:Needs Translation/LSL/es Template:Needs Translation/LSL/el Template:Needs Translation/LSL/he Template:Needs Translation/LSL/it Template:Needs Translation/LSL/ko Template:Needs Translation/LSL/nl Template:Needs Translation/LSL/hu Template:Needs Translation/LSL/no Template:Needs Translation/LSL/da Template:Needs Translation/LSL/sv Template:Needs Translation/LSL/tr Template:Needs Translation/LSL/pl Template:Needs Translation/LSL/pt Template:Needs Translation/LSL/ru Template:Needs Translation/LSL/th Template:Needs Translation/LSL/uk Template:Needs Translation/LSL/zh-Hans Template:Needs Translation/LSL/zh-Hant

/LSL

List2ListStrided

llList2ListStrided

Summary

Function: list llList2ListStrided( list src, integer start, integer end, integer stride );

0.0	Forced Delay
10.0	Energy

Returns a list of all the entries in the strided list whose index is a multiple of stride in the range start to end.

• list	src
• integer	start	–	start index
• integer	end	–	end index
• integer	stride

start & end support negative indexes.

Specification

Index	Positive	Negative
First	0	-length
Last	length - 1	-1

Indexes

• Positive indexes count from the beginning, the first item being indexed as 0, the last as (length - 1).

• Negative indexes count from the far end, the first item being indexed as -length, the last as -1.

Caveats

• If either start or end are out of bounds the script continues to execute without an error message.
• start & end will form an exclusion range when start is past end (Approximately: start > end).

Examples

<lsl>list mylist = [0,1,2,3,4,5,6]; list result_a = llList2ListStrided(mylist,0,-1,2); //start at first item in list, go to the end, return every 2nd item //result_a == [0,2,4,6]

list result_b = llList2ListStrided(mylist,1,-1,2); //start at second item in list, go to the end, return every 2nd item //result_b == [2,4,6]

list result_c = llList2ListStrided(mylist,2,-1,2); //start at third item in list, go to the end, return every 2nd item //result_c == [2,4,6]</lsl>

<lsl>list menu = ["1", "one", "2", "two", "3", "three"]; default {

   state_entry()
   {
       llListen(10, "", llGetOwner(), "");
   }
   touch_start(integer detected)
   {
       list buttons = llList2ListStrided(menu, 0, -1, 2);
       llDialog(llDetectedKey(0), "choose a number", buttons, 10);
   }
   listen(integer channel, string obj, key id, string message)
   {
       integer index = llListFindList(menu, [message]);
       if (index != -1)
       {
           llOwnerSay("you chose " + llList2String(menu, index + 1) + " (" + message + ")");
       }
   }

}</lsl>

Useful Snippets

• StrideOfList - Starting from start and stopping before end exceeded it skips every stride-1 items. start item is always returned.

Notes

Ranges & Indexes

The easiest way to explain how ranges work is to make all indexes positive. Negative indexes are just a way of counting from the tail end instead of the beginning, all negative indexes have a corresponding equivalent positive index (assuming they are in range). Positive indexes past length (after the last index), or negative indexes past the beginning (before the first index) are valid and the effects are predictable and reliable: the entries are treated as if they were there but were removed just before output.

• If start <= end then the range operated on starts at start and ends at end. [start, end]
• Exclusion range: If start > end then the range operated on starts at 0 and goes to end and then starts again at start and goes to -1. [0, end] + [start, -1]
  • If end is a negative index past the beginning, then the operating range would be [start, -1].
  • If end is a positive index past the end, then the operating range would be [0, end].
  • If both start and end are out of bounds then the function would have no operating range (effectively inverting what the function is supposed to do).

See negative indexes for more information. To get every first element in a "collection of data" in a strided list:

<lsl>list ListStridedFirstElement(list src, integer start, integer end, integer stride) {

    //start must be a multiple of stride or you won't get the first element of the stride.
    return llList2ListStrided(llList2List(src, start, end), 0, -1, stride);

}</lsl>

To get every second element in a "collection of data" in a strided list (that is to say, the second element of each stride): <lsl>list src = [1,2,3,4,5,6,7,8,9,10,11,12];

list result2 = llList2ListStrided(llDeleteSubList(src, 0, 0), 0, -1, 2);//stride of 2 //result2 == [2,4,6,8,10,12]

list result3 = llList2ListStrided(llDeleteSubList(src, 0, 0), 0, -1, 3);//stride of 3 //result3 == [2,5,8,11]

list result4 = llList2ListStrided(llDeleteSubList(src, 0, 0), 0, -1, 4);//stride of 4 //result4 == [2,6,10]</lsl>

See Also

Articles

•

Negative Index

Deep Notes

Signature
function list llList2ListStrided( list src, integer start, integer end, integer stride );