LlSubStringIndex

Template:Needs Translation/LSL/de Template:Needs Translation/LSL/es Template:Needs Translation/LSL/el Template:Needs Translation/LSL/he Template:Needs Translation/LSL/it Template:Needs Translation/LSL/ko Template:Needs Translation/LSL/nl Template:Needs Translation/LSL/hu Template:Needs Translation/LSL/no Template:Needs Translation/LSL/da Template:Needs Translation/LSL/sv Template:Needs Translation/LSL/tr Template:Needs Translation/LSL/pl Template:Needs Translation/LSL/pt Template:Needs Translation/LSL/ru Template:Needs Translation/LSL/th Template:Needs Translation/LSL/uk Template:Needs Translation/LSL/zh-Hans Template:Needs Translation/LSL/zh-Hant

/LSL

SubStringIndex

llSubStringIndex

Summary

Function: integer llSubStringIndex( string source, string pattern );

0.0	Forced Delay
10.0	Energy

Returns an integer that is the index of pattern in source.

• string	source
• string	pattern

If pattern is not found in source, -1 is returned.
The index of the first character in the string is 0

Caveats

• Performs a literal match (case sensitive).
  • Wildcards and RegEx are not supported.
• Attempting to match an empty string ("") will return 0 instead of -1.

Examples

Matching against last names:

default
{
    state_entry()
    {
        llSensorRepeat("", NULL_KEY, AGENT, PI, 96.0, 20);
    }
    
    sensor(integer NumDet)
    {
        integer i;
        
        //Loop through all the sensor data and match against " Linden", 
        //this causes it to match with any last name of Linden (since there can't be spaces before the firstname)
        //Alternatively you could match a firstname with "FirstName "
        for(i = 0; i < NumDet; ++i)
            if(~llSubStringIndex(llDetectedName(i), " Linden"))
                llInstantMessage(llDetectedKey(i), "Hello, I see you!");
    }
}

Useful Snippets

Easy ways to see if a string exists in another string...

1. Correct at a glance and drearily conventional:

integer contains(string haystack, string needle) // http://wiki.secondlife.com/wiki/llSubStringIndex
{
    return 0 <= llSubStringIndex(haystack, needle);
}

2. Smaller (~54 bytes rather than ~60):

integer contains(string haystack, string needle) // http://wiki.secondlife.com/wiki/llSubStringIndex
{
    return ~llSubStringIndex(haystack, needle);
}

Note: The llSubStringIndex function returns -1 only when not found and the ~ operator returns zero only for -1, so the arcane combination ~llSubStringIndex returns zero only for not found, else nonzero for found.

Note: Smaller was not noticeably faster when our Code Racer and Efficiency Tester harnesses measured the expression { contains("wiki.secondlife.com", "wiki"); }.

integer startswith(string haystack, string needle)
{
	return (0 == llSubStringIndex(haystack,needle));
}

NOTE: This function doesn't use llSubStringIndex

integer endswith(string haystack, string needle)
{
	return (llGetSubString(haystack,llStringLength(haystack)-llStringLength(needle),-1) == needle);
}

See Also

Functions

•

llListFindList

–

Find a list in another list

Deep Notes

Signature
function integer llSubStringIndex( string source, string pattern );