Difference between revisions of "LlGetAnimation"

From Second Life Wiki
Jump to: navigation, search
m
m
Line 8: Line 8:
 
|caveats=*This function can return an empty string while the avatar is logging out.
 
|caveats=*This function can return an empty string while the avatar is logging out.
 
*New return values could conceivably be added at any time and this list may not in-fact be complete. Scripts should be written under the assumption that they may receive a value they won't recognize.
 
*New return values could conceivably be added at any time and this list may not in-fact be complete. Scripts should be written under the assumption that they may receive a value they won't recognize.
|constants={{{!}}
+
|constants={{{!}} id="Constants"
 
{{!}}+ '''Complete list of return values as of August 15, 2011.'''{{Footnote|With the successful conclusion of {{jira|SCR-26}}, a complete list of values was posted; however no indication was given as to which of the previously undocumented codes are active but just uncommon.|With the successful conclusion of SCR-26, a complete list of values was posted; however no indication was given as to which of the previously undocumented codes are active but just uncommon.}}
 
{{!}}+ '''Complete list of return values as of August 15, 2011.'''{{Footnote|With the successful conclusion of {{jira|SCR-26}}, a complete list of values was posted; however no indication was given as to which of the previously undocumented codes are active but just uncommon.|With the successful conclusion of SCR-26, a complete list of values was posted; however no indication was given as to which of the previously undocumented codes are active but just uncommon.}}
 
{{!}}-valign="top"
 
{{!}}-valign="top"

Revision as of 09:44, 30 September 2011

Summary

Function: string llGetAnimation( key id );

Returns a string that is the name of the currently playing locomotion animation for avatar id. See the table below.

• key id avatar UUID that is in the same region

llGetAgentInfo provides information on some animation states not covered by this function (typing, away, busy). llGetAnimationList provides more detailed information about the running animations, but may not reflect avatar state as accurately as llGetAnimation.

Complete list of return values as of August 15, 2011.[1]
Common/Active values
Value Description
"" During logout
"Crouching"
"CrouchWalking"
"Falling Down"
"Flying"
"FlyingSlow"
"Hovering"
"Hovering Down"
"Hovering Up"
"Jumping" While still in the air during a jump.
"Landing" When landing from a jump.
"PreJumping" At the beginning of a jump.
"Init" At login and after teleports.
"Running"
"Sitting" Sitting on an object (and linked to it).
"Sitting on Ground" Sitting, but not linked to an object.[2]
"Standing"
"Standing Up" After falling a great distance. Sometimes referred to as Hard Landing.
"Striding" When the avatar is stuck on the edge of an object or on top of another avatar.
"Soft Landing" After falling a small distance.
"Taking Off"
"Turning Left"
"Turning Right"
"Walking"
Uncommon/Inactive return values
Value Description
"Crouch"
"Epsilon"
"Fall Down Land"
"Finish Animation"
"Fly"
"FlySlow"
"Hard Land"
"Hover Down"
"Hover Up"
"Hover"
"Medium Land"
"PreFlying"
"PreJump"
"Prep For Teleport"
"Run"
"Sit on Ground"
"Sit"
"Soft Land"
"Stand"
"Stride"
"Take Off"
"Turn Done"
"Turn Left"
"Turn Right"
"Uncrouch"
"Walk"

Caveats

  • This function can return an empty string while the avatar is logging out.
  • New return values could conceivably be added at any time and this list may not in-fact be complete. Scripts should be written under the assumption that they may receive a value they won't recognize.
All Issues ~ Search JIRA for related Bugs

Examples

<lsl> // A simple animation override example. // Make the avatar run in mid-air when jumping.

key gOwner; // the wearer's key string gLastAnimation; // last llGetAnimation value seen

// User functions

Initialize(key id) {

   if (id == NULL_KEY) { // detaching
       llSetTimerEvent(0.0); // stop the timer
   }
   else { // attached, or reset while worn
       llRequestPermissions(id, PERMISSION_TRIGGER_ANIMATION);
       gOwner = id;
   }

}


// Event handlers

default {

   state_entry() {
       // in case the script was reset while already attached
       if (llGetAttached() != 0) {
           Initialize(llGetOwner());
       }
   }
   attach(key id) {
       Initialize(id);
   }
   run_time_permissions(integer perm) {
       if (perm & PERMISSION_TRIGGER_ANIMATION) {
           llSetTimerEvent(0.25); // start polling
       }
   }
   timer() {
       string newAnimation = llGetAnimation(gOwner);
       if (gLastAnimation != newAnimation) { // any change?
           if (newAnimation == "Jumping") {
               
               // You can stop the built-in animation if you like, if
               // it might interfere with your own. Be aware that an
               // avatar can become stuck, and some llGetAgentInfo results
               // can be inaccurate, if you stop built-ins indiscriminately.
               // Always test.
               //
               // llStopAnimation("jump");
   
               llStartAnimation("run");
           }
           else if (gLastAnimation == "Jumping")  { // just finished jumping
               // "run" is looped, so we have to stop it when we are done.
               llStopAnimation("run");
           }
           
           gLastAnimation = newAnimation; // store away for  next time
       }
   }

}

</lsl>

See Also

Functions

•  llGetAgentInfo
•  llGetAnimationList

Deep Notes

Search JIRA for related Issues

Footnotes

  1. ^ With the successful conclusion of SCR-26, a complete list of values was posted; however no indication was given as to which of the previously undocumented codes are active but just uncommon.
  2. ^ "Sit down" on the avatar context menu allows ground sits anywhere: atop the terrain, objects or even in the air.

Signature

function string llGetAnimation( key id );