llDetectedTouchST

Template:Needs Translation/LSL/de Template:Needs Translation/LSL/es Template:Needs Translation/LSL/el Template:Needs Translation/LSL/fr Template:Needs Translation/LSL/he Template:Needs Translation/LSL/it Template:Needs Translation/LSL/ko Template:Needs Translation/LSL/nl Template:Needs Translation/LSL/hu Template:Needs Translation/LSL/no Template:Needs Translation/LSL/da Template:Needs Translation/LSL/sv Template:Needs Translation/LSL/tr Template:Needs Translation/LSL/pl Template:Needs Translation/LSL/pt Template:Needs Translation/LSL/ru Template:Needs Translation/LSL/th Template:Needs Translation/LSL/uk Template:Needs Translation/LSL/zh-Hans Template:Needs Translation/LSL/zh-Hant

/LSL

DetectedTouchST

llDetectedTouchST

Summary

Function: vector llDetectedTouchST( integer index );

0.0	Forced Delay
10.0	Energy

Returns a vector that is the surface coordinates for where the prim was touched. The x & y vector positions contain the horizontal (s) & vertical (t) face coordinates respectively (<s, t, 0.0>). Each component is in the interval [0.0, 1.0] with the origin in the bottom left corner.^[1]

TOUCH_INVALID_TEXCOORD is returned when the surface coordinates cannot be determined. See Caveats for further details.

• integer

index

–

Index of detection information

index does not support negative indexes. For the touch category of events only. The prim that was touched may not be the prim receiving the event, use llDetectedLinkNumber to check for this; likewise you can use llDetectedTouchFace to determine which face was touched.

Caveats

• If index is out of bounds the script continues to execute without an error message.
• TOUCH_INVALID_TEXCOORD is returned when...
  • The avatar's viewer does not support face touch detection.
    • To check if face touch detection is supported check the return of llDetectedTouchFace.
  • The touch has moved off the surface of the prim.
  • The touch happened too close to the edge of the face to determine a location.
  • The event triggered is not a touch event.

Examples

<lsl> default {

   touch_start(integer total_number)
   {
       integer touchFace = llDetectedTouchFace(0);
       vector  touchST   = llDetectedTouchST(0);

// ZERO_VECTOR (<0.0, 0.0, 0.0> ... the origin) is in the bottom left corner of the face // touchST.x goes across the face from the left to the right // touchST.y goes up the face from the bottom to the top

       if (touchFace == -1)
           llWhisper(PUBLIC_CHANNEL, "Sorry, your viewer doesn't support touched faces.");
       else if (touchST == TOUCH_INVALID_TEXCOORD)
           llWhisper(PUBLIC_CHANNEL, "Sorry, the touch position upon the face could not be determined.");
       else
           llSay(PUBLIC_CHANNEL, "llDetectedTouchST(0) = " + (string)touchST
                   + "\ntouchST.x = " + (string)touchST.x
                   + "\ntouchST.y = " + (string)touchST.y);
   }

} </lsl> <lsl> integer numberOfRows = 12; integer numberOfColumns = 12;

default {

   touch_start(integer total_number)
   {
       vector  touchST     = llDetectedTouchST(0);

// ZERO_VECTOR (<0.0, 0.0, 0.0> ... the origin) is in the bottom left corner of the face // touchST.x goes across the face from the left to the right // touchST.y goes up the face from the bottom to the top

       integer columnIndex = (integer) (touchST.x * numberOfColumns);
       integer rowIndex    = (integer) (touchST.y * numberOfRows);
       integer cellIndex   = (rowIndex * numberOfColumns) + columnIndex;

       llSay(PUBLIC_CHANNEL, "ST grid (" + (string)columnIndex + ", " + (string)rowIndex
                           + ") --> cell " + (string)cellIndex);
   }

} </lsl> <lsl> // with friendly permission of Supremius Maximus // who made the texture used in this script // // click&hold the mouse while dragging across // the face of the prim

default {

   touch(integer num_detected)
   {
       integer link    = llDetectedLinkNumber(0);
       integer face    = llDetectedTouchFace(0);
       vector  touchST = llDetectedTouchST(0);

// ZERO_VECTOR (<0.0, 0.0, 0.0> ... the origin) is in the bottom left corner of the face // touchST.x goes across the face from the left to the right // touchST.y goes across the face from the bottom to the top

       string uuid = "23badbe7-6d8c-639b-0131-bb321f8e9db5";

       llSetLinkPrimitiveParamsFast(link, [
           PRIM_TEXTURE, face, uuid, <1.0, 1.0, 0.0>, touchST, 0,
           PRIM_FULLBRIGHT, ALL_SIDES, TRUE]);
   }

}

</lsl>

See Also

Events

•	touch_start
•	touch
•	touch_end

Functions

•	llDetectedLinkNumber
•	llDetectedTouchFace
•	llDetectedTouchUV
•	llDetectedTouchPos
•	llDetectedTouchNormal
•	llDetectedTouchBinormal

Articles

•

Detected

Deep Notes

History

• Introduced in Viewer SVN:870 r92872 Branch:Release Wednesday, 23 July 2008, Supported by Beta Server 1.24.0.93754 (Wenesday 6th August 2008), and viewer binary 1.20.15 (93532).
• Date of Release 16-10-2008

Footnotes

1. ^ The ranges in this article are written in Interval Notation.

Signature
function vector llDetectedTouchST( integer index );